{Change Comments ***********************************************************}

{7/18/90
Copied & modified: Fanuc 10T MS [+] L004.69.7
For: Viratec
Machine: Mori Seiki TL40
Control: Fanuc 15TF
Deleted 'Preset Home' at FirstOperation and NewTool.
Moved OpToolID LatheOffset from Approach sub to FirstOperation and NewTool.
Added GearRange.
Cancel Tool Offset on line by itself after move to index position.
JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{9/25/90, Updated to Version 3.2 per Fanuc 10T MS [-] L001.71.1 Format, DWB}
{10/2/90, Added StockOff globally at FirstOperation, DWB}
{10/8/90, Replace CalcRPM2 globally with CalcEPRPM# at end of prog, DWB}

{3/28/91
Modified: Fanuc 15T MS (+) L166.71.3
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format.
All normal Fanuc Canned Cycles are supported.
DWB}

{8/5/91
Updated: Fanuc 15T MS (+) L166.80
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.82 Format.
KM}

{11/1/94
Updated: Fanuc 15T MS (+) L166.82
For: Gibbs & Associates/Premier Mfg/SimFlo Pumps Inc.
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.03/Compost 4.21.22
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82.1a Format.
DWB}

{11/1/94
Copied: Fanuc 15T MS (+) L166.82.1
Created: Fanuc 16T MS (+) L314.82.1
For: Premier Manufacturing/SimFlo Pumps Inc.
Machine:
Control:
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.03/Compost 4.21.23
Changes made per Glenn Johnson of Simflo, manual and sample printouts.
Modified Canned Cycles per manual.
DWB}

{1/9/95
Modified: Fanuc 16T MS (+) L314.82.1
Renamed: Fanuc 16T MS [+] L314.82.2
For: Premier Manufacturing/SimFlo Pumps Inc.
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.04/Compost 4.21.23
Versions: Catalyst v2.14.24C/Catalyst v2.14.24PPC/Compost 4.21.23
Changes made per Glenn Johnson of Simflo, cam and text files, and marked up printouts.
Added conditional move after returning from ToolPath, to SetPass1 XSPC for ApproachOD at
CannedCycle RoughContour.
Commented out File Length Comments at end of prog.
Customer reported problem with Communications software hanging up because control had read EOR at
end of output, and stopped reading, while sending software was still waiting to send the comments.
Deleted CheckGear sub and changed call to CheckGear to SpinOn at CheckOffset sub.
Deleted SpinOff and condition to output same when NewGear? = TRUE at CheckOffset sub and NewTool.
DWB}

{
Format: Fanuc 21T Mon [+] Lxxx.82.3
5/9/95
Replaced threading code with code from 15T (Existing code didn't work in VG)
Added bar feed code to start of output
Added support for a CutOff?
Move start up code around to match sample files
TH}

{
Format: Fanuc 21T Mon [+] L339.82.4
5/17/95
Set default format for T label to 00
TH}

{7/14/95
Initial: Fanuc 21T Mon [+] L339.82.4
Created: Fanuc 21T L367.82.2
ForUser: CIM Solutions / Alco Turning
Comment: Modifications per marked up readout and conversation with Mark Barrett at Alco
Looking for CutOff in any operation thru EachOp/NextOp loop at beginning of prog.
Setting Flag?('1') to true, to designate a BarFeed Program.
Suppressed output of Bar Feed routine at beginning of program if not a BarFeed program.
Deleted M38 from end of program, using M1 only for BarFeed program
Jim Radcliffe}

{8/24/95, renamed processor to Fanuc 21T Mon [+] L339.82.5, JR}

{6/18/96, Updated Fanuc 21T Mon [+] L339.82.5 to .85 format per Fanuc 10T MS [-] L001.85.01.01, JR}

{9/2/98
Initial: Fanuc 21T Mon [+] L339.85
Created: Fanuc 21TB MS Lxxx.85
ForUser: Yeamans Machine Shop
Control: Fanuc Series 21-TB
Machine: Mori Seiki Frontier L1
Develop: Compost2 1.6b7, Virtual Gibbs 4.29.51
Comment: New processor per marked up readout and conversation with Barbara Yeamans
Deleted 'T0' from saftey start block at beginning of program.
Changed 'G0X12.Z10.T0' at beginning of program to 'G28U0W0T0'
Added 'M42' to beginning of tools.
Added CoolOff to end of tools.
Changed tool offset cancel from T##00 to T0 and moved to home line at end of tools.
Changed Home at end of tools to 'G28U0W0.
Updated per Fanuc 10T MS [-] L001.85.01.02
Jim Radcliffe}

{01/13/99,
Initial: Fanuc 21TB MS [YMS] L770.85
Created: Fanuc MSC 500 MS [AP] L807.85
For: American Prototype

Changes to Prog:
1) Changed Bar Feed routine to a Bar Pull per customer specifications. Deleted Flag('1')
info. Replaced with OptCyc1 info so customer can control Bar Pull output through
post script.
2) FirstOp/NewTool/End of Prog - Added literals per customer request.
CDH}

{02/08/99,
Initial: Fanuc MSC 500 MS [AP] L807.85
Created: Fanuc MSC 500 MS [AP] L807.85.1
For: American Prototype

Changes to Form:
1) Lathe Drill Cycles - Added Peck Full Out drill cycle. Changed ChipBreaker values
to match Full Out values.

Changes to Prog:
1) Moved Bar Pull routine to end of prog. Modified it according to customer specs.
2) Deleted all 'M42' info.
3) DoEndOpPS - Added logic to use the TCZ postscript command. This command will be
used in the bar pull routine, to input X, Z, and W values into the post.
CDH}

{02/09/99,
Initial: Fanuc MSC 500 MS [AP] L807.85.1
Created: Fanuc MSC 500 MS [AP] L807.85.2
For: American Prototype

Changes to Prog:
1) FirstOp - Added 'M89' to Preset line if doing a bar pull (optcyc1).
2) End Of Prog - Added literal 'G4U0.4' to bar pull routine. Added literal '/M99' right
before EOP if doing bar pull.
CDH}

{02/23/99
Initial: Fanuc MSC 500 MS [AP] L807.85.2
Created: Fanuc MSC 500 MS [AP] L807.85.3
For: American Prototype

Changes to Prog:
1) Approach - Moved literal 'M73' from ToolPath to Approach sub.
CDH}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.####;0'
#6 = '###0'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(InFeedAngle#,2)
FORMAT(SPX#,2)
FORMAT(SPZ#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Peck#,2)
FORMAT(Recall#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ' - ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ' - ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
Save# Num#('21') Num#('22')
EachEOPS
SeqLabC EndOpPS EOL {literals}
IF CutOff?
IF LTEqual? Recall# Num#('21') Num#('24')
Save# Recall# Num#('21') TCZ#
Save# Num#('21') ADD# Num#('1') Recall# Num#('21')
END
END
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
IF CutOff?
SeqLabC 'M73' EOL { parts catcher advance }
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
DoOpComments
DoPostScript
IF NewToolOffset?
SeqLabC OpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
ELSE
SeqLabC Preset MaxRPM EOL
END
END
SeqLabC
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
ELSE
CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
CSSOff 'G97' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
END
END
IF LAST ProgStop?
SpinOn
END
EOL
SeqLabC
IF LAST ProgStop?
CoolOn
ELSE
IF NOT CoolOff? AND LAST CoolOff?
CoolOn
END
END
EOL
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC
IF LAST ThreadFeat?
Rapid
ELSE
RapidC
END
MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC ThrdLead EOL
END
END
END
END
END
IF LastFeat?
IF CutOff?
SeqLabC 'M74' EOL { parts catcher retract }
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
IF LAST Threading?
Rapid
ELSE
RapidC
END
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('3000')
SetMaxFeed('500')
OptCyc1F
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
'O' Program#
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT - ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
SeqLabC 'G97G99G40G0' EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM
IF OptCyc1? {Parts counter - CDH}
'M89'
END
EOL
END
SeqLabC 'G54G0X0Z0T0' EOL
SeqLab OpToolID LatheOffset EOL
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
SeqLabC
IF LAST ApproachOD?
LAST OpExitXCPC
ELSE
IF LAST ApproachID?
LAST XOpECDC
END
CoolOff EOL
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' CalcRPM2 EOL
END
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
SeqLabC 'G54G0X0Z0T0' EOL
SeqLab OpToolID LatheOffset EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn 'G96' Speed EOL
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle XatFinZ
IF ApproachFace?
'Z' FirstMoveEPZ#
ELSE
FinZ
END
IF Taper?
XTapAtZ
END
FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle CutDepth 'R.05' EOL { R = Retract }
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove 'Z' SPZ# EOL
SeqLabC FeedC 'X' SPX# EOL
ELSE
SeqLab StepMove 'X' SPX# EOL
SeqLabC FeedC 'Z' SPZ# EOL
END
ELSE
IF RoughPatternShift?
SeqLabC LCycle XminusU ZminusW NumCuts EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
END
END
ToolPath
IF ApproachOD?
SetPass1
StockOff
LoadFeat Num#('0') CycleStartX#
IF XMove?
SeqLab RapidC MoveXC EOL
END
END
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
IF Chamfer?
SeqLabC 'M23' EOL
END
SeqLabC LCycle XatFinZ FinZ XTapAtZ CutMethod ThrdHeight CutDepth ThrdLead 'A' InFeedAngle# EOL
IF AutoFinish?
SeqLabC 'G92' XatFinZ FinZ XTapAtZ ThrdLead EOL
END
IF Chamfer?
SeqLabC 'M24' EOL
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'F' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF Peck?
SeqLabC LCycle ZDepth RLevel Peck FeedRate EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
SeqLabC DrillOff Rapid ZOpECP EOL
END
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G32'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
IF Threading?
Rapid
ELSE
RapidC
END
END
SeqLabC
IF ApproachOD?
OpExitXCPC
ELSE
IF ApproachID?
XOpECDC
END
EOL
END
SeqLabC OpExitZCPC CoolOff EOL
IF ConstantSurfaceFeed?
SeqLabC CSSOff 'G97S' CalcEPRPM# EOL
END
SeqLabC SpinOff EOL
DoEndOpPS
IF CutOff? {Start Bar Pull}
IF OptCyc1?
IF UseComments?
'( BAR PULL )' EOL
END
SeqLabC 'Z' Recall# Num#('22') EOL
SeqLabC 'G98' Feed 'X' Recall# Num#('23') 'F0.0' EOL
SeqLabC 'M11' EOL
SeqLabC 'G4U0.4' EOL
SeqLabC 'G1W' Recall# Num#('24') EOL
SeqLabC 'M10' EOL
SeqLabC 'G99' Rapid OpExitXCP EOL
END
END {End Bar Pull}
SeqLabC 'G54G0X0Z0T0' EOL
IF ProgStop?
SeqLabC 'M0' EOL
END
IF OptCyc1?
SeqLabC '/M99' EOL
END
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH - ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH - ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH - ' FileMeters# ' METERS )' EOL
END
Close
END