{
MILL=T
LATHE=F
SIMPLE_ROT_POS=F
ROTARY_MILL=F
ADV_MILL=T
SUBS=T
MILLTURN_Y-AXIS=F
METRIC=T
}

{Change Comments ***********************************************************}

{ 10/24/94 [cwh]
D610.81.5 ( from D610.81.4 )

Made changes to ZOnlyRep and FinishSub1 subs to properly handle
Feed connects and clearance moves. }

{11/8/94
Modified: Fadal Format 1 (NW) D610.81.5
For: Gibbs & Associates
Versions: Catalyst v2.14.12C/Compost 4.21.23
Changes made per Pete Jackson
Changed all occurances of SeqC to SeqLab.
Charles reported a problem involving operations that do not change coordinate systems from
previous operations.
Added ClearCSOffset at NotSameToolWFO and SameToolWFO subs.
DWB}

{11/16/94 Fixed Program Stop bug in NewToolOp2. Tom Hubina}

{ Format: Fadal Format 1 (NW) D610.00
12/22/94
Changed version number to .00 from .81.7 per Fanuc 6M (PW) C001.00.03
Changed all CSAngleAC and CSAngleBC calls to CSAngleA and CSAngleB to output the A and B
commands at the start of every operation.
Added AAxisAvail? and BAxisAvail? checks to CSAngleA and CSAngleB subs
Added return to CS1 moves to End2
Added G92 reset of A and/or B axis to End2
Changed NotSameTool WFO so it would restate the current WFO if no change in CS
Added ClearCSOffset to OpenMP: CloseMP: and SubCSMP:
Added if AChange? OR BChange? to home postition call-out in SameToolOp1
Replaced SetZRepInc and RestoreAbsOrInc with one sub called DoAbsOrInc. Any line with SetZRepInc now
has DoAbsOrInc as the first command after the SeqC.
TH}

{ Format: Fadal Format 1 (NW) D610.00.01
1/13/95
Formatted TrackZNO# to #4 }

{ Added ClearCSOffset to SubCSMP TH}

{ Changed SeqC's to SeqLabs
4/21/95
TH}

{ Fixed unwind code in End2:
5/25/95
TH}

{6/9/95
Fixed CRC so it won't output on a helix
TH}

{7/10/95
Updated: Fadal Format 1 (NW) D610.00.04
For: Gibbs & Associates
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.06/Catalyst v2.14.40/Compost 4.21.30/1.0a
Changes made per Pete Jackson
Updated to Version 4.2 per Fanuc 6M M001.81.2g Format.
Added CkCRC sub for CRCOffC per version 4.2.
CutterRadiusCompensation ExitLength will output G40 on LastFeat AND LineFeat at StdLine sub.
Added logic to suppress output of CRCOnC on ZMove Feature.
Added logic to suppress output of CRCOnC in OneFeat ToolPath.
Moved ResetCRCNum at start of ToolPath to CkCRC sub.
Added support of CRC during multiple pocket dog-bone operation.
Added condition to output CRCOnC for XMove OR YMove only at CkCRC sub.
Outputs G41/G42 on First LineFeat after Z Plunge.
Modified condition to output CRCOffC for LastFeat AND AutoCycle at ToolPath RapidFeat.
Assures that G40 is not output prior to LastFeat.
Added CRCOffC to ZMoveOnly Feature at ToolPath RapidFeat.
Outputs G40 at all Z Retract blocks.
Deleted DoArcCRC sub.
CkCRC sub now also called at FormatArc sub.
Deletes use of Flag(8)
Deleted CRCValue sub.
Not needed because problem has been resolved, see CNCVIS1 M610.81.7, 5/5/93.
Moved SetFlag(4) from InitOp and NewToolOp1 to start of ToolPath.
Simplified output of Canned Drill Cycle block at IF Drilling.
DWB}

{8/23/95 - Updated to .10 format TH}

{ 12/15/95
Added CSAngleA CSAngleB to MP1ToollAllPXcp
TH}

{1/17/96, Updated .10 to .11 version, MPK}

{3/25/96, Tested ZOnlyRepAutoCycle, Changed version # to .12, MPK}

{4/15/97
Updated: Fadal Format 1 (NW) D610.12m
Created: Fadal Format 1 (NW) D610.15m
For: Gibbs & Associates/Precision Products
Versions: Catalyst v3.33C/ComPost2 MSL 68K
Changes made per Pete Jackson/David Davis of Precision Products
Updated for Catalyst v3.33C per Fanuc 6M (NW) D001.15 Format
Changed FORMAT#2 from ###.###;0. to #####.###;0. at Prog Numeric Format Definitions.
Changed FORMAT#3 from *###.###;0. to *#####.###;0. at Prog Numeric Format Definitions.
Added NOT LastFeat? AND Equal? SPZ# EPZ# condition at ckCRCNum sub.
Moved contents of StdLine back to ToolPath LineFeat.
Modified WorkFixtureOffset logic.
Added Flag(2) for WFOStuff at setup and initializations.
Added SetFlag(2) for EquallySpacedOffsets at OpenMP sub.
Added WFONum sub.
Rewrote logic at WFOStuff sub.
Added EOL to NewWFO MP WFOStuff sub Warning.
Deleted SeqLab and EOL at WFOStuff sub.
Added Flag(2) logic at start of EachOp/NextOp Loop.
Moved WFOStuff after MP-OTAP-FU condition at FirstOperation and NewTool.
Added WFOStuff for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added AbsOrInc Rapid to StrtPos block for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added SeqLab and EOL at WFOStuff calls at GetStartOfSameTool, FirstOperation and NewTool.
Added SetMaxFeed(100) for English VNC files.
Moved Speed SpinOn after MP-OTAP-FU condition at FirstOperation and NewTool.
Added Speed SpinOn for MP-OTAP-ECP condition at FirstOperation and NewTool.
Added Flag(5) to Suppress Redundant WFO for MultipleParts WorkFixtureOffsets programs.
Only concerns OneToolAllParts ExitClearancePlane situations.
Corrected problem with output of literal 'G8' block at ToolPath.
Deleted IF NOT Rapid? and IF LAST Rapid? Booleans.
IF LAST Rapid? Boolean was causing post to output extra EntryFeedRates during Toolpath.
IF LAST Rapid? Boolean is an incorrect use of a non-ToolPath command.
Developers original intent on 2/16/93 to block on FIRST LineFeat OR ArcFeat following RapidFeat
condition was not working as intended.
When I changed IF LAST Rapid? to IF LAST RapidFeat, the post output more 'G9' blocks and
extra EntryFeedRate problem disappeared.
Left IF FirstFeat? boolean in place.
This caused no difference in occurance of G8 blocks.
DWB}

{6/16/98,
Initial : Fadal Format1 (NW) D610.15m
Created: Fadal Format1 (NW) D610.15.1m
Customer: Gibbs & Associates

Changes to "Prog":

1. Moved G21 (metric output) block to be the first block in the main program.
2. Changed SetMaxFeed for Inch & Metric.
JHE}

{2/5/99
Updated: Fadal Format1 (NW) D610.15.1m
Created: Fadal Format1 (NW) D610.16.2m
For: Gibbs & Associates
Versions: Virtual 5.04.06/ComPost2 1.7b15
Changes made per Pete Jackson.
Updated for Catalyst v5 per Fanuc 6M M001.16.2 and Fanuc 6M [FW] B001.16 Format.
Added Header Comments at top of Prog.
Corrected problem with output of csAngleA and csAngleB.
Formulas at fadalAngleA and fadalAngleB Procedures sometimes did not work when value equaled zero.
This problem would cause post to output A360. or B360. instead of A0. or B0.
The Fadal control does not accept value greater than 359.999.
Deleted fadalAngleA Procedure.
Deleted fadalAngleB Procedure.
Added getFanucAngle Procedure.
Added getFadalAngle Procedure.
Modified csAngleA Procedure.
Modified csAngleB Procedure.
Added Var(4) for csAngleA and csAngleB at progStart.
Modified return of csAngleA and csAngleB to zero at end2.
Updated handling of csWFOs to .16.2.
Added missing csPartNum# Procedure.
Replaced calccsWFO Procedure with csWFO Procedure.
Contains call to csPartNum# Procedure.
Modified doCSWFOComment Procedure.
Changed SetWFOCS Limit to 48 Work Fixture Offsets two places at progStart.
Moved wfoStuff call to block by itself at firstOp2, newToolOp4 and sameToolOp3.
Other minor fine tuning:
Modified Prog Numeric Format Definitions.
Added IF NOT FirstFeat? at toolPath PointFeat Drilling.
Changed CRCOffsetC to ckCRCNum at toolPath LineFeat.
Deleted FIRST Modifier at zonlyRep Procedure.
Updated PSComments at progStart.
Added OR AChange? OR BChange? at sameToolOp1.
Added OR AChange? OR BChange? at sameToolOp3.
DWB}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '#####.###;0.'
#5 = '#######0'
#6 = '00'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(SUB#,2)
FORMAT(Dwell#,2)
FORMAT(CSOffsetA#,2)
FORMAT(CSOffsetB#,2)
FORMAT(Recall#,4)
FORMAT(SpeedRPM#,4)
FORMAT(ToolDiameter#,4)
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(TrackXNO#,4)
FORMAT(TrackYNO#,4)
FORMAT(TrackZNO#,4)
FORMAT(ADD#,5)
FORMAT(CS#,5)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(RapidF#,7)
FORMAT(CSSubID#,6)
FORMAT(CallMasterNum#,6)

{Prog Subroutines ****}

restoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is a Metric post}
END
RETURN

csPartNum#:
ADD# CS# MUL# NumOfCS# SUB# PartNum# Num#('1')
RETURN

csWFO:
'E' ADD# cSPartNum# Num#('0')
RETURN

wfo:
'E' ADD# PartNum# Num#('0')
RETURN

wfoStuff:
IF Flag?('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF NOT SameTool?
IF WFOCS?
csWFO
ELSE
wfo
END
ELSE
IF WFOCS?
IF ChangeCS?
IF MultipleParts?
{MP ChangeCS is handled in subCSMP and closeMP}
ELSE
csWFO
END
END
END
END
END
SetFlagF('2') { Do not output WFO second time wfoStuff is called for MP-WFO-OTAP-ECP }
RETURN

csG52:
SeqLab 'G52X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ# EOL
RETURN

g52Stuff:
IF NOT Flag?('7') AND NOT WFOCS?
IF FirstOperation? OR NewTool? OR ChangeCS?
IF MultipleParts?
IF WorkFixtureOffsets?
csG52
END
ELSE
csG52
END
END
END
RETURN

doCSComment:
SeqLab '* CS#' CS# ' - ' CSComment$ EOL
RETURN

getFanucAngle:
Save# Num#('4') DIV# Recall# Num#('4') Num#('360') { Reduce Angle to lowest terms }
Save# Num#('4') SUB# Recall# Num#('4') TRUNC# Recall# Num#('4') { Subtract whole value leaving decimal value }
Save# Num#('4') MUL# Recall# Num#('4') Num#('360') { Increase to value between -360 and +360 }
RETURN

getFadalAngle:
getFanucAngle
IF LTEqual? Recall# Num#('4') Num#('-.000495')
Save# Num#('4') ADD# Recall# Num#('4') Num#('360') { Convert to FadalMove }
END
RETURN

csAngleA:
IF AAxisAvail?
IF Flag?('6') AND WFOCS? AND NOT Flag?('21') { Flag(6) TRUE = B-Style Output, Flag(6) FALSE = C-Style Output }
'A0.'
ELSE
'A'
IF NOT Flag?('21')
IF FirstOperation?
IF LessThan? CSOffsetA# Num#('0')
'-'
END
ELSE
IF LessThan? CSOffsetA# LAST CSOffsetA#
'-'
END
END
END
Save# Num#('4') CSOffsetA#
getFadalAngle
FORMAT(Recall#,2)
Recall# Num#('4')
FORMAT(Recall#,4)
END
END
RETURN

csAngleAC:
IF AChange?
csAngleA
END
RETURN

csAngleB:
IF BAxisAvail?
IF Flag?('6') AND WFOCS? AND NOT Flag?('21') { Flag(6) TRUE = B-Style Output, Flag(6) FALSE = C-Style Output }
'B0.'
ELSE
'B'
IF NOT Flag?('21')
IF FirstOperation?
IF LessThan? CSOffsetB# Num#('0')
'-'
END
ELSE
IF LessThan? CSOffsetB# LAST CSOffsetB#
'-'
END
END
END
Save# Num#('4') CSOffsetB#
getFadalAngle
FORMAT(Recall#,2)
Recall# Num#('4')
FORMAT(Recall#,4)
END
END
RETURN

csAngleBC:
IF BChange?
csAngleB
END
RETURN

doCSWFOComment:
IF FirstOperation? OR NewTool? OR ChangeCS?
SetFlag('21')
SeqLab '* ' csWFO ' = X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ#
IF Flag?('6') { TRUE = B-Style Output, FALSE = C-Style Output }
IF AAxisAvail?
' ' csAngleA
END
IF BAxisAvail?
' ' csAngleB
END
END
EOL
SetFlagF('21')
END
RETURN

csComments:
doCSComment
IF WFOCS? AND NOT MultipleParts?
doCSWFOComment
END
RETURN

doSubComment:
IF UseComments? AND SubComment?
SeqLab '* SUB NUMBER: ' Program# EOL
END
RETURN

doOpComments:
IF UseComments?
SetScale('1')
SeqLab '* OPERATION ' Operation#
IF OperationIDComment?
': ' OperationType$
END
EOL
IF OperationComment?
SeqLab '* ' OperationComment$ EOL
END
IF WorkGroupComment?
SeqLab '* ' WorkGroupComment$ EOL
END
SeqLab '* TOOL ' Tool#
IF ToolTypeComment?
': ' ToolDiameter# ' ' ToolType$
END
EOL
IF ToolComment?
SeqLab '* ' ToolComment$ EOL
END
restoreScale
csComments
END
RETURN

psInit:
NewWFOF
FourthCWF
FourthCCWF
FifthCWF
FifthCCWF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

psStuff:
RETURN

doPostScript:
psInit
EachPS
SeqLab PostScript EOL
psStuff
NextPS
RETURN

doEndOpPS:
psInit
EachEOPS
SeqLab EndOpPS EOL
psStuff
NextPS
RETURN

absValueC:
IF NOT AbsValue?
AbsValue
END
RETURN

incValueC:
IF AbsValue?
IncValue
END
RETURN

absOrIncC:
IF AbsoluteMoves?
absValueC
ELSE
incValueC
END
RETURN

entryMove:
IF FirstOperation? OR NewTool?
RapidF# { Forces FeedEnt/FeedRate }
END
IF FeedEntry?
SeqLab Feed ZIn FeedEntC EOL
ELSE
SeqLab RapidC ZIn EOL
END
RETURN

startSub:
OpenSub
SeqLab SubIDF EOL
doSubComment
RETURN

subWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
SeqLab '* WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT' EOL
' ' EOL
END
END
RETURN

stdSub:
FORMAT(Recall#,6)
FORMAT(ADD#,4)
Save# Num#('10') Num#('0') { FORMATting for Number of Subroutine Loops }
EachRep
Save# Num#('10') ADD# Recall# Num#('10') Num#('1')
IF GreaterThan? Recall# Num#('10') Num#('99')
SeqLab CallLab '99' EOL
Save# Num#('10') Num#('1')
END
NextRep
SeqLab CallLab Recall# Num#('10') EOL
startSub
FORMAT(ADD#,5)
FORMAT(Recall#,4)
RETURN

finishSub1: {part 1}
IF NOT FeedConnect?
SeqLab RapidC ZCP3C EOL
END
RETURN

finishSubG92: {part 2}
SeqLab Preset ShiftR EOL
SeqLab EndSub EOL
CloseSub
SeqLab Preset UnshiftR EOL
RETURN

toggleIncDecWFO:
IF Flag?('3') { Incrementing WFOs in effect }
SetFlagF('3')
ELSE { Decrementing WFOs in effect }
SetFlag('3')
END
RETURN

doWFOOps:
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
ELSE
SeqLab Rapid StrtPos SetWFO EOL
END
SeqLab CallLab OnePart EOL
RETURN

openMP:
NewProg
IF WorkFixtureOffsets?
IF WFOCS?
startSub
SaveCSProg
SaveCSOpStart
ELSE
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
END
IF Flag?('3') { Incrementing WFOs in effect }
NewWFO
EachWFO {simple eachPart}
doWFOOps
IncWFO
NextWFO {simple NextPart}
DecWFO
ELSE { Decrementing WFOs in effect }
LastWFO
EachWFO {simple eachPart}
doWFOOps
DecWFO
NextPrevWFO {simple NextPart}
IncWFO
END
IF Flag?('4') { This post supports IncWFO/DecWFO }
toggleIncDecWFO
END
startSub
END
ELSE
FORMAT(Recall#,6)
FORMAT(ADD#,4)
Save# Num#('10') Num#('0') { FORMATting for Number of Subroutine Loops }
EachPart
Save# Num#('10') ADD# Recall# Num#('10') Num#('1')
IF GreaterThan? Recall# Num#('10') Num#('99')
SeqLab CallLab '99' EOL
Save# Num#('10') Num#('1')
END
NextPart
SeqLab CallLab Recall# Num#('10') EOL
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
startSub
FORMAT(Recall#,4)
FORMAT(ADD#,5)
END
RETURN

doCSWFOOps:
EachCSOp
doCSWFOComment
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
ELSE
SeqLab csWFO EOL
END
SeqLab SubCall CallLabB CSSubID# OnePart EOL
NextCSOp
RETURN

closeMP:
IF WorkFixtureOffsets?
SeqLab EndSub EOL
CloseSub
IF WFOCS?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
END
IF Flag?('3') { Incrementing WFOs in effect }
NewWFO
EachWFO {simple eachPart}
doCSWFOOps
IncWFO
NextWFO {simple NextPart}
DecWFO
ELSE { Decrementing WFOs in effect }
LastWFO
EachWFO {simple eachPart}
doCSWFOOps
DecWFO
NextPrevWFO {simple NextPart}
IncWFO
END
IF Flag?('4') { This post supports IncWFO/DecWFO }
toggleIncDecWFO
END
END
ELSE
SeqLab Preset ShiftP EOL
SeqLab EndSub EOL
CloseSub
SeqLab Preset UnshiftP EOL
END
RETURN

subCSMP:
IF WFOCS?
IF ChangeCS?
SeqLab EndSub EOL
CloseSub
NewProg
startSub
SaveCSProg
END
END
RETURN

doAbsOrInc:
IF Flag?('1') { Milling ZShiftOnly SepSubs/DrillSubs activated }
IF ZMove?
incValueC
ELSE
absOrIncC
END
END
RETURN

doDrillAbsOrInc:
IF Flag?('1') { DrillSubs activated }
IF SPZMove?
incValueC
ELSE
absOrIncC
END
END
RETURN

restoreAbsOrInc:
IF Flag?('1') { Milling ZShiftOnly SepSubs/DrillSubs activated }
SeqLab absOrIncC EOL
END
RETURN

ckCRC:
IF LastFeat?
IF NOT ArcFeat?
CRCOffC
END
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

ckCRCNum:
IF NOT LastFeat? AND Equal? SPZ# EPZ#
CRCOffsetC
END
RETURN

getACEPXY:
SetACSPCompF
Save# Num#('1') SPX# { Status Register Variable for X Axis }
Save# Num#('2') SPY# { Status Register Variable for Y Axis }
SetACSPComp
RETURN

setSRXYtoACEP:
SetPass1
SetSRXYtoEP
LoadFeat Num#('0') Num#('0') Num#('0')
TrackXNO# ADD# Recall# Num#('1') SPX# { Status Register Variable for X Axis }
TrackYNO# ADD# Recall# Num#('2') SPY# { Status Register Variable for Y Axis }
RETURN

toolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
IF LastFeat?
getACEPXY
END
SeqLab MoveSXYC EOL
SeqLab CallLab '01' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF NOT FirstFeat?
SeqLab doDrillAbsOrInc MoveSXYZC EOL
END
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqLab doAbsOrInc ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF FirstFeat? OR Rapid?
SeqLab 'G8' EOL
END
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
SeqLab doAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
SeqLab doAbsOrInc ckCRC
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
ArcFeedC ckCRCNum EOL
NEXTQuadrant
END
END
END
END
NEXTFeat
SeqLab CRCOffC EOL
restoreAbsOrInc
RETURN

autoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
startSub
SetSRXYtoSP
SeqLab incValueC EOL
RETURN

autoCycCutSub2: {part 2}
toolPath
SeqLab absOrIncC
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
RapidC ZCP2
END
EOL
SeqLab EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

autoCycPat:
SetPass2 {position pattern}
toolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

milling:
IF AutoCycle?
NewProg
autoCycCutSub1
entryMove
autoCycCutSub2
autoCycPat
ELSE
entryMove
toolPath
END
RETURN

g92Sub:
subWarning
stdSub
SeqLab absOrIncC Connect StrtPos EOL
milling
finishSub1
finishSubG92
RETURN

doSepSubZMoves:
IF FeedConnect?
SeqLab FeedC ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqLab RapidC ZCP2PlusInc EOL
END
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle? AND AutoCycle?
Rapid
END
SeqLab RapidC ZInPlusInc EOL
END
END
SeqLab CallLab '01' EOL
IF NOT FeedConnect? AND NOT AbsValue?
TrackZNO# ZCP2PlusInc#
SeqLab ZCP2C EOL
IF NOT AutoCycle?
TrackZNO# ClearancePlane3#
END
END
RETURN

setSepSubZ:
SetAbs
TrackZNO# ADD# SPZ# MUL# RepsLess1# RepeatZ#
SetInc
RETURN

zonlyRepAutoCycle:
autoCycPat {write pattern moves and main calls}
startSub
NewProg
EachCycle
SetSRXYtoEP
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLab incValueC Connect StrtPosC EOL
absOrIncC
ELSE
Connect
END
END
SetStatusOn
doSepSubZMoves
SetStatusOff
NextCycle
SetStatusOn
autoCycCutSub1 {build element sub}
TrackZNO# SPZ#
autoCycCutSub2
IF FeedConnect?
IF NOT AbsValue?
setSepSubZ
END
SeqLab Rapid ZCP2 EOL
END
SeqLab EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

zonlyRep:
EachCycle
SetSRXYtoEP
IF NOT FirstCycle?
Connect
IF SPXMove? OR SPYMove?
SeqLab StrtPosC EOL
END
END
doSepSubZMoves
NextCycle
startSub
TrackZNO# SPZ#
toolPath
finishSub1
SeqLab EndSub EOL
CloseSub
IF FeedConnect? AND NOT AbsValue?
setSepSubZ
END
RETURN

skipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

setDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

getSpeed:
IF Drilling?
GetCycle
END
IF Drilling? AND RigidTap?
IF FirstOperation? OR NewTool?
SeqLab Speed EOL
END
SeqLab SpeedC EOL
SeqLab 'G84.2' EOL
ELSE
IF FirstOperation? OR NewTool?
SeqLab Speed SpinOn EOL
ELSE { SameTool }
IF LAST ProgStop?
SeqLab SpeedC SpinOn EOL
ELSE
SeqLab SpeedC EOL
END
END
END
RETURN

checkPass: {use the correct StrtPos}
IF AutoCycle?
SetPass2
ELSE
SetPass1
END
IF NOT Flag?('7')
ClearCSOffset
END
RETURN

opGuts:
IF Milling?
SeqLab ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
zonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
SetFlag('1') { Milling ZShiftOnly SepSubs activated }
zonlyRep
SetFlagF('1') { Milling ZShiftOnly SepSubs deactivated }
END {end Auto Cycle IF}
ELSE {not Z only}
g92Sub
END {end Z only IF}
ELSE {no repeat OPs}
milling
END
IF AutoCycle?
SeqLab ZCP3C EOL
setSRXYtoACEP
ELSE
SeqLab RapidC ZCP3C EOL
END
ELSE
IF Drilling?
IF PosApproach? { Positive Approach On }
SeqLab 'M46' EOL
END
SeqLab DrillCP EOL
GetCycle
SeqLab
IF RigidTap?
'G84.1'
ELSE
Cycle
END
FromCP StrtPos ZDepth RLevel Dwell Peck Retract
IF Tap?
'F' SpeedRPM# FadalTapQ
ELSE
FeedEnt
END
EOL
IF CallMasterOp?
SeqLab CallLabB CallMasterNum# '01' EOL
skipToLastFeat
ELSE
TrackZNO# SPZ#
IF MasterOp?
SetFlag('1') { DrillSubs activated }
NewMasterProg
SeqLab CallLab '01' EOL
startSub
toolPath
SeqLab EndSub EOL
CloseSub
SetFlagF('1') { DrillSubs deactivated }
ELSE
toolPath
END
END
setDrillEndOpZ
IF PosApproach?
SeqLab 'M47' EOL
END
SeqLab DrillOff Rapid ZCP3 EOL
END
END
RETURN

progStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
SetMaxRPM('15000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
Save# Num#('1') Num#('0') { Status Register Variable for X Axis }
Save# Num#('2') Num#('0') { Status Register Variable for Y Axis }
Save# Num#('4') Num#('0') { csAngleA and csAngleB }
Save# Num#('10') Num#('0') { FORMATting for Number of Subroutine Loops }
SetFlagF('1') { Milling ZShiftOnly SepSubs/DrillSubs deactivated }
SetFlagF('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
SetFlag('3') { Incrementing WFOs in effect }
SetFlag('4') { This post supports IncWFO/DecWFO }
SetFlagF('5') { Suppress Redundant WFO for MP-WFO-OTAP-ECP }
SetFlagF('6') { TRUE = B-Style Output, FALSE = C-Style Output }
SetFlag('7') { TRUE = D-Style Output }
SetFlag('8') { TRUE = D-Style Output, FALSE = Local G52-WFO Coordinates }
SetFlagF('21') { csAngleA, csAngleB and doCSWFOComment }
IF PSComment? AND UseComments?
'Utility Data:' EOL
' At Op Start: All literals and commands will appear at the beginning of the operation.' EOL
' At Op End: All literals and commands will appear at the end of the operation.' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
END

IF NOT Flag?('7')
IF Equal? NumOfCS# Num#('1') { 3 Axis Part - Output M-Style }
SetFlag('7')
ELSE
IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('48')
SetWFOCS { use WFO for CS changes }
ELSE
IF Flag?('8')
SetFlag('7')
END
IF UseComments?
'* Not enough Work Fixture Offsets to handle this part.' EOL
'* Number of parts [ ' Parts# ' ] times CSs [ ' NumOfCS# ' ]' EOL
'* exceeds the machine limit. Switching to '
IF Flag?('7')
'non'
ELSE
'G52'
END
'-wfo style output.' EOL
END
END
ELSE
SetFlag('7')
END
ELSE
IF LTEqual? NumOfCS# Num#('48') {****}
SetWFOCS { use WFO for CS changes }
ELSE
IF Flag?('8')
SetFlag('7')
END
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of CSs [ ' NumOfCS# ' ] exceeds the machine limit. )' EOL
'( Switching to '
IF Flag?('7')
'non'
ELSE
'G52'
END
'-wfo style output. )' EOL
END
END
END
END
END
RETURN

initOp:
EOR EOL
SeqLab ProgID1
IF UseComments? AND ProgramNameComment?
'*' ProgramName$
END
EOL
SetProgNum('0')
IF UseComments?
IF ProgramComment?
SeqLab '* ' ProgramComment$ EOL
END
IF FormatNameComment?
SeqLab '* FORMAT: ' FormatName$ EOL
END
IF TimeComment?
SeqLab '* ' Date$ ' AT ' Time$ EOL
END
IF MovesComment?
SeqLab '* OUTPUT IN ' MoveType$ ' MILLIMETERS' EOL
END
IF PartsComment?
SeqLab '* PARTS PROGRAMMED: ' Parts# EOL
END
IF StartToolComment?
SeqLab '* FIRST TOOL NOT IN SPINDLE' EOL
END
END
OpenSub
restoreScale
RETURN

firstOp1:
IF ToolChangeAtHome?
SetHome
END
SeqLab 'G21' EOL { Metric Mode }
SeqLab OpToolID ToolChng EOL
doOpComments
doPostScript
RETURN

firstOp2:
SeqLab wfoStuff EOL
g52Stuff
getSpeed
checkPass
SeqLab Plane AbsOrInc Rapid StrtPos csAngleA csAngleB EOL
RETURN

firstOp3:
SeqLab OfstOn CoolOn EOL
RETURN

newToolOp1:
SeqLab SpinOff CoolOff EOL
SeqLab 'G53Z0' EOL { OfstOff }
RETURN

newToolOp2:
doEndOpPS
IF ToolChangeAtHome?
SeqLab 'G53' Home EOL
END
IF LAST ProgStop?
SeqLab 'M0' EOL
ELSE
SeqLab ProgStop EOL
END
RETURN

newToolOp3: {Start new Operation}
SeqLab OpToolID ToolChng EOL
doOpComments
doPostScript
RETURN

newToolOp4:
SeqLab wfoStuff EOL
g52Stuff
getSpeed
checkPass
SeqLab Plane AbsOrInc Rapid StrtPos csAngleA csAngleB EOL
RETURN

newToolOp5:
SeqLab OfstOn CoolOn EOL
RETURN

sameToolOp1:
doEndOpPS
IF LAST ProgStop?
SeqLab SpinOff CoolOff EOL
SeqLab 'G53Z0' EOL { OfstOff }
SeqLab 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLab CoolOff EOL
END
IF NewToolOffset? OR AChange? OR BChange?
SeqLab 'G53Z0' EOL { OfstOff }
END
END
RETURN

sameToolOp2: {Start new Operation}
doOpComments
doPostScript
checkPass
RETURN

sameToolOp3: {Start new Operation}
SeqLab wfoStuff EOL
g52Stuff
getSpeed
SeqLab PlaneC AbsOrInc Rapid StrtPos csAngleA csAngleB EOL
IF LAST ProgStop?
SeqLab OfstOn CoolOn EOL
ELSE
SeqLab
IF NewToolOffset? OR AChange? OR BChange?
OfstOn
END
IF NOT CoolOff? AND LAST CoolOff?
CoolOn
END
EOL
END
RETURN

end1:
SeqLab SpinOff CoolOff EOL
SeqLab 'G53Z0' EOL { OfstOff }
RETURN

end2:
doEndOpPS
IF ToolChangeAtHome?
SeqLab absOrIncC Rapid FirstHome EOL
END
IF AAxisAvail? OR BAxisAvail?
SeqLab absOrIncC 'G28' { Return to Zero }
IF AAxisAvail?
'A0.'
END
IF BAxisAvail?
'B0.'
END
EOL
END
IF ProgStop?
SeqLab 'M0' EOL
END
RETURN

end3:
SeqLab 'X0Y0Z0E0H0' EOL
SeqLab EOP EOL
EndSubs
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
SeqLab '* FILE LENGTH: ' FileBytes# ' CHARACTERS' EOL
END
IF FileFeetComment?
SeqLab '* FILE LENGTH: ' FileFeet# ' FEET' EOL
END
IF FileMetersComment?
SeqLab '* FILE LENGTH: ' FileMeters# ' METERS' EOL
END
Close
END
Retag
RETURN

mpAllTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
IF FirstOperation?
openMP
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
newToolOp2 {to tool change, CS problem}
subCSMP
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
subCSMP
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
end1
end2
closeMP
end3
RETURN

mp1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
END
IF FirstOperation?
firstOp1
openMP
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
closeMP
newToolOp2 {to tool change, CS problem}
newToolOp3
openMP
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
subCSMP
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
end1
closeMP
end2
end3
RETURN

mp1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
SetFlag('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF FirstOperation?
firstOp1
firstOp2
firstOp3
openMP
firstOp2 {need StrtPos in Sub}
ELSE
IF NewTool?
closeMP
newToolOp1
newToolOp2 {to tool change, CS problem}
newToolOp3
newToolOp4
newToolOp5
openMP
newToolOp4 {need StrtPos in Sub}
ELSE {implied SameTool?}
sameToolOp1
subCSMP
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
closeMP
end1
end2
end3
RETURN

noMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2') { Need to output wfoStuff twice for MP-ESO-OTAP-ECP, once for all others }
IF FirstOperation?
firstOp1
firstOp2
firstOp3
ELSE
IF NewTool?
newToolOp1
newToolOp2
newToolOp3
newToolOp4
newToolOp5
ELSE {implied SameTool?}
sameToolOp1
sameToolOp2
sameToolOp3
END
END {common point for all operations}
opGuts
NextOp {loops back to EachOP until last Operation}
end1
end2
end3
RETURN

{Start of executable Prog, Top Level ****}

progStart {setup and initializations}
initOp

IF MultipleParts?
IF AllToolsOnePart?
mpAllTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
mp1ToollAllPfu
ELSE {implied ExitClearancePlane?}
mp1ToollAllPXcp
END
END
ELSE
noMPs
END