{Change Comments ***********************************************************}

{
11/15/94 [ws]
Bxxx.81.2 (from M491.81.2)

Converted old style post to new style for use as a 5th Axis post.
}

{
12/11/94
Cxxx.00

Converted to C style post
Updated to .00 version per Fanuc 6M (PW) C001.00.02
}

{
Format: Maho HCNC 432 [NOAO] C722.00.01
1/10/95
Added ClearCSOffset to OpenMP: CloseMP: and SubCSMP:
Started using Flag('3') to determine toggle between incrementing through MPs and decrementing through MPs
Changed CloseMP to check Flag('3'). If true, the WFOs will increment from first to last. If false, the WFOs will
decrement from last to first.
Example:
TRUE for 4 parts: G54P1, G54P2, G54P3, G54P4
FALSE for 4 parts: G54P4, G54P3, G54P2, G54P1
This is most useful for tombstone machining on rotary tables. With this method, the code will machine part1, rotate, part2,
rotate, part3, rotate, part4, tool change, part4, part3, part2, part1, toolchange, etc. It minimizes the rotation and also
stops the machine from "winding up".
To do this a new sub was created called ToggleIncDecWFO. The flag is set to true in ProgStart and toggled inside CloseMP
after running through the parts
Replaced SetZRepInc and RestoreAbsOrInc with one sub called DoAbsOrInc. Any line with SetZRepInc now
has DoAbsOrInc as the first command after the SeqLabC.
Started using Flag ('4') to turn on Inc/Dec WFO's (See above). True means use Inc/Dec WFO's.
TH}

{
Format: Maho HCNC 432 [NOAO] C722.00.02
1/13/95
Formatted TrackZNO# to #4
TH}

{ Added ClearCSOffset to SubCSMP TH}

{
Format: Maho HCNC 432 [NOAO] C722.00.04
3/2/95
Replaced accidental SeqLabC with SeqLab
TH}

{
Format: Maho HCNC 432 [NOAO] C722.00.05
3/10/95
Added SeqLab in front of CSWFO Comments
TH}

{
4/25/95
Maho HCNC 432 [NOAO] C722.00.06
Removed the OR ChangeCS? from SameToolOp1:
Changed the drilling section of toolpath to output all
Removed the following from End2:
SeqLab ' T0 M67' EOL
SeqLab WFOOff ' X27.1662 Y17.3237 Z19.2922 ' EOL
TH}

{
Format: Maho HCNC 432 [NOAO] C722.00.07
For: Aura Inc.
6/22/95
Changed tapping cycle to use J style instead of F style
TH}

{8/23/95
Format: Maho HCNC 432 [NOAO] C722.10
For: Gibbs & Associates
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.06/Catalyst v2.22/Compost 4.21.32/1.0a
Changes made per Tom Hubina
Fixed problem with Tagging.
Changed Program# to Tag# at DoSubComment.
Added '>' Tag# EOL at StartSub.
Changed 'N9' Program# EOL to 'N9?' EOL at StartSub.
Deleted TagInc at StdSub.
Changed '>' Tag# EOL to 'È' Tag# EOL at StdSub.
Changed ' N=9' Program# to ' N=9Å‚' Tag# at StdSub.
Changed literal 'Å‚' to 'Ç' two places at StdSub.
Added TagDown prior to CloseSub at FinishSubG92.
Added TagUp to TagInc at OpenMP.
Deleted NewProg two places at OpenMP.
Changed ' N=9' Program# to ' N=9Å‚' Tag# two places at OpenMP.
Deleted TagInc at OpenMP.
Changed literal 'Å‚' to 'Ç' two places at OpenMP.
Changed CallLabB CSSubID# RepLab OnePart to ' N=9Å‚' Tag# two places at CloseMP.
Added TagDown three places at CloseSub.
Changed NewProg to TagInc at SubCSMP.
Changed ' N=9' Program# to ' N=9Å‚' Tag# at ToolPath PointFeat AutoCycle.
Changed NewProg to TagUp TagInc at Milling Sub.
Added TagDown at Milling Sub.
Changed NewProg to TagUp TagInc at ZonlyRepAutoCycle.
Changed ' N=9' Program# to ' N=9Å‚' Tag# at ZonlyRepAutoCycle.
Added TagDown at ZonlyRepAutoCycle.
Changed ' N=9' Program# to ' N=9Å‚' Tag# at ZonlyRep.
Added TagDown at ZonlyRep.
Added TagInit at ProgStart.
Changed NewProg to TagUp TagInc at OpGuts IF Milling.
Changed NewProg to TagUp TagInc at OpGuts IF Drilling Repeats.
Changed ' N=9' CallMasterNum# to ' N=9Å‚' CallMasterNum# at OpGuts IF Drilling CallMasterOp.
Deleted ' G14' block at OpGuts IF Drilling CallMasterOp.
Deleted '>' Tag# EOL at OpGuts IF Drilling MasterOp
Changed ' N=9' Program# to ' N=9Å‚' Tag# at OpGuts IF Drilling MasterOp.
Deleted ' G14' block at OpGuts IF Drilling MasterOp.
DWB}

{
Format: Maho HCNC 432 [NOAO] C722.10.01
9/14/95
Added 'K' Peck# to all peck cycles
Increased max RPM to 4000
TH}

{
Format: Maho HCNC 432 [NOAO] C722.10.02
10/17/95
Removed code to reset table back to A0B0.
Replaced CoolOff with SpinOff
TH}

{
Format: Maho VCNC 432 [NOAO] C722.10.02
12/21/95
Made vertical version of horizontal post
TH}

{1/17/96, Updated .10 to .11 version, MPK}

{ 3/25/96 Changed version number to .12 TH}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '###.####;0.'
#5 = '#######0'
#6 = '###.#;0.'
#7 = '#;'
#8 = '###.##;0.'
#9 = '###0'
#10 = '*###.##;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(PartShiftX#,4)
FORMAT(PartShiftY#,4)
FORMAT(PartShiftZ#,4)
FORMAT(RepeatX#,4)
FORMAT(RepeatY#,4)
FORMAT(RepeatZ#,4)
FORMAT(CalcZSurf#,4)
FORMAT(CP1LessCP2#,4)
FORMAT(CalcZFmSurf#,4)
FORMAT(CalcCP2FmSurf#,4)
FORMAT(HelixPitch#,4)
FORMAT(Retract#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Tag#,5)
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(CallMasterNum#,5)
FORMAT(Dwell#,6) {.72}
FORMAT(RapidF#,7)
FORMAT(Recall#,8) { FeedRate Scale }
FORMAT(SpeedRPM#,4)
FORMAT(FeedTapIPR#,4)

FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(DIV#,4)
FORMAT(MUL#,4)
FORMAT(ADD#,5)
FORMAT(CS#,5)
FORMAT(CSOffsetA#,10)
FORMAT(CSOffsetB#,10)
FORMAT(TrackZNO#,4)

{FeedRate Scale Subroutines ************************************************}

GetSpeed:
IF LTEqual? SpeedRPM# Recall# Num#('1')
Speed
ELSE
FORMAT(Recall#,9)
' S' Recall# Num#('1')
FORMAT(Recall#,8)
Save# Num#('2') DIV# Recall# Num#('1') SpeedRPM#
END
RETURN

GetSpeedC:
IF LTEqual? SpeedRPM# Recall# Num#('1')
SpeedC
ELSE
IF LessThan? LAST SpeedRPM# Recall# Num#('1')
GetSpeed
END
END
RETURN

GetRapidF:
Save# Num#('3') Num#('0')
RETURN

DoFeed:
' F' Recall# Num#('3')
RETURN

GetFeedEnt:
IF LTEqual? SpeedRPM# Recall# Num#('1')
FeedEnt
ELSE
Save# Num#('3') MUL# FeedEntry# Recall# Num#('2')
DoFeed
END
RETURN

GetFeedEntC:
IF LTEqual? SpeedRPM# Recall# Num#('1')
FeedEntC
ELSE
Save# Num#('4') MUL# FeedEntry# Recall# Num#('2')
IF NotEqual? Recall# Num#('3') Recall# Num#('4')
GetFeedEnt
END
END
RETURN

GetFeedRate:
IF LTEqual? SpeedRPM# Recall# Num#('1')
FeedRate
ELSE
Save# Num#('3') MUL# FeedContour# Recall# Num#('2')
DoFeed
END
RETURN

GetFeedRateC:
IF LTEqual? SpeedRPM# Recall# Num#('1')
FeedRateC
ELSE
Save# Num#('4') MUL# FeedContour# Recall# Num#('2')
IF NotEqual? Recall# Num#('3') Recall# Num#('4')
GetFeedRate
END
END
RETURN

GetDecelFeed:
IF LTEqual? SpeedRPM# Recall# Num#('1')
DecelFeed
ELSE
GetFeedRate
END
RETURN

GetArcFeedC:
IF LTEqual? SpeedRPM# Recall# Num#('1')
ArcFeedC
ELSE
GetFeedRateC
END
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
SeqLab '( SUB NUMBER: ' Tag# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLab '( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
SeqLab '( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
SeqLab '( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
SeqLab '( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
SeqLab '( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

CSWFO:
' G' ADD# CS# SUB# NewWFO# Num#('1')
RETURN

CalcCSWFO: {(iPart-1)*NumOfCS#)}
' G' ADD# MUL# NumOfCS# SUB# PartNum# Num#('1') ADD# CS# SUB# NewWFO# Num#('1')
RETURN

CSAngleA:
IF AAxisAvail?
' A' CSOffsetA#
END
RETURN

CSAngleAC:
IF AChange?
CSAngleA
END
RETURN

CSAngleB:
IF BAxisAvail?
' B' CSOffsetB#
END
RETURN

CSAngleBC:
IF BChange?
CSAngleB
END
RETURN

DoCSWFOComment:
SeqLab '( CS#' CS# ' - ' CSComment$ ' )' EOL
SeqLab '( ' CalcCSWFO '= X' CSOffsetX# ' Z' CSOffsetY# ' Y' CSOffsetZ# ' )' EOL
RETURN

PSInit:
MasterOpF
CallMasterOpF
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLab Feed ZIn GetFeedEnt EOL
ELSE
SeqLab RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
'>' Tag# EOL
'N9?' EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
SeqLab ' ' EOL
SeqLab '( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
SeqLab ' ' EOL
END
END
RETURN

StdSub:
'È' Tag# EOL
SeqLab SubCall ' N=9Å‚' Tag# EOL
SeqLab ' G14 J' RepsLess1 ' N1=Ç' Tag# ' N2=Ç' Tag# EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqLab CRCOffC EOL
IF NOT FeedConnect?
IF AutoCycle?
SeqLab ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqLab FeedC ZCP3C GetFeedEntC EOL
ELSE
SeqLab RapidC ZCP3C EOL
END
END
END
RETURN

FinishSubG92: {part 2}
SeqLab Preset ' X' RepeatX# ' Z' RepeatY# ' Y' RepeatZ# EOL
TagDown
CloseSub
SeqLab ' G93 X0 Y0 Z0' EOL
RETURN

ToggleIncDecWFO:
IF Flag?('3')
SetFlagF('3')
ELSE
SetFlag('3')
END
RETURN

OpenMP:
TagUp TagInc
IF WFOCS?
StartSub
SaveCSProg
SaveCSOpStart
ClearCSOffset
ELSE
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqLab SetWFO EOL
SeqLab SubCall ' N=9Å‚' Tag# EOL
IncWFO
NextWFO
ELSE
'È' Tag# EOL
SeqLab SubCall ' N=9Å‚' Tag# EOL
SeqLab ' G14' ' J' PartsLess1 ' N1=Ç' Tag# ' N2=Ç' Tag# EOL
END
StartSub
END
RETURN

CloseMP:
IF WFOCS?
SeqLab EndSub EOL
CloseSub
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
EachCSOp
DoCSWFOComment
ClearCSOffset
SeqLab CalcCSWFO EOL
SeqLab SubCall ' N=9Å‚' Tag# EOL
NextCSOp
ClearCSOffset
IncWFO
NextWFO {simple NextPart}
ELSE
LastWFO
EachWFO {simple eachPart}
EachCSOp
DoCSWFOComment
ClearCSOffset
SeqLab CalcCSWFO EOL
SeqLab SubCall ' N=9Å‚' Tag# EOL
NextCSOp
ClearCSOffset
DecWFO
NextPrevWFO {simple NextPart}
END
IF Flag?('4')
ToggleIncDecWFO
END
TagDown
ELSE
IF WorkFixtureOffsets?
TagDown
CloseSub
SeqLab WFO1 EOL
ELSE
SeqLab Preset ' X' PartShiftX# ' Z' PartShiftY# ' Y' PartShiftZ# EOL
TagDown
CloseSub
SeqLab ' G93 X0 Y0 Z0' EOL
END
END
RETURN

SubCSMP:
IF WFOCS?
IF ChangeCS?
SeqLab EndSub EOL
CloseSub
TagInc
StartSub
SaveCSProg
END
ClearCSOffset
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLab AbsValue EOL
END
RETURN

DoArc:
DoAbsOrInc
MoveXYZC
IF ArcIJFormat?
ArcIJ
ELSE
ArcRC
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF XYPlane? AND ZMove?
DoArc
FORMAT(HelixPitch#,4)
' J' HelixPitch#
ELSE
IF XZPlane? AND YMove?
DoArc
FORMAT(HelixPitch#,4)
' K' HelixPitch#
ELSE
IF YZPlane? AND XMove?
DoArc
FORMAT(HelixPitch#,11)
' I' HelixPitch#
ELSE
DoArc
END
END
END
RETURN

StdLine: {enables CRC on first call, .70}
SeqLab CRCOnC EOL
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab DoAbsOrInc FeedC MoveXYZC GetFeedRateC EOL
DecelMove2
END
SeqLab DoAbsOrInc FeedC MoveXYZC GetDecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLab DoAbsOrInc FeedC MoveXYZC GetFeedRateC EOL
END
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLab MoveSXYC EOL
SeqLab SubCall ' N=9Å‚' Tag# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLab ' G79' DoDrillAbsOrInc MoveSX MoveSY
IF FirstFeat?
' Y' CalcZSurf#
END
EOL
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqLab CRCOffC EOL
SeqLab DoAbsOrInc RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLab DoAbsOrInc RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqLab CRCOffC EOL
SeqLab DoAbsOrInc FeedC MoveXYZC GetFeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLab DoAbsOrInc FeedC MoveXYZC GetFeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab FormatArc GetArcFeedC EOL
DecelMove2
END
SeqLab FormatArc GetDecelFeed EOL
ELSE
SeqLab FormatArc GetArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLab IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqLab AbsOrInc EOL
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
SeqLab FeedC ZCP2 GetFeedEntC EOL
ELSE
SeqLab RapidC ZCP2 EOL
END
END
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after TagInc for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagUp TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
TagDown
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLab Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagUp TagInc
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLab Feed IncValue StrtPosC EOL
SeqLab AbsOrInc
ELSE
SeqLab Feed
END
ELSE
SeqLab Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLab Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqLab AbsOrInc ZCP2PlusInc EOL
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqLab Rapid ZCP2PlusInc EOL
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLab SubCall ' N=9Å‚' Tag# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqLab Feed ZCP2 GetFeedEnt EOL {.69}
ELSE
SeqLab Rapid ZCP2 EOL {.69}
END
END {.69}
TagDown
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLab Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqLab FeedC ZInPlusInc GetFeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLab RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLab Feed ZInPlusInc GetFeedEnt EOL
ELSE
SeqLab RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqLab SubCall ' N=9Å‚' Tag# EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
TagDown
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

ProgStart:
InitProg
TagInit
ReverseXZArcs
InitWFONum
SetFlood
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 2}
SetFlag('3') {True = incrementing WFO numbers for MP. False = decrementing WFO numebrs for MP}
SetFlag('4') {True = toggle between incrementing/decrementing WFO's }
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('20000') { FeedRate Scale }
Save# Num#('1') Num#('4000') { MaxRPM }
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END

IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('6')
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of parts [ ' Parts# ' ] times CSs [ ' NumOfCS# ' ] )' EOL
'( exceeds the machine limit. Switching to non-WFO output. )' EOL
END
END
END
ELSE
IF LTEqual? NumOfCS# Num#('6') {****}
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of CSs [ ' NumOfCS# ' ] exceeds the machine limit. )' EOL
'( Switching to non-WFO output. )' EOL
END
END
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
GetRapidF RapidF# { To force FeedRate }
IF Milling?
SeqLab ZCP2C EOL
IF Repeats?
TagUp TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') {std sep sub Zreps are in effect} {rep change 2}
ZonlyRep {rep change 1}
SetFlagF('1') {not std sep sub Zreps in effect} {rep change 3}
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLab ZCP3C EOL
ELSE
SeqLab CRCOffC EOL
IF FIFO? {.81}
SeqLab FeedC ZCP3C FeedEntC EOL
ELSE
SeqLab RapidC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
TagUp TagInc
StdSub
SeqLab Rapid StrtPos EOL
END
SeqLab DrillCP EOL
GetCycle
SeqLab Cycle
IF Dwell?
' X' Dwell#
END
' Y' CalcCP2FmSurf#
' Z' CalcZFmSurf#
IF RetractToCP1?
' B' CP1LessCP2#
END
IF Peck?
Peck ' I0.'
IF PeckChipBreaker?
' J' Retract#
END
' K' Peck#
ELSE
IF Tap?
' I' MUL# SpeedRPM# Num#('.01') ' J' FeedTapIPR# ('1')
END
END
IF NOT Tap?
GetFeedEnt
END
EOL
IF CallMasterOp?
SeqLab SubCall ' N=9Å‚' CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
TagUp NewMasterTag
SeqLab SubCall ' N=9Å‚' Tag# EOL
StartSub
ToolPath
TagDown
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqLab Rapid ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
RETURN

NotSameToolWFO:
IF WFOCS?
IF ChangeCS?
DoCSWFOComment
END
SeqLab CSWFO EOL
ClearCSOffset
ELSE
IF NeedWFO1?
SeqLab ' G' NewWFO# EOL
END
END
RETURN

SameToolWFO:
IF WFOCS?
IF ChangeCS?
DoCSWFOComment
SeqLab CSWFO EOL
END
ClearCSOffset
END
RETURN

InitOp:
EOR 'PM' EOL
'N9' Program# EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
SeqLab '( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
SeqLab '( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
SeqLab '( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
SeqLab '( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
SeqLab '( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
SeqLab '( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
SeqLab '( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
SeqLab AbsOrInc EOL
RETURN

FirstOp1:
SeqLab Plane EOL
SeqLab OpToolID ToolChng EOL
DoOpComments
DoPostScript
RETURN

FirstOp2:
{SeqLab WFOStuff Index EOL}
RETURN

FirstOp3:
CheckPass
SeqLab Rapid StrtPos CSAngleA CSAngleB ZCP1 GetSpeed SpinOn EOL
SeqLab CoolOn EOL
RETURN

FirstOp3a:
CheckPass
SeqLab Rapid StrtPos ZCP1 GetSpeed SpinOn EOL
SeqLab CoolOn EOL
RETURN

NewToolOp1:
SeqLab SpinOff EOL
RETURN

NewToolOp2:
DoEndOpPS
IF ToolChangeAtHome?
SeqLab Rapid Home EOL
END
RETURN

NewToolOp3: {Start new Operation}
SeqLab PlaneC EOL
SeqLab OpToolID ToolChng EOL
IF LAST ProgStop?
SeqLab ' M00' EOL
ELSE
SeqLab ProgStop EOL
END
DoOpComments
DoPostScript
RETURN

NewToolOp4:
{SeqLab WFOStuff Index EOL}
RETURN

NewToolOp5:
CheckPass
SeqLab Rapid StrtPos CSAngleA CSAngleB ZCP1 GetSpeed SpinOn EOL
SeqLab CoolOn EOL
RETURN

NewToolOp5a:
CheckPass
SeqLab Rapid StrtPos ZCP1 GetSpeed SpinOn EOL
SeqLab CoolOn EOL
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqLab SpinOff EOL
SeqLab ' M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLab SpinOff EOL
END
IF NewToolOffset?
SeqLab IncValue OfstOff EOL
END
END
RETURN

SameToolOp2: {Start new Operation}
SeqLab PlaneC EOL
DoOpComments
DoPostScript
{SeqLab WFOStuff Index EOL}
CheckPass
RETURN

SameToolOp3: {Start new Operation}
IF LAST ProgStop?
SeqLab Rapid StrtPos CSAngleA CSAngleB ZCP1 GetSpeedC SpinOn EOL
SeqLab CoolOn EOL
ELSE
SeqLab Rapid StrtPos CSAngleA CSAngleB GetSpeedC EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLab CoolOn EOL
END
END
RETURN

End1:
SeqLab SpinOff EOL
RETURN

End2:
DoEndOpPS
IF FIRST ToolChangeAtHome? {added FIRST modifier}
SeqLab Rapid FirstHome EOL
END
IF ProgStop?
SeqLab ' M00' EOL
END
RETURN

End3:
SeqLab EOP EOL
ASCII('04') EOL
CloseSub
Post2 {organize Subs into one program}
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
SubCSMP
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
OpenMP
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
OpenMP
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3a
OpenMP
SeqLab StrtPos EOL
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5a
OpenMP
SeqLab StrtPos EOL
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
NotSameToolWFO
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NotSameToolWFO
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolWFO
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, top level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END