{Change Comments ***********************************************************}

{.551, experimental repeats and multiple parts for manual machines}
{12/28/89, WFG}
{ also has .69 versions, but not sure if someone has a .56??}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}

{4/5/91
Modified: Dynapath 5M Excello M091.70
For: Bio-Rad
Fixed endless looping problem with Multiple Parts.
Updated to .80 format
Jim Radcliffe}

{4/17/91
Modified: Dynapath 5M Excello M091.80
For: Bio-Rad
Put AbsOrInc on line by itself at end of AutoCycle.
Changed 'E0' to WFOOff, same effect.
Deleted CRCOffC from OfstOff line in NewTool, its not needed.
Move OfstOff, in NewTool, to line by itself before literal Z14.
Added WFOOff, in NewTool, to OfstOff line.
Moved OfstOff & WFOOff, at end of program, to a line before literal Z14.
Jim Radcliffe}

{9/13/91
Modified: Dynapath 5M Excello M091.80.1
For: BioRad
All G codes on lines by themselves.
Deleted IncValue OfstOff
Moved OfstOff WFOOff Z14, proper handling of MPFU
Deleted Drilling? Rapid statement, G80 puts control in Rapid mode.
Modified WFOStuff to output in SameTool correctly.
Output forced to Absolute except for AutoCycles.
Added Header Comments
Jim Radcliffe}

{6/3/93
Modified: Dynapath 5M Excello M091.80.2
For: Bio-Rad
Control: Bendix 5M
Machine: Excello 104
Added subroutine and changed to NoNest format.
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '########;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
SeqC
IF FeedEntry?
FeedC Zin
IF SameTool?
FeedEntC
ELSE
FeedEnt
END
ELSE
RapidC Zin
END
EOL
RETURN

StartSub:
OpenSub
EOR EOL
{SubID EOL}
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
EachRep {no loop or repeat commands}
SeqC CallLab EOL
NextRep
StartSub
RETURN

FinishSub1: {part 1}
UnSkipZ
SeqC CRCOffC EOL
IF NOT FeedConnect?
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC ZCP3C EOL
END
END
END
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
NullFoot EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC SetWFO EOL
SeqC CallLab EOL
IncWFO
NextWFO
ELSE
EachPart {no loop or repeat commands}
SeqC CallLab EOL
NextPart
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
NullFoot EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
NullFoot EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC ArcIJC
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CRCOnC EOL
SeqC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
DecelMove2
END
SeqC CRCOnC EOL
SeqC FeedC MoveXYZC DecelFeed CRCOffsetC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC CRCOnC EOL
SeqC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
END
END
RETURN

ToolPath2: {NoNesting, AutoCycles only}
EACHFeat
IF RapidFeat?
IF LastFeat?
SeqC CRCOffC EOL
SeqC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF LastFeat?
SeqC CRCOffC EOL
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
NEXTFeat
RETURN

CutAutoCycle: {NoNesting}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
SeqC IncValue EOL
IF Repeats? AND ZshiftOnly? AND MultipleParts?
EachRep
EntryMove
ToolPath2
IF NOT FeedConnect?
IF FIFO? {.81}
SeqC FeedC PRIME ZCP2 FeedEntC EOL
ELSE
SeqC RapidC PRIME ZCP2 EOL
END
END
NextRep
SeqC AbsValue EOL
IF FIFO? {.81}
SeqC FeedC ZCP2 FeedEntC EOL
ELSE
SeqC RapidC ZCP2 EOL
END
ELSE
EntryMove
ToolPath2
SeqC AbsValue EOL
IF FIFO? {.81}
SeqC FeedC ZCP2 FeedEntC EOL
ELSE
SeqC RapidC ZCP2 EOL
END
END
SetSRSubXY {restore tool position}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
IF MultipleParts? {NoNesting}
CutAutoCycle
ELSE
IF Repeats?
IF ZShiftOnly?
SeqC CallLab EOL
ELSE
CutAutoCycle
END
ELSE
SeqC CallLab EOL
END
END
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle?
SeqC CRCOffC EOL
SeqC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle?
IF LastFeat?
SeqC CRCOffC EOL
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS'
ELSE
' E' NewWFO#
END
ELSE
IF SameTool?
IF LAST ProgStop? OR NewToolOffset?
IF NeedWFO1?
' E' NewWFO#
END
END
ELSE
IF NeedWFO1?
' E' NewWFO#
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqC AbsOrInc EOL {.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
SeqC AbsOrInc EOL
SeqC FeedC ZCP2 FeedEntC EOL
ELSE
SeqC AbsOrInc EOL
SeqC RapidC ZCP2 EOL {.71.2 removed CRCOffC, gets turned off in ToolPath}
END
END
SeqC EndSub EOL
NullFoot EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
IF MultipleParts? OR Repeats? {NoNesting}
ToolPath
ELSE
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
END
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
IF MultipleParts? {NoNesting}
EachRep
IF AutoCycle?
ToolPath
ELSE
IF FirstCycle?
EntryMove
ELSE
IF FeedConnect? {.72.1, minor changes to entry}
SeqC FeedC StrtPosC EOL
SeqC ZInC FeedEntC EOL
ELSE
SeqC RapidC StrtPosC EOL
SeqC ZCP2C EOL
IF FeedEntry?
SeqC FeedC ZInC FeedEntC EOL
ELSE
SeqC RapidC ZInC EOL
END
END
END
ToolPath
FinishSub1
END
NextRep
ELSE
NewProg
SubWarning
StdSub
SeqC Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
END
RETURN

ZonlyRepAutoCycle: {NoNesting}
IF MultipleParts?
ToolPath
ELSE
NewProg
AutoCycPat {write pattern moves and main calls}
AutoCycCutSub1
EachRep
IF NOT FirstCycle?
IF NOT FeedConnect?
SeqC ZCP2 EOL
END
END
EntryMove
ToolPath2
IF NOT FeedConnect?
IF FIFO? {.81}
SeqC FeedC PRIME ZCP2 FeedEntC EOL
ELSE
SeqC RapidC PRIME ZCP2 EOL
END
END
NextRep
IF FIFO? {.81}
SeqC AbsOrInc EOL
SeqC FeedC ZCP2 FeedEntC EOL
ELSE
SeqC AbsOrInc EOL
SeqC RapidC ZCP2 EOL
END
SetSRSubXY {restore tool position}
SetSRSubMove
SeqC EndSub EOL
NullFoot EOL
CloseSub
END
RETURN

ZonlyRep:
NewProg
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
IF MultipleParts? {NoNesting}
SkipZ
ToolPath
FinishSub1
ELSE
SeqC CallLab EOL
END
NextCycle
IF NOT MultipleParts? {NoNesting, nest OK here}
StartSub
SkipZ
ToolPath
FinishSub1
SeqC EndSub EOL
NullFoot EOL
CloseSub
END
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetFlood
InitWFONum
ReverseXZArcs
SetMaxRPM('10000') {not a real limit}
SetMaxFeed('500') {not a real limit}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
OpenSub
EOR EOL
'(TAPE NO. ' ProgramName$ '; TAPE REV. A)' EOL
'(' ProgramComment$ ')' EOL
'(N.C. OPER. NO. ' Program# '; ' Date$ '; EXCELLO 104)' EOL
' ' EOL
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
SeqC Plane EOL
SeqC CRCOff EOL
SeqC ' G80' EOL
SeqC AbsValue OfstOff ' D0' WFOOff EOL
SeqC Rapid ' X20. Y13.5 Z14.' EOL
SeqC Feed ' X21. F25.' EOL
SeqC Rapid ' B0' EOL
SeqC Feed ' X20.' EOL
DoPostScript
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Seq ToolChng OpToolID DoOpComments EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC Rapid StrtPos Speed SpinOn WFOStuff EOL
SeqC OfstOn CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF NewTool?
{Finish off last Operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
SeqC OfstOff WFOOff EOL
SeqC ' Z14.' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
IF LAST ProgStop?
SeqC ' M00' EOL
ELSE
SeqC ProgStop EOL
END

DoEndOpPS

{Start new Operation}

Seq ToolChng OpToolID DoOpComments EOL
SeqC Plane EOL
SeqC CRCOff EOL
SeqC ' G80' EOL
SeqC AbsValue OfstOff ' D0' WFOOff EOL
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC Rapid StrtPos Speed SpinOn WFOStuff EOL
SeqC OfstOn CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC OfstOff WFOOff EOL
SeqC ' Z14.' EOL
SeqC 'M00' EOL

{Start new Operation}

GetStartOfSameTool
Seq PlaneC StrtPos SpeedC SpinOn WFOStuff EOL
SeqC OfstOn CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC OfstOff WFOOff EOL
SeqC ' Z14.' EOL

{Start new Operation}

GetStartOfSameTool
Seq PlaneC StrtPos SpeedC WFOStuff EOL
SeqC OfstOn EOL
ELSE

{Start new Operation}

GetStartOfSameTool
Seq PlaneC StrtPos SpeedC WFOStuff EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
SeqC CRCOffC EOL
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats? {NoNesting}
IF MultipleParts?
EachRep
IF NOT FirstCycle?
SeqC StrtPos EOL
END
ELSE
NewProg
StdSub
SeqC Rapid StrtPos EOL
END
END
SeqC DrillCP EOL
GetCycle
SeqC Cycle FromCP ZDepth RLevel Dwell Peck Retract
IF SameTool?
FeedEntC
ELSE
FeedEnt
END
EOL
TrackZNO# ZDepth# {.81}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqC ' G80' EOL
IF Repeats? {NoNesting}
IF MultipleParts?
NextRep
ELSE
FinishSubG92
END
END
SeqC ZCP3C EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
SeqC OfstOff WFOOff EOL
SeqC ' Z14.' EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqC ' X20. Y13.5' EOL
IF ProgStop?
SeqC ' M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC Feed ' X21. F25.' EOL
SeqC Rapid ' B180.' EOL
SeqC Feed ' X20.' EOP EOL
CloseSub
Post2 {organize Subs into one program}
SetScale('1')
'(FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
'(FILE LENGTH: ' FileFeet# ' FEET )' EOL
'(FILE LENGTH: ' FileMeters# ' METERS )' EOL
Close