{Change Comments ***********************************************************}

{9/18/95, M580.81.7m, Updated for Catalyst v2.20 per Fanuc 6M M001.85 Format, DWB}

{9/18/95
Copied: Fanuc 15M STAMA M580.85m
Created: Fan 15MB Wahli [MGI] M850.85m
For: Fructus/MG Instrument
Machine: Wahli
Control: Fanuc 15MB
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.06/Catalyst v2.22/Compost 4.21.32/1.0a
Changes made per Mikael Bagge of Fructus.
Added Spaces to all Addresses except O and N in Form and Prog.
Deleted G17 from Select XY Plane field of Commands 2 Dialog in Form.
Set Arcs Stop On Quadrants to FALSE in Compost Booleans Dialog.
Commented out all Comments except for ToolComment.
Added unconditional MoveXY for ArcFeatures at GetMove sub
Deleted CheckGear sub and all calls to same.
Added AND OptCyc1? condition to Drilling Tap for RigidTap.
Normal Tapping Cycle was not being output.
Added Seq Block literal 'G10L2P1XYZB' at FirstOperation.
Deleted literal 'G98G49' from SafeStart at FirstOperation.
Deleted ToolChng at FirstOperation and NewTool.
Added SubCall CallLabB '9001' following OpToolID block at FirstOperation and NewTool.
M98P9001 is ToolChange Sub.
Moved PreTool from OfstOn CoolOn block to follow M98P9001 block at FirstOperation and NewTool.
Deleted GearRange at FirstOperation.
Deleted 'G98' from SafeStart at NewTool.
Changed Plane to PlaneC on SafeStart at NewTool.
Changed 'G28' OfstOff to 'Z0.' at NewTool and end of Prog.
Deleted 'G28' from 'G53' FirstHome block at end of Prog.
Deleted 'G28' from 'G53Y0.' block at end of Prog.
Modified MultipleParts with WorkFixtureOffsets to not output Incremental Part Sub.
DWB}

{1/17/96, Updated .85 to .86 version, MPK}

{3/25/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '####.###;0.'
#4 = '#####.###;0.'
#5 = '#######0'
#6 = '######^##0'
#7 = '#####.###'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Num#,3)
FORMAT(ClearancePlane3#,3)
FORMAT(EPX#,3)
FORMAT(EPY#,3)
FORMAT(SPX#,3)
FORMAT(SPY#,3)
FORMAT(ArcR#,3)
FORMAT(ToolLength#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(CallMasterNum#,5)
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(FeedEntry#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is an Metric post}
END
RETURN

DoSubComment:
{
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
}
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
{
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
}
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC ' M57' EOL
SeqC ' A' FourthDegree# EOL
FourthCWF {reset flag}
SetFlag('3') { PostScript 4thAxis 'A' EPY# }
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC ' M57' EOL
SeqC ' A' FourthDegree# EOL
FourthCCWF {reset flag}
SetFlag('3') { PostScript 4thAxis 'A' EPY# }
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC ' B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC ' B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
IF Flag?('3') { PostScript 4thAxis 'A' EPY# }
SeqC ' G7.1 A0.' EOL
SeqC ' M54' EOL
SetFlagF('3') { PostScript 4thAxis 'A' EPY# }
IF FIFO?
SeqC FeedC CRCOffC ZCP3C FeedRateC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SubID EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall CallLab EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSub2: {part 2}
SeqC EndSub EOL
SaveSubStatus
CloseSub
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC SetWFO EOL
SeqC SubCall CallLab EOL
IncWFO
NextWFO
ELSE
EachPart
IF FirstPart? AND OneToolAllParts?
IF FullUp?
SeqC Rapid StrtPos EOL
ELSE
SeqC Rapid ZCP2C EOL
END
SetStatusOff
ELSE
SeqC Rapid StrtPos EOL
END
SeqC SubCall CallLab EOL
NextPart
SetStatusOn
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC AbsOrInc EndSub EOL
CloseSub
END
RETURN

DoAbsOrInc:
IF MultipleParts? AND EquallySpacedOffsets?
ELSE
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
END
RETURN

DoDrillAbsOrInc:
IF MultipleParts? AND EquallySpacedOffsets?
ELSE
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
END
RETURN

RestoreAbsOrInc:
IF MultipleParts? AND EquallySpacedOffsets?
ELSE
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
SetFlag('2') { CRCOffsetC }
CRCOnC
END
END
RETURN

GetMove:
IF Flag?('3') { PostScript 4thAxis 'A' EPY# }
' X' EPX# ' A' EPY#
ELSE
IF ArcFeat?
MoveXY
END
MoveXYZC
END
RETURN

FormatLine:
DoAbsOrInc ckCRC FeedC GetMove
RETURN

ckCRCNum:
IF Flag?('2')
SetFlagF('2')
CRCOffsetC
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
GetMove
IF Flag?('3') { PostScript 4thAxis 'A' EPY# }
ArcRC
ELSE
IF ArcIJFormat?
ArcIJ
ELSE
ArcRC
END
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF Flag?('3') { PostScript 4thAxis 'A' EPY# }
SeqC ' X' SPX# ' A' SPY# EOL
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
END
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc ckCRC RapidC GetMove ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatLine FeedRateC ckCRCNum EOL
DecelMove2
END
SeqC FormatLine DecelFeed ckCRCNum EOL
ELSE
SeqC FormatLine FeedRateC ckCRCNum EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
ELSE
SeqC ' G' NewWFO# EOL
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
SeqC ' G' NewWFO# EOL
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
IncValue { Output on FIRST block of sub }
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF MultipleParts? AND EquallySpacedOffsets?
ELSE
AbsOrInc
END
SeqC
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

StdRep:
SubWarning
FindAnyZMoves
IF NOT NoZMoves?
EntryMove
StdSub
ELSE
StdSub
EntryMove
END
IF MultipleParts? AND EquallySpacedOffsets?
ToolPath
ELSE
IF AbsoluteMoves?
IncValue { Output on FIRST block of sub }
ToolPath
AbsValue { Output at FinishSub1 }
ELSE
ToolPath
END
END
FinishSub1
FinishSub2
EachRep
IF NOT FirstCycle?
IF FeedConnect?
SeqC Feed StrtPos EOL
ELSE
SeqC Rapid StrtPos EOL
END
IF NOT NoZMoves?
IF FeedConnect?
SeqC Feed ZIn FeedEnt EOL
ELSE
EntryMove
END
END
SeqC SubCall CallLab EOL
END
SetSRSubXYRC
IF FeedConnect?
SetSRSubZRC
ELSE
SetSRSubZ { because of AbsOrInc ZCP2C }
END
NextRep
SetSRSubMove
RETURN

XYOnlyRepAutoCycle:
EachRep
ToolPath { SetPass2 WGPts }
NextRep
AutoCycCutSub1
EntryMove
AutoCycCutSub2
RETURN

ZOnlyRepAutoCycle:
EachFeat
IF NOT FirstFeat?
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqC Rapid ZCP2 EOL {.69}
END
ELSE
Rapid
END {.69}
SeqC RapidC MoveSXYC EOL
END
CalcACSRXY {calc tool position, CalcAutoCycleStatusRecordXY}
SetPass1 {element cut moves}
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed IncValue StrtPosC EOL
SeqC AbsOrInc
ELSE
SeqC Feed
END
ELSE
SeqC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqC AbsOrInc ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqC Rapid ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLab EOL
NextCycle
SetStatusOn
ReSetPass2 {restore for positioning moves}
NextFeat
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqC Rapid ZCP2 EOL {.69}
END
END {.69}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqC SubCall CallLab EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

DrillStuff:
GetCycle
IF Tap? AND OptCyc1?
IF CWSpindle?
' G84.2'
ELSE
' G84.3'
END
SeqC StrtPos RLevel ZDepth
IF GTEqual? SpeedRPM# Num#('1500')
' S1500'
ELSE
Speed
END
' F' FeedEntry# EOL
ELSE
SeqC Cycle FromCP StrtPos RLevel ZDepth Dwell Peck Retract FeedEnt EOL
END
IF CallMasterOp?
SeqC SubCall CallLabB CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC SubCall CallLab EOL
StartSub
ToolPath
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqC Rapid ' G80' ZCP3 CoolOff EOL
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
WFOStuff
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('6000')
SetMaxFeed('12500')
SetMinRpm('36')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { CRCOffsetC }
SetFlagF('3') { PostScript 4thAxis 'A' EPY# }
SetFlag('4') { CoolOff }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) ' '100' '-' EOL
' To Handle the Cylinder Interpolation ' EOL
' This command will output : G7.1 A 100 - 100 is the raduis value' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) ' '100' '-' EOL
' To Handle the Cylinder Interpolation ' EOL
' This command will output : G7.1 A 100 - 100 is the raduis value' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
' Tapping Cycle : G84.2 with CW in General Info1 ' EOL
' Tapping Cycle : G84.3 with CCW in General Info1 ' EOL
END

EachOp {Start of G10 Comments ************************}
IF FirstOperation?
EOR EOL
ProgID1 EOL
END
{
IF UseComments?
IF FirstOperation? OR NewTool?
'( OPERATION ' Operation# ': TOOL ' Tool# ' ' ToolType$ ' ' ToolDiameter# ' H' ToolOffset#
IF CutterRadiusCompensation?
'/D' CRCOffset# ' )' EOL
ELSE
' )' EOL
' (G10 ' AbsOrInc 'L10 P' Tool# ' R' ToolLength# ' )' EOL
' (G10 ' AbsOrInc 'L12 P' Tool# ' R' ToolDiameter# ' )' EOL
END
END
END
}
NextOp

EachOp {Start of post processing *********************}
IF FirstOperation?
IF ToolChangeAtHome?
SetHome
END
{
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' MILLIMETERS )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
}
OpenSub
RestoreScale
CheckPass { For OpenMP StrtPos }
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Seq ' G10 L2 P1 X Y Z B' EOL
SeqC DrillOff AbsOrInc Rapid CRCOff Plane EOL
SeqC OpToolID EOL
SeqC SubCall CallLabB '9001' EOL { ToolChange Sub }
IF NOT LastTool?
SeqC PreTool EOL
END
DoOpComments
DoPostScript
WFOStuff
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
IF MultipleParts? AND EquallySpacedOffsets?
SetAbs
TrackXNO# StartPosX#
TrackYNO# StartPosY#
SeqC IncValue EOL
ELSE
SeqC AbsOrInc RapidC StrtPos EOL
END
IF Tap? AND OptCyc1?
SeqC SpinOn ' S0' EOL
ELSE
SeqC Speed SpinOn EOL
END
SeqC OfstOn CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
IF EquallySpacedOffsets?
SeqC IncValue EOL
END
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF LAST NOT CoolOff? AND Flag?('4') { CoolOff }
SeqC CoolOff EOL
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
IF MultipleParts? AND EquallySpacedOffsets? AND AllToolsOnePart?
IncValue
ELSE
AbsOrInc
END
SeqC Rapid Home EOL
END
IF LAST ProgStop?
SeqC ' M00' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

IF MultipleParts? AND EquallySpacedOffsets? AND AllToolsOnePart?
IncValue
ELSE
AbsOrInc
END
Seq DrillOff Rapid CRCOffC PlaneC EOL
SeqC OpToolID EOL
SeqC SubCall CallLabB '9001' EOL { ToolChange Sub }
SeqC PreTool EOL
DoOpComments
DoPostScript
WFOStuff
CheckPass { For OpenMP StrtPos }
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
IF MultipleParts? AND EquallySpacedOffsets?
SetAbs
TrackXNO# StartPosX#
TrackYNO# StartPosY#
SeqC IncValue EOL
ELSE
SeqC AbsOrInc RapidC StrtPos EOL
END
IF Tap? AND OptCyc1?
SeqC SpinOn ' S0' EOL
ELSE
SeqC Speed SpinOn EOL
END
SeqC OfstOn CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
IF EquallySpacedOffsets?
SeqC IncValue EOL
END
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
IF LAST NOT CoolOff? AND Flag?('4') { CoolOff }
SeqC CoolOff EOL
END
SeqC ' G53 Z0.' EOL { OfstOff }
SeqC ' M00' EOL

{Start new Operation}

GetStartOfSameTool
IF MultipleParts? AND EquallySpacedOffsets?
IncValue
ELSE
AbsOrInc
END
SeqC PlaneC Rapid StrtPos EOL
IF Tap? AND OptCyc1?
SeqC SpinOn ' S0' EOL
ELSE
SeqC SpinOn SpeedC EOL
END
SeqC OfstOn CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff? AND Flag?('4') { CoolOff }
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC ' G53 Z0.' EOL { OfstOff }
END

{Start new Operation}

GetStartOfSameTool
IF MultipleParts? AND EquallySpacedOffsets?
IncValue
ELSE
AbsOrInc
END
SeqC PlaneC Rapid StrtPos EOL
IF Tap? AND OptCyc1?
SeqC SpinOn ' S0' EOL
ELSE
SeqC SpeedC EOL
END
IF NewToolOffset?
SeqC OfstOn EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
SetFlag('4') { CoolOff }
IF Flag?('3') { PostScript 4thAxis 'A' EPY# }
SeqC ZCP2C EOL
EntryMove
SeqC ' G7.1 A' EOL
PSInit
EachPS
SeqC PostScript EOL {literals}
NextPS
ToolPath
ELSE { NOT Flag(3) PostScript 4thAxis 'A' EPY# }
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
StdRep
END
END {end Auto Cycle IF}
ELSE {not Z only}
IF AutoCycle?
XYOnlyRepAutoCycle
ELSE
StdRep
END {end Auto Cycle IF}
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
SeqC DrillCP EOL
IF Repeats?
EachRep
IF FirstCycle?
NewProg
StdSub
DrillStuff
IF MultipleParts? AND EquallySpacedOffsets?
IncValue
ELSE
AbsOrInc
END
FinishSub2
ELSE
SeqC StrtPos EOL
SeqC SubCall CallLab EOL
END
SetSRSubXYRC
SetSRSubZRC
NextRep
SeqC RapidC ZCP2C EOL
ELSE
DrillStuff
END
SetFlagF('4') { CoolOff }
END { IF Drilling }
END { IF Milling }
END { Flag(3) PostScript 4thAxis 'A' EPY# }
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF NOT CoolOff? AND Flag?('4') { CoolOff }
SeqC CoolOff EOL
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqC ' T0' ToolChng EOL
SeqC Rapid AbsValue ' G80 G53 Z0.' EOL { OfstOff }
IF First ToolChangeAtHome?
SeqC ' G53' FirstHome EOL
ELSE
SeqC ' G53 Y0.' EOL
END
IF ProgStop?
SeqC ' M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
{
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
}