{2/13/90, Updated: Fanuc 3000C Acroloc M066.53 to .70 & Added AbsOrInc on Preset ZCP1 line, JR}
{7/24/90, Added InitProg globally to posts with this remark, DWB}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}
{4/03/91
Modified: Fanuc 3000C Acroloc M066.71
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}
{6/23/94
Modified: Fanuc 3000C Acroloc M066.79
For: FEL Corp.
Altered default setting to included decimal points
Changed Tool Change sequence.
Dan Pilone}
#1 = '#.00'
#2 = '###.0000'
#3 = '00'
#4 = '###.###;0.'
#5 = '*###.###;0.'
FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CRCNormalVectorX#,2)
FORMAT(CRCNormalVectorY#,2)
FORMAT(ToolOffset#,3)
DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN
PSStuff:
IF Rotate?
IF FourthCW?
FORMAT(FourthDegree#,4)
SeqLabC 'A' FourthDegree# EOL
ELSE
IF FourthCCW?
FORMAT(FourthDegree#,5)
SeqLabC 'A' FourthDegree# EOL
ELSE
IF FifthCW?
FORMAT(FifthDegree#,4)
SeqLabC 'B' FifthDegree# EOL
ELSE
IF FifthCCW?
FORMAT(FifthDegree#,5)
SeqLabC 'B' FifthDegree# EOL
END
END
END
END
END
RETURN
DoPostScript:
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN
DoEndOpPS:
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN
DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN
EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN
StartSub:
OpenSub
DoSubComment
'>' Tag# EOL
RETURN
SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN
StdSub:
SubWarning
SeqLabC 'M98Pł' Tag# 'R' Repeats# EOL
StartSub
SeqLab AbsOrInc Connect StrtPos EOL
RETURN
FinishSub1: {part 1}
UnSkipZ
IF FeedConnect?
SeqLabC CRCOff EOL
ELSE
SeqLabC RapidC ZCP3C EOL
IF CutterRadiusCompensation?
SeqLabC CRCOff LastFeatExtend EOL
END
END
RETURN
FinishSubG92: {part 2}
SeqLabC Preset ShiftRC EOL
SeqLabC 'M99' EOL
CloseSub
SeqLabC Preset UnshftRC EOL
RETURN
OpenMP:
NewProg
TagInc
SeqLabC 'M98Pł' Tag# 'R' Parts# EOL
StartSub
RETURN
CloseMP:
SeqLabC Preset ShiftPC EOL
SeqLabC 'M99' EOL
CloseSub
SeqLabC Preset UnshftPC EOL
RETURN
FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN
StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC CRCOnC FeedC MoveXYZC
IF CutterRadiusCompensation? AND FirstFeat?
'I' CRCNormalVectorX# 'J' CRCNormalVectorY# CRCOfst
END
FeedRateC EOL
DecelMove2
END
SeqLabC CRCOnC FeedC MoveXYZC
IF CutterRadiusCompensation? AND FirstFeat?
'I' CRCNormalVectorX# 'J' CRCNormalVectorY# CRCOfst
END
DecelFeed EOL
ELSE
SeqLabC CRCOnC FeedC MoveXYZC
IF CutterRadiusCompensation? AND FirstFeat?
'I' CRCNormalVectorX# 'J' CRCNormalVectorY# CRCOfst
END
FeedRateC EOL
END
RETURN
ToolPath:
EACHFeat
IF PointFeat?
SeqLabC MoveSXYC EOL
IF AutoCycle?
SeqLabC 'M98Pł' Tag# EOL
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqLabC CRCOffC RapidC MoveXYZC EOL
ELSE
SeqLabC RapidC MoveXYZC EOL
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqLabC CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLabC FeedC MoveXYZC FeedRateC EOL
ELSE
IF NOT FirstFeat? AND LAST ZMove? {1st move after last Z move}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC CRCOnC FeedC MoveXYZC
IF CutterRadiusCompensation?
'I' CRCNormalVectorX# 'J' CRCNormalVectorY# CRCOfst
END
FeedRateC EOL
DecelMove2
END
SeqLabC CRCOnC FeedC MoveXYZC
IF CutterRadiusCompensation?
'I' CRCNormalVectorX# 'J' CRCNormalVectorY# CRCOfst
END
DecelFeed EOL
ELSE
SeqLabC CRCOnC FeedC MoveXYZC
IF CutterRadiusCompensation?
'I' CRCNormalVectorX# 'J' CRCNormalVectorY# CRCOfst
END
FeedRateC EOL
END
ELSE
StdLine {enables CRC on first call}
END
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN
AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLab IncValue EOL
SeqLabC StrtPosC EOL
RETURN
AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqLabC AbsOrInc CRCOffC EOL {.69 removed RapidC}
ELSE
SeqLabC AbsOrInc RapidC CRCOffC ZCP2 EOL
END
SeqLabC 'M99' EOL
CloseSub
SetSRSubXY {restore tool position}
SetSRSubMove
RETURN
AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
RETURN
Milling:
IF AutoCycle?
NewProg
TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN
G92Sub:
StdSub
Milling
FinishSub1
FinishSubG92
RETURN
ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
SeqLab {force N# for proper tag}
NewProg
TagInc
SetPass1 {for correct Z's}
EachCycle
IF FeedConnect?
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC Rapid ZCP2PlusInc EOL {.69 added Rapid, reads better}
{can't call for cycle = 1, .69 changed to ZCP2PlusInc}
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL {.69 added Rapid, reads better}
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLabC 'M98Pł' Tag# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
SeqLabC Rapid ZCP2 EOL {.69}
END {.69}
SeqLabC 'M99' EOL
CloseSub
{Element shift, not pattern}
RETURN
ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLabC StrtPos EOL
END
IF FeedConnect?
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC Rapid ZCP2PlusIncC EOL {can't call for cycle =1}
{.69 added Rapid, reads better}
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL {.69 added Rapid, reads better}
END
END
SeqLabC 'M98Pł' Tag# EOL
NextCycle
StartSub
SeqLab {force N# for proper tag}
SkipZ
ToolPath
FinishSub1
SeqLabC 'M99' EOL
CloseSub
RETURN
CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN
{Start of executable Prog **************************************************}
{setup and initializations}
InitProg
ReverseXZArcs
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50') {?}
SetMaxRPM('10000') {?}
SetMaxFeed('500') {?}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals : put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp
IF FirstOperation?
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL IN SPINDLE )' EOL
END
END
{'( TOOL OFFSET SET TO FIRST CLEARANCE PLANE )' EOL}
nullfoot EOL
'@' EOL
IF ToolChangeAtHome?
SetHome
END
OpenSub
DoSubComment
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
SeqLab Plane Rapid AbsOrInc 'G80' CRCOff 'Z5.0000' EOL
DoOpComments
DoPostScript
SeqLabC OpToolID ToolChng Speed5M EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLabC StrtPos SpinOn AbsOrInc Rapid EOL
SeqLabC {IncValue} 'G01' OfstOn 'F200.00' EOL
{SeqLabC AbsOrInc {Preset} ZCP1 EOL}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab StrtPos EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLabC {OfstOff} Rapid 'G46Z5.0000' LastToolOffset EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqLabC AbsOrInc Rapid Home EOL
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END
{DialTool}
SeqLabC {Plane 'G80'} CRCOffC EOL
DoOpComments
DoPostScript
SeqLabC OpToolID ToolChng Speed5M EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLabC AbsOrInc Rapid StrtPos SpinOn EOL
SeqLabC 'G01' OfstOn 'F200.00' EOL
{SeqLabC AbsOrInc Preset ZCP1 EOL}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLabC {OfstOff} Rapid 'G46Z5.0000' LastToolOffset EOL
SeqLabC 'M00' EOL
{Start new Operation}
DoOpComments
DoPostScript
CheckPass
SeqLabC PlaneC AbsOrInc Rapid StrtPos EOL
SeqLabC Speed5M SpinOn EOL
SeqLabC Feed IncValue OfstOn ZCP1 FeedEnt EOL
{SeqLabC AbsOrInc Preset ZCP1 EOL}
ELSE
IF NewToolOffset?
SeqLabC {OfstOff} Rapid 'G46Z5.0000' LastToolOffset EOL
{Start new Operation}
DoOpComments
DoPostScript
CheckPass
SeqLabC PlaneC AbsOrInc Rapid StrtPos EOL
SeqLabC Speed5M SpinOn EOL
SeqLabC IncValue OfstOn EOL
{SeqLabC AbsOrInc Preset ZCP1 EOL}
ELSE
{Start new Operation}
DoOpComments
DoPostScript
CheckPass
SeqLabC PlaneC AbsOrInc Rapid StrtPos EOL
SeqLabC Speed5M EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqLabC ZCP2C EOL
IF Repeats?
NewProg
TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
IF NOT AutoCycle?
SeqLabC RapidC ZCP3C EOL
IF CutterRadiusCompensation?
SeqLabC CRCOff LastFeatExtend EOL
END
END
END
SeqLabC RapidC CRCOffC ZCP3C EOL
ELSE
IF Drilling?
IF Repeats?
TagInc
NewProg
SeqLabC 'M98Pł' Tag# 'R' Repeats# EOL
OpenSub
DoSubComment
'>' Tag# EOL
SeqLabC AbsOrInc Rapid StrtPos EOL
END
SeqLabC DrillCP EOL
GetCycle
SeqLabC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
ToolPath
SeqLabC 'G80' EOL
IF Repeats?
SeqLabC Preset ShiftRC EOL
SeqLabC 'M99' EOL
CloseSub
SeqLabC Preset UnshftRC EOL
END
SeqLabC RapidC ZCP3C EOL
END
END
NextOp
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLabC {OfstOff} 'G46Z5.0000' LastToolOffset EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqLabC AbsOrInc Rapid
IF ToolChangeAtHome?
FirstHome
END
EOL
IF ProgStop?
SeqC 'M00' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
{ResetTool}
SeqLabC 'M30' EOL
{'%' EOL}
nullfoot EOL
{'%' EOL}
Post
'@' EOL
Close
Retag
IF UseComments?
SetScale('1')
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END