{12/2/88
General change to all Bandits.
Deleted: CRCOnC & CRCOffsetC commands from 6 places in ToolPath.
Added Comments.
Changed FormatArc to unconditionaly move X & Y & I & J
Jim Radcliffe}

{6/20/89
Modified; Bandit IIIA Shizouka M011.55.
Change "AbsValue" in first operation to "AbsOrInc".
Jim Radcliffe}

{7/26/89
Copied & modified; Bandit IIIA Shizouka M011.56, for Dougs Machine.
Using a literal 'S65' for speeds.
Move SpinOff to be before OfstOff if not MultipleParts & FullUp.
Jim Radcliffe}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{10/19/90, Updated: Bandit IIIA Kasuga M222.56 to .76.1 format, JR}

{12/21/90
Copied & modified: Bandit IIIA Kasuga M222.76.1
For:Alliance Precision
Added coolant.
Added reset tool changer at end of program.
Jim Radcliffe}

{6/24/91, Updated Bandit IIIA Kas [AP] M375.76.1 to .80 format, fixed ChipBreaker cycle, JR}

{11/19/91
Modified: Bandit IIIA Kas [AP] M375.80
For: Alliance Precision
Updated to fix the nesting problem by copying: Bandit IIIM SMax M024.81
Updated to new 4.0 Version Bandit IIIM SMax M024.81:
Kim Michelman}

{7/2/92
Modified: Bandit IIIA Kas [AP] M375.80
For: Alliance Precision
Removed '/' from the 'Z' in the 'G82' (Boring) cycle in the Mach Spec.
This will remove a rapid from the 'G82' cycle and therefore feeding.
Kim Michelman}

{10/27/92, Bandit IIIA Kas [AP] M375.81.1, corrections, changed to NoNest output, CRC changes, JR}


{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '########;0'
#6 = '##.##;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(Retract#,4)


{Prog Subroutines **********************************************************}

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags}
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
FeedEnt EOL
Feed ZIn EOL
ELSE
RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
MarkSub
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
CallLabB EOL
RepLab RepCycs EOL
'N' EOL
StartSub
RETURN

FinishSub1: {part 1}
UnSkipZ
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C EOL
ELSE
IF FIFO? {.81}
FeedRateC EOL
FeedC ZCP3C EOL
ELSE
RapidC ZCP3C EOL
END
END
END
RETURN

FinishSubG92: {part 2}
Feed ShiftRC Preset EOL
EndSub EOL
CloseSub
Feed UnshftRC Preset EOL
RETURN

OpenMP:
IF EquallySpacedOffsets?
CallLabB EOL
RepLab Parts EOL
'N' EOL
StartSub
END
RETURN

CloseMP:
IF EquallySpacedOffsets?
Feed ShiftPC Preset EOL
EndSub EOL
CloseSub
Feed UnshftPC Preset EOL
END
RETURN

FormatArc:
IF XMove? AND YMove?
IF ArcCW?
CWArcC {no output}
ELSE
CCWArcC {no output}
END
MoveXY MoveZC
IF ArcIJFormat?
ArcIJ
ELSE
ArcRC
END
ELSE
Feed MoveXYZC
END
RETURN

StdRapid:
IF XMove? OR YMove? OR ZMove?
RapidC MoveXYZC EOL
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
FeedRateC EOL
FeedC MoveXYZC EOL
DecelMove2
END
DecelFeed EOL
FeedC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
FeedRateC EOL
FeedC MoveXYZC EOL
END
END
RETURN

StdArc:
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
ArcFeedC EOL
FormatArc EOL
DecelMove2
END
DecelFeed EOL
FormatArc EOL
ELSE
ArcFeedC EOL
FormatArc EOL
END
NEXTQuadrant
RETURN

ToolPath2: {NoNesting} {.72.1, this is for AutoCycles only}
EACHFeat
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
NEXTFeat
RETURN

CutAutoCycle: {NoNesting}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
IncValue EOL
IF Repeats? AND ZshiftOnly? AND MultipleParts?
EachRep
CRCOnC EOL
EntryMove
ToolPath2
IF NOT FeedConnect?
IF FIFO? {.81}
FeedRateC EOL
FeedC PRIME ZCP2 EOL
ELSE
RapidC PRIME ZCP2 EOL
END
END
CRCOffC EOL
NextRep
IF FIFO? {.81}
AbsOrInc EOL
FeedRateC EOL
FeedC ZCP2 EOL
ELSE
AbsOrInc EOL
RapidC ZCP2 EOL
END
ELSE
CRCOnC EOL
EntryMove
ToolPath2
IF FIFO? {.81}
AbsOrInc EOL
FeedRateC EOL
FeedC ZCP2 EOL
ELSE
AbsOrInc EOL
RapidC ZCP2 EOL
END
CRCOffC EOL
END
SetSRSubXY {restore tool position}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF Drilling? AND RetractToCP1? AND NOT FirstFeat?
'G80' EOL
Rapid ZCP1 EOL
MoveSXYC EOL
'G89' EOL
Rapid ZCP2 EOL
ELSE
MoveSXYC EOL
IF AutoCycle?
IF MultipleParts? {NoNesting}
CutAutoCycle
ELSE
IF Repeats?
IF ZShiftOnly?
CallLabB EOL
ELSE
CutAutoCycle
END
ELSE
CallLabB EOL
END
END
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
END
END
ELSE
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
END
NEXTFeat
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
OpenSub
SetPass2 {position pattern}
EachFeat
MarkSub
NextFeat
SetPass1 {element cut moves}
DoSubComment
SetSRXYtoSP
IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
AbsOrInc EOL {.69 removed RapidC}
ELSE
IF FIFO? {.81}
AbsOrInc EOL
FeedRateC EOL
FeedC ZCP2 EOL
ELSE
AbsOrInc EOL
RapidC ZCP2 EOL
END
END
EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
IF MultipleParts? OR Repeats? {NoNesting}
ToolPath
ELSE
AutoCycCutSub1
CRCOnC EOL
EntryMove
AutoCycCutSub2
AutoCycPat
END
ELSE
CRCOnC EOL
EntryMove
ToolPath
END
RETURN

G92Sub:
IF MultipleParts? {NoNesting}
EachRep
IF AutoCycle?
ToolPath
ELSE
CRCOnC EOL
IF FirstCycle?
EntryMove
ELSE
IF FeedConnect?
FeedC StrtPosC EOL
FeedEntC EOL
ZInC EOL
ELSE
RapidC StrtPosC EOL
ZCP2C EOL
IF FeedEntry?
FeedEntC EOL
FeedC ZInC EOL
ELSE
RapidC ZInC EOL
END
END
END
ToolPath
FinishSub1
CRCOffC EOL
END
NextRep
ELSE
SubWarning
StdSub
Connect StrtPos EOL
IF NOT FeedConnect? {then Entry/Exit connect}
IF FeedEntry? {CP2 not needed for Rapid Entry, outputs consecutive Z rapid moves}
ZCP2 EOL
END
END
Milling
FinishSub1
CRCOffC EOL
FinishSubG92
END
RETURN

ZonlyRepAutoCycle: {NoNesting}
IF MultipleParts?
ToolPath
ELSE
AutoCycPat {write pattern moves and main calls}
AutoCycCutSub1
CRCOnC EOL
EachRep
IF NOT FirstCycle?
IF NOT FeedConnect?
ZCP2 EOL
END
END
EntryMove
ToolPath2
IF NOT FeedConnect?
IF FIFO? {.81}
FeedRateC EOL
FeedC PRIME ZCP2 EOL
ELSE
RapidC PRIME ZCP2 EOL
END
END
NextRep
IF FIFO? {.81}
AbsOrInc EOL
FeedRateC EOL
FeedC ZCP2 EOL
ELSE
AbsOrInc EOL
RapidC ZCP2 EOL
END
CRCOffC EOL
SetSRSubXY {restore tool position}
SetSRSubMove
EndSub EOL
CloseSub
END
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
Connect StrtPos EOL
END
CRCOnC EOL
IF FeedConnect?
FeedEnt EOL
FeedC ZInPlusInc EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
FeedEnt EOL
Feed ZInPlusInc EOL
ELSE
RapidC ZInPlusInc EOL
END
END
IF MultipleParts? {NoNesting}
SkipZ
ToolPath
FinishSub1
CRCOffC EOL
ELSE
CallLabB EOL
END
NextCycle
IF NOT MultipleParts? {NoNesting, nest OK here}
OpenSub
EachCycle
MarkSub
NextCycle
DoSubComment
SkipZ
ToolPath
FinishSub1
EndSub EOL
CloseSub
CRCOffC EOL
END
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

InitProg
ReverseXZArcs
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50') {?}
SetMaxRPM('10000') {?}
SetMaxFeed('500') {?}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL IN SPINDLE )' EOL
END
END
OpenSub
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
Plane SpinOn EOL
DoPostScript
CoolOn EOL
'S65' EOL
AbsOrInc EOL
Feed Home Preset EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
Rapid StrtPos EOL
OfstOnB3 EOL
Feed ZCP1 Preset EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP Rapid StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OfstOff EOL
CloseMP
CoolOff EOL
SpinOff EOL
ELSE
CoolOff EOL
SpinOff EOL
OfstOff EOL
END
DoEndOpPS
IF ToolChangeAtHome?
AbsOrInc EOL
Rapid Home EOL
END
IF LAST ProgStop?
'M00' EOL
END

{Start new Operation}

DoOpComments
AutoTool
Plane SpinOn EOL
DoPostScript
CoolOn EOL
'S65' EOL
AbsOrInc EOL
Feed Home Preset EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
Rapid StrtPos EOL
OfstOnB3 EOL
Feed ZCP1 Preset EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP Rapid StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
CoolOff EOL
SpinOff EOL
OfstOff EOL
'M00' EOL

{Start new Operation}

GetStartOfSameTool
Plane SpinOn EOL
CoolOn EOL
'S65' EOL
Rapid StrtPos EOL
OfstOnB3 EOL
Feed ZCP1 Preset EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
CoolOff EOL
END
IF NewToolOffset?

{Start new Operation}

GetStartOfSameTool
OfstOff EOL
Plane EOL
Rapid StrtPos EOL
OfstOnB3 EOL
Feed ZCP1 Preset EOL
ELSE

{Start new Operation}

GetStartOfSameTool
Plane EOL
Rapid StrtPos EOL
END
IF NOT CoolOff? AND LAST CoolOff?
CoolOn EOL
END
END
END
END
END {common point for all operations}
IF Milling?
Rapid ZCP2C EOL
IF Repeats?
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
ZCP3C EOL
ELSE
IF FIFO? {.81}
FeedRateC EOL
FeedC ZCP3C EOL
ELSE
RapidC ZCP3C EOL
END
END
CRCOffC EOL
ELSE
IF Drilling?
IF Repeats? {NoNesting}
IF MultipleParts?
EachRep
ELSE
StdSub
END
Rapid StrtPos EOL
END
Rapid ZCP2C EOL
GetCycle
FeedEnt EOL
ZDepth Dwell Peck Retract Cycle EOL
StrtPos EOL
TrackZNO# ZDepth# {.81}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
'G80' EOL
Rapid ZCP3C EOL
IF Repeats? {NoNesting}
IF MultipleParts?
NextRep
ELSE
FinishSubG92
END
END
Rapid ZCP3C EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OfstOff EOL
CloseMP
CoolOff EOL
SpinOff EOL
ELSE
CoolOff EOL
SpinOff EOL
OfstOff EOL
END
DoEndOpPS
IF FIRST ToolChangeAtHome?
AbsOrInc EOL
Rapid FirstHome EOL
END
IF ProgStop?
'M00' EOL
END
IF NOT FirstTool?
'M20' EOL
'M27' EOL
'M23' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
EOP EOL
Post
Close
IF UseComments?
SetScale('1')
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
Renum