{Change Comments ***********************************************************}

{11/28/88
Modified processor Fanuc 10T-MS [+] L004.52 for Cemco.
Machine is a Takisawa TS-20 with Fanuc 3TF control.
Added 'G30U0W0' saftey feature to move to index position.
Added empty line between tools. Modified canned cycles.
Added GearRange. Modified CheckOffset and SameTool accordingly.
Jim Radcliffe}

{2/3/89
Added 'FeedRate' to toolpath if first feature and not canned cycle.
'FeedRateC' was not calling 'FeedRate' if new tool and same feedrate.
Jim Radcliffe}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{5/30/91. Updated Fanuc 3TF Takasawa L085.56 to .81 format, JR}

{08/05/91
Updated: Fanuc 3TF Takasawa L085.81
Updated to Version 4.0 per Fanuc 6M M001.82 Format.
Kim Michelman}

{4/27/92
Copied & Modified: Fanuc 3TF Takasawa L085.82
For: Lemco
Added ZStockMin#.
Added the OPTIONALCYCLE1, OPTCYC1 to PostScript.
Changed the StartUp code.
Added BarFeed in FirstOp and at the end of the prog.
Changed for 'R' value arcs in form at 180 degrees.
KLM}

{5/26/92
Updated: Fanuc 3TF Takasawa L258.82.1
For: Lemco
Replaced the OfstOff command with a literal 'G28' to illiminate the 'Z.0'.
Removed the Home command on the Preset line.
Added capability for 'M' and 'G' codes to have three digits. (in the form)
Moved the 'G96' line to be output before the FeedRate line in the Approach.
Modified the OpToolID in the Barfeed and FirstOp to a literal 'T1000', customer will always use Tool# 1000.
Removed the 'G30U0W0M42' line.
Added output to NewTool section to resemble the FirstOp output, customer wants startup code to look similair.
Added output to NewTool section to resemble the FirstOp output, customer wants startup code to look similair.
**THIS POST SUPPORTS TAILSTOCK**
KLM}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0.'
#3 = '########;0'
#4 = '###^##0'
#5 = '#.######;0.'
#6 = '####.####;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ZStockMin#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(SPX#,2)
FORMAT(SPZ#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(NewHomeX#,6)
FORMAT(NewHomeZ#,6)
FORMAT(FirstHomeX#,6)
FORMAT(FirstHomeZ#,6)

{Prog Subroutines **********************************************************}

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn
END
RETURN

ConstantSurfaceFeed:
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn 'G96' Speed EOL
END
RETURN

ODApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
ConstantSurfaceFeed
SeqLabC Feed StockOnNoCan XSPC FeedRate EOL
RETURN

IDApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
ConstantSurfaceFeed
SeqLabC Feed StockOnNoCan XSPC FeedRate EOL
RETURN

FaceApproachSP:
SeqLabC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
ConstantSurfaceFeed
SeqLabC Feed StockOnNoCan ZSPC FeedRate EOL
RETURN

AppMove:
OpToolID LatheOffset
RETURN

Approach: { FOR TAILSTOCK, .82 }
IF ApproachOD?
SeqLabC Rapid ZCP AppMove EOL
SeqLabC XCP EOL
ODApproachSP
ELSE
IF ApproachID?
SeqLabC Rapid ZCP AppMove EOL
SeqLabC XOpCD EOL
IDApproachSP
ELSE {ApproachFace}
SeqLabC Rapid ZCP AppMove EOL
SeqLabC StockOnNoCan XSP StockOff EOL
FaceApproachSP
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF NewGear?
SeqLabC SpinOff EOL
END
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
IF NewGear?
SeqLabC GearRange EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
SeqLabC SpeedC EOL
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G96' Speed EOL
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' Speed EOL
ELSE
SeqLabC SpeedC EOL
END
END
IF LAST ProgStop?
SeqLabC SpinOn EOL
SeqLabC CoolOn EOL
ELSE
IF NewGear?
SeqLabC SpinOn EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
SetMaxRPM('10000') {?}
SetMaxFeed('500') {?}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' OPTIONALCYCLE1, OPTCYC1 -' EOL
' Enter in first operation before an EndOp command.' EOL
' The program will then become one to use for Barfeed work.' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )' EOL
ELSE
EOL
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
OpenSub
StockOff {.71.2}
SetHome
Plane
SeqLabC 'G28' 'U0.' EOL
SeqLabC 'G28' 'W0.' EOL
SeqLabC Rapid Home EOL
SeqLabC ProgStop EOL
DoPostScript

IF OptCyc1?
IF UseComments?
'( Bar Feed )' EOL
END
'Åš' '1000' EOL
SeqLab Rapid 'T1000' GearRange EOL
SeqLabC 'G97' 'S150' SpinOn EOL
SeqLabC Rapid 'X0Z.120' 'T100' LatheOffset EOL
SeqLabC Feed 'Z' ZStockMin# 'F0.8' EOL { Customer specified '-1.625' - not ZStockMin# }
SeqLabC 'M69' EOL
SeqLabC 'G04U0.5' EOL
SeqLabC Feed 'Z0.03' EOL
SeqLabC 'M31' EOL
SeqLabC 'M68' EOL
SeqLabC 'G04U0.5' EOL
SeqLabC Rapid 'Z.2' EOL
SeqLabC Home 'T1000' EOL
SeqLabC ProgStop EOL
END
DoOpComments
SeqLabC Preset MaxRPM EOL
SeqLabC Rapid OpToolID '00' CoolOn EOL
SeqLabC GearRange EOL
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC XCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC ZCPC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' CalcRPM2 EOL
END
SeqLabC Rapid 'X' NewHomeX# LOfstOff '00' CoolOff EOL
SeqLabC 'Z' NewHomeZ# EOL
IF NewGear?
SeqLabC SpinOff EOL
END
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

' ' EOL {empty line}
Plane
DoOpComments
DoPostScript
SeqLab Preset MaxRPM EOL
SeqLabC Rapid OpToolID '00' CoolOn EOL
SeqLabC GearRange EOL
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

DoOpComments
StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
SeqLabC XCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
END
SeqLabC ZCPC EOL
SeqLabC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
{IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn 'G96' Speed EOL
END}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
IF ApproachFace?
SeqLabC LCycle 'Z' FirstMoveEPZ# XatFinZ XTapAtZ FeedRate EOL
ELSE
SeqLabC LCycle XatFinZ FinZ XTapAtZ FeedRate EOL
END
SimpleRough
ELSE
TagInc
IF RoughContour?
SetPass2
SeqLabC LCycle CutDepth 'R.01' EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove 'Z' SPZ# EOL
SeqLabC 'X' SPX# EOL
ELSE
SeqLab StepMove 'X' SPX# EOL
SeqLabC 'Z' SPZ# EOL
END
{SeqLab StepMove StrtPos EOL}
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
ELSE
IF RoughPatternShift?
SetPass2
SeqLabC LCycle XminusU ZminusW NumCuts EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
END
END
END
ELSE
IF Threading?
SeqLabC LCycle 'P'
IF AutoFinish?
'02' {2 finish passes}
ELSE
'01'
END
IF Chamfer?
'10' {1 thread lead}
ELSE
'00'
END
IF SingleEdgeCut?
'60' {standard tool angle}
ELSE
'00'
END
EOL
SeqLabC LCycle XatFinZ FinZ XTapAtZ ThrdHeight CutDepth ThrdLead EOL
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF PeckChipBreaker?
SeqLabC LCycle Retract EOL
SeqLabC LCycle ZDepth Peck FeedRate EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
ELSE
IF Grooving?
SeqLab StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving?
StockOff
IF Turning?
SetPass1
ELSE
SetPass2
END
SeqLabC RapidC StrtPos EOL
ToolPath
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
IF CannedCycle?
Rapid
ELSE
RapidC
END
SeqLabC
IF ApproachOD?
XCPC
ELSE
IF ApproachID?
XOpECDC
END
END
ZCPC EOL
DoEndOpPS
SeqLabC RapidC 'X' FirstHomeX# 'Z' FirstHomeZ# OpToolID '00' CoolOff EOL
SeqLabC SpinOff EOL
IF ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END
SeqLabC 'G28U0.W0.' EOL
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
Reopen
SetScale('1')
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END