{Change Comments ***********************************************************}

{8/16/95,
Updated for Catalyst v2.20 per Fanuc 10T MS [-] L001.85.01 Format.
DWB}

{
Format: Okuma OSP 5000 LB15 Lxxx.85
5/21/96
For: Red Head Brass
Removed DA from canned drilling cycles
TH}

{5/12/97
Initial: Okuma OSP 5000 [RHB] L459.85
Created: Okuma OSP 5020L LB15 L000.85
ForUser: Braden Engineering / Precision Brass Services, Inc.
Control: Okuma OSP 5020L
Machine: Okuma LB-15
Develop: ComPost2 68K 1.0b11, CatalystPPC v3.33C
Comment: New processor per marked up readout and conversation with Landon
Added LNS Bar Stock feeder to begining of program..
Added Graphics coding to beginning of program.
Added program looping.
Added Bar Catcher codes.
Added Bar Feeder hard coded to end of program..
Changed to R format arcs with label L.
Jim Radcliffe}

{5/13/97
Initial: Okuma OSP 5020L LB15 L000.85
Created: Okuma OSP 5020L LB15 L000.85.1
Comment: Deleted '.MIN' from beginning of program.
Jim Radcliffe}

{10Dec97
Original:Okuma OSP 5020L [PB] L604.85.1
Created: Okuma OSP 5020L [WMC] L676.85
For: WMC Grinding Inc
Changes made per: Lee
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
Deleted Literal 'NTOP' from FirstOp
Deleted LNS Bar Feeder sequence from FirstOp
Deleted Literal 'GOTO NTOP' from End of Prog
Changed M2 to M30 in MachSpec
Changed G74 to G01 in MachSpec FIRO and FI_D_RO Drill Cycs
Changed Bar Feeder code at End of Prog to output only if OptCyc1? is TRUE
Charles Winston}

{11Dec97
Original: Okuma OSP 5020L [WMC] L676.85
Created: Okuma OSP 5020L [WMC] L676.85.1
For: WMC Grinding Inc
Changes made per: Lee
Added formatting for ZOpECP# in Prog Numeric Format Definitions
Added a move to ZOpECP# at IF Drilling? if FIRO? is TRUE
Charles Winston}

{11Dec97
Original: Okuma OSP 5020L [WMC] L676.85.1
Created: Okuma OSP 5020L [WMC] L676.85.2
For: WMC Grinding Inc
Deleted FIRO Drill Cycle in MachSpec ( Customer does not have a canned cycle for this in his control )
Charles Winston}

{06Jan98
Original: Okuma OSP 5020L [WMC] L676.85.2
Created: Okuma OSP 5020L [WMC] L676.85.3
For: WMC Grinding Inc
Changed MoveXC to MoveX and MoveZC to MoveZ in FormatArc, forces X and Z to be output
Charles Winston}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '+####.####;0'
#3 = '#######0'
#4 = '###.##;0'
#5 = '####.####;0'
#6 = '###0'
#7 = '#'
#8 = '0^0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(XCutDepth#,2)
FORMAT(ZCutDepth#,2)
FORMAT(ZOpECP#,2)
FORMAT(Program#,3)
FORMAT(Operation#,3)
FORMAT(Tool#,3)
FORMAT(Dwell#,4)
FORMAT(Peck#,5)
FORMAT(ThisOpEntryXCP#,5)
FORMAT(ADD#,5)
FORMAT(ABS#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
FORMAT(XStockMax#,8)
FORMAT(SUB#,8)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC ' M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
CSSOff
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
IF LAST ProgStop?
CSSOn ' G96' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
CSSOn ' G96' Speed
END
END
ELSE
SeqLabC Preset MaxRPM EOL
CSSOn ' G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
' G97' Speed
ELSE
IF LAST ProgStop?
' G97' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
' G97' Speed
END
END
END
END
IF LAST ProgStop?
SeqLabC {SpeedC} SpinOn EOL
SeqLabC CoolOn EOL
ELSE
SeqLabC {SpeedC} EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveX MoveZ
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC:
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC ' G4 P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC ' G4 P' Dwell# EOL
END
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC ' G33' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC Rapid
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
TagInit
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
'$' ProgramName$ EOR EOL
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff
SetHome

{ Gaphics Definition }
SeqLabC ' CLEAR' EOL
SeqLabC ' DEF WORK' EOL
SeqLabC ' PS RC, [0,0],[' SUB# ZStockMax# ZStockMin# ',' XStockMax# ']' EOL
SeqLabC ' END' EOL
SeqLabC ' DRAW' EOL

DoOpComments
DoPostScript
Plane
IF ConstantSurfaceFeed?
SeqLab Preset MaxRPM EOL
SeqLabC Rapid CSSOff ' G97' CalcRPM1
ELSE
SeqLab Rapid CSSOff ' G97' Speed
END
OpToolID LatheOffset SpinOn CoolOn ' M42' EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff ' G97' CalcRPM2 EOL
END
SeqLabC NewHome
IF LAST ProgStop?
' M0'
ELSE
ProgStop
END
EOL

{Start new Operation}

DoOpComments
DoPostScript
IF ConstantSurfaceFeed?
SeqLab Preset MaxRPM EOL
SeqLabC Rapid CSSOff ' G97' CalcRPM1
ELSE
SeqLab Rapid CSSOff ' G97' Speed
END
OpToolID LatheOffset SpinOn CoolOn ' M42' EOL
Approach
ELSE
IF SameTool?

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn ' G96' Speed EOL
END
IF CutOff?
SeqLabC ' M101' EOL {part catcher down}
END
IF CannedCycle?
StockOff
IF Roughing?
IF NOT RoughSimple?
TagInc
SetPass2
IF RoughContour?
SeqLabC ' G85 Nł' Tag#
IF ApproachFace?
' D' ZCutDepth#
ELSE
' D' XCutDepth#
END
FeedRate XStkLeft ZStkLeft EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab ' G82' EOL
ELSE
SeqLab ' G81' EOL
END
ELSE
IF RoughPatternShift?
SeqLabC ' G86 Nł' Tag#
IF ApproachFace?
' D' ZCutDepth#
ELSE
' D' XCutDepth#
END
FeedRate XStkLeft ZStkLeft EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab ' G82' EOL
ELSE
SeqLab ' G81' EOL
END
END
END
SeqLabC StepMove StrtPos EOL
ToolPath
SeqLabC ' G80' EOL
IF AutoFinish?
SeqLabC ' G87 Nł' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?

{ G72 Face Threads modification would require changes to XTapAtZ command with W Address }

SeqLabC ' G71' XatFinZ FinZ XTapAtZ
IF SingleEdgeCut?
ToolAngle
ELSE
' B0'
END
CutDepth ThrdHeight ThrdLead ' M32'
IF ConstantVolumeCut?
' M75'
ELSE
' M74'
END
IF Chamfer?
' M23'
ELSE
' M22'
END
EOL
IF AutoFinish?
SeqLabC ' G33' XatFinZ FinZ XTapAtZ ThrdLead EOL
SeqLabC Rapid XCSP EOL
SeqLabC ZCSP EOL
END
ELSE
IF Drilling?
SeqLabC
IF Tap? AND NOT CWSpindle?
' G78'
ELSE
LCycle
END
XCSP ZDepth Peck Retract
IF PeckFullRetract?
' L' Peck#
END
FeedRate Dwell EOL
IF FIRO?
SeqLabC Rapid ' Z' ZOpECP# EOL
ELSE
IF FIFO?
SeqLabC Feed ' Z' ZOpECP# EOL
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC ' X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC ' G33'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC ' G4 P2000' EOL
SeqLabC Speed SpinOn EOL
END
END
IF CutOff?
SeqLabC ' M102' EOL {part catcher up}
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC Rapid
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
SeqLabC CoolOff EOL
IF ConstantSurfaceFeed?
SeqLabC CSSOff ' G97 S' CalcEPRPM# EOL
END
SeqLabC FirstHome
IF ProgStop?
' M0'
ELSE
ProgStop
END
EOL

{ Bar Feeder }
IF OptCyc1?
SeqLab ' T0818' SpinOff EOL
SeqLabC Rapid ' X0 Z' ADD# ZStockMin# Num#('.01') EOL
SeqLabC ' G94' EOL {IPM}
SeqLabC ' M84' EOL {open chuck}
SeqLabC ' G04 F.2' EOL
SeqLabC Feed ' Z' ADD# ZStockMax# Num#('.015') ' F100.' EOL
SeqLabC ' M83' EOL {close chuck}
SeqLabC ' G04 F.02' EOL
SeqLabC Rapid ' G95' FirstHome EOL
SeqLabC ProgStop EOL
END

SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END