{Change Comments ***********************************************************}

{6/20/89
Copied & modified; Bandit IV AB M089.54, for Quality Mold.
Change "PartsLess1" to "Parts", and "RepsLess1" to "RepCycs".
Jim Radcliffe}

{6/21/90, Updated: Bandit IV AB M044.55 to .72.1 format, JR}

{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}

{4/03/91
Modified: Bandit IV AB M044.73
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{7/15/93
Modified: Bandit IV AB M044.79
Updated to .81.2 format.
This processor used LastFeatExtend for CRCOff,
changed to use the Exit Distance from ncCAM and CRCOff on LastFeat.
Jim Radcliffe}

{7/20/93
Copied & modified: Bandit IV AB M044.82
For: Motorola
Control: Allen Bradley Series B 8400 MP Revision E
Machine: Yamazan Knee Mill
Added G70 for inch output.
Changed to output M1 with ProgStop.
Added ToolChng.
Added Speed to SpinOn line & moved SpinOn before CoolOn, also added SpeedC to SameTool.
Moved ZCP1 to line after ToolOfset# is called.
Changed GZO to 'O0' followed by 'Z0' for OfstOff.
Moved DoOpComments to at at very beginnig of operation, after ToolChng.
Changed CoolOn to output M8.
Added Helical Interpolation.
Jim Radcliffe}

{
Format: AB 8400 Rev F Mxxx.82.1
10/24/95
Changed to tag style post
TH}

{
Format: AB 8400 Rev F Mxxx.85
11/2/95
Updated to .85 post. No drill subs.
TH}

{
Format: AB 8400 Rev F M876.85.1
1/3/96
Moved TagDown from AutoCycCutSub2 to ZOnlyRepAutoCycle
TH}

{
Format: AB 8400 Rev F M876.85.2
1/5/96
Added StrtPos if NOT FirstCycle to ZOnlyRepAutoCycle
TH}

{1/17/96 - Updated .85 to .86 format, MPK}

{
Format: AB 8400 Rev F [CAS] M876.86.3
1/29/96
Changed tagging style to place all subs at end of output instead of behind each op.
Changed helical interpolation to correctly output only the blocks needed. (Preventing over-definition)
TH}

{2/28/96
Initial: AB 8400 Rev F [CAS] M876.86.3
Created: AB 8400 Rev F [CAS] M876.86.4
Removed EOR at beginning and end of prog, added colon after EOP before subs, put all G90 and G91 on their own line,
Added EOP at prog end, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed varsion # to .89, MPK}

{3/4/97,
Initial: AB 8400 Rev F [CAS] M876.89
Created: AB 8400 Rev F [CAS] M876.89.1
Added startup block in FirstOp,
Added EOR at beginning of File,
deleted several extraneous lines from output,
deleted all spindle control blocks,
Deleted output of optional stops,
deleted output of tool changes,
added M41 and M42 to drill cycles, turns drill on/off,
deleted calls to WFOStuff, replaced with 'G45O' Tool#, sustomer wants WFO# to Match Tool#,
disabled multiple parts with WFOs,
removed Rapid from drill cancel line,
added end of program block,
changed ':' after EOP to ';',
added support for two spindles: W axis is used for tools 2 and 4, Z is used for all others,
therefore had to replace all commands that output a Z move with Number commands, and
subsequently, some of the output of clearance planes has lost their conditionality, MPK}

{3/5/97,
Initial: AB 8400 Rev F [CAS] M876.89.1
Created: AB 8400 Rev F [CAS] M876.89.2
Added tool offset line in FirstOp and NewTool, outputs 'O' with Tool#,
Deleted output of Speed from SameTool,
MPK}

{10/30/97,
Initial: AB 8400 Rev F [CAS] M876.89.2
Created: AB 8400 Rev F [] Mxxx.89
For: Enterprise IND.
Added numerous literals to FirstOp and NewTool.
Added Speed and SpinOn at StrtPos in FirstOp and NewTool.
Deleted sub-routine ZLab.
Added StrtPos to same line as Cycle definitions in Drilling.
Deleted all 'M41' and 'M42' literals.
CDH}

{11/3/97,
Initial: AB 8400 Rev F [] Mxxx.89
Created: AB 8400 Rev F [] Mxxx.89.1
For: Enterprise Ind.
Added 'EOL' after ZCP2C at beginning of Common point.
Deleted IF Progstop? boolean and added literal 'M00' in NewTool.
CDH}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0'
#3 = '*###.###;0'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '###.##;0;'
#7 = '###.####;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(TrackXNO#,4)
FORMAT(TrackYNO#,4)
FORMAT(TrackZNO#,4)
FORMAT(EPZ#,4)
FORMAT(SPZ#,4)
FORMAT(ClearancePlane1#,4)
FORMAT(ClearancePlane2#,4)
FORMAT(ClearancePlane3#,4)
FORMAT(ZInPlusInc#,4)
FORMAT(ZCP2PlusInc#,4)
FORMAT(Tag#,5) {.72}
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(ToolOffset#,5)
FORMAT(Dwell#,6)
FORMAT(HelixPitch#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'; SUB NUMBER: ' Tag# EOL
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLabC 'U' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLabC 'U' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLabC 'V' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLabC 'V' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'; OPERATION ' Operation# ': ' OperationType$ EOL
END
IF OperationComment?
'; ' OperationComment$ EOL
END
IF WorkGroupComment?
'; ' WorkGroupComment$ EOL
END
IF ToolTypeComment?
'; TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
IF ToolComment?
'; ' ToolComment$ EOL
END
RestoreScale
END
RETURN

ZLab: {supplies proper label for depth axis depending on which tool is used}
RETURN

EntryMove:
IF FeedEntry?
SeqLabC FeedC ZIn FeedEntC EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
DoSubComment
'>' Tag# EOL
SeqLab ' ' EOL
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqLabC 'HÅ‚' Tag# 'E²' Tag# 'L' Repeats# EOL
StartSub
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqLabC FeedC ZCP3 FeedEntC EOL
ELSE
SeqLabC RapidC ZCP3 EOL
END
END
END
RETURN

FinishSubG92: {part 2}
SeqLabC Preset ShiftRC EOL
SeqLab ' ' EOL
'<' Tag# EOL
TagDown
CloseSub
SeqLabC Preset UnshftRC EOL
RETURN

OpenMP:
TagUp TagInc
IF WorkFixtureOffsets?
'****MULTIPLE PARTS WITH WORK FIXTURE OFFSETS IS NOT SUPPORTED BY THIS POST PROCESSOR****' EOL
'****************REPOST USING EQUALLY SPACED OFFSETS FOR CORRECT OUTPUT******************' EOL
ELSE
SeqLabC 'HÅ‚' Tag# 'E²' Tag# 'L' Parts# EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
ELSE
SeqLabC Preset ShiftPC EOL
SeqLab ' ' EOL
'<' Tag# EOL
TagDown
CloseSub
SeqLabC Preset UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLab AbsValue EOL
END
RETURN

ArcDirection:
IF ArcCW?
'G22'
ELSE
'G23'
END
RETURN

FormatArc:
DoAbsOrInc
IF XYPlane? AND ZMove?
TrackXNO# EPX#
TrackYNO# EPY#
ArcDirection MoveZC ArcIJ 'K' HelixPitch#
ELSE
IF XZPlane? AND YMove?
TrackXNO# EPX#
TrackZNO# EPZ#
ArcDirection MoveYC ArcI 'J' HelixPitch# ArcJ
ELSE
IF YZPlane? AND XMove?
TrackYNO# EPY#
TrackZNO# EPZ#
ArcDirection MoveXC 'I' HelixPitch# ArcI ArcJ
ELSE
IF ArcCW?
CWArc
ELSE
CCWArc
END
MoveXYZC ArcIJ
END
END
END
RETURN

StdLine: {enables CRC on first call, .70}
SeqLabC CRCOnC EOL
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC DoAbsOrInc EOL
SeqLabC FeedC MoveXYC
IF NOT Equal? SPZ# EPZ#
'Z' EPZ#
END
FeedRateC EOL
DecelMove2
END
SeqLabC DoAbsOrInc EOL
SeqLabC FeedC MoveXYC
IF NOT Equal? SPZ# EPZ#
'Z' EPZ#
END
DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc EOL
SeqLabC FeedC MoveXYC
IF NOT Equal? SPZ# EPZ#
'Z' EPZ#
END
FeedRateC EOL
END
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC EOL
SeqLabC 'HÅ‚' Tag# 'E²' Tag# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLabC DoDrillAbsOrInc EOL
SeqLabC MoveSXYC
IF NOT Equal? SPZ# LAST SPZ#
'Z' SPZ#
END
EOL {.80.01}
END
ELSE
IF LastFeat?
SeqLabC CRCOffC EOL
END
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc EOL
SeqLabC RapidC MoveXYC
IF NOT Equal? SPZ# EPZ#
'Z' EPZ#
END
EOL
END
ELSE
IF LineFeat?
IF LastFeat?
SeqLabC DoAbsOrInc EOL
SeqLabC FeedC MoveXYC
IF NOT Equal? SPZ# EPZ#
'Z' EPZ#
END
FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLabC DoAbsOrInc EOL
SeqLabC FeedC MoveXYC
IF NOT Equal? SPZ# EPZ#
'Z' EPZ#
END
FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
{WFO USE IS NON-STANDARD, NEWWFO AND MULTIPLE PARTS WITH WFOS NOT SUPPORTED, MPK}
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLabC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqLabC AbsOrInc EOL
ELSE
SeqLabC AbsOrInc EOL
IF FIFO? {.81}
SeqLabC FeedC ZCP2 FeedEntC EOL
ELSE
SeqLabC RapidC ZCP2 EOL
END
END
SeqLab ' ' EOL
'<' Tag# EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after TagUp TagInc for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagUp TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
TagDown
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLab Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagUp TagInc
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC IncValue EOL
SeqLabC Feed StrtPosC EOL
SeqLabC AbsOrInc EOL
SeqLabC
ELSE
SeqLabC Feed
END
ELSE
SeqLabC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC IncValue EOL
SeqLabC Rapid StrtPosC EOL
IF FeedEntry?
SeqLabC AbsOrInc EOL
SeqLabC 'Z' ZCP2PlusInc# EOL
SeqLabC Feed 'Z' ZInPlusInc# FeedEnt EOL
ELSE
SeqLabC AbsOrInc EOL
SeqLabC 'Z' ZInPlusInc# EOL
END
ELSE
IF FeedEntry?
SeqLabC Rapid 'Z' ZCP2PlusInc# EOL
SeqLabC Feed 'Z' ZInPlusInc# FeedEnt EOL
ELSE
SeqLabC Rapid 'Z' ZInPlusInc# EOL
END
END
ELSE
IF FeedEntry?
SeqLabC Feed 'Z' ZInPlusInc# FeedEnt EOL
ELSE
SeqLabC Rapid 'Z' ZInPlusInc# EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLab EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqLabC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqLabC Rapid ZCP2 EOL {.69}
END
END {.69}
SeqLab ' ' EOL
TagDown
'<' Tag# EOL
CloseSub
TagDown
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqLabC FeedC 'Z' ZInPlusInc# FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC 'Z' ZInPlusInc# EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLabC Feed 'Z' ZInPlusInc# FeedEnt EOL
ELSE
SeqLabC RapidC 'Z' ZInPlusInc# EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqC SubCall CallLab EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLab ' ' EOL
'<' Tag# EOL
TagDown
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
TagInit
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + U move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - U move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + V move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - V move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
IF ToolChangeAtHome?
SetHome
END
EOR EOL
IF UseComments?
IF ProgramNameComment?
'; ' ProgramName$ EOL
END
IF ProgramComment?
'; ' ProgramComment$ EOL
END
IF FormatNameComment?
'; FORMAT: ' FormatName$ EOL
END
IF TimeComment?
'; ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
'; OUTPUT IN ' MoveType$ ' INCHES' EOL
END
IF PartsComment?
'; PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
'; FIRST TOOL IN SPINDLE ' EOL
END
END
OpenSub
RestoreScale
SeqLabC 'G70' EOL
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
SeqLabC 'G99' EOL
SeqLabC Plane EOL
SeqLabC 'O0Z0' EOL
SeqLabC 'G45O0' EOL
SeqLabC 'X0Y0' EOL
DoPostScript
DoOpComments
SeqLabC 'G45O1' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLabC AbsOrInc EOL
SeqLabC Rapid StrtPos Speed SpinOn EOL
SeqLabC 'O0' Tool# EOL
SeqLabC ZCP1 CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC StrtPos EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqLabC 'O0Z0' EOL
IF ToolChangeAtHome?
SeqLabC Rapid Home EOL
END
SeqLabC 'G99' EOL
SeqLabC 'M00' EOL

{Start new Operation}

DoOpComments
SeqLabC PlaneC EOL
DoPostScript
SeqLabC 'G45O1' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLabC AbsOrInc EOL
SeqLabC Rapid StrtPos Speed SpinOn EOL
SeqLabC 'O0' Tool# EOL
SeqLabC ZCP1 CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLabC StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL

{Start new Operation}

GetStartOfSameTool
SeqLabC CoolOn EOL
SeqLabC PlaneC EOL
SeqLabC AbsOrInc EOL
SeqLabC Rapid StrtPos EOL
SeqLabC 'O' ToolOffset# EOL
SeqLabC ZCP1 EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF NewToolOffset?
SeqLabC 'O0' EOL
SeqLabC Rapid 'Z0' EOL

{Start new Operation}

GetStartOfSameTool
SeqLabC PlaneC EOL
SeqLabC AbsOrInc EOL
SeqLabC Rapid StrtPos EOL
SeqLabC 'O' ToolOffset# EOL
SeqLabC ZCP1 EOL
ELSE
{Start new Operation}

GetStartOfSameTool
SeqLabC PlaneC EOL
SeqLabC AbsOrInc EOL
SeqLabC Rapid StrtPos EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqLabC ZCP2C EOL
IF Repeats?
TagUp TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLabC ZCP3C
ELSE
IF FIFO? {.81}
SeqLabC FeedC ZCP3C FeedEntC
ELSE
SeqLabC RapidC ZCP3C
END
END
IF NOT LastOp?
IF NEXT NOT SameTool?
CoolOff EOL
ELSE
EOL
END
END
ELSE
IF Drilling?
IF Repeats?
TagUp TagInc
StdSub
SeqLabC Rapid StrtPos EOL
END
SeqLabC
IF RetractToCP1? {this boolean expression replaces DrillCP}
IF SameTool?
ZCP1C
END
ELSE
ZCP2C
END
EOL
GetCycle
SeqLabC Cycle ZDepth StrtPos RLevel Dwell
IF Peck?
Peck FromCP FeedEnt
IF PeckChipBreaker?
'JKW' Retract 'U'
END
ELSE
FromCP FeedEnt
END
EOL
TrackZNO# FIRST SPZ#
ToolPath
SetDrillEndOpZ
SeqLabC 'G80' EOL
IF Repeats?
FinishSubG92
END
SeqLabC ZCP3
IF NOT LastOp?
IF NEXT NOT SameTool?
CoolOff EOL
ELSE
EOL
END
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqLabC 'O0Z0' EOL
SeqLabC 'G45O0' EOL
SeqLabC 'X0Y0' EOL
SeqLabC 'G99' EOL
IF FIRST ToolChangeAtHome?
SeqLabC Rapid FirstHome EOL
END
IF ProgStop?
SeqLabC 'M0' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLabC EOP ';' EOL {semicolon added for computer load}
CloseSub
Post2
SeqLabC EOP EOL
Close
ReTag
IF UseComments?
SetScale('1')
Reopen
IF FileBytesComment?
'; FILE LENGTH: ' FileBytes# ' CHARACTERS ' EOL
END
IF FileFeetComment?
'; FILE LENGTH: ' FileFeet# ' FEET ' EOL
END
IF FileMetersComment?
'; FILE LENGTH: ' FileMeters# ' METERS ' EOL
END
Close
END