{Change Comments ***********************************************************}

{11/14/91
Modified: Fanuc 10T MS [-] L001.82
For: Gibbs & Associates
Added RestoreScale Sub per 4-Axis Post Processor.
Added Logic to suppress Feed and FeedRate for Approaches.
Modified output of Speed & ConstantSurfaceFeed for SameTool in CheckOffset sub.
Changed SetAbs to SetAbsOrInc at setup and initializations.
Added bypass of AutoFinish for Non-Canned RoughSimple Operations.
Modified AutoFinish Approach.
DWB}

{4/4/95
Initial: Fanuc 10T MS [-] L001.82ż
ForUser: Envirotech Pump
Control: Fagor 8030 TG
Machine: Mazak
Version: ComPost 4.21.26, ncCAD 4.33, ncCAM 4.33, ncPost 4.33.04
Created new Postprocessor per sample and manual.
Jim Radcliffe}

{
Format: Fagor 8025 TG Lxxx.81.2
5/9/95
Added spaces between all commands
TH}

{
Format: Fagor 8025 TG L342.81.3
5/17/95
Added T00.00 to start and end of prog
Removed CSS stuff from start of prog
Removed preset stuff from start of prog and NewTool?
Removed all coolant commands
TH}

{
Format: Fagor 8025 TG L342.81.4
5/22/95
Changed to NegSideLathe
TH}

{
Format: Fagor 8025 TG L342.81.5
5/31/95
Added ReverseXZArcs to prog start
TH}

{
Format: Fagor 8025 TG L342.81.6
6/15/95
For: Litton
Fixed CSS code in FirstOp
Put coolant commands back in
TH}

{9/7/95, Updated Fagor 8025 TG L342.81.6 to .85 format per Fanuc 10T MS [-] L001.85.01.01, JR}

{10/11/95
Copied: Fagor 8025 TG L342.85
Created: Aurki 8020 [MS] L388.85m
For: Maquinser
Machine: Fagor Aurki 8020
Control: Late Guztior-Bat
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.06/Catalyst v2.27/Compost 4.21.32/1.0a
Changes made per Juan Jose Osoro and Antonio Postigo of Maquinser.
Created Metric Version.
Changed Compost General Default Formats.
Changed FORMAT for address F from ##.####;0 to ###.###;0
Changed FORMAT for address G from 00;0 to #0
Changed FORMATs for addresses M and T from 00 to #0
Corrected bad FORMATs for addresses X and Z from ' ####.####;0' to '#####.###;0'
Changed FORMATs for addresses I, J, K, Q, R and Y from ####.####;0 to #####.###;0
Changed Prog Numeric Format Definitions.
Changed FORMAT#2 from ###.####;0 to ####.###;0
Changed FORMAT#5 from #.######;0 to ##.#####;0
Changed RestoreScale sub.
Changed IF Metric? to IF NOT Metric?
Changed SetScale argument from .03937007874 to 25.4
Switched English and Metric words in commented stuff.
Changed literal INCHES to MILLIMETERS at FirstOperation ProgComments.
Moved CoolOn from AppMove sub to FirstOperation and NewTool.
Added support of GearRange at CheckOffset sub, FirstOperation and NewTool.
Deleted LOfstOff '.00' block at CheckOffset sub and NewTool.
Modified handling of Speed at CheckOffset sub, FirstOperation, NewTool, common point and end of Prog.
Modified Handling of CRCOnC/CRCOffC at CkCRC sub.
Deleted SetAbs at setup and initializations.
Changed NegSideLathe to PosSideLathe at setup and initializations.
Changed ReverseXZArcs to StandardXZArcs at setup and initializations.
Changed SetMaxRPM from 10000 to 900 at setup and initializations.
Deleted ' T00.00' block at FirstOperation.
Deleted FeedRate at FirstOperation.
Added CoolOff to NewHome block at NewTool.
Moved CoolOff to FirstHome block at end of Prog.
Deleted ' T00.00' SpinOff at end of Prog.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '####.###;0'
#3 = '#######0'
#4 = '##.##;0'
#5 = '##.#####;0'
#6 = '###0'
#7 = '#'
#8 = '00000'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(InFeedAngle#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
FORMAT(Program#,8)

{Prog Subroutines **********************************************************}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is a Metric post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLabC ' ( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
SeqLabC ' ( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
SeqLabC ' ( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
SeqLabC ' ( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
SeqLabC ' ( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC ' M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF NewGear?
SeqLabC SpinOff EOL
END
END
IF NewGear?
SeqLabC GearRange EOL
END
IF NewToolOffset?
SeqLabC OpToolID '.' LatheOffset EOL
END
CSSOff
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
IF LAST ProgStop? OR NewGear?
CSSOn ' G96' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
CSSOn ' G96' Speed
END
END
ELSE
SeqLabC Preset MaxRPM EOL
CSSOn ' G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
' G97' Speed
ELSE
IF LAST ProgStop? OR NewGear?
' G97' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
' G97' Speed
END
END
END
END
IF LAST ProgStop? OR NewGear?
SeqLabC {SpeedC} SpinOn EOL
SeqLabC CoolOn EOL
ELSE
SeqLabC {SpeedC} EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJ
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF LastFeat?
CRCOffC { Exit Length Feature }
ELSE
CRCOnC { Entry Length Feature }
END
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC ' G4 K2.' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC ' G4 K' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC ' G33' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
PosSideLathe
StandardXZArcs
SetMaxRPM('900')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR Program# EOL
IF UseComments?
IF ProgramNameComment?
SeqLabC ' ( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
SeqLabC ' ( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
SeqLabC ' ( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
SeqLabC ' ( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
SeqLabC ' ( OUTPUT IN ABSOLUTE MILLIMETERS )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
SeqLab OpToolID '.' LatheOffset EOL
SeqLabC AbsValue GearRange EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
CSSOff ' G96'
ELSE
CSSOn ' G97'
END
SeqLabC Speed SpinOn CoolOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
SeqLabC NewHome CoolOff EOL
IF LAST ProgStop?
SeqLabC ' M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
SeqLab OpToolID '.' LatheOffset EOL
SeqLabC AbsValue GearRange EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
CSSOff ' G96'
ELSE
CSSOn ' G97'
END
SeqLabC Speed SpinOn CoolOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
' Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle ' PÅ‚' Tag# ' Q²' Tag# XStkLeft ZStkLeft CutDepth FeedRate EOL
'>' Tag# EOL
SeqLab StepMove StrtPos EOL
ELSE
IF RoughPatternShift?
SeqLabC LCycle ' PÅ‚' Tag# ' Q²' Tag# XStkLeft ZStkLeft XminusU ZminusW NumCuts FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
END
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC ' G70' ' PÅ‚' Tag# ' Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
IF Chamfer?
SeqLabC ' M23' EOL
END
SeqLabC LCycle XatFinZ FinZ XTapAtZ CutMethod ThrdHeight CutDepth ThrdLead ' A' InFeedAngle# EOL
IF AutoFinish?
SeqLabC ' G92' XatFinZ FinZ XTapAtZ ThrdLead EOL
END
IF Chamfer?
SeqLabC ' M24' EOL
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth ' E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC ' G4 K2.' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF PeckChipBreaker?
SeqLabC LCycle ZDepth RLevel Dwell Peck Retract FeedRate EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC ' G4 K' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
ELSE
IF Grooving?
StockOn
SetPass1
SeqLabC StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC ' X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC ' G33'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC ' G4 K2.' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
SeqLabC FirstHome CoolOff EOL
IF ProgStop?
SeqLabC ' M0' EOL
END
SeqLabC EOP EOL
Post
IF UseComments?
SetScale('1') {restore scale for comments}
IF FileBytesComment?
SeqLabC ' ( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
SeqLabC ' ( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
SeqLabC ' ( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
ASCII('27') EOL
Close
Retag