{Change Comments ***********************************************************}

{1/29/90, Updated: Fanuc 0T-Miyano L008.52 to .69 format, JR}
{7/24/90, Added InitProg globally to posts with this remark, DWB}
{9/25/90, Updated to Version 3.2 per Fanuc 10T MS [-] L001.71.1 Format, DWB}
{10/2/90, Added StockOff globally at FirstOperation, DWB}
{10/8/90, Replace CalcRPM2 globally with CalcEPRPM# at end of prog, DWB}

{3/27/91
Modified: Fanuc 0T/3T Miyano L008.71.3
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format.
All normal Fanuc Canned Cycles are supported.
Added Math to calculate start of Tapered Thread for AutoFinish.
DWB}

{07/24/91
For: Precision Machine (Phoenix)
Modified: Fanuc 0T/3T Miyano L008.80
Changed Tailstock positioning ('X' and 'Z' moves to separate lines
To avoid tools that overhang the chuck and part putting the 'Z' move first)
Changed 'G50' output adding 'home'.
Moved 'G96' block in front of first 'G1' block.
Added GearRanges for (2 GEAR) machine.
Added PalletIn/PalletOut commands to advancing -'M10'
and retracting -'M11' tailstock.
Added 'M68' and 'M69' to open and close chuck.
Kim Michelman}

{08/02/91
Updated: Fanuc 0T TS [3GEAR] L225.80
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.82 Format.
Kim Michelman}

{11/20/91 - Modified: Fanuc 3TF TS [3GEAR] L225.82/ Added a RETURN to a sub that was missing it & changed
Approach to - for Tailstock.}

{01/06/92
Modified: Fanuc 0T TS [3GEAR] L225.82.1
For: Precision Machine
Added Format #7, and HomeX# and HomeZ#.
Changed TurnOnCRC to TurnOnCSS.
Capitalized the Return command.
Separated the 'Z' and the 'X' to different lines in the Approach sub for Tailstock.
Added GearRange to the PostScript.
Added GearRange command to the program.
Changed the IF ConstantSurfaceFeed? boolean to only output the MaxRPM.
Removed all 'X0.Z0.' literals and replaced with 'X' HomeX# 'Z' HomeZ#. (on separate lines)
Commented out the section in SameTool that applies to the LAST ToolChangeAtHome? - This will never be
true and was causing a bug in the program. Commented out to enable when capability is furnished.
Added AFODApproachSP, AFIDApproachSP, AFFaceApproachSP subs for the AutoFinish w/o Canned Cycles.
Added Approach section to the IF AutoFinish? - IF Turning? - IF NOT Canned Cycle? This is only needed in long hand SetPass1.
*The added section to the AutoFinish is a BUG in all Lathe processors and needs to be corrected.
Kim Michelman}

{02/13/92
Modified: Fanuc 0T TS [3GEAR] L225.82.2
For: Precision Machine
Changed the HomeX# & HomeZ# to NewHomeX# & NewHomeZ# in NewTool Section.
Changed LAST HomeX# and LAST HomeZ# to NewHomeX# & NewHomeZ# in
the commented out section in case of usage.
Changed HomeX# & HomeZ# to FirstHomeX# & FirstHomeZ# at the end of the program.
Kim Michelman}

{03/18/92
Modified: Fanuc 0T TS [3GEAR] L225.82.3
For: Precision Machine
Added FORMAT(NewHomeX#,7) and FORMAT(NewHomeZ#,7), not added when last modified.
And FORMAT(FirstHomeX#,7), FORMAT(FirstHomeZ#,7).
Kim Michelman}

{4/12/92
Updated:Fanuc 0T TS [3GEAR] L225.82.4
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 0T/3T Miyano L008.82.1 Format.
KM}

{1/8/97, updated to .85 format, MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.######;0.'
#6 = '###0'
#7 = '####.####;0.'
#8 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ADD#,2)
FORMAT(SPX#,2)
FORMAT(SPZ#,2)
FORMAT(FinishXDia#,2)
FORMAT(Taper#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(HomeX#,7)
FORMAT(HomeZ#,7)
FORMAT(NewHomeX#,7)
FORMAT(NewHomeZ#,7)
FORMAT(FirstHomeX#,7)
FORMAT(FirstHomeZ#,7)
FORMAT(RapidF#,8)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
PalletInF
PalletOutF
OptCyc1F
RETURN

PSStuff:
IF PalletIn? {For advancing Tailstock}
SeqLabC 'M10' EOL
END
IF PalletOut? {For retracting Tailstock}
SeqLabC 'M11' EOL
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

TurnOnCSS:
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn 'G96' Speed EOL
END
RETURN

ODApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
TurnOnCSS
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC Feed XSPC FeedRate EOL
ELSE
RapidF# { No Output - Forces FeedRate in ToolPath }
END
RETURN

IDApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
TurnOnCSS
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC Feed XSPC FeedRate EOL
ELSE
RapidF# { No Output - Forces FeedRate in ToolPath }
END
RETURN

FaceApproachSP:
SeqLabC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
TurnOnCSS
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC Feed ZSPC FeedRate EOL
ELSE
RapidF# { No Output - Forces FeedRate in ToolPath }
END
RETURN

AppMove:
OpToolID LatheOffset CoolOn
RETURN

Approach: { FOR TAILSTOCK, .82 }
IF ApproachOD?
SeqLabC Rapid ThisOpEntryZCP AppMove EOL
SeqLabC ThisOpEntryXCP EOL
ODApproachSP
ELSE
IF ApproachID?
SeqLabC Rapid ThisOpEntryZCP AppMove EOL
SeqLabC XOpCD EOL
IDApproachSP
ELSE {ApproachFace}
SeqLabC Rapid ThisOpEntryZCP AppMove EOL
SeqLabC StockOnNoCan XSP StockOff EOL
FaceApproachSP
END
END
RETURN

AFODApproachSP: {Without the 'TurnOnCSS' sub to avoid double execution of 'G96' line}
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
SeqLabC Feed StockOnNoCan XSPC FeedRate EOL
RETURN

AFIDApproachSP: {Without the 'TurnOnCSS' sub to avoid double execution of 'G96' line}
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
SeqLabC Feed StockOnNoCan XSPC FeedRate EOL
RETURN

AFFaceApproachSP: {Without the 'TurnOnCSS' sub to avoid double execution of 'G96' line}
SeqLabC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
SeqLabC Feed StockOnNoCan ZSPC FeedRate EOL
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF NewGear?
SeqLabC SpinOff EOL
END
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
IF NewGear?
SeqLabC GearRange EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset Home MaxRPM EOL
END
ELSE
SeqLabC Preset Home MaxRPM EOL
SeqLabC CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' Speed
END
END
IF LAST ProgStop?
SeqLabC SpeedC SpinOn EOL
SeqLabC CoolOn EOL
ELSE
SeqLabC SpeedC EOL
IF NewGear?
SeqLabC SpinOn EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
CRCOnC
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
IF Drilling? AND OptCyc1?
IF FirstFeat?
SeqC 'M68' EOL {Open Chuck}
SeqC 'G4P' EOL {Dwell}
END
IF LastFeat?
SeqC 'M69' EOL {Close Chuck}
SeqC 'G4P' EOL {Dwell}
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' PalletIn() -' EOL
' PalletIn will need an argument (any number) between the ()' EOL
' when Palletin is used, it will output the M code for advancing tailstock ' EOL
' PalletOut -' EOL
' Will retract the tailstock with the M code for retracting tailstock ' EOL
' GearRange -'EOL
' this machine allows for set-up of GearRange at: 11-323 is M41, 323-900 is M42, ' EOL
' 900-2500 is M43. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
SeqLabC GearRange EOL
IF Drilling? AND OptCyc1?
SeqLabC OpToolID '00' SpinOff EOL { Programmer is doing BarFeed Operation }
ELSE
SeqLabC Preset Home
IF ConstantSurfaceFeed?
MaxRPM
END
EOL
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
OpToolID '00' SpinOn EOL
END
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' CalcRPM2 EOL
END
SeqLabC Rapid 'X' NewHomeX# LOfstOff '00' EOL
SeqLabC 'Z' NewHomeZ# EOL
IF NewGear?
SeqLabC SpinOff EOL
END
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
SeqLabC GearRange EOL
IF Drilling? AND OptCyc1?
SeqLabC OpToolID '00' SpinOff EOL { Programmer is doing BarFeed Operation }
ELSE
SeqLabC Preset Home
IF ConstantSurfaceFeed?
MaxRPM
END
EOL
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
OpToolID '00' SpinOn EOL
END
Approach
ELSE
IF SameTool? {.62}

{The customer would like the capability of returning to Home
in a 'Same Tool' situation. If we ever add this feature, either
thru Postscript or a button in CAM, then this is how they want the code.}
{IF LAST ToolChangeAtHome?

[Finish off last Operation]

StockOff [.62]
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' CalcRPM2 EOL
END
SeqLabC Rapid 'X' NewHomeX# LOfstOff '00' EOL
SeqLabC 'Z' NewHomeZ# EOL
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END

[Start new Operation]

DoOpComments
DoPostScript
IF ConstantSurfaceFeed?
SeqLabC Preset Home MaxRPM EOL
END
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL
SeqLabC Rapid
Approach
ELSE}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
CheckOffset
FaceApproachSP
END { ApproachID }
END { ApproachOD }
END { StraightConnect }
END { SameTool }
END { NewTool }
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
IF ApproachFace?
SeqLabC LCycle 'Z' FirstMoveEPZ# XatFinZ XTapAtZ FeedRate EOL
ELSE
SeqLabC LCycle XatFinZ FinZ XTapAtZ FeedRate EOL
END
SimpleRough
ELSE
TagInc
IF RoughContour?
SetPass2
SeqLabC LCycle CutDepth EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove 'Z' SPZ# EOL
SeqLabC 'X' SPX# EOL
ELSE
SeqLab StepMove 'X' SPX# EOL
SeqLabC 'Z' SPZ# EOL
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
ELSE
IF RoughPatternShift?
SetPass2
SeqLabC LCycle XminusU ZminusW NumCuts EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
END
END
END
ELSE
IF Threading?
IF Chamfer?
SeqLabC 'M23' EOL
END
SeqLabC LCycle XatFinZ FinZ XTapAtZ CutMethod ThrdHeight CutDepth ThrdLead ToolAngle EOL
IF AutoFinish?
IF Taper?
SeqLabC Rapid
'X' ADD# FinishXDia# MUL# Taper# NumSc#('2') { Outputs start of Taper }
EOL
SeqLabC 'G32' XatFinZ FinZ ThrdLead EOL
ELSE
SeqLabC Rapid XatFinZ EOL
SeqLabC 'G32' FinZ ThrdLead EOL
END
SeqLabC Rapid XCSP EOL
SeqLabC ZCSP EOL
END
IF Chamfer?
SeqLabC 'M24' EOL
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF PeckChipBreaker?
SeqLabC LCycle ZDepth RLevel Dwell Peck Retract FeedRate EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple?
StockOff
IF Turning? {OR RoughSimple?}
SetPass1
IF ApproachOD?
SeqLabC RapidC XOpECDC EOL
AFODApproachSP
ELSE
IF ApproachID?
SeqLabC RapidC XOpECDC EOL
AFIDApproachSP
ELSE {ApproachFace}
SeqLabC RapidC ZOpECPC EOL
AFFaceApproachSP
END
END
ELSE
SetPass2
END
SeqLabC RapidC StrtPos EOL
ToolPath
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
SeqLabC CoolOff EOL
IF ConstantSurfaceFeed?
SeqLabC CSSOff 'G97S' CalcEPRPM# EOL
END
SeqLabC Rapid 'X' FirstHomeX# EOL
SeqLabC 'Z' FirstHomeZ# OpToolID '00' SpinOff EOL
SeqLabC UnTool '00' EOL
IF ProgStop?
SeqLabC 'M0' EOL
END
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END