{Change Comments ***********************************************************}

{added separate sub call code and warning for not separate, 7/5/88 WFG}
{separate sub calls turned off in this post- 'UseSeparateSubCalls' commented out}
{ncPost3ż24 or better}
{added IF ToolChangeAtHome?, & SetHome 9/26/88 WFG}
{added PostScript commands 3/11/89 WFG}
{added PostScript command comments 5/9/89, WFG, use ncPost 3.10Ś9 or better}
{removed run time comments, 5/9/89, WFG}
{added "must be all capital letters when typed in" to Postscript Command comment, 5/17/89, JR}
{added metric, 6/5/89, WFG}
{suppressed first cycle StrtPos for sep subs,7/17/89 WFG}
{last tool now goes to FirstHome when finished, 7/26/89, WFG}
{changed to Sep Sub standard}
{.65, corrected Sep sub problem if 1st cut <> Z step, 9/14/89 WFG, requires ncPost 3.19Ś5}
{.66, added name comment to Prog ID # line, 10/30/89, WFG}
{.67, new prog commands, 11/20/89, WFG}
{*.68, AutoCycles and 3.2 support, 12/4/89, WFG (Good luck on the upgrades to other posts)}
{.69, corrected 2 repeat op/autocycle problems, 12/21/89, WFG}

{1/8/90-2/7/90
Changes to M001.69
Moved DoPostScript command to very beginning of NewTool & SameTool op's, same as FirstOp.
Deleted last line of NewWFO PostScript comment, it no longer applies.
Move DoEndOpPS command in NewTool & end of prog to end of operation outside of Full-up MP.
Restucture to have M01 or M00 in New Tool.
Deleted ProgStop? from end of prog, not neccesary.
Check for ProgStop at beginning AND end of operation does not work, it comes out both places,
only using for end of operation. Reflected in PSComments.
Deleted StopProg sub.
Re-wrote SameTool section for many reasons.
Deleted ClearancePlane3# prog format it is no longer needed.
New sub CheckPass to replace statement in main for SetPass.
Modified WFOStuff sub to include SameTool.
Deleted StrtPos from OpenMP sub and added to main where needed.
Updated to .70 format.
Jim Radcliffe}

{.71.1, added InitProg, 4/11/90, JR}
{.71.2, FIRST modifier, no CRCOffC in AutoCycCutSub2, add Connect for ZOnlyRep, 4/23/90, JR}
{.72.1, New PS subs, formats, CoolOff?, ProgStop to start of NewTool & SameTool, 5/23/90, JR}
{.72.2, modified subroutine stuff (same effect), 7/1/90, DWB}
{.73, Replaced SetSRXYZero with SetSRXYtoSP, CoolOff, new formaters, 7/24/90, DWB}
{.74, ResetCRCNum, modified PostScript comments, 8/1/90, JR}
{.76, corrected AutoCycle SP and EP Status Record errors}
{.76.2, removed beginning Op ProgStop capability and Get Coolant, 2/6/91, WFG}

{2/15/91,
Updated to new 4.0 Version Fanuc 6M M001.80:
Added Coolant checking for SameTool.
Added ProgStop checking for final Operation.
DWB}

{5/21/91
Copied & modified: Fanuc 6M M001.80
For: Hosmer Dorrance
Control: Fanuc 10M
Machine: Kitamura Mycenter 1
Custom processor, each tool is put into a subroutine. Then that sudb is called for MP and/or Repeats.
**Unsupported features**
Does not do "Muliple Parts One Part All Tools"
AutoCycles will not be output into a subroutine, the same program information will be repeated in the Tool Sub.
All Repeated Operations will be Entry/Exit connect regardless of the selection in ncCAM. Except for AutoCycle, Z shift only, as mentioned above.
DO NOT create consecutive Repeated and non-Repeated operations with the same tool.
DO NOT create consecutive Repeated operations with differing shift values with the same tool.
Sep sub calls with mian program positioning for Z only repeats is not supported, uses G52 offset.
**Options**
Use OptCyc1 PostScript command to get G61 for the current operation, G64 is output as default.
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '########;0'
#6 = '####^###;'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}

{Prog Subroutines **********************************************************}

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )'
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
DecelMove2
END
SeqC CRCOnC FeedC MoveXYZC DecelFeed CRCOffsetC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
END
END
RETURN

ToolPath2: {for AutoCycle element moves}
EACHFeat
IF RapidFeat?
IF LastFeat?
SeqC CRCOffC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF LastFeat?
SeqC CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
NEXTFeat
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

CutAutoCycle:
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
SeqC IncValue EOL
IF Repeats? AND ZshiftOnly?
EachRep
EntryMove
ToolPath2
IF NOT FeedConnect?
SeqC RapidC PRIME ZCP2 EOL
END
NextRep
SeqC AbsOrInc RapidC ZCP2 EOL
ELSE
EntryMove
ToolPath2
SeqC AbsOrInc RapidC ZCP2 EOL
END
SetSRSubXY {restore tool position}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

ToolPath:
EACHFeat
IF PointFeat?
SeqC MoveSXYC EOL
IF AutoCycle?
CutAutoCycle
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
END
ELSE
IF RapidFeat?
SeqC RapidC MoveXYZC EOL
ELSE
IF LineFeat?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
DecelMove2
END
SeqC CRCOnC FeedC MoveXYZC DecelFeed CRCOffsetC EOL
ELSE
SeqC CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CRCOnC FormatArc ArcFeedC CRCOffsetC EOL
DecelMove2
END
SeqC CRCOnC FormatArc DecelFeed CRCOffsetC EOL
ELSE
SeqC CRCOnC FormatArc ArcFeedC CRCOffsetC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts? AND WorkFixtureOffsets?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS '
ELSE
'G' NewWFO#
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
'G' NewWFO#
END
END
END
RETURN

DoRepeats:
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
EachRep
IF NOT FirstCycle?
SeqC
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
'/'
END
'G52' 'X' CurOriginPosX# 'Y' CurOriginPosY# 'Z' CurOriginPosZ# SubCall CallLab EOL
END
NextRep
IF MultipleParts? AND OneToolAllParts?
IF WorkFixtureOffsets?
SeqC
IF NOT FirstPart?
'/'
END
'G52' 'X' CurOriginPosX# 'Y' CurOriginPosY# 'Z' CurOriginPosZ# EOL
END
ELSE
SeqC 'G52' 'X' CurOriginPosX# 'Y' CurOriginPosY# 'Z' CurOriginPosZ# EOL
END
END
END
RETURN

DoMultipleParts:
IF WorkFixtureOffsets?
NewWFO
EachWFO
IF NOT FirstPart?
SeqC '/' SetWFO SubCall CallLab EOL
END
DoRepeats
IF FullUp? AND NOT LastPart?
SeqC '/' 'G49' OfstOff EOL
END
IncWFO
NextWFO
SeqC WFO1 EOL
ELSE
EachPart
IF NOT FirstPart?
SeqC '/' 'G52' 'X' CurOriginPosX# 'Y' CurOriginPosY# 'Z' CurOriginPosZ# SubCall CallLab EOL
END
DoRepeats
IF FullUp? AND NOT LastPart?
SeqC '/' 'G49' OfstOff EOL
END
NextPart
SeqC 'G52' 'X' CurOriginPosX# 'Y' CurOriginPosY# 'Z' CurOriginPosZ# EOL
END
RETURN

EndToolSub:
SeqC EndSub ASCII('13') EOL
CloseSub
RETURN

DoToolSub:
NewProg
SeqC SubCall CallLab EOL
IF MultipleParts? AND OneToolAllParts?
DoMultipleParts
ELSE
DoRepeats
END
RETURN

StartToolSub:
DoToolSub
OpenSub
SubID DoSubComment EOL
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
SeqC WFOStuff EOL
CheckPass
RETURN

GetCoolant:
IF NOT CoolOff?
SeqC CoolOn EOL
IF FirstOperation?
SeqC 'G4P1500' EOL
ELSE
SeqC 'G4P500' EOL
END
END
RETURN

ExactPositioning:
IF OptCyc1?
'G61'
ELSE
'G64'
END
RETURN


{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50')
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
OpenSub
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
IF Metric? {CAM file is in metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
DoPostScript
Seq Rapid AbsOrInc ExactPositioning WFOStuff 'G49' OfstOff OpToolID ToolChng EOL
DoOpComments
GetCoolant
StartToolSub
CheckPass
SeqC Rapid Plane AbsOrInc StrtPos Speed SpinOn EOL
SeqC OfstOn EOL
ELSE
IF NewTool?

{Finish off last Operation}

EndToolSub
SeqC CoolOff EOL
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid AbsOrInc Home EOL
END
IF LAST ProgStop?
SeqC 'M00' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

DoPostScript
Seq Rapid AbsOrInc ExactPositioning WFOStuff 'G49' OfstOff OpToolID ToolChng EOL
DoOpComments
GetCoolant
StartToolSub
CheckPass
SeqC Rapid Plane AbsOrInc StrtPos Speed SpinOn EOL
SeqC OfstOn EOL
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC 'G49' OfstOff CoolOff EOL
SeqC 'M00' EOL

{Start new Operation}

GetStartOfSameTool
GetCoolant
SeqC Rapid PlaneC AbsOrInc StrtPos SpeedC SpinOn EOL
SeqC OfstOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC 'G49' OfstOff EOL

{Start new Operation}

GetStartOfSameTool
SeqC Rapid PlaneC AbsOrInc StrtPos SpeedC EOL
SeqC OfstOn EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqC Rapid PlaneC AbsOrInc StrtPos SpeedC EOL
END
IF LAST CoolOff?
GetCoolant
END
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF NOT AutoCycle?
EntryMove
END
ToolPath
SeqC RapidC CRCOffC ZCP3C EOL
ELSE
IF Drilling?
SeqC DrillCP EOL
GetCycle
SeqC Cycle FromCP StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt EOL
ToolPath
SeqC DrillOff EOL
SeqC RapidC ZCP3C EOL
END
END {common point for all operations}
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}

EndToolSub
SeqC CoolOff EOL
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC Rapid AbsOrInc FirstHome EOL
END
IF ProgStop?
SeqC 'M00' EOL
END
SeqC Rapid AbsOrInc 'G49' OfstOff UnTool ToolChng EOL
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END