{Change Comments ***********************************************************}

{
10/24/94 [cwh]
C001.81.4 ( from C001.81.3 )

Made changes to ZOnlyRep and FinishSub1 subs to properly handle
Feed connects and clearance moves.
}

{11/3/94
Copied: Fanuc 6M (PW) C001.81.4
Created: Fanuc 6M (PW) C001.81.4m
For: Gibbs & Associates
Versions: Catalyst v2.14.06C/Compost 4.21.23
Changes made per Pete Jackson
Created Metric Version.
DWB}

{11/8/94
Modified: Fanuc 6M (PW) C001.81.4m
For: Gibbs & Associates
Versions: Catalyst v2.14.12C/Compost 4.21.23
Changes made per Pete Jackson
Charles reported a problem involving operations that do not change coordinate systems from
previous operations.
Added ClearCSOffset at NotSameToolWFO and SameToolWFO subs.
DWB}

{
12/01/94 [TH]
C001.81.6m

Changed all CSAngleAC and CSAngleBC calls to CSAngleA and CSAngleB to output the A and B
commands at the start of every operation.
Changed FORMAT command for CSOffsetA# and CSOffsetB# to invert the values
}

{
12/02/94
Changed version number to .00 from .81
TH}

{
Format: Fanuc 6M (PW) C001.00.01m
12/08/94
Added AAxisAvail? and BAxisAvail? checks to CSAngleA and CSAngleB subs
Added return to CS1 moves to End2
Added G92 reset of A and/or B axis to End2
TH}

{
Format: Fanuc 6M (PW) C001.00.01m
12/09/94
Changed NotSameTool WFO so it would restate the current WFO if no change in CS
TH}

{
Format: Fanuc 6M (PW) C001.00.03m
12/19/94
Added ClearCSOffset to OpenMP: CloseMP: and SubCSMP:
Added if AChange? OR BChange? to home postition call-out in SameToolOp1
Started using Flag('3') to determine toggle between incrementing through MPs and decrementing through MPs
Changed CloseMP to check Flag('3'). If true, the WFOs will increment from first to last. If false, the WFOs will
decrement from last to first.
Example:
TRUE for 4 parts: G54P1, G54P2, G54P3, G54P4
FALSE for 4 parts: G54P4, G54P3, G54P2, G54P1
This is most useful for tombstone machining on rotary tables. With this method, the code will machine part1, rotate, part2,
rotate, part3, rotate, part4, tool change, part4, part3, part2, part1, toolchange, etc. It minimizes the rotation and also
stops the machine from "winding up".
To do this a new sub was created called ToggleIncDecWFO. The flag is set to true in ProgStart and toggled inside CloseMP
after running through the parts
Replaced SetZRepInc and RestoreAbsOrInc with one sub called DoAbsOrInc. Any line with SetZRepInc now
has DoAbsOrInc as the first command after the SeqC.
TH}

{
Format: Fanuc 6M (PW) C001.00.04m
1/10/95
NewToolOp3 now has an AbsOrInc on the line that calls out the Plane 'G80' CRCOff
NewToolOp5 no longer has the AbsOrInc command
NewToolOp5b has been created and has the AbsOrInc command
Changed MP1ToollAllPfu to call NewToolOp5b
Added AbsOrInc and Rapid to the FirstOperation? section of MP1ToollAllPXcp
Added Rapid to the NewTool? section of MP1ToollAllPXcp
Started using Flag ('4') to turn on Inc/Dec WFO's (See above). True means use Inc/Dec WFO's.
MP1ToollAllPXcp, MP1ToollAllPFU, and MPallTools1P now output WFO if NOT WorkFixtureOffsets?
TH}

{
Format: Fanuc 6M (PW) C001.00.05m
1/13/95
Replaced TrackZNO# ZDepth# with TrackZNO# FIRST SPZ# in the drilling section
Formatted TrackZNO# to #4
}

{ Added ClearCSOffset to SubCSMP TH}

{
Format: Fanuc 6M C001.10m
3/1/95
Replaced use of Flag('2') for inc/abs with AbsValue?
Added support for MasterOps for multiple drills ops using same hole pattern
Changed PointFeat section of ToolPath: to switch to incremental for holes with Z changes if Flag('1') is set.
TH}

{
Format: Fanuc 15MA Makino C767.10m
4/12/95
For: CAI (Nemo?)
ĄĄĄĄĄ This post cannot be used by anyone besides the original customer. It uses custom macros set up on the control.
Implemented use of custom macros for Tool changes and startup codes
Removed all of our start up codes and tool change stuff
Multiple parts will most likely not work in this processor
TH}

{
Format: Fanuc 15MA Makino C767.10.01m
5/23/95
For: CAI/NERA
Changed tool change style to Pretool
All operations are in their own subs if multiple parts
Moved G65P7010 macro to be called outside of sub programs
Hard coded all H's to 1 and D's to 2
Added ASCI('13') in between subs
ĄĄĄĄĄ This post will not work with One Tool All parts right now
TH}

{
Format: Fanuc 15MA Makino C767.10.02m
5/24/95
For: CAI/NERA
Changed all Seq to SeqC
Removed RepLabs from subs without reps
Fixed multiple parts to call out WFOs and G65P7010 correctly
CS Comments now only output if UseComments?
Added ASCI('11') in between subs
Made sure A0B0 is being output in the correct locations to handle A and B values in the fixture offsets
TH}

{
Format: Fanuc 15MA Makino C767.10.03m
6/5/95
Set Max speed/feed to 20000/30000
Added M135 Speed to a tap cycle
Changed the way sub programs work so it places consecutive ops with the same tool in a single sub
The tool comment is always output regardless of UseComments?
Changed format to sequence numbers always output 4 digits
TH}

{
Format: Fanuc 15MA Makino C767.10.04m
6/17/95
Changed default format for all moves to only output to 3 decimal places
Fixed output of WFO's greater than G54
TH}

{
Format: Fanuc 15MA Makino C767.10.05m
6/23/95
Added program comment to be output with the program number
Added 'Nxxx' where xxx is the number of the current operations tool to all tool changes
Moved tool comment to follow the 'Nxxx' at toolchanges
Added:
SeqC 'G91G30Z0' EOL
SeqC 'G28X0Y0' EOL
SeqC 'G90' EOL
to the EachCSOp/NextCSOp loops in CloseMP
Moved index so it comes before the G657010 line
TH}

{
Format: Fanuc 15MA Makino C767.10.08m
10/24/95
Reformatted CSAngleB# to output in integer format
Changed non-multiple parts case to output like a multiple parts case.
TH}

{1/17/96, Updated .10 to .11 version, MPK}

{3/25/96, Tested ZOnlyRepAutoCycle, Changed version # to .12, MPK}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '#####.###;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '####0;0.'
#8 = '*#####.##;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(ToolDiameter#,4)
FORMAT(ADD#,5)
FORMAT(SUB#,5)
FORMAT(Tool#,5)
FORMAT(CS#,5)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(CSOffsetA#,8)
FORMAT(CSOffsetB#,7)
FORMAT(TrackZNO#,4)

{Prog Subroutines ****}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is a Metric post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

OutputTheWFONum: {uses variable #1 for CS# input, output is direct}
IF GTEqual? RECALL# Num#('1') Num#('7') {G54P1 -> G54P48}
'54.1R' SUB# RECALL# Num#('1') Num#('6')
ELSE
ADD# RECALL# Num#('1') Num#('53') {std 6, G54 - G55}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
RestoreScale
END
RETURN

CSWFO:
SAVE# Num#('1') CS#
RETURN

CalcCSWFO: {(iPart-1)*NumOfCS#)}
SAVE# Num#('1') ADD# MUL# NumOfCS# SUB# PartNum# Num#('1') CS#
OutputTheWFONum
RETURN

CSAngleA:
IF AAxisAvail?
'A' CSOffsetA#
IF NOT Flag?('9')
IF FirstOperation?
IF GreaterThan? CSOffsetA# Num#('0') {Must be greater than because angles are inverted}
'M15'
END
ELSE
IF GreaterThan? CSOffsetA# LAST CSOffsetA# {Must be greater than because angles are inverted}
'M15'
END
END
END
RETURN

CSAngleAC:
IF AChange?
CSAngleA
END
RETURN

CSAngleB:
IF BAxisAvail?
'B' CSOffsetB#
IF NOT Flag?('9')
IF FirstOperation?
IF GreaterThan? CSOffsetB# Num#('0') {Must be greater than because angles are inverted}
'M15'
END
ELSE
IF GreaterThan? CSOffsetB# LAST CSOffsetB# {Must be greater than because angles are inverted}
'M15'
END
END
END
END
RETURN

CSAngleBC:
IF BChange?
CSAngleB
END
RETURN

DoCSWFOComment:
IF UseComments?
'( CS#' CS# ' - ' CSComment$ ' )' EOL
SetFlag('9')
'( G' CalcCSWFO '= X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ# ' )' EOL
SetFlagF('9')
END
RETURN

DoPostScript:
MasterOpF
CallMasterOpF
OptCyc1F
EachPS
SeqC PostScript EOL {literals}
NextPS
RETURN

DoEndOpPS:
EachEOPS
SeqC EndOpPS EOL {literals}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
ASCII ('13') ASCII ('10')
':O' Program# EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall CallLab EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

ToggleIncDecWFO:
IF Flag?('3')
SetFlagF('3')
ELSE
SetFlag('3')
END
RETURN

OpenMP:
IF WFOCS?
NewProg
StartSub
SaveCSProg
SaveCSOpStart
ClearCSOffset
ELSE
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO {simple eachPart}
SeqC SetWFO EOL
SeqC SubCall CallLab EOL
IncWFO
NextWFO {simple NextPart}
ELSE
SeqC SubCall CallLab RepLab Parts EOL
END
StartSub
END
RETURN

CloseMP:
IF WFOCS?
SeqC EndSub EOL
CloseSub
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
EachCSOp
DoCSWFOComment
ClearCSOffset
IF AChange? OR BChange?
SeqC 'G91G30Z0' EOL
SeqC 'G28X0Y0' EOL
SeqC 'G90' EOL
END
SeqC CSAngleA CSAngleB EOL
SeqC 'G65P7010A' CalcCSWFO StrtPos Speed 'H1' EOL
SeqC SubCall CallLabB CSSubID# EOL
NextCSOp
ClearCSOffset
IncWFO
NextWFO {simple NextPart}
ELSE
LastWFO {simple eachPart}
EachWFO
EachCSOp
DoCSWFOComment
ClearCSOffset
IF AChange? OR BChange?
SeqC 'G91G30Z0' EOL
SeqC 'G28X0Y0' EOL
SeqC 'G90' EOL
END
SeqC CSAngleA CSAngleB EOL
SeqC 'G65P7010A' CalcCSWFO StrtPos Speed 'H1' EOL
SeqC SubCall CallLabB CSSubID# EOL
NextCSOp
ClearCSOffset
DecWFO
NextPrevWFO {simple NextPart}
END
IF Flag?('4')
ToggleIncDecWFO
END
ELSE
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
SeqC WFO1 EOL
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
END
RETURN

SubCSMP:
IF WFOCS?
IF ChangeCS?
SeqC EndSub EOL
CloseSub
NewProg
StartSub
SaveCSProg
END
ClearCSOffset
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND ZMove? AND AbsoluteMoves? AND AbsValue?
IncValue
ELSE
IF Flag?('1') AND NOT AbsValue? AND NOT ZMove? AND AbsoluteMoves?
AbsValue
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND SPZMove? AND AbsoluteMoves? AND AbsValue?
IncValue
ELSE
IF Flag?('1') AND NOT AbsValue? AND NOT SPZMove? AND AbsoluteMoves?
AbsValue
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1')
IF AbsValue? AND AbsoluteMoves?
ELSE
IF AbsValue?
SeqC IncValue EOL
ELSE
IF AbsoluteMoves?
SeqC AbsValue EOL
END
END
END
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

DoCRCOffSetC:
IF Flag?('5')
SetFlagF('5')
'D2'
END
RETURN

StdLine: {enables CRC on first call}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC DoCRCOffSetC EOL
DecelMove2
END
SeqC DoAbsOrInc CRCOnC FeedC MoveXYZC DecelFeed DoCRCOffSetC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC DoCRCOffSetC EOL
END
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle?
SeqC DoAbsOrInc CRCOffC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle?
IF LastFeat?
SeqC DoAbsOrInc CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{removed RapidC}
{removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed IncValue StrtPosC EOL
SeqC AbsOrInc
ELSE
SeqC Feed
END
ELSE
SeqC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqC AbsOrInc ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqC Rapid ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLab EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
SetFlag('1') {std sep sub Zreps are in effect} {rep change 2}
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL {changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL {added Rapid, reads better} {changed to RapidC, reads better}
END
END
SeqC SubCall CallLab EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 2}
SetFlag('3') {True = incrementing WFO numbers for MP. False = decrementing WFO numebrs for MP}
SetFlagF('4') {True = toggle between incrementing/decrementing WFO's }
SetFlagF('5') {False = CRC Off so no D. Reset in OpGuts}
UseSeparateSubCalls
SetMaxSeparateSubCalls('5000')
SetMaxRPM('20000')
SetMaxFeed('30000')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END

IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('58')
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of parts [ ' Parts# ' ] times CSs [ ' NumOfCS# ' ] )' EOL
'( exceeds the machine limit. Switching to non-WFO output. )' EOL
END
END
END
ELSE
IF LTEqual? NumOfCS# Num#('58') {****}
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of CSs [ ' NumOfCS# ' ] exceeds the machine limit. )' EOL
'( Switching to non-WFO output. )' EOL
END
END
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF CutterRadiusCompensation?
SetFlag('5') {Turn on D values}
END
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
ZonlyRep {rep change 1}
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO?
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC AbsOrInc Rapid StrtPos EOL
END
SeqC 'Z' DrillCPValue EOL
GetCycle
IF Tap?
SeqC 'M135' Speed EOL
END
SeqC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
IF CallMasterOp?
SeqC SubCall 'P' CallMasterNum# EOL
SkipToLastFeat
SetDrillEndOpZ
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
NewMasterProg
SeqC SubCall CallLab EOL
StartSub
SetFlag('1') {std sep sub Zreps in effect}
ToolPath
SetDrillEndOpZ
SeqC EndSub EOL
CloseSub
ELSE
ToolPath
SetDrillEndOpZ
END
END
SeqC Rapid 'G80' ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 3}
RETURN

NotSameToolWFO:
IF WFOCS?
IF ChangeCS?
DoCSWFOComment
ClearCSOffset
CSWFO
ELSE
ClearCSOffset { 11/8/94 }
END
ELSE
IF NeedWFO1?
END
END
RETURN

SameToolWFO:
IF WFOCS?
IF ChangeCS?
DoCSWFOComment
ClearCSOffset
CSWFO
ELSE
ClearCSOffset { 11/8/94 }
END
END
RETURN

InitOp:
EOR EOL
':O' Program#
IF ProgramComment?
'( ' ProgramComment$ ' )'
END
EOL
IF UseComments? AND ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' METERS )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
Plane {No output}
SeqC OpToolID EOL
SeqC 'G65P9000' PreTool EOL
'N' Tool# '( ' ToolComment$ ' )' EOL
DoOpComments
DoPostScript
RETURN

FirstOp2:
CheckPass
SeqC CSAngleA CSAngleB EOL
SeqC 'G65P7010A' OutputTheWFONum StrtPos Speed 'H1' EOL
RETURN

FirstOp2a:
CheckPass
RETURN

FirstOp3:
RETURN

FirstOp3a: {can't XY position before WFO}
CheckPass
RETURN

NewToolOp1:
RETURN

NewToolOp2:
DoEndOpPS
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
Plane {No output}
SeqC 'G65P9000' PreTool EOL
'N' Tool# '( ' ToolComment$ ' )' EOL
DoOpComments
DoPostScript
RETURN

NewToolOp4:
CheckPass
SeqC CSAngleA CSAngleB EOL
SeqC 'G65P7010A' OutputTheWFONum StrtPos Speed 'H1' EOL
RETURN

NewToolOp4a:
CheckPass
RETURN

NewToolOp5:
RETURN

NewToolOp5a:
RETURN

NewToolOp5b:
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC IncValue OfstOff EOL
SeqC SpinOff EOL
SeqC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
Plane {No output}
IF ChangeCS?
IF AChange? OR BChange?
SeqC 'G91G30Z0' EOL
SeqC 'G28X0Y0' EOL
SeqC 'G90' EOL
END
END
SeqC CSAngleA CSAngleB EOL
SeqC 'G65P7010A' CalcCSWFO StrtPos Speed 'H1' EOL
RETURN

SameToolOp2a: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
Plane {No output}
SeqC StrtPos SpeedC EOL
RETURN

SameToolOp3: {Start new Operation}
IF LAST ProgStop?
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
RETURN

End1:
RETURN

End2:
DoEndOpPS
IF ProgStop?
SeqC 'M0' EOL
END
RETURN

End3:
SeqC 'M98P7030' EOL
SeqC 'G91G28G40Z0' EOL
SeqC 'G28B0' EOL
SeqC 'G65P9000T0' EOL
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
OpenMP
FirstOp1
IF NOT WorkFixtureOffsets?
SeqC WFO1 EOL
END
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
SubCSMP
NewToolOp3
IF NOT WorkFixtureOffsets?
SeqC WFO1 EOL
END
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
IF NOT WorkFixtureOffsets?
SeqC WFO1 EOL
END
FirstOp2a
OpenMP
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2
NewToolOp3
IF NOT WorkFixtureOffsets?
SeqC WFO1 EOL
END
NewToolOp4a
OpenMP
NewToolOp5b
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2a
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
IF NOT WorkFixtureOffsets?
SeqC WFO1 EOL
END
FirstOp2
FirstOp3a
OpenMP
SeqC AbsOrInc Rapid StrtPos EOL
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
IF NOT WorkFixtureOffsets?
SeqC WFO1 EOL
END
NewToolOp4
NewToolOp5a
OpenMP
SeqC Rapid StrtPos EOL
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
SeqC Rapid StrtPos EOL
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
NotSameToolWFO
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NotSameToolWFO
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolWFO
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, top level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
MP1ToollAllPfu
{ NoMPs}
END