{Change Comments ***********************************************************}

{9/5/91
Copied & modified: Okuma OSP 5000 LB15 L103.82
For: Machine Specialties
Machine: Okuma LC10
Control: OSP 5000 L-G
Deleted Spaces between Addresses.
This Control has Twin Independent Turrets:
Turret is determined by Tool#.
Tools <= 20 control Turret A with G13 Mirror Image Off Code.
Tools > 20 control Turret B with G14 Mirror Image On Code.
For Turret B we are SUBtracting 20 from Tool# and ToolOffset#.
G13/G14 takes care of:
NegSideLathe/PosSideLathe switching.
ReverseXZArcs/StandardXZArcs switching.
Spindle Direction.
Added Tab Sub:
Output Tabs at Coolant/Speed blocks and Canned Cycle blocks.
Added TurretHome Sub:
Called from FirstOperation, NewTool and end of Prog.
Replaces Home, NewHome and FirstHome Commands with literal 'X30.Z30.'.
Added SetTurret Sub:
Called from FirstOperation, NewTool and SameTool.
Stores Tool# in VarNum1.
Stores ToolOffset# in VarNum2.
IF Tool# > 20, SUBtracts 20 from both VarNums.
This could cause a problem if User changes value of ToolOffset#.
Sends both Turrets Home.
Added TurretSequence Sub:
Called from FirstOperation and NewTool.
Outputs special Seq and necessary G13/G14 code.
Added TurretToolID Sub:
Called from FirstOperation, NewTool and SameTool.
Outputs VarNum(2) VarNum(1) VarNum(2) for 6-digit OpToolID.
Modified ToolTypeComment to output current Turret.
This Post Processor Supports RoughContour, RoughPatternShift, Threading, FIRO, FIDRO, Peck and
Tap Canned Cycles.
RoughContour and RoughPatternShift Cycles start at 'NLAP' Tag# and end at G80 Command.
No need for Start and End Block Tagging and unconditional SeqLabs.
Changed OpToolID LatheOffset to ToolID at AppMove and moved to FirstOperation and NewTool.
Moved CoolOn at AppMove to FirstOperation and NewTool.
Modified CheckOffset sub to match similar output at FirstOperation and NewTool.
Changed Manual Threading Cycle G32 to G33 at ToolPath and Canned Threading AutoFinish.
Deleted CheckRapid sub, changed CheckRapid to RapidC at NewTool, SameTool and end of Prog.
Changed SetAbs to SetAbsOrInc at setup and initializations.
Changed NegSideLathe to PosSideLathe at setup and initializations.
Changed ReverseXZArcs to StandardXZArcs at setup and initializations.
Deleted ProgID1 at FirstOperation.
Modified StartUp output at FirstOperation and NewTool.
Turning ConstantSurfaceFeed on at Home.
Deleted CalcRPM1 at FirstOperation and NewTool, always using Speed.
Deleted CalcRPM2 at NewTool.
Deleted ConstantSurfaceFeed logic at CommonPoint.
Deleted CalcEPRPM# at end of Program, and FORMAT for same.
Deleted LOfstOff '00' at NewTool.
Deleted CoolOff at end of Prog.
Deleted OpToolID '00' at end of Prog.
Deleted UnTool '00' at end of Prog.
JR}

{7/15/92
Modified: Okuma OSP 5000 LC10 L235.82
For: Machine Specialties
Changes made per Joseph Landry and Bob Shumaker at Machine Specialties.
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82 Format.
Deleted AppMove Sub.
Modified Approach Sub to bypass Move to XCP and/or ZCP when coming from ToolChng Position.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '+####.####;0'
#3 = '#######0'
#4 = '###.##;0'
#5 = '00' { See TurretToolID sub }
#6 = '####.####;0'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(XCutDepth#,2)
FORMAT(ZCutDepth#,2)
FORMAT(Recall#,3)
FORMAT(ToolOffset#,3)
FORMAT(ToolLess20#,3)
FORMAT(ToolOffsetLess20#,3)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(Peck#,6)
FORMAT(RapidF#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

Tab:
' '
RETURN

TurretHome:
SeqLabC 'X30.Z30.' EOL
RETURN

SetTurret:
Save# Num#('1') Tool#
Save# Num#('2') ToolOffset#
IF GreaterThan? Tool# Num#('20')
Save# Num#('1') SUB# Recall# Num#('1') Num#('20')
Save# Num#('2') SUB# Recall# Num#('2') Num#('20')
END
IF FirstOperation? { Send Turrets Home }
SeqLabC 'G13' EOL
Rapid TurretHome
SeqLabC 'G14' EOL
Rapid TurretHome
END
RETURN

TurretSequence:
IF GreaterThan? Tool# Num#('20')
'Ś2' Recall# Num#('1') '00' EOL
SeqLab
IF FirstOperation?
SeqLabC 'G14' EOL
ELSE { NewTool }
IF LTEqual? LAST Tool# Num#('20')
SeqLabC 'G14' EOL
END
END
ELSE
'Ś1' Recall# Num#('1') '00' EOL
SeqLab
IF FirstOperation?
SeqLabC 'G13' EOL
ELSE { NewTool }
IF GreaterThan? LAST Tool# Num#('20')
SeqLabC 'G13' EOL
END
END
END
RETURN

TurretToolID:
FORMAT(Recall#,5)
'T' Recall# Num#('2') Recall# Num#('1') Recall# Num#('2')
FORMAT(Recall#,3)
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TURRET '
IF GreaterThan? Tool# Num#('20')
'B'
ELSE
'A'
END
' TOOL ' Recall# Num#('1') ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ODApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

IDApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

FaceApproachSP:
SeqLabC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC XOpCD StockOnNoCan ZSP EOL
ODApproachSP
ELSE
IF ApproachID?
SeqLabC XOpCD StockOnNoCan ZSP EOL
IDApproachSP
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP StockOff ZOpCP EOL
FaceApproachSP
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
ELSE
SeqLabC Preset MaxRPM EOL
END
END
SeqLabC
IF NewToolOffset?
SetTurret
TurretToolID
END
IF LAST ProgStop?
Tab CoolOn
ELSE
IF NOT CoolOff? AND LAST CoolOff?
Tab CoolOn
END
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
SpeedC
ELSE
Tab CSSOn 'G96' Tab Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
Tab CSSOff 'G97' Tab Speed
ELSE
SpeedC
END
END
IF LAST ProgStop?
SpinOn
END
EOL
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G33' MoveXC MoveZC
IF Taper?
XTapAtZ
END
ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbsOrInc
PosSideLathe
StandardXZArcs
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
SetTurret
DoOpComments
DoPostScript
Plane
TurretSequence
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
SeqLabC TurretToolID Tab CoolOn Tab
IF ConstantSurfaceFeed?
CSSOn 'G96'
ELSE
CSSOff 'G97'
END
Tab Speed SpinOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
RapidC
IF LAST ApproachOD?
SeqLabC XCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC ZCPC EOL
DoEndOpPS
TurretHome
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

SetTurret
DoOpComments
DoPostScript
TurretSequence
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
SeqLabC TurretToolID Tab CoolOn Tab
IF ConstantSurfaceFeed?
CSSOn 'G96'
ELSE
CSSOff 'G97'
END
Tab Speed SpinOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
RapidC
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
RapidC
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
SeqLabC XCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
END
SeqLabC ZCPC EOL
SeqLabC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
TagInc
SetPass2
IF RoughContour?
SeqLabC 'G85NLAP' Tag# Tab CutDepth FeedRate XStkLeft ZStkLeft EOL
'NLAP' Tag# Tab LCycle EOL
ELSE
IF RoughPatternShift?
SeqLabC LCycle 'NLAP' Tag# Tab 'D'
IF ApproachFace?
ZCutDepth#
ELSE
XCutDepth#
END
FeedRate XStkLeft ZStkLeft EOL
'NLAP' Tag# Tab
IF ApproachFace?
'G82'
ELSE
'G81'
END
EOL
END
END
SeqLabC StepMove StrtPos EOL
ToolPath
SeqLabC 'G80' EOL
IF AutoFinish?
SeqLabC 'G87NLAP' Tag# EOL
END
SetAbs
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
SetAbsOrInc
ELSE
IF Threading?
{ Face Threads require G72, ZTapAtX and W Address for XTapAtZ }
SeqLabC LCycle XatFinZ FinZ XTapAtZ
IF SingleEdgeCut?
ToolAngle
ELSE
'B0'
END
CutDepth ThrdHeight ThrdLead 'M32'
IF ConstantVolumeCut?
'M75'
ELSE
'M74'
END
IF Chamfer?
'M23'
ELSE
'M22'
END
EOL
IF AutoFinish?
SeqLabC 'G33' XatFinZ FinZ
IF Taper?
XTapAtZ
END
ThrdLead EOL
END
ELSE
IF Drilling?
SeqLabC
IF Tap? AND NOT CWSpindle?
'G78'
ELSE
LCycle
END
XCSP ZDepth Peck Retract
IF PeckFullRetract?
'L' Peck#
END
FeedRate Dwell EOL
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple?
StockOff
IF Turning?
SetPass1
RapidC
IF ApproachFace?
SeqLabC ZOpECPC EOL
FaceApproachSP
ELSE
SeqLabC XOpECDC EOL
IF ApproachOD?
ODApproachSP
ELSE {ApproachID}
IDApproachSP
END
END
ELSE
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
END
ToolPath
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed SpinOn EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
RapidC
IF ApproachOD?
SeqLabC XCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC ZCPC EOL
DoEndOpPS
TurretHome
IF ProgStop?
SeqLabC 'M0' EOL
END
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END