{Change Comments ***********************************************************}

{9/18/95
Modified: Fanuc 0M G54 [Cont] M835.85
For: Contemporary Machine
This Prog uses Flags '6' and '7' to control pretool output
pretooling is done in StdLine or ToolPath
Updated for Catalyst v2.20 per Fanuc 6M M001.85 Format, MPS}

{1/18/96
Modified: Fanuc 0M G54 [Cont] M835.85.1
For: Contemporary Machine
Changed each instance of /IF FirstFeat? AND Flag?('7')/
to /IF {1/18/96} Flag?('7')/.
- MPS}

{2/29/96- Updated to .86 format, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{15/May/97
Original: Fanuc 0M G54 [Cont] M835.89
Created: Fanuc 0M G54 [Cont] M835.89.1
For: Contemporary Machine
Changes made per: Troy Hasty
Moved ToolChangeAtHome? after ProgStop? in NewTool?
Added Boolean in SameTool? to turn Speed and Spindle back on after a ProgStop
Charles Winston}



{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '########;0'
#6 = '####^##0;'
#7 = '0000'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(Program#,7)
FORMAT(Repeats#,5)

{Prog Subroutines **********************************************************}

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

CkSpeed:
IF RigidTap? OR Tap?
'S2500' {always start with S2500 for Tapping per Troy at Contemporary Mach.}
ELSE
IF NewTool?
Speed
ELSE
SpeedC
END
END
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SubID EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC 'M98P' Repeats# Program# EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedRateC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
SeqC 'M98P1' Program# EOL
IncWFO
EachWFO
SeqC SetWFO EOL
SeqC 'M98P1' Program# EOL
IncWFO
NextWFO
ELSE
SeqC 'M98P' Parts# Program# EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC:
IF XMove? OR YMove? { Approach Length Feature and Multiple Pockets }
IF NOT ZMove?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

StdLine:
IF Decelerate?
IF RoomToDecel?
DecelMove1
IF {1/18/96} Flag?('7')
SeqC DoAbsOrInc CkCRC FeedC MoveXYZC FeedRateC CRCOffsetC PreTool 'M106'
SetFlagF('7') {don't preselect tool until after next toolchange}
ELSE
SeqC DoAbsOrInc CkCRC FeedC MoveXYZC FeedRateC CRCOffsetC
END
EOL
DecelMove2
END
SeqC DoAbsOrInc CkCRC FeedC MoveXYZC DecelFeed CRCOffsetC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
IF {1/18/96} Flag?('7')
SeqC DoAbsOrInc CkCRC FeedC MoveXYZC FeedRateC CRCOffsetC PreTool 'M106'
SetFlagF('7') {don't preselect tool until after next toolchange}
ELSE
SeqC DoAbsOrInc CkCRC FeedC MoveXYZC FeedRateC CRCOffsetC
END
EOL
END
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
IF {1/18/96} Flag?('7')
SeqC MoveSXYC PreTool 'M106'
SetFlagF('7') {don't preselect tool until after next toolchange}
ELSE
SeqC MoveSXYC
END
EOL
SeqC 'M98P1' Program# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF FirstFeat? AND LastFeat?
SeqC {DoDrillAbsOrInc} MoveSXYC PreTool 'M106' EOL {no change in 'Z' output}
ELSE
IF FirstFeat?
SeqC {DoDrillAbsOrInc} MoveSXYC EOL {no change in 'Z' output}
SetFlag('6') {we have output first no move drill point feat}
ELSE
IF Flag?('6') AND Flag?('7')
SeqC {DoDrillAbsOrInc} MoveSXYC PreTool 'M106' EOL {no change in 'Z' output}
SetFlagF('6') {reset flag, probably unnecessary because of Flag('7')}
SetFlagF('7') {don't preselect tool until after next toolchange}
ELSE
SeqC MoveSXYC EOL
END
END
END
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle?
SeqC DoAbsOrInc CRCOffC RapidC MoveXYZC EOL
ELSE
IF {1/18/96} Flag?('7')
SeqC DoAbsOrInc RapidC MoveXYZC PreTool 'M106'
SetFlagF('7') {don't preselect tool until after next toolchange}
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc RapidC MoveXYZC
END
END
EOL
END
ELSE
IF LineFeat?
IF AutoCycle?
IF LastFeat?
SeqC DoAbsOrInc CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
IF {1/18/96} Flag?('7')
SeqC DoAbsOrInc FeedC MoveXYZC FeedRateC PreTool 'M106'
SetFlagF('7') {don't preselect tool until after next toolchange}
ELSE
SeqC DoAbsOrInc FeedC MoveXYZC FeedRateC
END
EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
IF {1/18/96} Flag?('7')
SeqC FormatArc ArcFeedC PreTool 'M106'
SetFlagF('7') {don't preselect tool until after next toolchange}
ELSE
SeqC FormatArc ArcFeedC
END
EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
IF {1/18/96} Flag?('7')
SeqC FormatArc ArcFeedC PreTool 'M106'
ELSE
SeqC FormatArc ArcFeedC
SetFlagF('7') {don't preselect tool until after next toolchange}
END
EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
ELSE
'G' NewWFO#
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
IF MultipleParts? AND OneToolAllParts?
'G' NewWFO#
ELSE
IF FirstOperation?
'G' NewWFO#
END
END
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
IF Repeats? AND FeedConnect? AND ZshiftOnly?
SeqC AbsOrInc EOL
ELSE
IF FIFO?
SeqC AbsOrInc FeedC ZCP2 FeedRateC EOL
ELSE
SeqC AbsOrInc RapidC ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed IncValue StrtPosC EOL
SeqC AbsOrInc
ELSE
SeqC Feed
END
ELSE
SeqC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqC AbsOrInc ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqC Rapid ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC 'M98P1' Program# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect?
IF FIFO?
SeqC Feed ZCP2 FeedRate EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL
END
END
SeqC 'M98P1' Program# EOL
IF Flag?('7')
SeqC PreTool 'M106' EOL {pretool in main program after first sub call per Troy}
SetFlagF('7') {don't preselect tool until after next toolchange}
END
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50')
SetMaxRPM('10000')
SetMaxFeed('500')

SetFlagF('1') { Milling ZShiftOnly SepSubs }

IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?

SetFlagF('6') {have we output first no move drill point feat?}
SetFlag('7') {need preselect tool output?}

EOR EOL
ProgID1 EOL
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( START WITH ' OpToolID ' IN SPINDLE )' EOL
END
END
OpenSub
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
SeqC 'G91G28Z0.' EOL
Seq OpToolID ToolChng EOL
DoOpComments
DoPostScript
SeqC CkSpeed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC WFO1 EOL
OpenMP
END
CheckPass
SeqC AbsOrInc WFOStuff Plane Rapid StrtPos EOL
SeqC OfstOn EOL
SeqC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF NewTool?
{Finish off last Operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL

IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC IncValue OfstOff EOL
CloseMP
SeqC SpinOff EOL
SeqC '/G28Y0.' EOL
ELSE
SeqC IncValue OfstOff SpinOff EOL
SeqC '/G28Y0.' EOL
END

DoEndOpPS
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
IF ToolChangeAtHome?
SeqC AbsOrInc Rapid Home EOL
END

{Start new Operation}
SetFlagF('6') {have we output first no move drill point feat?}
SetFlag('7') {need preselect tool output?}

Seq {OpToolID} ToolChng EOL
DoOpComments
DoPostScript
SeqC CkSpeed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC WFO1 EOL
OpenMP
END
CheckPass
SeqC AbsOrInc WFOStuff PlaneC Rapid StrtPos EOL
SeqC OfstOn EOL
SeqC CoolOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC IncValue OfstOff EOL
SeqC SpinOff EOL
SeqC '/G28Y0.' EOL
SeqC 'M0' EOL

{Start new Operation}

GetStartOfSameTool
IF RigidTap? OR Tap?
SeqC 'S2500'
ELSE
SeqC Speed
END
SpinOn EOL
SeqC AbsOrInc WFOStuff PlaneC Rapid StrtPos EOL
SeqC OfstOn EOL
SeqC CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC IncValue OfstOff EOL
{Start new Operation}

GetStartOfSameTool
SeqC AbsOrInc WFOStuff PlaneC Rapid StrtPos CkSpeed EOL
SeqC OfstOn EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqC AbsOrInc WFOStuff PlaneC Rapid StrtPos CkSpeed EOL
EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}

IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO?
SeqC FeedC CRCOffC ZCP3C FeedRateC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC DrillCP EOL
GetCycle
IF RigidTap? OR Tap?
SeqC 'M54' Speed EOL {'M54' with speed per Troy}
END
SeqC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
IF CallMasterOp?
IF Flag?('7')
SeqC PreTool 'M106' EOL {If using MasterOp: pretool in main program not subprogram}
SetFlagF('7') {don't preselect tool until after next toolchange}
END
SeqC SubCall 'P' CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
IF Flag?('7')
SeqC PreTool 'M106' EOL {If using MasterOp: pretool in main program not subprogram}
SetFlagF('7') {don't preselect tool until after next toolchange}
END
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC SubCall CallLab EOL
StartSub
ToolPath
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqC Rapid 'G80' ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqC CoolOff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC IncValue OfstOff EOL
CloseMP
SeqC SpinOff EOL
SeqC '/G28Y0.' EOL
ELSE
SeqC IncValue OfstOff SpinOff EOL
SeqC '/G28Y0.' EOL
END

DoEndOpPS

IF ProgStop?
SeqC 'M0' EOL
ELSE
SeqC 'M1' EOL
END

SeqC UnTool ToolChng EOL

IF MultipleParts? AND AllToolsOnePart?
CloseMP
END

IF FIRST ToolChangeAtHome?
SeqC AbsOrInc Rapid FirstHome EOL
ELSE
SeqC 'G28Y0' EOL
SeqC 'G90' EOL
END

SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END