Mazatrol M32A [IMM] MW39 89 2


{Change Comments ***********************************************************}

{1/3/89
Copied & modified Fanuc 10M M008.54 for R.C.H. Eng.
Machine is a Mazak VQC 20/40A with Mazatrol M-2 control.
Calling the OpToolID cancels the offset & sends Z home &
puts the tool in the spindle & calls the length offset.
Replaced OfstOff with OpToolID or UnTool at end of prog
so first tool is in spindle at prog start.
Added GearRange. Deleted tool changes & length offset calls.
Deleted Home & SpinOff commands
Put ZCP1 and CoolOn on StrtPos line.
Changed sequence numbers to 3 fixed places.
Jim Radcliffe}

{3/6/89
Modified; Mazatrol M2 Mazak M162.55, for RCH Eng.
Add 'G92Z0.' to end of Prog.
Jim Radcliffe}

{5/23/90, corrected tool call for for multiple parts full up, see above notes, JR}
{5/23/90, Updated: Mazatrol M2 Mazak M162.56 to .72.1 format, JR}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}
{12/12/90, Updated: Mazatrol M2 Mazak M162.73 to .76.1 format, JR}

{12/12/90
Copied & modified: Mazatrol M2 Mazak M162.76.1
For: Precision Machine
Control: Mazatrol M-32
Move ProgramComment & TimeComment to Before EOR code at beginning of prog.
Add AbsOrInc to beginning of prog.
Move WFOStuff to StrtPos line.
First tool not in spindle format.
Deleted GearRange.
Deleted ZCP1 from StrtPos line & added OfstOn.
Move coolant to OfstOn line.
Changed length offset cancel to typical stuff.
Put CRCOff on line by itself after Z move unless AutoCycle.
Add tool change positions 'G28X0Y0'.
Delete UnTool from end of prog.
Added PreTool.
Changed Tapping feed to IPR.
Jim Radcliffe}

{4/3/91
Modified: Mazatrol M-32 Mazak M368.76
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{6/3/91
Modified: Mazatrol M-32 Mazak M368.79
For: Precision Machine
Changed EOR at beginning of program to '='.
Suppress custom ProgramComment & TimeComment before '=' when UseComments? is false.
Modified Saftey Start & Tool Change blocks at beginning of each tool.
Jim Radcliffe}

{10/31/91
Modified: Mazatrol M-32 Mazak M368.79.1
For: Precision Machine
Added ResetCRCNum at beginning of Toolpath to correctly set cutter comp number.
Kim Michelman}

{1/3/92
Modified: Mazatrol M-32 Mazak M368.79.2
For: Precision Machine
Deleted date and time line prior to the ProgID1 per customer request.
Kim Michelman}

{12/22/94
Updated: Mazatrol M-32 Mazak M368.79.3
For: Gibbs & Associates/ASKO
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.04/Compost 4.21.23
Changes made per Pete Jackson
Updated to Version 4.2 per Fanuc 6M M001.81.2f Format.
Corrected FORMAT5 from '########;0' to '#######0'.
Corrected FORMAT6 for Dwell# from '####^###;' to '####^##0'.
Added RestoreScale Sub per 4-Axis Post Processor.
Moved UnSkipZ from FinishSub1 to ZOnlyRep where SkipZ is set.
Added FIFO? at FinishSub1, AutoCycCutSub2, ZonlyRepAutoCycle subs and end of IF Milling.
Added CkCRC sub for CRCOffC per version 4.2.
CutterRadiusCompensation ExitLength will output G40 on LastFeat AND LineFeat at StdLine sub.
Added logic to output CRCOnC in OneFeat ToolPath.
Added logic to suppress output of CRCOnC on ZMove Feature.
Added support of CRC during multiple pocket dog-bone operation.
Added condition to output CRCOnC for XMove OR YMove only at CkCRC sub.
Outputs G41/G42 on First LineFeat after Z Plunge.
Modified condition to output CRCOffC for LastFeat AND AutoCycle at ToolPath RapidFeat.
Assures that G40 is not output prior to LastFeat.
Added CRCOffC to RapidFeat at ToolPath.
Outputs G40 at all ZMoveOnly Feature Retract blocks.
Deleted CRCOnC and CRCOffsetC from ToolPath ArcFeat.
Added TrackZNO# FIRST SPZ# at IF Drilling? section to allow for conditionality of MoveSXYZC command.
DWB}

{9/27/95, Updated Mazatrol M32 Mazak M368.81.2 to .85 format per Fanuc 6M M001.85.01.03, JR}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{1/21/97
Initial: Mazatrol M32 Mazak M368.89
Created: Mazatrol M32 [SK] Mxxx.89
ForUser: SK Machining
Control: Mazatrol M32
Machine: VTC16A
Develop: ComPost2 MSL 68K, Virtual Gibbs 3.23
Comment: New processor per marked up readout from Sanjeev Kapoor.
Changed '=' to '%' at beginning of program.
Moved OpToolID to lin by itself.
Deleted ToolChng.
Deleted PreTool.
Changed OfstOn to 'G43' ZCP1, to eliminate H offset.
Changed machine home to standard ToolChangeAtHome at end of tool.
Jim Radcliffe}

{10/30/97,
Initial Post: Mazatrol M32 Mazak [SK] MY13.89
Created: Mazatrol M32A Mazak [IMM] MW39.89
Customer: Island Mould & Machine

Changes to "Form":

1. Changed Default Format as follow: D00, G00, H00, & N###0.
2. Changed First Work Fixture Offset to G58.
3. Changed Tool Lenght Offset Cancel to G30.
4. Changed End of Program code to G2.

Changes to "Prog":

1. Changed program start sequence.
2. Changed tool change sequenc.
3. Changed program end sequence.
4. Combined DrillOff (G80) with the Z-axis motion.
JHE}

{12/7/97,
Initial Post: Mazatrol M32A Mazak [IMM] MW39.89
Created: Mazatrol M32A Mazak [IMM] MW39.89.1
Customer: Island Mould & Machine

Changes to "Prog":

1. Changed program start sequence.
2. Changed tool change sequenc.
3. Changed program end sequence.
4. Revised output for SameTool and ProgStop.
5. Modified SameTool to output Optional Stop (M01) when OptionalStops? is true.
***** WARNING: THIS IS NOT STANDARD PROCEDURE FOR OptionalStops? ****
JHE}

{1/16/98,
Initial Post: Mazatrol M32A Mazak [IMM] MW39.89.1
Created: Mazatrol M32A Mazak [IMM] MW39.89.2
Customer: Island Mould & Machine

Changes to "Prog":

1. Added RapidC ZCP1C before tool change, SameTool with STOP/OSTOP, & end.
JHE}


{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '####.####;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(FeedEntIPR#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SubID EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall CallLab RepLab RepCycs EOL
StartSub
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC ZCP3C EOL
END
END
END
SeqC CRCOffC EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC SetWFO EOL
SeqC SubCall CallLab RepLab OnePart EOL
IncWFO
NextWFO
ELSE
SeqC SubCall CallLab RepLab Parts EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF LastFeat?
SeqC DoAbsOrInc CRCOffC RapidC MoveXYZC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc CRCOnC RapidC MoveXYZC CRCOffsetC EOL
END
END
END
ELSE
IF LineFeat?
IF LastFeat?
SeqC DoAbsOrInc CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
DecelMove2
END
SeqC DoAbsOrInc CRCOnC FeedC MoveXYZC DecelFeed CRCOffsetC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
END
END
END
END
ELSE
IF ArcFeat?
IF LastFeat?
SeqC CRCOffC FormatArc ArcFeedC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FormatArc ArcFeedC EOL
ELSE
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CRCOnC FormatArc ArcFeedC CRCOffsetC EOL
DecelMove2
END
SeqC CRCOnC FormatArc DecelFeed CRCOffsetC EOL
ELSE
SeqC CRCOnC FormatArc ArcFeedC CRCOffsetC EOL
END
END
END
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
SeqC
ELSE
'G' NewWFO#
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
'G' NewWFO#
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed IncValue StrtPosC EOL
SeqC AbsOrInc
ELSE
SeqC Feed
END
ELSE
SeqC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqC AbsOrInc ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqC Rapid ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLab EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqC Rapid ZCP2 EOL {.69}
END
END {.69}
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqC SubCall CallLab EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *************************************}
IF FirstOperation?
'%' EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
SeqC 'G20' EOL {Added this line - JHE}
SeqC Plane CRCOff DrillOff EOL {Removed CoolOff - JHE 12/7}
SeqC SpinOff CoolOff IncValue OfstOff 'Y0.' EOL {Added this line - JHE 12/7}
SeqC OpToolID PreTool ToolChng EOL {Added PreTool & ToolChng - JHE}
DoOpComments {Changed Seq to SeqC - JHE 12/7}
DoPostScript
SeqC Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC AbsOrInc WFOStuff Rapid StrtPos OfstOn EOL {Added OfstOn - JHE 12/7}
SeqC CoolOn EOL {Removed 'G43' ZCP1 - JHE}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CRCOff EOL {Removed CoolOff - JHE 12/7}
SeqC RapidC ZCP1C EOL {Added this line - JHE 1/16}
SeqC SpinOff CoolOff IncValue OfstOff 'Y0.' EOL {Added this line - JHE 12/7}
{SeqC 'G49' EOL} {Removed this line - JHE}
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
IF ToolChangeAtHome?
SeqC AbsOrInc RapidC Home EOL
END
DoEndOpPS
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

DoOpComments
{Seq Plane CRCOff DrillOff AbsOrInc Rapid 'M19' EOL} {Removed this line - JHE}
SeqC OpToolID PreTool ToolChng EOL {Added PreTool & ToolChng - JHE}
DoPostScript {Changed Seq to SeqC - JHE 12/7}
SeqC Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqC AbsOrInc WFOStuff Rapid StrtPos OfstOn EOL {Added OfstOn - JHE 12/7}
SeqC CoolOn EOL {Removed 'G43' ZCP1 - JHE}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF SameTool?

{Finish off last Operation}
IF LAST ProgStop? OR OptionalStops? {Revised this logic - JHE 12/7}
SeqC RapidC ZCP1C EOL {Added this line - JHE 1/16}
SeqC SpinOff CoolOff IncValue OfstOff 'Y0.' EOL
ELSE
IF NewToolOffset?
SeqC IncValue OfstOff EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
END
DoEndOpPS
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
CheckPass
IF LAST ProgStop? OR OptionalStops? {Revised this logic - JHE 12/7}
SeqC Speed SpinOn EOL
END
IF LAST ProgStop? OR OptionalStops? OR NewToolOffset?
SeqC SpeedC PlaneC AbsOrInc WFOStuff Rapid StrtPos OfstOn EOL
ELSE
SeqC SpeedC PlaneC AbsOrInc WFOStuff Rapid StrtPos EOL
END
IF LAST ProgStop? OR OptionalStops?
SeqC CoolOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC ZCP3C EOL
END
END
SeqC CRCOffC EOL
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC DrillCP EOL
GetCycle
SeqC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract
IF Tap?
'F' FeedEntIPR# EOL
ELSE
FeedEnt EOL
END
IF CallMasterOp?
SeqC SubCall CallLabB CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC SubCall CallLab EOL
StartSub
ToolPath
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
{SeqC 'G80' EOL} {Removed this line - JHE}
SeqC DrillOff Rapid ZCP3 EOL {Added DrillOff - JHE}
IF Repeats?
FinishSubG92
SeqC RapidC ZCP3C EOL
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CRCOff EOL {Added this line - JHE}
SeqC RapidC ZCP1C EOL {Added this line - JHE 1/16}
SeqC SpinOff CoolOff IncValue 'G28Z0.G30Y0.' EOL {Added this line - JHE 12/7}
SeqC 'G28Y0.' EOL {Added this line - JHE}
SeqC OfstOff EOL {Removed IncValue - JHE}
SeqC AbsValue EOL {Removed 'G49' and added AbsValue - JHE}
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC AbsOrInc Rapid FirstHome EOL
END
IF ProgStop?
SeqC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END


Wyszukiwarka

Podobne podstrony:
Mazatrol M32 Mazak M368 89
Servo II [IMM] MW38 89 2
Mazatrol M32 [LP] M590 89
Mazatrol M2 Mzk [ST] M630 89
Mazatrol M32 Mz [NM] MX55 89 7m
Mazatrol M32 Mazak NM MZ20 89 2
Mazatrol M32 Mazak [SK] MY13 89 1
Mazatrol M2 Mzk [ST] M630 89 1m
Mazatrol M32 [B] M488 89
Mazatrol M2 Maz [6D] MT03 89
Mazatrol M2 Mzk [HT] M676 89
Mazatrol M32 Mzk [SP] MU82 89 1
Mazatrol M2 Mazak [WI] M127 89
Mazatrol M32 Mzk [FG] MZ53 89 2
Mazatrol M32 Mz [NM] MX55 89 7

więcej podobnych podstron