{Change Comments ***********************************************************}

{12/5/89
Copied & modified: Dynapath 10M (SM) M262.62
For: General Dynamics
Deleted literal 'G' 3 places in ToolPath.
JR}

{12/18/89
Modified: Dynapath 10M [GD] M277.61
For: General Dynamics
Delete Coolant & GearRange commands.
Control requires ASCII('36') at end of every conversational block.
Added ASCII('36') Line Terminator Code in Mach Spec ('$'), but Retag command causes '$$',
which is not acceptable.
Added '$' to every block of output in Prog.
Modified for 'FIRST TOOL NOT IN SPINDLE' FORMAT.
Move ToolTypeComment to be last Comment of DoOpComments.
Added ToolChng after DoOpComments in FirstOperation and NewTool.
Moved SpinOn OpToolID Speed to line following ToolChng.
Added WorkFixtureOffsets, E1 to E9, in Mach Spec.
Modified MiltipleParts to use WorkFixtureOffsets.
JR}

{6/5/90, Updated: Dynapath 10M [GD] M277.62 to .72.1 format, JR}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}

{4/16/91
Copied & modified: Dynapath 10M [GD] M277.73
For: Gibbs & Associates
Machine:
Control: Dynapath 10M
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
Made major modifications per conversation with Dale Bachman at Dynapath Systems, Inc.
This processor is totally conversational.
Added Flag('1') to check if CRCOn (C1) has been output.
CutterRadiusCompensation rules:
CRCOn (C1) must only be activated when Feed (1) or CWArc/CCWArc (2) are active.
Control requires CRCOff (C0) DummyMove on line preceeding CRCOn (C1).
Added logic to output SPX# SPY# CRCOff (C0) in TurnOnCRC Sub.
Rapid (0) must NOT be output while CRCOn (C1) is active.
When RapidFeat, CutterRadiusCompensation and Flag('1') are TRUE:
Added logic to output FeedC (1) MoveXYZC RapidFC (F199.1) in ToolPath.
RapidFC set to output F199.1 in Mach Spec.
Control requires CRCOff (C0) DummyMove when cancelling CRCOn (C1).
Added logic to output MoveXY CRCOff (C0) in TurnOffCRC Sub.
DWB}

{9/21/95, Updated Dynapath 10M [GD] M277.80 to .85 format per Dynapath 10M M078.85 .01, JR}

{12/13/95
Initial: Dynapath 10M [GD] M277.85
Created: Dynapath 10M [AM] Mxxx.85
ForUser: Applied Materials
Develop: ComPost 4.21.33, Catalyst68K v2.30.18C
Comment: Modifications per notes from John King
Changed ToolOfst to OpToolID & moved to ToolChng line in FirstOp and NewTool.
Deleted ToolOfst from SameTool.
Added CoolOn and CoolOff commands.
Modified to support retract to first clearance plane for drilling.
Jim Radcliffe}

{1/26/96
Initial: Dynapath 10M [AM] M906.85
Created: Dynapath 10M [AM] M906.85.1
Comments: Added"$" after coolant on & off, changed rigid tapping cycle to output
pitch as feed rate and to output feed rate as negative if ² 4, eliminated CoolOff betwwen mulitple parts
as per customer request, MPK}

{8/19/96
Initial: Dynapath 10M [AM] M906.85.1
Created: Dynapath 10M [AM] M906.85.2
ForUser: Murtaugh / Applied Materials
Develop: ComPost2 68k, Catalyst68K v3.04.10.C
Comment: Changes per John King
Added missing Get$ call at WFO1 line in CloseMP.
Added missing prog formatter for RapidF
Changed RapidF from 199.1 to 199.
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '###.#;0'
#7 = '*####.####;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(SPX#,4)
FORMAT(SPY#,4)
FORMAT(Retract#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(RapidF#,6)
FORMAT(Recall#,7)

{Prog Subroutines **********************************************************}

Get$:
IF NOT EmptyLine?
'$'
END
RETURN

DrillCycle:
RLevel ZDepth Dwell Peck
IF PeckChipBreaker?
'/Q' Retract#
END
IF Tap? AND OptCyc1?
Save# Num#('1') DIV# Num#('1') FeedTapIPR#('1')
IF LTEqual? Recall# Num#('1') Num#('4') {Evaulate for metric thread}
FORMAT(Recall#,7)
ELSE
FORMAT(Recall#,4)
END
'F' Recall# Num#('1') 'G8'
ELSE
FeedEnt Cycle
END
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
NewProg
IF UseComments? AND SubComment?
SeqLab '(T) SUB NUMBER ' Program# Get$ EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLab '(T) OPERATION ' Operation# ' ' OperationType$ Get$ EOL
END
IF OperationComment?
SeqLab '(T) ' OperationComment$ Get$ EOL
END
IF WorkGroupComment?
SeqLab '(T) ' WorkGroupComment$ Get$ EOL
END
IF ToolComment?
SeqLab '(T) ' ToolComment$ Get$ EOL
END
IF ToolTypeComment?
SeqLab '(T) TOOL# ' Tool# ' ' ToolDiameter# ' ' ToolType$ Get$ EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLab '(0)' 'A' FourthDegree# Get$ EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLab '(0)' 'A' FourthDegree# Get$ EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLab '(0)' 'B' FifthDegree# Get$ EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLab '(0)' 'B' FifthDegree# Get$ EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLab PostScript Get$ EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS Get$ EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLab '(1)' ZIn
IF NOT AbsValue?
'/'
END
FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZIn
IF NOT AbsValue?
'/'
END
Get$ EOL
END
RETURN

StartSub:
OpenSub
DoSubComment
'>' Tag# EOL
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
SeqLab '(T) ' Get$ EOL
SeqLab '(T) *** WARNING ***' Get$ EOL
SeqLab '(T) Z CLEARANCE WILL' Get$ EOL
SeqLab '(T) CHANGE WITH EACH' Get$ EOL
SeqLab '(T) CYCLE OF SUB!' Get$ EOL
SeqLab '(T) ' Get$ EOL
END
END
RETURN

StdSub:
'È' Tag# EOL
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
SeqLab '(6)FÇ' Tag# 'T' RepsLess1 Get$ EOL
StartSub
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
IF AutoCycle?
SeqLab '(0)' ZCP3 Get$ EOL
ELSE
IF FIFO? {.81}
SeqLab '(1)' ZCP3 FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZCP3 Rapid Get$ EOL
END
END
END
RETURN

FinishSubG92: {part 2}
SeqLab '(0)' ShiftRC Preset Get$ EOL
'<' Tag# EOL
TagDown
CloseSub
SeqLab '(0)' UnshftRC Preset Get$ EOL
RETURN

OpenMP:
TagUp TagInc
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqLab '(9)' SetWFO Get$ EOL
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
IncWFO
NextWFO
ELSE
'È' Tag# EOL
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
SeqLab '(6)FÇ' Tag# 'T' PartsLess1 Get$ EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
'<' Tag# EOL
TagDown
CloseSub
SeqLab '(9)' WFO1 Get$ EOL
ELSE
SeqLab '(0)' ShiftPC Preset Get$ EOL
'<' Tag# EOL
TagDown
CloseSub
SeqLab '(0)' UnshftPC Preset Get$ EOL
END
RETURN

GetPlane:
IF XYPlane?
IF NOT AutoCycle?
IF FirstFeat?
IF XMove? OR YMove?
'P0' { This is the default Plane select }
END
END
END
ELSE
IF XZPlane?
'P2'
ELSE {YZPlane}
'P1'
END
END
RETURN

CheckMove:
IF AbsValue?
MoveXYZC
ELSE
IF XMove?
MoveX '/'
END
IF YMove?
MoveY '/'
END
IF ZMove?
MoveZ '/'
END
END
RETURN

CheckDrillMove:
IF AbsValue?
MoveSXYZC
ELSE
IF SPXMove?
MoveSX '/'
END
IF SPYMove?
MoveSY '/'
END
IF SPZMove?
MoveSZ '/'
END
END
RETURN

DoAbsOrInc:
IF Flag?('2') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
SetInc
ELSE
IF NOT ZMove? AND NOT AbsValue?
SetAbs
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('2') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
SetInc
ELSE
IF NOT SPZMove? AND NOT AbsValue?
SetAbs
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('2') AND AbsoluteMoves? AND NOT AbsValue?
SetAbs
END
RETURN

FormatArc:
DoAbsOrInc
GetPlane CheckMove
IF AbsValue?
ArcIJ
ELSE
ArcI '/' ArcJ '/'
END
IF ArcCW?
CWArc
ELSE
CCWArc
END
RETURN

TurnOnCRC:
IF CutterRadiusCompensation? AND NOT Flag?('1')
SetFlag('1')
SeqLab '(1)'
IF AbsValue?
'X' SPX# 'Y' SPY#
ELSE
'X' SPX# '/Y' SPY# '/'
END
CRCOff Get$ EOL
END
RETURN

TurnOffCRC:
IF CutterRadiusCompensation? AND Flag?('1')
SeqLab '(1)'
IF AbsValue?
MoveXY
ELSE
MoveX '/' MoveY '/'
END
CRCOff Get$ EOL
END
RETURN

StdLine: {enables CRC on first call, .70}
TurnOnCRC
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab '(1)' DoAbsOrInc GetPlane CheckMove CRCOnC FeedRateC Get$ EOL
DecelMove2
END
SeqLab '(1)' DoAbsOrInc GetPlane CheckMove CRCOnC DecelFeed Get$ EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLab '(1)' DoAbsOrInc GetPlane CheckMove CRCOnC FeedRateC Get$ EOL
END
END
RETURN

ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
IF AutoCycle?
IF NOT FirstFeat?
SeqLab '(0)' MoveSXYC Get$ EOL
END
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF NOT FirstFeat?
IF RetractToCP1? AND NotEqual? ClearancePlane1# ClearancePlane2#
SeqLab '(0)' ZCP1 Rapid Get$ EOL {retracting from last hole!}
SeqLab '(0)' MoveSX MoveSY Rapid Get$ EOL
SeqLab '(0)' MoveSX MoveSY DrillCycle Get$ EOL
ELSE
SeqLab '(0)' DoDrillAbsOrInc CheckDrillMove Get$ EOL
END
END
END
ELSE
IF RapidFeat?
IF CutterRadiusCompensation? AND Flag?('1')
IF XMove? OR YMove? OR ZMove?
SeqLab '(1)' DoAbsOrInc GetPlane CheckMove RapidFC Get$ EOL
END
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLab '(0)' DoAbsOrInc GetPlane CheckMove Get$ EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLab '(1)' DoAbsOrInc CheckMove FeedRateC Get$ EOL
ELSE
StdLine {enables CRC on first call}
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab '(2)' FormatArc ArcFeedC Get$ EOL
DecelMove2
END
SeqLab '(2)' FormatArc DecelFeed Get$ EOL
ELSE
SeqLab '(2)' FormatArc ArcFeedC Get$ EOL
END
NEXTQuadrant
END
END
END
IF LastFeat?
TurnOffCRC
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
Get$ EOL
SeqLab '(T) ' Get$ EOL
SeqLab '(T) *** WARNING ***' Get$ EOL
SeqLab '(T) DO NOT USE' Get$ EOL
SeqLab '(T) NEWWFO() WITH' Get$ EOL
SeqLab '(T) NCPOST MULTIPLE' Get$ EOL
SeqLab '(T) PARTS!' Get$ EOL
SeqLab '(T) ' Get$ EOL
ELSE
SeqLab '(9)E' NewWFO# Get$ EOL
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
SeqLab '(9)E' NewWFO# Get$ EOL
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SetInc
SeqLab '(1)' 'P0X0./Y0./' Get$ EOL { AutoCycle dummy move to select correct Plane }
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SetAbs
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO? {.81}
SeqLab '(1)' ZCP2 FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZCP2 Rapid Get$ EOL
END
END
'<' Tag# EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagUp TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
TagDown
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLab
IF FeedConnect?
'(1)'
ELSE
'(0)'
END
StrtPos Get$ EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagUp TagInc
EachCycle
IF FeedConnect?
SeqLab '(1)' ZInPlusInc FeedEnt Get$ EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqLab '(0)' ZCP2PlusInc Get$ EOL {.69 added Rapid, reads better}
{can't call for cycle = 1, .69 changed to ZCP2PlusInc}
END
SeqLab '(1)' ZInPlusInc FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZInPlusInc Get$ EOL {.69 added Rapid, reads better}
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqLab '(1)' ZCP2 FeedEnt Get$ EOL {.69}
ELSE
SeqLab '(0)' ZCP2 Rapid Get$ EOL {.69}
END
END {.69}
TagDown
'<' Tag# EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLab
IF FeedConnect? {.71.2, added Connect}
'(1)'
ELSE
'(0)'
END
StrtPos Get$ EOL
END
IF FeedConnect?
SeqLab '(1)' ZInPlusInc FeedEnt Get$ EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLab '(0)' ZCP2PlusInc Get$ EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLab '(1)' ZInPlusInc FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZInPlusInc Get$ EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
'<' Tag# EOL
TagDown
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

CheckRapid:
IF Repeats?
IF FeedConnect?
Rapid
END
ELSE
Rapid
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
WFOStuff
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetAbs
SetFlagF('2') { Milling ZShiftOnly SepSubs }
IF PSComment? AND UseComments?
SeqLab '(T) PostScript:' Get$ EOL
SeqLab '(T) Literals: put between single or double quotes.' Get$ EOL
SeqLab '(T) Separate commands and literals with at least one space.' Get$ EOL
SeqLab '(T) A CR ( RETURN key ) will start a new line.' Get$ EOL
SeqLab '(T) Commands: may be capital and/or lower case letters. Separate commands with a space.' Get$ EOL
SeqLab '(T) EndOP -' Get$ EOL
SeqLab '(T) all literals and commands before an ENDOP command' Get$ EOL
SeqLab '(T) will appear at the beginning of the operation. All' Get$ EOL
SeqLab '(T) literals and commands after an ENDOP command will appear' Get$ EOL
SeqLab '(T) at the end of the operation.' Get$ EOL
SeqLab '(T) NewWFO(56), NWFO(56) -' Get$ EOL
SeqLab '(T) The Work Fixture Offset # you specify will be used for all following operations.' Get$ EOL
SeqLab '(T) Do not use with the ncPost multiple part option.' Get$ EOL
SeqLab '(T) 4thAxisCW(12.5), 4ACW(12.5) -' Get$ EOL
SeqLab '(T) generates a + A move of the value you specify' Get$ EOL
SeqLab '(T) 4thAxisCCW(22.5), 4ACCW(22.5) -' Get$ EOL
SeqLab '(T) generates a - A move of the value you specify' Get$ EOL
SeqLab '(T) 5thAxisCW(30), 5ACW(30) -' Get$ EOL
SeqLab '(T) generates a + B move of the value you specify' Get$ EOL
SeqLab '(T) 5thAxisCCW(22.5), 5ACCW(22.5) -' Get$ EOL
SeqLab '(T) generates a - B move of the value you specify' Get$ EOL
END
EachOp {Start of post processing *********************}
SetFlagF('1') { Flag to set-up CutterRadiusCompensation }
Plane { no output }
IF FirstOperation?
'(' Program# ')' EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
SeqLab '(T) PROGRAM ' ProgramName$ Get$ EOL
END
IF ProgramComment?
SeqLab '(T) ' ProgramComment$ Get$ EOL
END
IF FormatNameComment?
SeqLab '(T) FORMAT ' FormatName$ Get$ EOL
END
IF TimeComment?
SeqLab '(T) ' Date$ ' AT ' Time$ Get$ EOL
END
IF MovesComment?
SeqLab '(T) OUTPUT IN ABSOLUTE INCHES' Get$ EOL
END
IF PartsComment?
SeqLab '(T) PARTS PROGRAMMED ' Parts# Get$ EOL
END
IF StartToolComment?
SeqLab '(T) FIRST TOOL NOT IN SPINDLE' Get$ EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
DoPostScript
WFOStuff
SeqLab '(9)' OpToolID ToolChng Get$ EOL
SeqLab '(9)' SpinOn Speed Get$ EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
SeqLab '(9)' CoolOn Get$ EOL
CheckPass
SeqLab '(0)' StrtPos ZCP1 Rapid Get$ EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab '(0)' StrtPos Rapid Get$ EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
SeqLab '(9)' CoolOff Get$ EOL
DoEndOpPS
IF LAST ProgStop?
SeqLab '(9)' 'M0' Get$ EOL
ELSE
IF OptionalStops?
SeqLab '(9)' ProgStop Get$ EOL
END
END

{Start new Operation}

DoOpComments
DoPostScript
WFOStuff
SeqLab '(9)' OpToolID ToolChng Get$ EOL
SeqLab '(9)' SpinOn Speed Get$ EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
SeqLab '(9)' CoolOn Get$ EOL
CheckPass
SeqLab '(0)' StrtPos ZCP1 Rapid Get$ EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab '(0)' StrtPos Rapid Get$ EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLab '(9)' CoolOff Get$ EOL
SeqLab '(9)' 'M0' Get$ EOL

{Start new Operation}

GetStartOfSameTool
SeqLab '(9)' SpinOn Speed Get$ EOL
SeqLab '(9)' CoolOn Get$ EOL
SeqLab '(0)' StrtPos ZCP1 Rapid Get$ EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLab '(9)' CoolOff Get$ EOL
END
IF NewToolOffset?

{Start new Operation}

GetStartOfSameTool
SeqLab '(9)' Speed Get$ EOL
SeqLab '(0)' StrtPos ZCP1 Rapid Get$ EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqLab '(9)' Speed Get$ EOL
SeqLab '(0)' StrtPos Rapid Get$ EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLab '(9)' CoolOn Get$ EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqLab '(0)' ZCP2 Get$ EOL
IF Repeats?
TagUp TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('2') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('2')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLab '(0)' ZCP3 Get$ EOL
ELSE
IF FIFO? {.81}
SeqLab '(1)' ZCP3 FeedEntC Get$ EOL
ELSE
SeqLab '(0)' ZCP3 CheckRapid Get$ EOL
END
END
ELSE
IF Drilling?
IF Repeats?
TagUp TagInc
StdSub
SeqLab '(0)' StrtPos Get$ EOL
END
GetCycle
SeqLab '(0)' StrtPos DrillCycle Get$ EOL
IF RetractToCP1? AND NotEqual? ClearancePlane1# ClearancePlane2#
ToolPath
ELSE
IF CallMasterOp?
SeqLab '(7)FÅ‚' CallMasterNum# 'L²' CallMasterNum# Get$ EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('2') {std sep sub Zreps in effect}
TagUp NewMasterTag
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
StartSub
ToolPath
'<' Tag# EOL
TagDown
CloseSub
SetFlagF('2') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
END
IF Repeats?
FinishSubG92
END
SeqLab '(0)' ZCP3 Rapid Get$ EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLab '(9)' CoolOff Get$ EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqLab '(0)' FirstHome Get$ EOL
END
IF ProgStop?
SeqLab '(9)' 'M0' Get$ EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLab '(9)' EOP Get$ EOL
CloseSub
Post2 {organize Subs into one program}
SeqLab '(9)' EOP Get$ EOL { This is required a second time, at end of all subs }
'END' EOL
Close
ReTag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'N9997(T) FILE LENGTH: ' FileBytes# ' CHARACTERS' Get$ EOL
END
IF FileFeetComment?
'N9998(T) FILE LENGTH: ' FileFeet# ' FEET' Get$ EOL
END
IF FileMetersComment?
'N9999(T) FILE LENGTH: ' FileMeters# ' METERS' Get$ EOL
END
Close
END