{Change Comments ***********************************************************}

{6/22/93
Copied & modified: Fanuc 3T MS [-] L007.80
For: IDESSYS

This Post Processor was created by Michel JEAN FRANCOIS at IDESSYS and during transfer
to ABELSYS, the source code was lost. The Form was decompiled, restored and fully tested
as best as possible. The following comments were reported by Daniel Ball of Gibbs & Associates.

Updated to Version 4.0 per Fanuc 10T MS [-] L001.81 Format.
Changed FORMAT #2 from '###.0###' to '###.###;0'.
Changed FORMAT #4 from '###^##0' to '###.###;0'.
Changed FORMAT #5 from '#.######;0.' to '###.####;0.'.
Added FORMAT #7 '0000' for Program#.
Added FirstHomeX#, FirstHomeZ#, HomeX#, HomeZ#, TurretX#, TurretZ#, ToolOffsetZ# and SUB# to
FORMAT #2.
Changed to Metric.
Added GetIndexID sub.
Outputs 'M90' IF LAST Tool# Equals Tool#, 'M91' IF NOT.
Added GetOpToolID sub.
Outputs 'T11' IF Tool# Equals 13, OpToolID IF NOT.
Added GetLOfstOff sub.
Outputs 'T11' IF LAST Tool# Equals 13, OpToolID IF NOT.
Deleted OpToolID LatheOffset from Approach block.
NewToolOffset makes calles to GetLOfstOff, GetIndexID and GetOpToolID at CheckOffset.
Added FirstFeed sub to force FeedRate on FirstFeat of non-Canned Cycle Operation.
Deleted SpinOff, Dwell, Speed and InverseSpinOn for Tapping at ToolPath.
Changed 'G4P' to 'G04X' at ToolPath LastFeat.
Added FirstFeed at ToolPath RapidFeat.
Changed FeedRateC to FirstFeed at ToolPath LineFeat and ArcFeat.
Added XTapAtZ at ToolPath ThreadFeat.
Deleted CheckRapid1 sub.
Changed name of CheckRapid2 sub to CheckRapid.
Changed NegSideLathe to PosSideLathe at setup and initializations
Changed ReverseXZArcs to StandardXZArcs at setup and initializations
Changed SetMaxRPM from 10000 to 3500 at setup and initializations
Changed SetMaxFeed from 500 to 7600 at setup and initializations
Added Comments for PostScript ProgramStop and CoolantOff commands at PostScript Comments.
Added blank line to be output FIRST at FirstOperation
Changed EOR to ':' Program# at FirstOperation.
Changed INCHES to MM at MovesComment at FirstOperation.
Deleted literal '/G28U0' at FirstOperation.
Deleted literal '/G28W0' at FirstOperation.
Changed Rapid Home to Rapid 'X360.' 'Z' SUB# HomeZ# ToolOffsetZ# at FirstOperation.
Changed Rapid 'G99' OpToolId '00' to call to GetIndex sub at FirstOperation.
Added Preset Home at FirstOperation.
Added GetOpToolID LatheOffset at FirstOperation and NewTool.
Added CoolOff at NewTool.
Changed Rapid Home to Preset Home at NewTool.
Added call to GetIndex sub at NewTool.
Changed literal 'R.01' to 'R.5' at CannedCycle RoughContour.
Changed StrtPos to StrtPosC at CannedCycle RoughContour and RoughPatternShift.
Changed literal 'P020560' to 'P021060Q100R100' at CannedCycle Threading SingleEdgeCut AutoFinish.
Changed literal 'P010560' to 'P011060Q100R100' at CannedCycle Threading SingleEdgeCut
Non-AutoFinish.
Changed literal 'P020500' to 'P021000Q100R100' at CannedCycle Threading ConstantVolumeCut
AutoFinish.
Changed literal 'P010500' to 'P011000Q100R100' at CannedCycle Threading ConstantVolumeCut
Non-AutoFinish.
Added condition to output XTapAtZ only IF Taper?=TRUEat CannedCycle Threading.
Deleted AutoFinish for Threading NOT SingleEdgeCut AND NOT ConstantVolumeCut.
Combined all Canned Drilling Cycles into one output.
Will output LCycle Retract IF Retract#<>0.
Deleted SpinOff, Dwell, Speed and SpinOn for Tapping prior to NextOp command.
Moved CoolOff to Home block at end of Prog.
Changed FirstHome to Rapid Home at end of Prog.
Added Preset 'X' First TurretX# 'Z' First TurretZ# at end of Prog
Moved SpinOff to after 'M00' at end of Prog.
Deleted UnTool '00' at end of Prog.
Changed EOP to literal 'M30' at end of Prog.
DWB}

{6/24/93
Modified: Fanuc 3T-J&L L007.80.10m
For: Gibbs & Associates/ABELSYS/Brusselle Marine Industries
Changes made per Beno"t DE Hertogh at Abelsys.
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82.1 Format.
Made major clean-up changes for smoothness and to reduce confusion.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0'
#3 = '#######0'
#4 = '###.###;0'
#5 = '###.####;0.'
#6 = '###0'
#7 = '#'
#8 = '0000'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(SUB#,2)
FORMAT(HomeZ#,2)
FORMAT(TurretX#,2)
FORMAT(TurretZ#,2)
FORMAT(FirstMoveEPX#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(SPX#,2)
FORMAT(SPZ#,2)
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
FORMAT(Program#,8) {.72}

{Added Subroutines *********************************************************}

GetLOfstOff:
IF LAST ToolOver?('12') AND LAST NOT ToolOver?('13')
'T11'
ELSE
LOfstOff
END
RETURN

GetIndexID:
IF LTEqual? LAST Tool# Tool#
'M90'
ELSE
'M91'
END
RETURN

GetOpToolID:
IF ToolOver?('12') AND NOT ToolOver?('13')
'T11'
ELSE
OpToolID
END
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF NOT Metric? {CAM file is in Metric, tools and tool path}
SetScale('25.4') { change to Metric, this is an Metric post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ODApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

IDApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

FaceApproachSP:
SeqLabC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
RETURN

AppMove:
StockOff ZCP CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC StockOff XCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqLabC StockOff XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
FaceApproachSP
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC GetLOfstOff '00' CoolOff EOL
SeqLabC GetIndexID EOL
SeqLabC GetOpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' Speed
END
END
IF LAST ProgStop?
SeqLabC SpeedC SpinOn EOL
SeqLabC CoolOn EOL
ELSE
SeqLabC SpeedC EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling? AND Dwell?
SeqLabC 'G04X' Dwell# EOL
END
IF CannedCycle?
SeqLab
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC
IF Taper?
XTapAtZ
END
ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('3500')
SetMaxFeed('7600')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
' ' EOL
':' Program# EOL
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE MM )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
SeqLab Rapid 'X360.Z' SUB# HomeZ# ToolOffsetZ# EOL
SeqLabC GetIndexID EOL
SeqLabC Preset Home EOL
SeqLabC GetOpToolID LatheOffset EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC XCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC ZCPC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' CalcRPM2 EOL
END
SeqLabC NewHome GetLOfstOff '00' CoolOff EOL
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
SeqLab Preset Home EOL
SeqLabC GetIndexID EOL
SeqLabC GetOpToolID LatheOffset EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
END
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
SeqLabC XCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
END
SeqLabC ZCPC EOL
SeqLabC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn 'G96' Speed EOL
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
'Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE { Special two Line ToolPath, FIRST Line is preparatory }
TagInc
SetPass2
IF RoughContour?
IF ApproachFace? { G72 Rough Face Cutting Cycle }
SeqLabC LCycle CutDepth 'R.5' EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
ELSE { G71 Rough Turn Cutting Cycle }
SeqLabC LCycle CutDepth 'R.5' EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
END
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove 'Z' SPZ# EOL
SeqLabC 'X' SPX# EOL
ELSE
SeqLab StepMove 'X' SPX# EOL
SeqLabC 'Z' SPZ# EOL
END
ELSE
IF RoughPatternShift? { G73 Pattern Repeated Cutting Cycle }
SeqLabC LCycle XminusU ZminusW NumCuts EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
END
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
IF SingleEdgeCut? OR ConstantVolumeCut?
SeqLabC 'G76'
IF AutoFinish?
'P0210'
ELSE
'P0110'
END
IF SingleEdgeCut?
'60' { A60 }
ELSE
'00' { A0 }
END
'Q100R100' EOL
SeqLabC 'G76' XatFinZ FinZ
IF Taper?
XTapAtZ
END
ThrdHeight CutDepth ThrdLead EOL
ELSE
SetPass1
SeqLabC 'G92X' FirstMoveEPX# FinZ ThrdLead EOL
SimpleRough
END
ELSE
IF Drilling?
IF NotEqual? Retract# Num#('0')
SeqLabC LCycle Retract EOL
END
SeqLabC LCycle ZDepth Peck FeedRate EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G04X' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple?
StockOff
IF Turning?
SetPass1
RapidC
IF ApproachFace?
SeqLabC ZOpECPC EOL
FaceApproachSP
ELSE
SeqLabC XOpECDC EOL
IF ApproachOD?
ODApproachSP
ELSE {ApproachID}
IDApproachSP
END
END
ELSE
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
END
SeqLabC StockOff StrtPosC EOL
ToolPath
END
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC XCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC ZCPC EOL
DoEndOpPS
IF ConstantSurfaceFeed?
SeqLabC CSSOff 'G97S' CalcEPRPM# EOL
END
SeqLabC Home OpToolID '00' CoolOff EOL
SetAddToolsF
SeqLabC Preset 'X' First TurretX# 'Z' First TurretZ# EOL
IF ProgStop?
SeqLabC 'M00' EOL
END
SeqLabC SpinOff EOL
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END