{Change Comments ***********************************************************}

{12/5/89
Copied & modified: Dynapath 10M (SM) M262.62
For: General Dynamics
Deleted literal 'G' 3 places in ToolPath.
JR}

{12/18/89
Modified: Dynapath 10M [GD] M277.61
For: General Dynamics
Delete Coolant & GearRange commands.
Control requires ASCII('36') at end of every conversational block.
Added ASCII('36') Line Terminator Code in Mach Spec ('$'), but Retag command causes '$$',
which is not acceptable.
Added '$' to every block of output in Prog.
Modified for 'FIRST TOOL NOT IN SPINDLE' FORMAT.
Move ToolTypeComment to be last Comment of DoOpComments.
Added ToolChng after DoOpComments in FirstOperation and NewTool.
Moved SpinOn OpToolID Speed to line following ToolChng.
Added WorkFixtureOffsets, E1 to E9, in Mach Spec.
Modified MiltipleParts to use WorkFixtureOffsets.
JR}

{6/5/90, Updated: Dynapath 10M [GD] M277.62 to .72.1 format, JR}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}

{4/16/91
Copied & modified: Dynapath 10M [GD] M277.73
For: Gibbs & Associates
Machine:
Control: Dynapath 10M
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
Made major modifications per conversation with Dale Bachman at Dynapath Systems, Inc.
This processor is totally conversational.
Added Flag('1') to check if CRCOn (C1) has been output.
CutterRadiusCompensation rules:
CRCOn (C1) must only be activated when Feed (1) or CWArc/CCWArc (2) are active.
Control requires CRCOff (C0) DummyMove on line preceeding CRCOn (C1).
Added logic to output SPX# SPY# CRCOff (C0) in TurnOnCRC Sub.
Rapid (0) must NOT be output while CRCOn (C1) is active.
When RapidFeat, CutterRadiusCompensation and Flag('1') are TRUE:
Added logic to output FeedC (1) MoveXYZC RapidFC (F199.1) in ToolPath.
RapidFC set to output F199.1 in Mach Spec.
Control requires CRCOff (C0) DummyMove when cancelling CRCOn (C1).
Added logic to output MoveXY CRCOff (C0) in TurnOffCRC Sub.
DWB}

{2/14/94
Copied & modified: From Dynapath 10M [GD] M277.80 to Dynapath 10M [SM] M632.80.1
Removed M6 tool changes and replaced with the following three lines of code:
N-(9)M5T00$, N-(0)Z0G0$, N-(9)M00$.
Removed most of the comment lines. (Customer using Virtual Gibbs and cannot control
except to turn all on or all off).
Extended WFO's from E9 to E14.
All the above at customer request.
KC}

{3/14/96,
Initial: Dynapath 10M [SM] M632.80.1
Created: Dynapath 10M [SM] M632.80.2
Added support for Coolant, returns to WFO 'E0' before tool changes and at program end,
Added tool List, MPK}

{3/27/96
Initial: Dynapath 10M [SM] M632.80.2
Created: Dynapath 10M [SM] M632.89
ForUser: Sanders Machine
Control: Dynapath 20M ( just had it updated with a new board )
Machine: Lagun
Develop: ComPost 4.21.34, Catalyst68K v3.02.07C
Comment: Modifications per customer requests
Moved CoolOn to line by itself. Can only have 1 M code per line!
Modified end of tool sequence.
Changed 'E0' to WFOOff, output is the same!
Updated to .85 format per Dynapath 10M [GD] M277.85.1
Updated to .89 format per Fanuc 6M M001.86 & Dynapath 50M [MT] M963.89
Added missing Rapid/RapidC and Feed/FeedC commands per Fanuc 6M M001.86
Mainly to keep the status register updated.
Feed has no output!
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '###.#;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(SPX#,4)
FORMAT(SPY#,4)
FORMAT(StartPosX#,4)
FORMAT(StartPosY#,4)
FORMAT(Retract#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Recall#,5)
FORMAT(Tag#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(RapidF#,6)
FORMAT(Dwell#,6) {.72}

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

Get$:
IF NOT EmptyLine?
'$'
END
RETURN

TurnCRCOn:
IF CutterRadiusCompensation? AND NOT Flag?('2')
IF NOT LastFeat? AND NOT ZMove?
SetFlag('2')
SeqLab '(1)'
IF AutoCycle?
MoveSX '/' MoveSY '/'
ELSE
MoveSX MoveSY
END
CRCOff Get$ EOL
END
END
RETURN

TurnCRCOff:
IF CutterRadiusCompensation? AND Flag?('2')
SetFlagF('2')
SeqLab '(1)'
IF AutoCycle?
MoveX '/' MoveY '/'
ELSE
MoveXY
END
CRCOff Get$ EOL
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
SeqLab '(T) SUB NUMBER ' Tag# ' ' Get$ EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLab '(T) OPERATION ' Operation# ' ' OperationType$ Get$ EOL
END
IF OperationComment?
SeqLab '(T) ' OperationComment$ Get$ EOL
END
IF WorkGroupComment?
SeqLab '(T) ' WorkGroupComment$ Get$ EOL
END
IF ToolTypeComment?
SeqLab '(T) TOOL# ' Tool# ' ' ToolDiameter# ' ' ToolType$ Get$ EOL
END
IF ToolComment?
SeqLab '(T) ' ToolComment$ Get$ EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLab '(0)' 'A' FourthDegree# Get$ EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLab '(0)' 'A' FourthDegree# Get$ EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLab '(0)' 'B' FifthDegree# Get$ EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLab '(0)' 'B' FifthDegree# Get$ EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLab PostScript Get$ EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS Get$ EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoZIn:
ZIn
IF AutoCycle? { Implies Incremental }
'/'
END
RETURN

EntryMove:
IF FeedEntry?
SeqLab '(1)' DoZIn FeedEnt Feed Get$ EOL
ELSE
SeqLab '(0)' DoZIn RapidC Get$ EOL
END
RETURN

StartSub:
OpenSub
DoSubComment
'>' Tag# EOL
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
SeqLab '(T) ' Get$ EOL
SeqLab '(T) *** WARNING ***' Get$ EOL
SeqLab '(T) Z CLEARANCE WILL' Get$ EOL
SeqLab '(T) CHANGE WITH EACH' Get$ EOL
SeqLab '(T) CYCLE OF SUB!' Get$ EOL
SeqLab '(T) ' Get$ EOL
END
END
RETURN

StdSub:
'È' Tag# EOL
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
SeqLab '(6)FÇ' Tag# 'T' RepsLess1 Get$ EOL
StartSub
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
SeqLab
IF AutoCycle?
'(0)' ZCP3
ELSE
IF FIFO? {.81}
'(1)' ZCP3 FeedC FeedEntC
ELSE
'(0)' ZCP3 RapidC
END
END
Get$ EOL
END
RETURN

FinishSubG92: {part 2}
SeqLab '(0)' ShiftRC Preset Get$ EOL
'<' Tag# EOL
TagDown
CloseSub
SeqLab '(0)' UnshftRC Preset Get$ EOL
RETURN

OpenMP:
TagUp TagInc
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqLab '(9)' SetWFO Get$ EOL
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
IncWFO
NextWFO
ELSE
'È' Tag# EOL
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
SeqLab '(6)FÇ' Tag# 'T' PartsLess1 Get$ EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
'<' Tag# EOL
TagDown
CloseSub
SeqLab '(9)' WFO1 Get$ EOL
ELSE
SeqLab '(0)' ShiftPC Preset Get$ EOL
'<' Tag# EOL
TagDown
CloseSub
SeqLab '(0)' UnshftPC Preset Get$ EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') { AbsoluteMoves? = TRUE }
IF ZMove? AND AbsValue?
SetInc
ELSE
IF NOT ZMove? AND NOT AbsValue?
SetAbs
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') { AbsoluteMoves? = TRUE }
IF SPZMove? AND AbsValue?
SetInc
ELSE
IF NOT SPZMove? AND NOT AbsValue?
SetAbs
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND NOT AbsValue? { AbsoluteMoves? = TRUE }
SetAbs
END
RETURN

GetPlane:
IF XYPlane?
IF NOT AutoCycle?
IF FirstFeat?
IF XMove? OR YMove?
'P0' { This is the default Plane select }
END
END
END
ELSE
IF XZPlane?
'P2'
ELSE {YZPlane}
'P1'
END
END
RETURN

CheckMove:
IF Drilling?
IF Flag?('1') AND NOT AbsValue? { AbsoluteMoves? = TRUE }
IF XMove?
MoveSX '/'
END
IF YMove?
MoveSY '/'
END
IF ZMove?
MoveSZ '/' {.80.01}
END
ELSE
MoveSXYZC {.80.01}
END
ELSE
IF AutoCycle? { Implies Incremental }
IF XMove?
MoveX '/'
END
IF YMove?
MoveY '/'
END
IF ZMove?
MoveZ '/'
END
ELSE
IF Flag?('1') AND NOT AbsValue? { AbsoluteMoves? = TRUE }
IF XMove?
MoveX '/'
END
IF YMove?
MoveY '/'
END
IF ZMove?
MoveZ '/'
END
ELSE
MoveXYZC
END
END
END
RETURN

FormatArc:
DoAbsOrInc GetPlane CheckMove
IF AutoCycle?
ArcI '/' ArcJ '/'
ELSE
IF Flag?('1') AND NOT AbsValue? { AbsoluteMoves? = TRUE }
ArcI '/' ArcJ '/'
ELSE
ArcIJ
END
END
IF ArcCW?
CWArc
ELSE
CCWArc
END
RETURN

ckCRC:
IF CutterRadiusCompensation? AND Flag?('2')
IF NOT LastFeat? AND NOT ZMove?
CRCOnC
END
END
RETURN

FormatLine:
DoAbsOrInc GetPlane CheckMove ckCRC
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
IF NOT FirstFeat?
SeqLab '(0)' MoveSXYC Get$ EOL
END
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF NOT FirstFeat?
SeqLab '(0)' DoDrillAbsOrInc CheckMove Get$ EOL
END
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
TurnCRCOn
IF CutterRadiusCompensation? AND Flag?('2')
SeqLab '(1)' FormatLine FeedC RapidFC Get$ EOL
ELSE
SeqLab '(0)' FormatLine RapidC Get$ EOL
END
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
TurnCRCOn
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab '(1)' FormatLine FeedC FeedRateC Get$ EOL
DecelMove2
END
SeqLab '(1)' FormatLine FeedC DecelFeed Get$ EOL
ELSE
SeqLab '(1)' FormatLine FeedC FeedRateC Get$ EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab '(2)' FormatArc ArcFeedC Get$ EOL
DecelMove2
END
SeqLab '(2)' FormatArc DecelFeed Get$ EOL
ELSE
SeqLab '(2)' FormatArc ArcFeedC Get$ EOL
END
NEXTQuadrant
END
END
END
IF LastFeat?
TurnCRCOff
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
SeqLab '(T) ' Get$ EOL
SeqLab '(T) *** WARNING ***' Get$ EOL
SeqLab '(T) DO NOT USE' Get$ EOL
SeqLab '(T) NEWWFO() WITH' Get$ EOL
SeqLab '(T) NCPOST MULTIPLE' Get$ EOL
SeqLab '(T) PARTS!' Get$ EOL
SeqLab '(T) ' Get$ EOL
ELSE
SeqLab '(9)E' NewWFO# Get$ EOL
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
SeqLab '(9)E' NewWFO# Get$ EOL
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SetInc
SeqLab '(1)' 'P0X0./Y0./' Get$ EOL { AutoCycle dummy move to select correct Plane }
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SetAbs
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO? {.81}
SeqLab '(1)' ZCP2 FeedC FeedEntC Get$ EOL
ELSE
SeqLab '(0)' ZCP2 RapidC Get$ EOL
END
END
'<' Tag# EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after TagInc for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagUp TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
TagDown
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SetAbs
IF FeedConnect?
SeqLab '(1)' StrtPos Feed Get$ EOL
ELSE
SeqLab '(0)' StrtPos Rapid Get$ EOL
END
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagUp TagInc
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SetInc
SeqLab '(1)' 'X' StartPosX# '/' 'Y' StartPosY# '/' Get$ EOL
SetAbs
SeqLab
ELSE
SeqLab '(1)'
END
ELSE
SeqLab '(1)'
END
ZInPlusInc Feed FeedEnt Get$ EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SetInc
SeqLab '(0)' 'X' StartPosX# '/' 'Y' StartPosY# '/' Rapid Get$ EOL
SetAbs
IF FeedEntry?
SeqLab '(0)' ZCP2PlusInc Get$ EOL
SeqLab '(1)' ZInPlusInc Feed FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZInPlusInc Get$ EOL
END
ELSE
IF FeedEntry?
SeqLab '(0)' ZCP2PlusInc Rapid Get$ EOL
SeqLab '(1)' ZInPlusInc Feed FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZInPlusInc Rapid Get$ EOL
END
END
ELSE
IF FeedEntry?
SeqLab '(1)' ZInPlusInc Feed FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZInPlusInc Rapid Get$ EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqLab '(1)' ZCP2 Feed FeedEnt Get$ EOL {.69}
ELSE
SeqLab '(0)' ZCP2 Rapid Get$ EOL {.69}
END
END {.69}
TagDown
'<' Tag# EOL
CloseSub
{Element shift, not pattern}
TagDown
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLab
IF FeedConnect?
'(1)'
ELSE
'(0)'
END
StrtPos Get$ EOL
END
IF FeedConnect?
SeqLab '(1)' ZInPlusInc Feed FeedEnt Get$ EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLab '(0)' ZCP2PlusInc RapidC Get$ EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLab '(1)' ZInPlusInc Feed FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZInPlusInc RapidC Get$ EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
'<' Tag# EOL
TagDown
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
TagInit
SetAbs
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { CutterRadiusCompensation }
IF PSComment? AND UseComments?
SeqLab '(T) PostScript:' Get$ EOL
SeqLab '(T) Literals: put between single or double quotes.' Get$ EOL
SeqLab '(T) Separate commands and literals with at least one space.' Get$ EOL
SeqLab '(T) A CR ( RETURN key ) will start a new line.' Get$ EOL
SeqLab '(T) Commands: may be capital and/or lower case letters. Separate commands with a space.' Get$ EOL
SeqLab '(T) EndOP -' Get$ EOL
SeqLab '(T) all literals and commands before an ENDOP command' Get$ EOL
SeqLab '(T) will appear at the beginning of the operation. All' Get$ EOL
SeqLab '(T) literals and commands after an ENDOP command will appear' Get$ EOL
SeqLab '(T) at the end of the operation.' Get$ EOL
SeqLab '(T) NewWFO(56), NWFO(56) -' Get$ EOL
SeqLab '(T) The Work Fixture Offset # you specify will be used for all following operations.' Get$ EOL
SeqLab '(T) Do not use with the ncPost multiple part option.' Get$ EOL
SeqLab '(T) 4thAxisCW(12.5), 4ACW(12.5) -' Get$ EOL
SeqLab '(T) generates a + A move of the value you specify' Get$ EOL
SeqLab '(T) 4thAxisCCW(22.5), 4ACCW(22.5) -' Get$ EOL
SeqLab '(T) generates a - A move of the value you specify' Get$ EOL
SeqLab '(T) 5thAxisCW(30), 5ACW(30) -' Get$ EOL
SeqLab '(T) generates a + B move of the value you specify' Get$ EOL
SeqLab '(T) 5thAxisCCW(22.5), 5ACCW(22.5) -' Get$ EOL
SeqLab '(T) generates a - B move of the value you specify' Get$ EOL
END
EachOp {Start of post processing *********************}
Plane { no output }
IF FirstOperation?
'(' Program# ')' EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
SeqLab '(T) PROGRAM ' ProgramName$ Get$ EOL
END
IF ProgramComment?
SeqLab '(T) ' ProgramComment$ Get$ EOL
END
IF FormatNameComment?
SeqLab '(T) FORMAT ' FormatName$ Get$ EOL
END
IF TimeComment?
SeqLab '(T) ' Date$ ' AT ' Time$ Get$ EOL
END
IF MovesComment?
SeqLab '(T) OUTPUT IN ABSOLUTE INCHES' Get$ EOL
END
IF PartsComment?
SeqLab '(T) PARTS PROGRAMMED ' Parts# Get$ EOL
END
IF StartToolComment?
SeqLab '(T) FIRST TOOL NOT IN SPINDLE' Get$ EOL
END
EachTool {tool loop to give a list of tools in program header}
SeqLab '(T) TOOL ' TLNum# ': ' TLToolComment$ ' ' Get$ EOL
NextTool
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
DoPostScript
WFOStuff
SeqLab '(9)' SpinOn ToolOfst Speed Get$ EOL
IF NOT CoolOff?
SeqLab '(9)' CoolOn Get$ EOL
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab '(0)' StrtPos ZCP1 Rapid Get$ EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab '(0)' StrtPos Rapid Get$ EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqLab '(9)' SpinOff 'T00' Get$ EOL
SeqLab '(0)' 'Z0' Rapid Get$ EOL
SeqLab '(9)' WFOOff Get$ EOL
SeqLab '(9)' CoolOff Get$ EOL
IF ToolChangeAtHome?
SeqLab '(0)' FirstHome Get$ EOL
END
IF OptionalStops?
SeqLab '(9)' ProgStop Get$ EOL
END
SeqLab '(9)' 'M0' Get$ EOL

{Start new Operation}

DoOpComments
DoPostScript
WFOStuff
SeqLab '(9)' SpinOn ToolOfst Speed Get$ EOL
IF NOT CoolOff?
SeqLab '(9)' CoolOn Get$ EOL
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab '(0)' StrtPos ZCP1 Rapid Get$ EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab '(0)' StrtPos Rapid Get$ EOL
END
ELSE
IF SameTool?

{Finish off last Operation}

DoEndOpPS
IF LAST ProgStop? OR NewToolOffset?
SeqLab '(9)'
IF LAST ProgStop?
SpinOff
END
'T00' Get$ EOL
SeqLab '(0)' 'Z0' Rapid Get$ EOL
END
IF LAST ProgStop? OR CoolOff? AND LAST NOT CoolOff?
SeqLab '(9)' CoolOff Get$ EOL
END
IF LAST ProgStop?
SeqLab '(9)' 'M0' Get$ EOL
END

{Start new Operation}

DoOpComments
DoPostScript
WFOStuff
SeqLab '(9)'
IF LAST ProgStop?
SpinOn
END
IF LAST ProgStop? OR NewToolOffset?
ToolOfst
END
Speed Get$ EOL
IF LAST ProgStop? OR NOT CoolOff? AND LAST CoolOff?
IF NOT CoolOff?
SeqLab '(9)' CoolOn Get$ EOL
END
END
CheckPass
SeqLab '(0)' StrtPos
IF LAST ProgStop? OR NewToolOffset?
ZCP1
END
Rapid Get$ EOL
END
END
END {common point for all operations}
IF Milling?
SeqLab '(0)' ZCP2 Get$ EOL
IF Repeats?
TagUp TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
IF AutoCycle?
SeqLab '(0)' ZCP3 Get$ EOL
ELSE
IF FIFO? {.81}
SeqLab '(1)' ZCP3 Feed FeedEntC Get$ EOL
ELSE
SeqLab '(0)' ZCP3 Rapid Get$ EOL
END
END
END
ELSE
IF Drilling?
IF Repeats?
TagUp TagInc
StdSub
SetAbs
SeqLab '(0)' StrtPos Rapid Get$ EOL
END
IF RetractToCP1?
LoadFeat Num#('0') Num#('0') ClearancePlane1#
ELSE
LoadFeat Num#('0') Num#('0') ClearancePlane2#
END
IF ZMove?
SeqLab '(0)' MoveZ Get$ EOL
END
GetCycle
SeqLab '(0)' StrtPos RLevel ZDepth Dwell Peck
IF PeckChipBreaker?
'/Q' Retract#
END
FeedEnt Cycle Get$ EOL
IF CallMasterOp?
SeqLab '(7)'
'FÅ‚' CallMasterNum#
'L²' CallMasterNum# Get$ EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
SetFlag('4') { SubPrograms require 2nd M30 at end }
TagUp
NewMasterTag
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
StartSub
ToolPath
'<' Tag# EOL
TagDown
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqLab '(0)' ZCP3 Rapid Get$ EOL
IF Repeats?
FinishSubG92
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqLab '(9)' SpinOff 'T00' Get$ EOL
SeqLab '(0)' 'Z0' Rapid Get$ EOL
SeqLab '(9)' WFOOff Get$ EOL
SeqLab '(9)' CoolOff Get$ EOL
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqLab '(0)' FirstHome Get$ EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLab '(9)' EOP Get$ EOL
CloseSub
Post2 {organize Subs into one program}
'END' EOL
Close
ReTag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'N9997(T) FILE LENGTH: ' FileBytes# ' CHARACTERS' Get$ EOL
END
IF FileFeetComment?
'N9998(T) FILE LENGTH: ' FileFeet# ' FEET' Get$ EOL
END
IF FileMetersComment?
'N9999(T) FILE LENGTH: ' FileMeters# ' METERS' Get$ EOL
END
Close
END