{Change Comments ***********************************************************}

{11/14/91
Modified: Fanuc 10T MS [-] L001.82
For: Gibbs & Associates
Added RestoreScale Sub per 4-Axis Post Processor.
Added Logic to suppress Feed and FeedRate for Approaches.
Modified output of Speed & ConstantSurfaceFeed for SameTool in CheckOffset sub.
Changed SetAbs to SetAbsOrInc at setup and initializations.
Added bypass of AutoFinish for Non-Canned RoughSimple Operations.
Modified AutoFinish Approach.
DWB}

{4/4/95
Initial: Fanuc 10T MS [-] L001.82ż
ForUser: Envirotech Pump
Control: Fagor 8030 TG
Machine: Mazak
Version: ComPost 4.21.26, ncCAD 4.33, ncCAM 4.33, ncPost 4.33.04
Created new Postprocessor per sample and manual.
Jim Radcliffe}

{
Format: Fagor 8025 TG Lxxx.81.2
5/9/95
Added spaces between all commands
TH}

{
Format: Fagor 8025 TG L342.81.3
5/17/95
Added T00.00 to start and end of prog
Removed CSS stuff from start of prog
Removed preset stuff from start of prog and NewTool?
Removed all coolant commands
TH}

{
Format: Fagor 8025 TG L342.81.4
5/22/95
Changed to NegSideLathe
TH}

{
Format: Fagor 8025 TG L342.81.5
5/31/95
Added ReverseXZArcs to prog start
TH}

{
Format: Fagor 8025 TG L342.81.6
6/15/95
For: Litton
Fixed CSS code in FirstOp
Put coolant commands back in
TH}

{9/7/95, Updated Fagor 8025 TG L342.81.6 to .85 format per Fanuc 10T MS [-] L001.85.01.01, JR}

{14/May/97
Original: Fagor 8025 TG L342.85
Created: Fagor 8025 TG L342.85.1
For: Astro Machine
Changes made per: Al Boothe
Corrected CheckOffset: to prevent redundant output of Speed
Charles Winston}

{24Jul98
Original: Fagor 8025 TG L342.85.1
Created: Fagor 8025 GT [PHT] Lxxx.85
Control: GT Upgrade Technologies
For: Precision Hermetic
Changes made per: Phil Laplante
Changed to PosSideLathe
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
Added Formating for ADD#, SUB#, DIV#, CycleStartZ#, ThreadXInc#, LastCutXRadius#, Recall#, RunOutZ#,2
Moved CoolOn from AppMove to to FirstOperation and NewTool
Deleted LOfstOff in CheckOffset, FirstOperation and NewTool
Added AbsOrInc ' G95 G97 S1000' to FirstOperation and NewTool
Deleted FeedRate CSSOff and replaced with CSSOn Boolean in FirstOperation and NewTool
Deleted CSS Boolean at the Common Point
Added G86 Thread Cycle with Paramaters P1 thru P12
Charles Winston}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0'
#3 = '#######0'
#4 = '##.##;0'
#5 = '#.######;0'
#6 = '###0'
#7 = '#'
#8 = '00000'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(InFeedAngle#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(ADD#,2)
FORMAT(SUB#,2)
FORMAT(DIV#,2)
FORMAT(CycleStartZ#,2)
FORMAT(ThreadXInc#,2)
FORMAT(LastCutXRadius#,2)
FORMAT(Recall#,2)
FORMAT(RunOutZ#,2)
FORMAT(Operation#,3)
FORMAT(Tool#,3)
FORMAT(Dwell#,4)
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
FORMAT(Program#,8)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLabC ' ( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
SeqLabC ' ( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
SeqLabC ' ( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
SeqLabC ' ( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
SeqLabC ' ( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC ' M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC OpToolID '.' LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC Speed
END
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn ' G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff ' G97' Speed
END
END
IF LAST ProgStop?
SeqLabC SpeedC SpinOn EOL
SeqLabC CoolOn EOL
ELSE
EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJ
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC ' G04K2.' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC ' G04K' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC ' G33' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
ReverseXZArcs
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR Program# EOL
IF UseComments?
IF ProgramNameComment?
SeqLabC ' ( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
SeqLabC ' ( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
SeqLabC ' ( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
SeqLabC ' ( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
SeqLabC ' ( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff
SetHome
DoOpComments
DoPostScript
Plane
SeqLab AbsOrInc ' G95 G97 S1000' OpToolID '.' LatheOffset SpinOn EOL
SeqLabC Rapid Home CoolOn EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn ' G96'
ELSE
SeqLabC CSSOff ' G97'
END
Speed EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff ' G97' CalcRPM2 EOL
END
SeqLabC NewHome EOL
IF LAST ProgStop?
SeqLabC ' M00' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
SeqLab AbsOrInc ' G95 G97 S1000' OpToolID '.' LatheOffset SpinOn EOL
SeqLabC Rapid Home CoolOn EOL
SeqLabC Preset MaxRPM EOL
IF ConstantSurfaceFeed?
SeqLabC CSSOn ' G96'
ELSE
SeqLabC CSSOff ' G97'
END
Speed EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
' Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle ' PÅ‚' Tag# ' Q²' Tag# XStkLeft ZStkLeft CutDepth FeedRate EOL
'>' Tag# EOL
SeqLab StepMove StrtPos EOL
ELSE
IF RoughPatternShift?
SeqLabC LCycle ' PÅ‚' Tag# ' Q²' Tag# XStkLeft ZStkLeft XminusU ZminusW NumCuts FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
END
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC ' G70' ' PÅ‚' Tag# ' Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
IF ApproachOD? {OD Threads}

{Major Dia @ Thread Start}
Save# Num#('1') ADD# FinishXDia# MUL# ThreadXInc# Num#('2')
{Major Dia @ Thread End}
Save# Num#('2') ADD# Recall# Num#('1') MUL# Taper# Num#('2')

SeqLabC LCycle
' P0=K' Recall# Num#('1')
' P1=K' CycleStartZ#
' P2=K' Recall# Num#('2')
' P3=K' FinishZ#
' P4=K' ThreadXInc#
' P5=K' CutDepth#
' P6=K' DIV# SUB# XOpCD# Recall# Num#('1') Num#('-2')
' P7=K' LastCutXRadius#
' P10=K' DIV# Num#('1') Thread#
' P11=K' RunOutZ#
' P12=K60' EOL

ELSE {ID Threads}

{Major Dia @ Thread End}
Save# Num#('1') SUB# FinishXDia# MUL# ThreadXInc# Num#('2')
{Major Dia @ Thread Start}
Save# Num#('2') SUB# Recall# Num#('1') MUL# Taper# Num#('2')

SeqLabC LCycle
' P0=K' Recall# Num#('2')
' P1=K' CycleStartZ#
' P2=K' Recall# Num#('1')
' P3=K' FinishZ#
' P4=K-' ThreadXInc#
' P5=K' CutDepth#
' P6=K' DIV# SUB# XOpCD# Recall# Num#('1') Num#('2')
' P7=K' LastCutXRadius#
' P10=K' DIV# Num#('1') Thread#
' P11=K' RunOutZ#
' P12=K60' EOL
END
IF AutoFinish?
SeqLabC ' G92' XatFinZ FinZ XTapAtZ ThrdLead EOL
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth ' E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC ' G04K2.' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF PeckChipBreaker?
SeqLabC LCycle ZDepth RLevel Dwell Peck Retract FeedRate EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC ' G04K' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
ELSE
IF Grooving?
StockOn
SetPass1
SeqLabC StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G32'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC ' G04K2.' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
SeqLabC CoolOff EOL
IF ConstantSurfaceFeed?
SeqLabC CSSOff ' G97S' CalcEPRPM# EOL
END
SeqLabC FirstHome ' T00.00' SpinOff EOL
IF ProgStop?
SeqLabC ' M00' EOL
END
SeqLabC EOP EOL
Post
IF UseComments?
SetScale('1') {restore scale for comments}
IF FileBytesComment?
SeqLabC ' ( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
SeqLabC ' ( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
SeqLabC ' ( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
ASCII('27') EOL
Close
Retag