{Change Comments ***********************************************************}

{10/31/89
Copied & modified: Fan 6M MS MV35 [¨] M051.55
For: Accutool
Machine: Matsura RA2
Control: Yasnac MX3
Modified per customer requests.
JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}

{4/26/91,
Modified: Yasnac MX3 Mat [AM] M267.62
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{2/25/93
Copied & modified: Yasnac MX3 Mat [AM] M267.79
For: Majic Mfg
Updated to Version 4.1 per Fanuc 6M M001.81 Format.
Changed OfstOff in MachSpec to output G49.
Changed FORMAT for Dwell to 3 place, Trailing Zeros.
250 = 1/4 second.
Changed Comments back to M001 standard.
Moved CRCOff back to M001 standard.
Added FIRST TOOL NOT IN SPINDLE.
Added ASCII('13') at FirstOperation and NewTool.
Moved Speed SpinOn to StrPos block at FirstOperation and NewTool.
Changed IncValue to WFOOff at OfstOff block at NewTool, SameTool and end of Prog.
This is a one shot G53 code to return to Machine Reference Coordinates, i.e. Fanuc G28.
Added Rigid Tapping Mode at Drilling.
Added G89 Bore Cycle with Dwell at Drilling.
JR}

{8/17/93
Updated: Yasnac MX3 Mat [MM] M553.81
For: Gibbs & Associates/Matsurra
Updated per Fanuc 6M M001.81.2 Format.
Needed for creation of Yas MX3 Mat [AbsZAC] M.81.2 for Makato Uemura at Matsurra.
DWB}

{2/16/95
Modified: Yasnac MX3 Mat [MM] M553.81.2
For: Murtaugh Represents / Aero Precision
Control: Yasnac i80
First Tool In Spindle. PreTool. Block delete CoolOn.
Changed output of OfstOff.
Jim Radcliffe}

{3/16/95
Modified: Yasnac i80 M00A.81.2
For: Murtaugh Represents / Aero Precision
Control: Fanuc 0M
Modified sub repetitions calls.
Modified Rigid Tapping cycle.
Jim Radcliffe}

{8/19/95, Updated Fanuc 0M [AP] M788.81.2 to .85 format per Fanuc 6M M001.85.01.02, JR}

{1/9/96
Initial: Fanuc 0M [AP] M788.85
Created: Fanuc 16M [AP] C000.10.02
ForUser: Murtaugh Represents / Aero Precision
Control: Fanuc 16M
Machine: Mori Seiki SH-50
Develop: ComPost 4.21.33, Catalyst68K v2.30.22C
Comment: New Processor per marked up readout and conversation with Pete Lonero
Converted to C Style Advanced Mill Processor
Separate multiple parts sub call and WFO to separate lines.
ToolChangeAtHome Position is not supported. Hardcoded G91G30X0Y0Z0!
48 Work Offsets G54P1 thru G54P48.
MachSpec is P1 thru P48!
Added literal G54 to Prog before WFO calls!
Jim Radcliffe}

{1/19/96
Initial: Fanuc 16M [AP] C000.10.02
Created: Fanuc 16M [AP] C000.10.03
ForUser: Murtaugh Represents / Aero Precision
Develop: ComPost 4.21.33, Catalyst68K v2.30.26C
Comment: additional request per Peter Lonero
Added G91G28B0 to the beginning of the program.
Machine must be at B home before shuttling!
Added G8P1 to milling operations
Added G8P0 to drilling operations
Corrected bug of literal 2 being output when doing multiple parts
reversed the oder of the boolaen statment from:
IF WFOCS? OR Flag?('2')
to:
IF Flag?('2') OR WFOCS?
Jim Radcliffe}

{1/24/96
Initial: Fanuc 16M [AP] C000.10.03
Created: Fanuc 16M [AP] C000.10.04
ForUser: Murtaugh Represents / Aero Precision
Develop: ComPost 4.21.33, Catalyst68K v2.30.27C
Comment: Per Pete Lonero, B move before XY positioning move.
Jim Radcliffe}

{7/10/96,
Initial: Fanuc 16M [AP] C789.10.04
Created: Fanuc 16M [AP] C789.13
Added redundant StrtPos to BeginTool2 that only outputs when multiple part OTAP, customer wants
to have Start Pos in the main program. Updated to .13 format, MPK}

{7/15/96,
Initial: Fanuc 16M [AP] C789.13
Created: Fanuc 16M [AP] C789.13.1
Put the redundant output of StartPos along with Offset on into OpenMP and CloseMP when OTAP so that
XY positioning always comes before Z move, MPK}
{7/17/96,
Initial: Fanuc 16M [AP] C789.13.1
Created: Fanuc 16M [AP] C789.13.2
Made output of Length offset in OpenMP and CloseMP conditional upon being the first part cut with each tool, used
Flag('7') to keep track since I could not use if FirstPart? because of the toogling of increasing/decreasing WFOs, MPK}

{7/17/96,
Initial: Fanuc 16M [AP] C789.13.2
Created: Fanuc 16M [AP] C789.13.3
Modified output of CoolOn to output insode the MP subroutine when OTAP, MPK}

{9/30/96,
Initial: Fanuc 16M [AP] C789.13.3
Created: Fanuc 16M [AP] C789.13.4
deleted tool change, offset cancel, rotacaion reset and m60 from InitOp,
added AbsOrInc and ProgStop to InitOp,
changed Seq in BeginTool1 to 'N' Tool# (control does not have a problem with duplicate sequence numbers,
added CSAngle moves to saftey start block in BeginTool1,
Move tool changes from EndTool2 to BeginTool1,
made CSangle moves in BeginTool3 conditional upon being MP, OTAP (this was to avoid possible
problems with the rotation being outside of the MP sub.)
deleted tool change at program end,
MPK}

{11/19/96
Initial: Fanuc 16M [AP] C789.13.4
Created: Fanuc 16M [AP] C789.13.5
ForUser: Aero Precision
Develop: ComPost2 68k v1.0b4, Catalyst68K v3.09.05C
Comment: Modified per marked up readout from Peter Lonero
Moved CoolOn to wherever we call OfstOn.
Moved CoolOff to wherever we call OfstOff.
Added redundant Speed output for Multiple Parts subs as Speed may get changed with next SameTool.
Jim Radcliffe}

{14May98
Original: Fanuc 16M [AP] C789.13.5
Created: Fanuc 18M MS [WPI] Cxxx.15
For: Westwood Precision
Changes made per: Dave Picket
NEW POST: FIRST DRAFT Per conversations with Dave Picket and Customers FAX
Changed from BeginTool/EndTool Style of Post and Updated to.15 format Fanuc 6M (PW) C001.15
Changes too numerous to list at this time.
Charles Winston}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.###;0.0'
#3 = '*####0.0##;0.0'
#4 = '###0.0###;0.0'
#5 = '#######0'
#6 = '####^##0'
#7 = '0000'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(CSOffsetA#,3)
FORMAT(CSOffsetB#,3)
FORMAT(FeedTapIPR#,4)
FORMAT(TCZ#,4)
FORMAT(ToolDiameter#,4)
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(TrackZNO#,4)
FORMAT(ADD#,5)
FORMAT(CS#,5)
FORMAT(Program#,7)
FORMAT(CallMasterNum#,7)
FORMAT(CSSubID#,7)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

CalcCSWFO#:
ADD# MUL# NumOfCS# SUB# PartNum# Num#('1') CS#
RETURN

CSWFO:
IF GreaterThan? CalcCSWFO# NUM#('6')
' G' ADD# CalcCSWFO# Num#('103')
ELSE
' G' ADD# CalcCSWFO# Num#('53')
END
RETURN

WFO:
IF GreaterThan? PartNum# NUM#('6')
' G' ADD# PartNum# Num#('103')
ELSE
' G' ADD# PartNum# Num#('53')
END
RETURN

WFOStuff:
IF Flag?('2')
IF NOT SameTool?
IF WFOCS?
CSWFO
ELSE
WFO
END
ELSE
IF WFOCS?
IF ChangeCS?
IF MultipleParts?
{MP ChangeCS is handled in SubCSMP and CloseMP}
ELSE
CSWFO
END
END
END
END
END
SetFlagF('2')
RETURN

CSG52:
IF FirstOperation? OR NewTool? OR ChangeCS?
SeqC 'G52X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ# EOL
END
ClearCSOffset
RETURN

G52Stuff:
IF AAxisAvail? OR BAxisAvail?
IF NOT WFOCS?
IF MultipleParts?
IF WorkFixtureOffsets?
CSG52
END
ELSE
CSG52
END
END
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoCSComment:
IF AAxisAvail? OR BAxisAvail?
'( CS#' CS# ' - ' CSComment$ ' )' EOL
END
RETURN

DoCSWFOComment:
IF AAxisAvail? OR BAxisAvail?
IF FirstOperation? OR NewTool? OR ChangeCS?
'( ' CSWFO ' = X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ# ' )' EOL
END
ClearCSOffset
END
RETURN

CSComments:
IF WFOCS?
IF MultipleParts?
IF OneToolAllParts? AND ExitClearancePlane?
ClearCSOffset { Necessary for correct StrtPos in Main }
END
ELSE
DoCSComment
DoCSWFOComment
END
ELSE
DoCSComment
END
RETURN

DoToolComments:
IF UseComments?
SetScale('1')
' ( TOOL ' Tool#
IF ToolTypeComment?
' - ' ToolDiameter# ' ' ToolType$
END
IF ToolComment?
' ' ToolComment$
END
' )'
RestoreScale
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
CSComments
RETURN

CSAngleA:
IF AAxisAvail?
' A' CSOffsetA#
END
RETURN

CSAngleAC:
IF AChange?
CSAngleA
END
RETURN

CSAngleB:
IF BAxisAvail?
' B' CSOffsetB#
END
RETURN

CSAngleBC:
IF BChange?
CSAngleB
END
RETURN

PSInit:
NewWFOF
FourthCWF
FourthCCWF
FifthCWF
FifthCCWF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
ASCII('13') SubID EOL
DoSubComment EOL
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
SeqC SubCall CallLabB RepCycs Program# EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

ToggleIncDecWFO:
IF Flag?('3')
SetFlagF('3')
ELSE
SetFlag('3')
END
RETURN

DoCSG52Ops:
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
ELSE
IF GreaterThan? PartNum# NUM#('6')
SeqC ' G' ADD# PartNum# NUM#('103') EOL
ELSE
SeqC SetWFO EOL
END
END
SeqC SubCall CallLabB OnePart Program# EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
IF WFOCS?
StartSub
SaveCSProg
SaveCSOpStart
ClearCSOffset
ELSE
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-OTAP-ECP }
END
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
DoCSG52Ops
IncWFO
NextWFO {simple NextPart}
DecWFO
ELSE
LastWFO
EachWFO {simple eachPart}
DoCSG52Ops
DecWFO
NextPrevWFO {simple NextPart}
IncWFO
END
IF Flag?('4')
ToggleIncDecWFO
END
StartSub
END
ELSE
SeqC SubCall CallLab RepLab Parts EOL
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { WFOStuff }
END
StartSub
END
RETURN

DoCSWFOOps:
EachCSOp
DoCSComment
DoCSWFOComment
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
ELSE
SeqC CSWFO EOL
END
SeqC SubCall CallLabB OnePart CSSubID# EOL
NextCSOp
RETURN

CloseMP:
IF WorkFixtureOffsets?
SeqC EndSub EOL
CloseSub
IF WFOCS?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-OTAP-ECP }
END
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
DoCSWFOOps
IncWFO
NextWFO {simple NextPart}
DecWFO
ELSE
LastWFO
EachWFO {simple eachPart}
DoCSWFOOps
DecWFO
NextPrevWFO {simple NextPart}
IncWFO
END
IF Flag?('4')
ToggleIncDecWFO
END
END
ELSE
SeqC Preset ShiftPC EOL
SeqC EndSub EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

SubCSMP:
IF WFOCS?
IF ChangeCS?
SeqC EndSub EOL
CloseSub
NewProg
StartSub
SaveCSProg
END
ClearCSOffset
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

CkCRCNum:
IF NOT LastFeat? AND Equal? SPZ# EPZ#
CRCOffsetC
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLabB OnePart Program# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC DoDrillAbsOrInc MoveSXYZC EOL
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC DoAbsOrInc ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
DecelMove2
END
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC DecelFeed ckCRCNum EOL
ELSE
SeqC DoAbsOrInc ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
END
SeqC ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqC IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqC ZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle?
Rapid
END
SeqC RapidC ZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC SubCall CallLabB OnePart Program# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqC Feed ZCP2 FeedEnt EOL
ELSE
SeqC Rapid ZCP2 EOL
END
END
SeqC EndSub EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL
END
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC RapidC ZInPlusInc EOL
END
END
SeqC SubCall CallLabB OnePart Program# EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
SeqC EndSub EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF Milling?
SeqC ' G8 P1' EOL
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO?
SeqC FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC CRCOffC ZCP3C EOL
END
END
SeqC ' G8 P0' EOL
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqC Rapid StrtPos EOL
END
GetCycle
IF Tap? AND OptCyc1? {Rigid Tapping Mode}
SeqC ' M29' Speed EOL
END
SeqC FromCP
IF FIFO? AND Dwell?
' G89'
ELSE
Cycle
END
ZDepth RLevel Dwell Peck Retract FeedEnt EOL
IF CallMasterOp?
SeqC SubCall CallLabB OnePart CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqC SubCall CallLabB OnePart Program# EOL
StartSub
ToolPath
SeqC EndSub EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqC DrillOff ZCP3 EOL
IF Repeats?
FinishSubG92
SeqC ZCP3C EOL
END
END
END
RETURN

ProgStart:
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('12000')
IF Metric?
SetMaxFeed('7620')
ELSE
SetMaxFeed('300')
END
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { WFOStuff }
SetFlag('3') { True = incrementing WFO numbers for MP. False = decrementing WFO numebrs for MP }
SetFlag('4') { True = toggle between incrementing/decrementing WFO's }
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
SetFlagF('6') {True = need CRCOffset }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END

IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('48')
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of parts [ ' Parts# ' ] times CSs [ ' NumOfCS# ' ] )' EOL
'( exceeds the machine limit. Switching to G52 style output. )' EOL
END
END
END
ELSE
IF LTEqual? NumOfCS# Num#('48') {****}
SetWFOCS { use WFO for CS changes }
ELSE
IF UseComments?
'( Not enough Work Fixture Offsets to handle this part. )' EOL
'( Number of CSs [ ' NumOfCS# ' ] exceeds the machine limit. )' EOL
'( Switching to G52 style output. )' EOL
END
END
END
RETURN

InitOp:
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
' ( PROGRAM: ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
'N' Tool# Rapid Plane CRCOff ' G49' DrillOff AbsOrInc WfOOff ' Z0' OpToolID EOL
SeqC ToolChng DoToolComments EOL
SeqC ' M1' EOL
SeqC ' M80' EOL
DoOpComments
DoPostScript
RETURN

FirstOp2:
G52Stuff
CheckPass
SeqC WFOStuff AbsOrInc Rapid StrtPos CSAngleA CSAngleB SpinOn Speed PreTool EOL
RETURN

FirstOp3:
SeqC OfstOn CoolOn EOL
RETURN

NewToolOp1:
'N' Tool# Rapid Plane CRCOff ' G49' DrillOff AbsOrInc WfOOff ' Z0' OpToolID EOL
RETURN

NewToolOp2:
DoEndOpPS
SeqC ToolChng DoToolComments EOL
SeqC ProgStop EOL
SeqC ' M80' EOL
RETURN

NewToolOp3: {Start new Operation}
SeqC DrillOff EOL
DoOpComments
DoPostScript
RETURN

NewToolOp4:
G52Stuff
CheckPass
SeqC WFOStuff AbsOrInc Rapid StrtPos CSAngleA CSAngleB SpinOn Speed PreTool EOL
RETURN

NewToolOp5:
SeqC OfstOn CoolOn EOL
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqC ' M0' EOL
ELSE
IF NewToolOffset? or ChangeCS?
SeqC Rapid WfOOff ' Z0.0' EOL
END
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END

END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
G52Stuff
IF LAST ProgStop?
SeqC WFOStuff CSAngleA CSAngleB EOL
SeqC AbsOrInc Rapid StrtPos SpinOn SpeedC EOL
SeqC OfstOn CoolOn EOL
ELSE
SeqC WFOStuff CSAngleA CSAngleB EOL
SeqC AbsOrInc Rapid StrtPos SpeedC EOL
SeqC
IF NewToolOffset? OR ChangeCS?
OfstOn
END
IF NOT CoolOff? AND LAST CoolOff?
CoolOn
END
EOL
END
RETURN

End1:
SeqC CoolOff EOL
IF AbsoluteMoves?
SeqC IncValue OfstOff EOL
SeqC AbsValue EOL
ELSE
SeqC OfstOff EOL
END
RETURN

End2:
DoEndOpPS
'N9999' Rapid CRCOff ' G49' DrillOff AbsOrInc WfOOff ' Z0' SpinOff CoolOff ' M81' EOL
IF ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
SeqC ' M160' EOL
RETURN

End3:
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
SubCSMP
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
FirstOp1
OpenMP
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
OpenMP
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
SetFlag('2')
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
OpenMP
FirstOp2 {need StrtPos in Sub}
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
OpenMP
NewToolOp4 {need StrtPos in Sub}
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2') { WFOStuff }
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END