ANSYS APDL

Wyboczenie rury

Zadania do wykonania

1. Wykonać modelowanie i symulacje 

analogicznie jak dla prezentacji różnicując 
geometrie.

2. Wykonać modelowanie i symulacje dla rury o 

przekroju kwadratu i boku równym 
promieniowi okręgu z zadania bazowego.

3. Wyniki umieścić w Wordzie i przedstawić 

prowadzącemu zajęcia.

finish
/clear
/UNITS,SI
/PREP7
/TITLE, WYB‐POWL2: Analiza stateczności powłoki
! Model powłokowy rury obciążonej osiowo na końcu
! Definicje wymiarów, materiałów i stałych materiałowych
R1=0.030               ! promień powłoki

+0.00numer na liście

Gp=0.005              ! grubość powłoki
Hz=2                      ! wysokość powłoki
ET,1,63 !93 , 181    ! typ elementu
MP,EX,1,2.1e11      ! moduł Younga
MP,NUXY,1,0.3      ! współczynnik Poissona
R,1,Gp                   ! stała elementowa
K,1,0,0                   ! punkty bazowe 
K,2,0,0,Hz
L,1,2                       ! L1, Linia ścieżki
CIRCLE,1,R1         ! L2,3,4,5‐ generowanie okręgu 

ADRAG,2,3,4,5,0,0,1  ! wyciąganie powierzchni powłokowej
!APLOT
np=10                   ! podział dla łuku okręgu
nz=30                    ! podział dla tworzącej powłoki
LSEL,s,Loc,z,0      ! selekcja linii okręgów
LSEL,a,Loc,z,Hz
Lesize,all,,,np

! podział łuków okręgów

Lsel,all

! selekcja wszystkich linii

Lesize,all,,,nz

! podział tworzących

TYPE,1  $  MAT,1  $  REAL,1   ! atrybuty powierzchni powłoki
AMESH,all

! generowanie elementów

SAVE
FINISH

/SOLUTION        ! faza nr 1
ANTYPE,static ! Analiza statyczna
PSTRES,on

! w przyp. liniowej stateczności

Lsel,s,Loc,z,Hz ! selekcja górnej krawędzi powłoki
! SFL,Line,pres,qz
! qz=sigmaz*gp ! siła powłokowa 
SFL,all,pres,1       ! jednostkowa siła powłokowa  
Lsel,all
! Ustalenie warunków brzegowych
NSEL,s,loc,z,0.   ! wybór węzłów dla wsp. Z = 0
D,all,ux,0     ! ux=0 (podparcie ux=uy=uz=0)
D,all,uy,0     ! uy=0
D,all,uz,0     ! uz=0
NSEL,s,loc,z,Hz ! wybór węzłów dla wsp. Z = Hz
D,all,ux,0      ! ux=0 (podparcie ux=uy=0))
D,all,uy,0      ! uy=0
Nsel,all

! powrót do wszystkich węzłów

/PBC,all,1     ! włączenie oznaczenia warunków brzegowych
/PSF,pres,norm,2
SBCTRA      ! transfer obciążeń z modelu geometr. do MES

/TITLE,WYB‐POWL2 ‐ ELEMENTY Z WAR. BRZEGOWYMI
/view,1,1,2,3
EPLOT          ! rysunek elementów
/wait,4
SOLVE          ! rozwiązanie zadania
SAVE
FINISH
/SOLUTION  ! faza nr 2
ANTYPE,Buckling ! Analiza stateczności 
BUCOPT,Subsp,2    !  Lanb, subsp
MXPAND,2             !  deklaracja liczby form do obliczenia
SOLVE                    ! rozwiązanie zadania
FINISH

/POST1                    ! otwarcie postprocesora
*get,pkryt,mode,1,freq  ! odczyt obciążenia krytycznego (Freq, Load Factor)
sigz=pkryt/gp /1e6         ! naciski powierzchniowe [MPa]
fp=2*3.14159*R1*Gp ! pole powierzchni przekroju rury [m^2]
Qw=fp*sigz/10000*1e6 ! [T],  wypadkowa krytyczna siła osiowa 
! set,step,substep (set,krok,forma) ‐ wybór rozwiązania dla określonego kroku 
SET,1,1             ! krok nr 1, forma nr 1
Rsys,1               !  przejście do walcowego układu dla rozwiązania, x=> r
/view,1,0,‐1,0      ! oś Y prostopadła do ekranu
/TITLE,WYB‐POWL2 ‐ Forma 1, pkryt=%pkryt%, sigz=%sigz% [MPa],Qw=%Qw% [T]
plnsol,u,x

! mapa przemieszczenia promieniowego 

Modyfikacja:

Przeprowadzić obliczenia dla dwukrotnie grubszej rury