{Change Comments ***********************************************************}

{2/11/93
Updated: Heid TNC 155 M281.81.2m
For: Fructus
Changes made per Mikael Bagge of Fructus.
Added Program2# to Format#5.
Added SaveProgNum2 to setup and initializations.
Changed ProgramName$ to Program# at FirstOperation.
Deleted literal 'Z' from 'BLK FORM 0.1' at FirstOperation.
Added 6 blocks of Tool Change sub at FirstOperation.
Added call to Tool Change sub at NewTool and end of Prog.
Deleted ToolChangeAtHome output at end of Prog.
Changed literal ' STOP M02' to ' L R F M02' at end of Prog.
Changed ProgramName$ to Program2# at end of Prog.
Added Flag(1) to output ArcFeat as LineFeat IF LTEqual? ArcR# Num#(.002mm) at ToolPath.
DWB}

{2/23/93
Updated: Heid TNC 155 [PB] M550.81.2m
For: Fructus
Changes made per Mikael Bagge of Fructus.
Deleted SpeedRPM# from FORMAT Definitions.
Added IF UseComments? at SubWarning.
Changed SetMaxRPM from 10000 to 3000 at setup and initializations.
Added SetProgNum('1') at setup and initializations.
Changed Program# to Program2# at FirstOperation.
Added literal 'Z' to 'BLK FORM 0.1' at FirstOperation.
This was deleted per Mikaels instructions of 2/11/93, he admitted his mistake.
Deleted literal 'R F' on block following CoolOff at FirstOperation.
Changed all occurances of TABLE(4001,SpeedRPM#,1) to Speed.
Deleted Table from Form Resources.
Added literal 'ETX', End of Transmission at end of Prog.
DWB}

{3/2/93
Updated: Heid TNC 155 [PB] M550.81.3m
For: Fructus
Changes made per Mikael Bagge of Fructus.
Changed IF LTEqual? ArcR# Num#('.002') to IF LessThan? ArcR# Num#('.02') at ToolPath ArcFeat.
Changed literal 'ETX' to ASCII('3') at end of Prog.
DWB}

{3/2/93
Updated: Heid TNC 155 [PB] M550.81.4m
For: Fructus
Changes made per Mikael Bagge of Fructus.
Changed FORMAT for ClearancePlane2# from Ä…####0.000 to Ä…*####0.000.
DWB}

{12/3/93
Modified: Heid TNC 155 [PB] M550.81.5m
To: Heid TNC 155 [PB] M550.81.6m
Fixed the RestoreScale function to work with both english and metric parts. Also removed
unneeded setscale commands and replaced them with math ( number ) commands.
Forced all drilling parameter values ( depth, clearance, peck, etc. ) to be
negative.
[cwh]}

{4/4/96
Updated: Heid TNC 155 [PB] M550.81.6m
For: Fructus/Pharmacia Biosensors
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.02.07/Compost 4.21.34.1/1.0a
Changes made per Mikael Bagge of Fructus.
Updated for Catalyst v3.0 per Fanuc 6M M001.89m Format.
This post was updated using Heid TNC 155 [EMC] M612.85m.
DWB}

{4/24/97
Updated & Modified: Heid TNC 155 [PB] M550.89m
Created: Heid TNC 155 [FS] MY83.89m
For: Fructus/Stiga
Machine:
Control:
Versions: Catalyst v3.33C/ComPost2 MSL 68K
Changes made per Mikael Bagge of Fructus, EMail and Post Test VNC File.
Mikael requested that the TOOL DEF blocks be deleted because customer's machine has a
Tool Register.
Deleted TLDia# from FORMAT#4 at Prog Numeric Format Definitions.
Deleted TLLength# from FORMAT#4 at Prog Numeric Format Definitions.
Deleted TLNum# from FORMAT#4 at Prog Numeric Format Definitions.
Deleted EachTool/NextTool loop at FirstOperation.
Corrected Drilling Operations for RetractToCP1 and variable DrillDepths.
RetractToCP1 and variable DrillDepths requires entire Cycle to redefined at appropriate hole
locations.
This means MasterOp and CallMasterOp cannot be supported for these situations.
Deleted contents of DoDrillAbsOrInc sub.
Added DrillCycle sub for redefinition of Cycle.
Called from ToolPath PointFeat.
Added support of RetractToCP1 and variable DrillDepths at ToolPath PointFeat.
Added RetractToCP1 and SPZMove test at IF Drilling.
Deleted Flag(1) at IF Drilling.
Corrected AutoCycles.
Modified ToolPath PointFeat.
Was outputting CYCL CALL block which does applies only to Drilling Cycles.
Was outputting M99 which does applies only to Drilling Cycles.
Other modifications:
Changed IF AutoCycle? to IF NOT AbsValue? at EntryMove.
For support of Incremental InFeed.
Changed ArcR# to ABS# ArcR# two places at ToolPath ArcFeat.
Post was outputting a LineFeat for any ArcR# less than .02.
This modification repairs any unwanted situation when negative ArcR# is less than -.02.
Updated ZonlyRepAutoCycle.
Added StartPosX# to FORMAT#4 at Prog Numeric Format Definitions.
Added StartPosY# to FORMAT#4 at Prog Numeric Format Definitions.
Changed SPX# to StartPosX# two places at ZonlyRepAutoCycle.
Changed SPY# to StartPosY# two places at ZonlyRepAutoCycle.
Rewrote logic per Catalyst v3.0.
Added IF EquallySpacedOffsets? condition for MP-OTAP-ECP condition at FirstOperation and NewTool.
Suppresses second StrtPos block for WorkFixtureOffset programs.
Deleted LoadFeat to ZCP3 at end of IF Milling.
NOT ZMove result bypassed output of CoolOff command.
Updated for Catalyst v3.33C per Fanuc 6M M001.89b Format.
Used Heid TNC 355 [SP] MY41.15m.
Deleted version comments.
Added NewWFOF at PSInit.
DWB}

{5/8/97
Modified: Heid TNC 155 [FS] MY83.89m
Created: Heid TNC 155 [FS] MY83.89.1m
For: Fructus/Stiga
Versions: Catalyst v3.33C/ComPost2 MSL 68K
Changes made per Mikael Bagge of Fructus, EMail and "Post Test 1" VNC File.
Deleted RetractToCP1 conditions at ToolPath PointFeat and IF Drilling.
Changed literal 'S 0.000' to 'S' at FirstOperation.
DWB}

{6/25/97
Modified: Heid TNC 155 [FS] MY83.89.1m
Created: Heid TNC 155 [FS] MY83.89.2m
For: Fructus/Stiga
Versions: Catalyst v3.33C/ComPost2 MSL 68K
Changes made per Mikael Bagge of Fructus, EMail and "Post Test 2" VNC File.
Modified handling of Spindle and Coolant.
Mikael requested that M03 be changed to M13 and M05, M08 and M09 be deleted.
Added GetSpinCoolOn sub.
Called from FirstOperation, NewTool and SameTool.
Deleted CheckCoolOn sub.
Was called from start of IF Milling and IF Drilling.
Deleted CheckCoolOff sub.
Was called from end of IF Milling and IF Drilling.
Changed literal ' X+0.000 Y+0.000' to ' X' HomeX# ' Y' HomeY# at FirstOperation.
DWB}

{9/10/97
Modified: Heid TNC 155 [FS] MY83.89.2m
Created: Heid TNC 155 [FS] MY83.89.3m
For: Fructus/Stiga
Versions: Catalyst v3.35C/ComPost2 MSL 68K
Changes made per Mikael Bagge of Fructus, EMail and "Post Test 3" VNC File.
Added SeqLab ' L R F' ToolChng EOL block to LBL 1 sub at FirstOperation.
DWB}

{9/25/97
Copied: Heid TNC 155 [FS] MY83.89.3m
Created: Heid TNC 155 [FLV] Mxxx.89m
For: Fructus/LŠckš Verktyg
Machine:
Control:
Versions: Catalyst v3.35C/ComPost2 MSL 68K
Changes made per Mikael Bagge of Fructus, EMail and "M_POST" VNC File.
Deleted seven ToolChange blocks at FirstOperation.
Consist of LBL 1, TOOL CALL 0, SpinOff, CoolOff, Home, ToolChng and LBL 0 blocks.
Added L R F ToolChng block following TOOL CALL block at FirstOperation and NewTool.
Deleted CALL LBL 1 REP block at NewTool and end of Prog.
DWB}

{Prog Numeric Format Definitions ****}

#1 = '####0.000'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = 'Ä…####0.000'
#5 = '#######0'
#6 = 'Ä…*####0.000'
#7 = '###0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Dwell#,1)
FORMAT(XStockMin#,4)
FORMAT(XStockMax#,4)
FORMAT(YStockMin#,4)
FORMAT(YStockMax#,4)
FORMAT(ZStockMin#,4)
FORMAT(ZStockMax#,4)
FORMAT(HomeX#,4)
FORMAT(HomeY#,4)
FORMAT(StartPosX#,4)
FORMAT(StartPosY#,4)
FORMAT(SPX#,4)
FORMAT(SPY#,4)
FORMAT(SPZ#,4)
FORMAT(EPX#,4)
FORMAT(EPY#,4)
FORMAT(EPZ#,4)
FORMAT(ArcI#,4)
FORMAT(ArcJ#,4)
FORMAT(ZDepth#,4)
FORMAT(RepeatX#,4)
FORMAT(RepeatY#,4)
FORMAT(RepeatZ#,4)
FORMAT(PartShiftX#,4)
FORMAT(PartShiftY#,4)
FORMAT(PartShiftZ#,4)
FORMAT(OriginUnShiftPX#,4)
FORMAT(OriginUnShiftPY#,4)
FORMAT(OriginUnShiftPZ#,4)
FORMAT(OriginUnShiftRX#,4)
FORMAT(OriginUnShiftRY#,4)
FORMAT(OriginUnShiftRZ#,4)
FORMAT(DIV#,4)
FORMAT(Peck#,4)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4)
FORMAT(Program#,5)
FORMAT(Program2#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(Parts#,5)
FORMAT(ABS#,6)
FORMAT(ClearancePlane2#,6)
FORMAT(FeedEntry#,7)

{Special Subs ***********************}

DoL:
' L '
RETURN

DoZL:
DoL
RETURN

Space: { 10 Spaces }
' '
RETURN

XYZSpace:
' ' Space
RETURN

XYSpace:
Space Space
RETURN

ZSpace:
Space Space Space
RETURN

IXYZSpace:
Space
RETURN

IXYSpace:
Space Space
RETURN

IZSpace:
Space Space Space
RETURN

DoR0:
IF NOT Flag?('3') { ArcFeat }
' '
END
IF Flag?('2') { CutterRadiusCompensation }
IF CRCleft?
' RL'
ELSE
' RR'
END
ELSE
' R0'
END
RETURN

RF: { RapidF }
' F9999'
RETURN

DoM:
' M'
RETURN

ckCRCOff:
IF Flag?('2') { CRCOn }
SetFlagF('2')
SeqLab DoL ' IX+0.000 IY+0.000' IXYSpace DoR0 RF DoM EOL
END
RETURN

GetSpinCoolOn:
IF FirstOperation? OR NewTool? OR LAST ProgStop?
IF CoolOff?
SpinOn
ELSE
IF CWSpindle?
' M13'
ELSE
' M14'
END
END
ELSE { SameTool }
IF CoolOff? AND LAST NOT CoolOff?
CoolOff
ELSE
IF NOT CoolOff? AND LAST CoolOff?
CoolOn
ELSE
DoM
END
END
END
RETURN

{Prog Subroutines ****}

RestoreScale:
IF NOT Metric? { CAM file is in English, tools and tool path }
SetScale('25.4') { change to Metric, this is a Metric post }
ELSE
SetScale('1')
END
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets. }
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLab ' A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLab ' A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLab ' B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLab ' B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLab PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
SeqLab DoZL
IF NOT AbsValue?
' IZ' SPZ# IZSpace
ELSE
ZIn ZSpace
END
DoR0
IF FeedEntry?
Feed {no output}
FeedEnt
ELSE
Rapid {no output}
RF
END
DoM EOL
RETURN

StartSub:
OpenSub
DoSubComment
SeqLab ' LBL ' Program# EOL
RETURN

SubWarning:
IF UseComments?
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
END
RETURN

StdSub:
SeqLab ' CALL LBL ' Program# ' REP ' Repeats# ' / ' Repeats# EOL
StartSub
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
SeqLab DoZL ZCP3 ZSpace
IF Flag?('2') { CRCOn }
SetFlagF('2')
DoR0
SetFlag('2')
ELSE
DoR0
END
IF AutoCycle?
RF
ELSE
IF FIFO?
Feed {no output}
FeedEnt
ELSE
Rapid {no output}
RF
END
END
DoM EOL
END
ckCRCOff
RETURN

FinishSubG92: {part 2}
SeqLab ' CYCL DEF 7.0 NOLLPUNKT' EOL
SeqLab ' CYCL DEF 7.1 IX' RepeatX# EOL
SeqLab ' CYCL DEF 7.2 IY' RepeatY# EOL
SeqLab ' CYCL DEF 7.3 IZ' RepeatZ# EOL
SeqLab ' LBL 0' EOL
CloseSub
SeqLab ' CYCL DEF 7.0 NOLLPUNKT' EOL
SeqLab ' CYCL DEF 7.1 IX' OriginUnShiftRX#('0') EOL
SeqLab ' CYCL DEF 7.2 IY' OriginUnShiftRY#('0') EOL
SeqLab ' CYCL DEF 7.3 IZ' OriginUnShiftRZ#('0') EOL
RETURN

OpenMP:
IF EquallySpacedOffsets?
NewProg
SeqLab ' CALL LBL ' Program# ' REP ' Parts# ' / ' Parts# EOL
StartSub
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
SeqLab ' CYCL DEF 7.0 NOLLPUNKT' EOL
SeqLab ' CYCL DEF 7.1 IX' PartShiftX# EOL
SeqLab ' CYCL DEF 7.2 IY' PartShiftY# EOL
SeqLab ' CYCL DEF 7.3 IZ' PartShiftZ# EOL
SeqLab ' LBL 0' EOL
CloseSub
SeqLab ' CYCL DEF 7.0 NOLLPUNKT' EOL
SeqLab ' CYCL DEF 7.1 IX' OriginUnShiftPX#('0') EOL
SeqLab ' CYCL DEF 7.2 IY' OriginUnShiftPY#('0') EOL
SeqLab ' CYCL DEF 7.3 IZ' OriginUnShiftPZ#('0') EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
SetInc
ELSE
IF NOT ZMove? AND NOT AbsValue?
SetAbs
END
END
END
RETURN

DoDrillAbsOrInc:
{ Not Supported }
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SetAbs
END
RETURN

CheckMove:
IF AutoCycle? OR NOT AbsValue?
IF XMove? OR YMove? OR ArcFeat?
' IX' EPX# ' IY' EPY#
IF ZMove?
' IZ' EPZ# IXYZSpace
ELSE
IXYSpace
END
ELSE
IF ZMove?
' IZ' EPZ# IZSpace
END
END
ELSE
IF XMove? OR YMove? OR ArcFeat?
MoveX MoveY
IF ZMove?
MoveZC XYZSpace
ELSE
XYSpace
END
ELSE
IF ZMove?
MoveZC ZSpace
END
END
END
RETURN

FormatArc:
DoAbsOrInc
SeqLab ' CC '
IF AutoCycle? OR NOT AbsValue? {implies incremental}
' IX' ArcI# ' IY' ArcJ#
ELSE
ArcIJ
END
EOL
SeqLab ' C ' CheckMove
IF ArcCW?
'DR-' CWArc {no output}
ELSE
'DR+' CCWArc {no output}
END
SetFlag('3')
DoR0
SetFlagF('3')
RETURN

ckCRC:
IF CutterRadiusCompensation?
IF LastFeat?
SetFlagF('2') { CRCOff }
ELSE
IF NOT ZMove?
SetFlag('2') { CRCOn }
END
END
END
RETURN

ckCRCNum:
{ Not Supported }
RETURN

FormatLine:
IF ZMove? AND NOT XMove? AND NOT YMove?
DoZL
ELSE
DoL
END
DoAbsOrInc CkCRC CheckMove DoR0
RETURN

DrillCycle:
IF Tap?
SeqLab ' CYCL DEF 2.0 G€NGBORRNING' EOL
SeqLab ' CYCL DEF 2.1 AVST ' ABS# ClearancePlane2# EOL
SeqLab ' CYCL DEF 2.2 DJUP ' ABS# SPZ# EOL
SeqLab ' CYCL DEF 2.3 V.TID 0' EOL
SeqLab ' CYCL DEF 2.4' FeedEnt EOL
ELSE
SeqLab ' CYCL DEF 1.0 DJUPBORRNING' EOL
SeqLab ' CYCL DEF 1.1 AVST ' ABS# ClearancePlane2# EOL
SeqLab ' CYCL DEF 1.2 DJUP ' ABS# SPZ# EOL
SeqLab ' CYCL DEF 1.3 INSTICK '
IF Peck?
ABS# Peck#
ELSE
ABS# SPZ#
END
EOL
SeqLab ' CYCL DEF 1.4 V.TID '
IF Dwell?
Dwell#
ELSE
'0'
END
EOL
SeqLab ' CYCL DEF 1.5' FeedEnt EOL
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
Rapid {no output}
IF AutoCycle?
IF NOT FirstFeat?
SeqLab DoL MoveSX MoveSY XYSpace DoR0 RF DoM EOL
END
SeqLab ' CALL LBL ' Program# ' REP' EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF FirstFeat?
SeqLab ' CYCL CALL ' XYZSpace ZSpace DoM EOL
ELSE
IF SPZMove?
SeqLab DoL MoveSX MoveSY XYSpace DoR0 RF DoM EOL
DrillCycle
SeqLab ' CYCL CALL ' XYZSpace ZSpace DoM EOL
ELSE
SeqLab DoL MoveSX MoveSY XYSpace DoR0 RF ' M99' EOL
END
END
TrackZNO# SPZ#
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
Rapid {no output}
SeqLab FormatLine RF DoM EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
Feed {no output}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab FormatLine FeedRate DoM EOL
DecelMove2
END
SeqLab FormatLine DecelFeed DoM EOL
ELSE
SeqLab FormatLine FeedRate DoM EOL
END
END
ELSE
IF ArcFeat?
SetStatusOff
IF Metric? AND LessThan? ABS# ArcR# Num#('.02')
SetFlag('4')
ELSE
IF NOT Metric? AND LessThan? ABS# ArcR# Num#('.0007874015748031') { .02 Ö 25.4 }
SetFlag('4')
END
END
SetStatusOn
IF Flag?('4')
SeqLab FormatLine FeedRate DoM EOL { StdLine }
ELSE
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
FormatArc ArcFeed DoM EOL
DecelMove2
END
FormatArc DecelFeed DoM EOL
ELSE
FormatArc ArcFeed DoM EOL
END
NEXTQuadrant
END
SetFlagF('4')
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SetInc
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SetAbs
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
SeqLab DoZL ZCP2 ZSpace DoR0
IF FIFO?
Feed {no output}
FeedEnt
ELSE
Rapid {no output}
RF
END
DoM EOL
END
SeqLab ' LBL 0' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SetAbs
SeqLab DoL StrtPos XYSpace DoR0
IF FeedConnect?
Feed {no output}
FeedEnt
ELSE
Rapid {no output}
RF
END
DoM EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed {no output}
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SetInc
SeqLab DoL ' IX' StartPosX# ' IY' StartPosY# IXYSpace DoR0 FeedEnt DoM EOL
SetAbs
END
END
SeqLab DoZL ZInPlusInc ZSpace DoR0 FeedEnt DoM EOL
ELSE
IF NOT FirstCycle?
Rapid {no output}
IF SPXMove? OR SPYMove?
SetInc
SeqLab DoL ' IX' StartPosX# ' IY' StartPosY# IXYSpace DoR0 RF DoM EOL
SetAbs
END
IF FeedEntry?
SeqLab DoZL ZCP2PlusInc ZSpace DoR0 RF DoM EOL
END
END
SeqLab DoZL ZInPlusInc ZSpace DoR0
IF FeedEntry?
Feed {no output}
FeedEnt
ELSE
Rapid {no output}
RF
END
DoM EOL
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLab ' CALL LBL ' Program# ' REP' EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
SeqLab DoZL ZCP2 ZSpace DoR0
IF FIFO?
Feed {no output}
FeedEnt
ELSE
Rapid {no output}
RF
END
DoM EOL
END
SeqLab ' LBL 0' EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLab DoL StrtPos XYSpace DoR0
IF FeedConnect?
Feed {no output}
FeedEnt
ELSE
Rapid {no output}
RF
END
DoM EOL
END
IF FeedConnect?
Feed {no output}
SeqLab DoZL ZInPlusInc ZSpace DoR0 FeedEnt DoM EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
Rapid {no output}
SeqLab DoZL ZCP2PlusInc ZSpace DoR0 RF DoM EOL
END
Feed {no output}
SeqLab DoZL ZInPlusInc ZSpace DoR0 FeedEnt DoM EOL
ELSE
Rapid {no output}
SeqLab DoZL ZInPlusInc ZSpace DoR0 RF DoM EOL
END
END
SeqLab ' CALL LBL ' Program# ' REP' EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqLab ' LBL 0' EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
ReverseXZArcs
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('3000')
SaveProgNum2
SetProgNum('1')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { CRCOff }
SetFlagF('3') { ArcFeat }
SetFlagF('4') { OutPut ArcFeat as StdLine when ArcR# LessThan Num#('.02mm') }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END

IF MultipleParts? AND WorkFixtureOffsets?
'( *** WARNING *** )' EOL
'( THIS POST PROCESSOR DOES NOT SUPPORT WORKFIXTURE OFFSETS. )' EOL
'( PLEASE SELECT EQUALLY SPACED OFFSETS. )' EOL
'( *** WARNING *** )' EOL
END

EachOp {Start of post processing *********************}
IF FirstOperation?
SeqLab ' BEGIN PGM ' Program2# ' MM' EOL
IF ToolChangeAtHome?
SetHome
END
SeqLab ' BLK FORM 0.1 Z X' XStockMin# ' Y' YStockMin# ' Z' ZStockMin# EOL
SeqLab ' BLK FORM 0.2 X' XStockMax# ' Y' YStockMax# ' Z' ZStockMax# EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE METERS )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
Plane {no output}
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
DoPostScript
SeqLab ' TOOL CALL ' Tool# ' Z ' Speed EOL
SeqLab ' L R F' ToolChng EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab DoL StrtPos XYSpace DoR0 RF GetSpinCoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
IF EquallySpacedOffsets?
SeqLab DoL StrtPos XYSpace DoR0 RF DoM EOL
END
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
Rapid {no output}
SeqLab DoL ZCP1 ZSpace DoR0 RF DoM EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF LAST ProgStop?
SeqLab ' STOP M02' EOL
END

{Start new Operation}

Plane {no output}
DoOpComments
DoPostScript
SeqLab ' TOOL CALL ' Tool# ' Z ' Speed EOL
SeqLab ' L R F' ToolChng EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab DoL StrtPos XYSpace DoR0 RF GetSpinCoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
IF EquallySpacedOffsets?
SeqLab DoL StrtPos XYSpace DoR0 RF DoM EOL
END
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLab ' STOP M02' EOL
END

{Start new Operation}

GetStartOfSameTool
SetAbs
Plane {no output}
SeqLab DoL StrtPos XYSpace DoR0 RF GetSpinCoolOn EOL
END
END
END {common point for all operations}
IF Milling?
SeqLab DoZL ZCP2 ZSpace DoR0 RF DoM EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
SeqLab DoZL ZCP3 ZSpace
IF Flag?('2') { CRCOn }
SetFlagF('2')
DoR0
SetFlag('2')
ELSE
DoR0
END
IF AutoCycle?
Rapid {no output}
RF
ELSE
IF FIFO?
Feed {no output}
FeedEnt
ELSE
Rapid {no output}
RF
END
END
DoM EOL
ckCRCOff
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
Rapid {no output}
SeqLab DoL StrtPos XYSpace DoR0 RF DoM EOL
END
SeqLab DoZL ZCP2 ZSpace DoR0 RF DoM EOL
GetCycle
IF Tap?
SeqLab ' CYCL DEF 2.0 G€NGBORRNING' EOL
SeqLab ' CYCL DEF 2.1 AVST ' ABS# ClearancePlane2# EOL
SeqLab ' CYCL DEF 2.2 DJUP ' ABS# ZDepth# EOL
SeqLab ' CYCL DEF 2.3 V.TID 0' EOL
SeqLab ' CYCL DEF 2.4' FeedEnt EOL
ELSE
SeqLab ' CYCL DEF 1.0 DJUPBORRNING' EOL
SeqLab ' CYCL DEF 1.1 AVST ' ABS# ClearancePlane2# EOL
SeqLab ' CYCL DEF 1.2 DJUP ' ABS# ZDepth# EOL
SeqLab ' CYCL DEF 1.3 INSTICK '
IF Peck?
ABS# Peck#
ELSE
SetInc ABS# ZDepth# SetAbs
END
EOL
SeqLab ' CYCL DEF 1.4 V.TID '
IF Dwell?
Dwell#
ELSE
'0'
END
EOL
SeqLab ' CYCL DEF 1.5' FeedEnt EOL
END
TrackZNO# FIRST SPZ#
EachFeat
IF SPZMove?
SetFlag('5')
END
NextFeat
IF Flag?('5')
SetFlagF('5')
TrackZNO# FIRST SPZ#
ToolPath
ELSE
IF CallMasterOp?
SeqLab ' CALL LBL ' CallMasterNum# ' REP' EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
NewMasterProg
SeqLab ' CALL LBL ' Program# ' REP' EOL
StartSub
ToolPath
SeqLab ' LBL 0' EOL
CloseSub
ELSE
ToolPath
END
END
END
SetDrillEndOpZ
Rapid {no output}
SeqLab DoZL ZCP3 ZSpace DoR0 RF DoM EOL
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
Rapid {no output}
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqLab ' L R F M02' EOL
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
Post
SeqLab ' END PGM ' Program2# ' MM' EOL
ASCII('3') EOL { ETX - End of Transmission }
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END