{Change Comments ***********************************************************}

{2/1/91
Copied & modified: Siemens 810T L040.69.3
For: Oskar Vatterott, Inc
Machine: Emco Meyer #340
Control: Siemens Sinumeric 810T
Replaced all occurances of the obsolete StockXDiameter# command with StockXRadius#.
Added InverseSpinOn for Tapping Operation in ToolPath.
SK}

{4/23/91
Modified: Siemens 810T EM L155.71.2
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format.
Only Canned Cycles supported are RoughContour, Threading and PeckChipBreaker.
DWB}

{11/10/94
Updated: Siemens 810T EM L155.80
For: Gibbs & Associates
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.03/Compost 4.21.23
Changes made per Jackson
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82.1b Format.
Corrected FORMAT3 from '########;0' to '#######0' at Prog Numeric Format Definitions.
Added FORMAT7 '#' for RapidF# at Prog Numeric Format Definitions.
Added RestoreScale Sub per 4-Axis Post Processor.
Modified handling of Approaches.
Added FeedNoCan and FeedRateNoCan subs.
Adds Logic to suppress Feed and FeedRate for SameTool Approaches.
Added ODApproachSP, IDApproachSP, FaceApproachSP and AppMove subs.
Broke up Approach sub for all operations for improved readability and less nested decisions.
Moved StockOff to XCPC and XOpCDC only at Approach sub.
StockOnNoCan still at XSPC.
Added RapidF# at Approach sub.
No Output.
Forces FIRST FeedRateC to Output from ToolPath during FirstOperation OR NewTool.
Modified output of Speed & ConstantSurfaceFeed for SameTool in CheckOffset sub.
Combined and modified CheckRapid subs.
Added StandardXZArcs at setup and initializations.
This ensures correct output following use of NegSideLathe Post Processor containing ReverseXZArcs.
Restructured handling of Exit to Approach moves at SameTool.
Moved XOpECDC for IDExit from end of operation to NewTool, SameTool and end of Prog.
This was to ensure that all operations end at the LAST Features EndPoint.
Added Tracking at end of CannedCycle Roughing RoughContour.
Modified handling of non CannedCycle AutoFinish.
Added bypass of AutoFinish for Non-Canned RoughSimple.
Added bypass of AutoFinish for Non-Canned Threading.
Method of testing for IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple? AND NOT Threading?
did not allow for AutoFinish pass of IF Turning?
Rewrote to test for IF Turning? ELSE IF Roughing? AND NOT RoughSimple?
Modified AutoFinish Approaches.
Changed RapidC StrtPos to StockOff StrtPosC for Turning.
Added XSPC ZSPC for RoughContour.
Changed ThrdLead to FeedRateC at ToolPath ThreadFeat.
ThreadLead was outputting value without an address.
Added SetPass1 at CannedCycle Roughing RoughContour for safety reasons.
DWB}

{
Format: Hyundai HiTrol 840C[-] L330.85
5/17/95
For: Hyundai
Fixed pitch in G33 style thread
Added G92 to G96 lines
All canned drills now use L98 cycle
Fixed the output of the start position in a canned cycle
Fixed output of pitch in L97 thread cycle
Added support for many of the new Virtual threading options
TH}

{
Format: Hyundai HiTrol 840C[-] L330.85.1
9/29/95
For: AE Thurber
Added G53DO to home position
Seperated G92 MaxRPM from the G96 lines
Added Tool Change pos to end of program
Changed R20 in thread cycle to output pitch
TH}

{
Format: Hyundai HiTrol 840C[-] L330.85.2
10/12/95
For: Hyundai
Changed Canned Threading to Output Major Dia for R21 & R31
Changed G33 threading to output pitch instead of TPI
Remove M51 from output
Fixed Canned Drilling to output forrect values for R24
TH}

{
Format: Hyundai HiTrol 840C[-] L330.85.3
10/30/95
For: AE Thurber
Moved G53 line to be before Tool ID in NewTool
Dwell values (R27,R28) now always output
TH}

{
Format: Hyundai HiTrol 840C[-] L330.85.4
11/1/96
For: Hyundai
Removed M51 from output


5/21/97 [ws]
Hyundai HiTrol 840C[-] L330.85.5 (Hyundai HiTrol 840C[-] L330.85.4)
For: Hyundai
fixed to support AutoClearance by doing the following:
replaced ZCP with ThisOpEntryZCP in AppMove
replaced XCP with ThisOpEntryXCP in Approach
replaced XCPC with OpExitXCPC in various places
replaced ZCPC with OpExitZCPC in various places
WS}

{10/20/97
Changed Rev L330.85.5 Inch to Metric

Changes to 'Prog':
1. Changed #2 FORMAT to 5.3.
2. Changed RestoreScale Sub-routine.
3. Changed SetMaxFeed to 12500.
4. Changed MoveComment? to MILLIMETERS.

Changes to 'Form':
1. General Info - changed Rapid Move Speed to 12500.
2. Default Formats - changed F Format to 3.3, I J K Q R X Y and Z to 5.3.
3. Arcs - Changed I J Max Arc Radius to 2500.
4. Turn Rough OD/ID & Face - changed R Format to 5.3.
5. Threading - changed R Format to 5.3.
6. Lathe Drill Cycles - changed Peck-Partial Retract Format to 5.3.

JHE}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '#####.###;0'
#3 = '#######0'
#4 = '#####.###;0'
#5 = '0000'
#6 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CycleStartXDia#,2)
FORMAT(CycleStartZ#,2)
FORMAT(StockXRadius#,2)
FORMAT(StockZ#,2)
FORMAT(CutDepth#,2)
FORMAT(FeedIPR#,2)
FORMAT(FinishXDia#,2)
FORMAT(FinishZ#,2)
FORMAT(ThreadXInc#,2)
FORMAT(Retract#,2)
FORMAT(Peck#,2)
FORMAT(DIV#, 2)
FORMAT(SUB#, 2)
FORMAT(ADD#, 2)
FORMAT(SpringPasses#, 2)
FORMAT(ToolOffset#,3)
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(RapidF#,6)
FORMAT(FeedContour#,2)
FORMAT(SPX#,2)
FORMAT(SPZ#,2)
FORMAT(RunInZ#,2)
FORMAT(RunOutZ#,2)
FORMAT(InFeedAngle#,2)
FORMAT(FirstMoveEPX#,2)

{Prog Subroutines **********************************************************}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is a Metric post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

CkCRC:
IF NOT CannedCycle?
IF XMove? OR ZMove?
CRCOnC
END
IF LastFeat? AND EmptyLine?
CRCOffC
END
END
RETURN

ODApproachSP:
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

IDApproachSP:
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL { for SameTool ApproachID }
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

FaceApproachSP:
SeqC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqC FeedNoCan ZSPC FeedRateNoCan EOL
END
RETURN

AppMove:
StockOff ThisOpEntryZCP CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqC Rapid StockOff ThisOpEntryXCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqC Rapid StockOff XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqC Rapid StockOnNoCan XSP AppMove EOL
FaceApproachSP
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF NewToolOffset?
SeqC OpToolID EOL
SeqC 'D' ToolOffset# EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqC Preset MaxRPM EOL
END
ELSE
SeqC Preset MaxRPM EOL
SeqC CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqC CSSOff 'G95' Speed
END
END
IF LAST ProgStop?
SeqC SpeedC SpinOn EOL
SeqC CoolOn EOL
ELSE
SeqC SpeedC EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
InverseSpinOn
ELSE
IF Dwell?
SeqC 'G4X' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC 'G33' MoveXC MoveZC 'K' FeedIPR# EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('10000')
SetMaxFeed('12500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR 'MPF' Program# EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' MILLIMETERS )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
Seq AbsOrInc EOL
SeqC 'G53' Rapid 'D0' Home EOL
SeqC OpToolID EOL
SeqC 'G54D' ToolOffset# SpinOn EOL
IF ConstantSurfaceFeed?
SeqC 'G92' MaxRPM EOL
SeqC CSSOn 'G96'
ELSE
SeqC CSSOff 'G95'
END
SeqC Speed EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
END
SeqC LAST OpExitZCPC EOL
DoEndOpPS
SeqC Rapid 'D0G53' NewHome EOL
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
SeqC 'G53' Rapid 'D0' Home EOL
SeqC OpToolID EOL
SeqC 'G54D' ToolOffset# SpinOn EOL
IF ConstantSurfaceFeed?
SeqC 'G92' MaxRPM EOL
SeqC CSSOn 'G96'
ELSE
SeqC CSSOff 'G95'
END
SeqC Speed EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC LAST OpExitXCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughContour?
SetPass2
NewProg
SeqC
FORMAT(Program#,6)
'R20=' Program#
'R21=' SPX#
'R22=' SPZ#
'R24=' StockXRadius#
'R25=' StockZ#
'R26=' CutDepth#
'R27=' {Need to set up for cutter comp}
IF CutterRadiusCompensation?
IF CRCLeft?
'41'
ELSE
'42'
END
ELSE
'40'
END
'R28=' FeedContour#
IF ApproachOD?
'R29=11'
ELSE
IF ApproachID?
'R29=13'
ELSE {OD ApproachFace}
'R29=12' {R29=14 is for ID ApproachFace}
END
END
'R30=1'
EOL
SetPass2
SeqC 'L95P1' EOL
OpenSub
'L' Program# EOL
DoSubComment
SeqC StepMove StrtPos EOL
ToolPath
SeqC 'M17' EOL
CloseSub
IF AutoFinish?
SeqC 'R24=0R25=0'
IF ApproachID?
'R29=22'
ELSE
'R29=21'
END
EOL
SeqC 'L95P1' Feedrate EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
SetPass1
SeqC
'R20=' FeedIPR#
IF ApproachID?
'R21=' ADD# DiaDistanceToThread# CycleStartXDia#
ELSE
'R21=' SUB# DiaDistanceToThread# CycleStartXDia#
END
'R22='
IF ZMinusCutDir?
SUB# CycleStartZ# RunInZ#
ELSE
ADD# CycleStartZ# RunInZ#
END
'R23=' SpringPasses#
IF ApproachID?
'R24=' ThreadXInc#
ELSE
'R24=-' ThreadXInc#
END
'R25=' StockXRadius#
'R26=' RunInZ#
'R27=' RunOutZ#
EOL
SeqC
'R28=' CalcNumCuts
'R29=' InFeedAngle#
'R31='
IF Taper?
Save# Num#('1') SUB# FinishZ# CycleStartZ# {Z delta}
Save# Num#('2') DIV# Taper# Recall# Num#('1') {Slope of taper}
Save# Num#('3') MUL# Recall# Num#('1') Recall# Num#('2')
IF ApproachID?
SUB# FinishXDia# Recall# Num#('3')
ELSE
ADD# FinishXDia# Recall# Num#('3')
END
ELSE
IF ApproachID?
ADD# DiaDistanceToThread# CycleStartXDia#
ELSE
SUB# DiaDistanceToThread# CycleStartXDia#
END
END
'R32='
IF ZMinusCutDir?
ADD# FinishZ# RunOutZ#
ELSE
SUB# FinishZ# RunOutZ#
END
'L97P1'
EOL
ELSE
IF Drilling?
SeqC
IF PeckChipBreaker?
'R11=0'
ELSE
'R11=1'
END
'R22=' CycleStartZ#
IF Peck?
'R24=' Peck# {Peck decrease amount}
'R25=' SUB# CycleStartZ# Peck# {First Peck Depth}
END
'R26=' FinishZ#
'R27=' Dwell# {Dwell at start}
'R28=' Dwell# {Dwell at end}
EOL
SeqC 'L98P1' Feedrate EOL
EOL
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1b }
StockOff
IF Turning?
SetPass1
RapidC
IF ApproachFace?
SeqC ZOpECPC EOL
FaceApproachSP
ELSE
SeqC XOpECDC EOL
IF ApproachOD?
ODApproachSP
ELSE {ApproachID}
IDApproachSP
END
END
SeqC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqC RapidC XSPC ZSPC EOL
SeqC StockOff StrtPosC EOL
ToolPath
END
END
END
END
IF Drilling? AND Tap?
SeqC SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqC XOpECDC EOL
END
END
SeqC OpExitZCPC EOL
DoEndOpPS
SeqC CoolOff EOL
SeqC SpinOff EOL
IF ProgStop?
SeqC 'M0' EOL
END
SeqC 'G53' Rapid 'D0' Home EOL
SeqC EOP EOL
Post
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END