{Change Comments ***********************************************************}

{3/7/89
Copied & modified; Fanuc 10T-MS [-] L001.57, for Angelus Can.
Machine is a Warner & Swasey 2SC with Alan Bradley 7360 control
Jim Radcliffe}

{3/10/89
Deleted 'StockOnNoCan:' subroutine which sets post to 'StockOn' if
'CannedCycle?' is false. Changed 'StockOnNoCan' subcall to 'StockOn'
Altough this machine has no canned cycles, and ncPOST should always
be directed to 'StockOn', I left the canned cycle
info in the Mach Spec and am using the 'CannedCycle?' boolean
to control the rapid feed around the part if
'Prefered Canned Cycles' was selected in ncCAM.
Jim Radcliffe}

{9/27/89, updated & added PostScript to W & S 2SC AB 7360 L096.55, JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{8/9/90, Updated: W & S 2SC AB 7360 L096.62 to .71 format, JR}

{8/13/92
Updated: W & S 2SC AB 7360 L096.71
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.82 Format.
Kim Michelman}

{3/8/95
Updated: W & S 2SC AB 7360 L096.82
For: Gibbs & Associates/Lincoln Automotive
Versions: ncCad 4.33.01/ncCAM 4.33/ncPost 4.33.05/Catalyst v2.14.30/Compost 4.21.27
Updated to Version 4.2 per Fanuc 6M M001.81.2f Format.
DWB}

{4/13/95
Copied: W & S 2SC AB 7360 L096.82.1
Created: W & S 1SC AB 7360 L327.82.1
For: Lincoln Automotive
Machine: Warner & Swasey 1SC
Control: Allen Bradley 7360
Versions: ncCad 4.33.01/ncCAM 4.33/ncPost 4.33.05/Catalyst v2.14.30/Compost 4.21.27
Changes made per Bill White of Lincoln Automotive.
Using G21, G22 and G23, which serve the same purpose as G01, G02 and G03 except that these commands
ensure that the machine has completed the last programmed move before it acts on the next block.
DWB}

{6/6/96, Updated W & S 1SC AB 7360 L327.82.1 to .85 format per Fanuc 10T MS [-] L001.85.01.01, JR}

{6/6/96
Initial: W & S 1SC AB 7360 L327.85
Created: W & S 1SC AB 7360 Lxxx.85
ForUser: KO Lee
Develop: ComPost 4.21.37, Catalyst68K v3.04.10.C
Comment: New Processor per marked up readout from Ted Heupel
Allways output RPM as an even number to prevent spindle from shifting to low clutch.
Deleted Dwell from tool call line, its taking tool long!
Jim Radcliffe}

{6/12/96
Initial: W & S 1SC AB 7360 [KOL] L460.85
Created: W&S 1SC AB 7360 [KOL] L460.85.1
ForUser: KO Lee
Develop: ComPost 4.21.37, Catalyst68K v3.05
Comment: added N# format to the form.
WS}

{6/21/97
MODIFIED: W&S 1SC AB 7360 [KOL] L460.85
Created: AB 7360 [SHAFFER] Lxxx.85
added GearRange, added ToolID '00' top of operation. reformatted 4 digit with decimal point,
changed arcs to G2/G3, added spinoff at change of spindle direction,modified to output G0 for
rapid moves along with F0,Added 'O' Tool# at beginning of each tool operation,
added 'U-1.0 W-1.0 before tool offset,
Texas Offline}

{7/3/97,
Initial: AB 7360 [SHAFFER] Lxxx.85
Created: AB 7360 [SH] Lxxx.85
For: Shaffer
added logic to move the tool one inch in the negative X and Z directions after move to home pos in FirstOp and
NewTool.
Tool now moves to 1 inch from ThisOpEntryCP in AppMove, then moves to ThisOpEntryCP on next line.
MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '0#^####'
#3 = '####.###;0.'
#4 = '#######0'
#5 = '0000:2'
#6 = '0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(StartPosX#,2)
FORMAT(ThisOpEntryZCP#,2)
FORMAT(Dwell#,2) {.72}
FORMAT(ADD#,3) { Non-Canned Threading AutoFinish }
FORMAT(SUB#,3)
FORMAT(Program#,4) {.72}
FORMAT(Operation#,4) {.72}
FORMAT(Tool#,4) {.72}
FORMAT(CalcEPRPM#,5)
FORMAT(RapidF#,6)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
StockOn { CannedCycle not supported }
RETURN

FeedNoCan:
FeedC { CannedCycle not supported }
RETURN

FeedRateNoCan:
FeedRateC { CannedCycle not supported }
RETURN

CheckRapidFC:
IF NOT EmptyLine?
RapidFC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqC StockOnNoCan XSPC EOL
SeqC StockOff ZOpCP EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff 'Z' ADD# ThisOpEntryZCP# Num#('1') CoolOn
IF Threading?
'F20' RapidF#
ELSE
RapidF
END
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
IF ApproachOD?
SeqC Rapid ThisOpEntryXCP AppMove EOL
SeqC ThisOpEntryZCP EOL
ELSE
IF ApproachID?
SeqC Rapid XOpCD AppMove EOL
SeqC ThisOpEntryZCP EOL
ELSE {ApproachFace}
SeqC Rapid StockOnNoCan XSP AppMove EOL
SeqC ThisOpEntryZCP EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF NewToolOffset?
SeqC OpToolID LatheOffset EOL
END
IF NewGear?
SeqLabC SpinOff EOL
SeqLabC GearRange EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqC Preset MaxRPM EOL
END
ELSE
SeqC Preset MaxRPM EOL
END
SeqC CSSOff 'G97' CalcRPM1
ELSE
IF LAST ConstantSurfaceFeed?
SeqC CSSOff 'G97' Speed
ELSE
SeqC SpeedC
END
END
IF LAST ProgStop?
SpinOn EOL
SeqC CoolOn EOL
ELSE
EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqC SpinOff EOL
SeqC 'G04X02' EOL
SeqC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqC 'G04X' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC RapidC MoveXC MoveZC
IF LAST ThreadFeat?
RapidF
ELSE
RapidFC
END
EOL
ELSE
IF LineFeat?
SeqC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqC 'G33' MoveXC MoveZC XTapAtZ ThrdLead EOL
Feed
END
END
END
END
END
NEXTFeat
RETURN

ThreadPath: {straight thread along Z axis no single edge or chamfer}
EACHFeat
IF ThreadFeat?
SeqC 'G33' MoveZC ThrdLead EOL
ELSE
IF RapidFeat?
IF NOT FirstFeat? AND LAST ThreadFeat?
SeqC Feed MoveXC 'F20' RapidF# EOL
ELSE
SeqC MoveXC MoveZC EOL
END
END
END
NEXTFeat
SeqC Feed XSP 'F20' RapidF# EOL
RETURN

CheckRapid:
SeqC CRCOffC EOL
RapidC
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
PosSideLathe
StandardXZArcs
XsAreRadii
NoIJKSigns
SetMaxRPM('2014')
SetMaxFeed('300')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
'O' Program# EOL
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
DoOpComments
DoPostScript
SeqC 'G70' EOL
{SetHome}
Plane
Seq OpToolID '00' EOL
Seq Preset Home EOL
SeqC 'X' SUB# HomeX# Num#('1') 'Z' SUB# HomeZ# Num#('1') EOL
Seq Preset MaxRPM GearRange EOL
SeqC AbsOrInc EOL
IF Threading?
SeqC 'G94' EOL { Inches per Minute }
ELSE
SeqC 'G95' EOL { Inches per Revolution }
END
SeqC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL
SeqC OpToolID LatheOffset EOL { Dwell }
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqC LAST OpExitXCPC CheckRapidFC EOL
ELSE
IF LAST ApproachID?
SeqC LAST XOpECDC CheckRapidFC EOL
END
END
SeqC LAST OpExitZCPC CheckRapidFC EOL
DoEndOpPS
SeqC CoolOff EOL
IF LAST ConstantSurfaceFeed?
SeqC CSSOff 'G97' CalcRPM2 EOL
END
SeqC OpToolID '00' EOL
SeqC LAST Home CheckRapidFC EOL
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
'O' TOOL# EOL
IF CWSpindle? AND LAST NOT CWSpindle?
SeqC SpinOff EOL
ELSE
IF NOT CWSpindle? AND LAST CWSpindle?
SeqC SpinOff EOL
END
END
Seq OpToolID '00' EOL
Seq Preset Home EOL
SeqC 'X' SUB# HomeX# Num#('1') 'Z' SUB# HomeZ# Num#('1') EOL
Seq Preset MaxRPM GearRange EOL
SeqC AbsOrInc EOL
IF Threading?
SeqC 'G94' EOL { Inches per Minute }
ELSE
SeqC 'G95' EOL { Inches per Revolution }
END
SeqC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL
SeqC OpToolID LatheOffset EOL { Dwell }
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqC StockOnNoCan XSPC ZSPC CheckRapidFC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC CheckRapidFC EOL
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC CheckRapidFC EOL
END
SeqC LAST OpExitZCPC CheckRapidFC EOL
SeqC LAST OpExitXCPC CheckRapidFC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC CheckRapidFC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC CheckRapidFC EOL
END
SeqC LAST OpExitZCPC CheckRapidFC EOL
SeqC XOpCDC CheckRapidFC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC CheckRapidFC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC CheckRapidFC EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC CheckRapidFC EOL
END
SeqC LAST OpExitZCPC CheckRapidFC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed?
SeqC CSSOn 'G96R' StartPosX# Speed EOL
END
StockOn
SetPass1
IF Threading?
ThreadPath
IF AutoFinish? { .82.1c }
SeqC 'X' ADD# FinishXRadius# Taper# EOL
SeqC 'G33' FinZ ThrdLead EOL {straight thread along Z axis no single edge or chamfer}
SeqC Feed XSP 'F20' RapidF# EOL
SeqC ZSP EOL
END
ELSE
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC FeedC ZOpECPC CheckRapidFC EOL
ELSE
SeqLabC FeedC XOpECDC CheckRapidFC EOL
END
ApproachSP
SeqC StockOff StrtPosC CheckRapidFC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqC FeedC XSPC ZSPC CheckRapidFC EOL
SeqC StockOff StrtPosC CheckRapidFC EOL
ToolPath
SetPass1
END
END
END
END
IF Drilling? AND Tap?
SeqC SpinOff EOL
SeqC 'G04X02' EOL
SeqC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
SeqC CRCOffC EOL
FeedC
IF ApproachOD?
SeqC OpExitXCPC CheckRapidFC EOL
ELSE
IF ApproachID?
SeqC XOpECDC CheckRapidFC EOL
END
END
SeqC OpExitZCPC CheckRapidFC EOL
DoEndOpPS
SeqC CoolOff EOL
IF ConstantSurfaceFeed?
SeqC CSSOff 'G97S' CalcEPRPM# EOL
END
SeqC OpToolID '00' EOL
SeqC Home CheckRapidFC EOL
IF ProgStop?
SeqC 'M00' EOL
END
SeqC EOP EOL
Post
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END