{Change Comments ***********************************************************}

{6/19/89
Copied & modified: GE 1050 LeBlonde Rgl L033.55
For: Schober's
Machine: LeBlond Universal 12/12 Mark II
Control: GE 1050T P.C.I. Mark Century
JR}

{10/25/89, Updated: GE 1050T LeBlonde L105.59, JR}
{4/6/90, Updated: GE 1050T LeBlonde L105.60, to .69.3 format, JR}
{7/24/90, Added InitProg globally to posts with this remark, DWB}
{9/24/91, Updated GE 1050T LeBlonde L105.70 to .80 format, JR}

{12/12/91
Modified: GE 1050T LeBlonde L105.80
For: Gibbs & Associates
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82 Format.
Rapid is not used, Feed outputs 'G21', CWArc outputs 'G23' and CCWArc outputs 'G22'.
No Canned Cycles supported.
DWB}

{5/8/97
Updated: GE 1050T LeBlonde L105.82
Created: GE 1050T LeBlonde L105.85
For: Gibbs & Associates/General Tool
Versions: Catalyst v3.33C/ComPost2 MSL 68K
Updated for Catalyst v3.25C per Fanuc 10T MS [-] L001.85.02b Format.
DWB}

{12/19/97
Updated: GE 1050T LeBlonde L105.85
Created: GE 1050T LeBlonde L105.85.1
For: Gibbs & Associates/General Tool/General Hone Corporation
Versions: Catalyst v4.21.30(mac)/ComPost2 1.1b3
Updated for Catalyst v3.35C per Fanuc 10T MS [-] L001.85.02e Format.
DWB}

{1/13/98
Copied: GE 1050T LeBlonde L105.85.1
Created: GE 1050T LB Knght [GH] L691.85
For: General Hone Corporation
Machine: LeBlonde Knight 30
Control: GE 1050T
Versions: Catalyst v4.21.30(mac)/ComPost2 1.1b3
Changes made per Dave Kauffman of General Hone Corporation, phone calls, G200B5701.VNC,
L691.85 Test, L691.85 V Tool & Gear, L691.85 Tool & Gear.
Changed Seq to 'N' Operation# '00' at FirstOperation and NewTool.
Added 'N' Operation# '00' EOL at SameTool.
Changed Spindle Forward from M03 to M04 in Compost2 Spindle and Coolant Dialog.
Changed Spindle Reverse from M04 to M03 in Compost2 Spindle and Coolant Dialog.
Changed to Diameter Output.
Changed to Decimal Output.
Added support for Front and Back Turret.
Front Turret set to PosSideLathe.
Front Turret consists of Tools 1 through 6.
Back Turret set to NegSideLathe.
Back Turret consists of Tools 11 through 16.
Changed from G95 RapidF, G21, G22 and G23 style to G00, G01, G02 and G03 style.
Deleted NullFoot ASCII(4) at end of Prog.
Made other changes per customer requests.
DWB}

{2/11/98
Modified: GE 1050T LB Knght [GH] L691.85
Created: GE 1050T LB Kngt [GH] L691.85.1
For: General Hone Corporation
Versions: Catalyst v4.21.30(mac)/ComPost2 1.1b3
Changes made per Dave Kauffman of General Hone Corporation, phone calls.
Changed $ to Address O in Program ID Label Edit Field in Compost2 General Info Dialog.
Added ###0 to FORMAT for Address O in Compost2 Default Formats Dialog.
Added ProgID1 at FirstOperation.
Customer requested that all Line Numbers be based on Operation#.
Changed Sequence Label from N to N? in Compost2 General Info Dialog.
Changed all Seq/SeqC to SeqLab/SeqLabC throughout Prog.
Added SetOpLines sub.
Outputs 'Ś' Operation# '00' EOL
Added call to SetOpLines at FirstOperation, NewTool and SameTool.
Changed 'N' Operation# '00' to SeqLab at FirstOperation and NewTool.
Changed 'N' Operation# '00' to SeqLab ' ' at and SameTool.
Added Retag at end of Prog.
DWB}

{4/22/98
Modified: GE 1050T LB Kngt [GH] L691.85.1
Created: GE 1050T LB Kngt [GH] L691.85.2
For: General Hone Corporation
Versions: Catalyst v4.23.13(mac)/ComPost2 1.1b3
Changes made per Dave Kauffman of General Hone Corporation, fax, phone calls.
Changed FORMAT for F from #0.####;.0 to ##.####;.0 in Compost2 Default Formats.
Deleted 'S' ASCII ('18') at FirstOperation.
Deleted EOR at FirstOperation.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '##0.####;0.'
#3 = '#######0'
#4 = '###^###0'
#5 = '0.######;0.'
#6 = '0000'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(HomeX#,2)
FORMAT(HomeZ#,2)
FORMAT(NewHomeX#,2)
FORMAT(NewHomeZ#,2)
FORMAT(FirstHomeX#,2)
FORMAT(FirstHomeZ#,2)
FORMAT(SPX#,2)
FORMAT(XOpCD#,2)
FORMAT(XOpECD#,2)
FORMAT(OpExitXCP#,2)
FORMAT(Dwell#,2) {.72}
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)

{Added Subroutines *********************************************************}

GetGearRange:
IF ConstantSurfaceFeed?
IF GTEqual? SpeedSFPM# Num#('426')
'M42'
ELSE
'M41'
END
ELSE
GearRange
END
RETURN

CSSOnToCSSOn:
IF GTEqual? SpeedSFPM# Num#('426')
IF LessThan? LAST SpeedSFPM# Num#('426')
SetFlag('2')
END
ELSE
IF GTEqual? LAST SpeedSFPM# Num#('426')
SetFlag('2')
END
END
RETURN

CSSOffToCSSOn:
IF GTEqual? SpeedSFPM# Num#('426')
IF LessThan? LAST SpeedRPM# Num#('426')
SetFlag('2')
END
ELSE
IF GTEqual? LAST SpeedRPM# Num#('426')
SetFlag('2')
END
END
RETURN

CSSOnToCSSOff:
IF GTEqual? SpeedRPM# Num#('426')
IF LessThan? LAST SpeedSFPM# Num#('426')
SetFlag('2')
END
ELSE
IF GTEqual? LAST SpeedSFPM# Num#('426')
SetFlag('2')
END
END
RETURN

ckNewGear:
CSSOff
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
CSSOnToCSSOn
ELSE
CSSOffToCSSOn
END
ELSE
IF LAST ConstantSurfaceFeed?
CSSOnToCSSOff
ELSE
IF NewGear?
SetFlag('2')
END
END
END
RETURN

GetCSSR:
IF FirstOperation? OR NewTool?
'R' HomeX#
ELSE
IF ApproachOD?
IF LAST ApproachOD?
'R' LAST XOpECD#
ELSE {around}
'R' LAST OpExitXCP#
END
ELSE
IF ApproachID?
IF LAST ApproachID?
'R' LAST XOpECD#
ELSE
'R' LAST XOpCD#
END
ELSE {ApproachFace}
IF LAST ApproachFace?
LoadFeat CycleStartZ# CycleStartX# { Not sure if this works }
'R' SPX#
ELSE
IF LAST ApproachOD? {around}
'R' LAST OpExitXCP#
ELSE {LAST ApproachID}
'R' LAST XOpECD#
END
END
END
END
END
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

setOpLines:
'Ś' Operation# '00' EOL
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
AbsOrInc RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
SetFlagF('2') { NewGear }
ckNewGear
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
IF Flag?('2') { NewGear }
SeqLabC SpinOff EOL
SeqLabC GetGearRange EOL
END
IF ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
CSSOn
IF LAST ConstantSurfaceFeed?
IF Flag?('2') { NewGear }
'G96' Speed GetCSSR
ELSE
IF LAST ProgStop?
'G96' Speed GetCSSR
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
'G96' Speed GetCSSR
END
END
END
ELSE
'G96' Speed GetCSSR
END
ELSE
CSSOff
IF Flag?('2') { NewGear }
'G97' Speed
ELSE
IF LAST ConstantSurfaceFeed?
'G97' Speed
ELSE
IF LAST ProgStop?
'G97' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
'G97' Speed
END
END
END
END
END
IF LAST ProgStop?
SeqLabC {SpeedC} SpinOn EOL
SeqLabC CoolOn EOL
ELSE
SeqLabC {SpeedC}
IF Flag?('2') { NewGear }
SpinOn
END
EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
SetFlagF('2') { NewGear }
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC ArcIJC
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF LastFeat?
CRCOffC { Exit Length Feature }
ELSE
CRCOnC { Entry Length Feature }
END
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G04X2.' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G04X' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
IF LAST ThreadFeat?
Rapid
END
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G33' MoveXC MoveZC ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle? OR LAST Threading?
Rapid
ELSE
RapidC
END
RETURN

GetTurret:
IF GTEqual? Tool# Num#('11')
NegSideLathe
ELSE
PosSideLathe
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
NoIJKSigns
SetMaxRPM('1500')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
SetFlagF('2') { NewGear }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
ProgID1 EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
GetTurret
DoOpComments
DoPostScript
Plane
SetOpLines
SeqLab Preset Home
IF ConstantSurfaceFeed?
MaxRPM
END
EOL
SeqLabC Rapid OpToolID LatheOffset EOL
IF ConstantSurfaceFeed?
SeqLabC GetGearRange EOL
SeqLabC CSSOn 'G96' Speed GetCSSR SpinOn EOL
ELSE
SeqLabC GearRange EOL
SeqLabC CSSOff 'G97' Speed SpinOn EOL
END
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
SeqLabC 'X' NewHomeX# CoolOff EOL
SeqLabC LOfstOff '00' EOL
SeqLabC 'Z' NewHomeZ# EOL
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

GetTurret
DoOpComments
DoPostScript
SetOpLines
SeqLab Preset Home
IF ConstantSurfaceFeed?
MaxRPM
END
EOL
SeqLabC Rapid OpToolID LatheOffset EOL
SetFlagF('2') { NewGear }
ckNewGear
IF Flag?('2') { NewGear }
SeqLabC SpinOff EOL
SetFlagF('2') { NewGear }
END
IF ConstantSurfaceFeed?
SeqLabC GetGearRange EOL
SeqLabC CSSOn 'G96' Speed GetCSSR SpinOn EOL
ELSE
SeqLabC GearRange EOL
SeqLabC CSSOff 'G97' Speed SpinOn EOL
END
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
SetOpLines
SeqLab ' ' EOL
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G33'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G04X2.' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle? OR Threading?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
SeqLabC 'X' FirstHomeX# CoolOff EOL
SeqLabC OpToolID '00' EOL
SeqLabC 'Z' FirstHomeZ# EOL
IF ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END
SeqLabC SpinOff EOL
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END