{Change Comments ***********************************************************}

{6/5/89, changed tool path to force feed on first TP move after a tool change,added Metric, WFG}
{.62,1/24/90, added OP clearances for v3.2, WFG}

{1/29/90
Modified: Fanuc 10T MS [-] L001.69
Deleted ClearancePlane1# & FirstMoveEPX# prog format, they are not being used.
Deleted extra 4 lines not needed from fall thru if not canned cycle.
Added SetHome command, enables incremental ouput.
Deleted ZeroPosReg command, has no effect.
Jim Radcliffe}

{2/16/90
Modified: Fanuc 10T MS [-] L001.69.1
Added Feedrate to Approach sub.
Deleted FirstFeed sub & changed FirstFeed command to Feedrate in ToolPath.
Jim Radcliffe}

{2/20/90
Modified: Fanuc 10T MS [-] L001.69.2
Deleted extra StockOnNoCan command from Approach sub.
Added missing CheckOffset commands to Sametool.
Added FeedrateC commands to SameTool Feed lines.
Jim Radcliffe}

{3/9/90
Copied & modified: Fanuc 10T MS [-] L001.69.3
For: H&B
Machine: Takasawa
Control: Fanuc 2000C
Added descrimination for front or back turret
Deleted coolant
SpinOff at all index positions
M02 at end of prog.
No decimals, 4 trailing zeros.
Only canned cycles are RoughSimple & Threading.
Jim Radcliffe}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{9/25/90, Update to Version 3.2 per Fanuc 10T MS [-] L001.71.1 Format, DWB}
{10/2/90, Added StockOff globally at FirstOperation, DWB}

{10/18/94
Updated: Fanuc 2000C Taka L138.71.2
For: Gibbs & Associates
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.03/Compost 4.21.22
Changes made per Pete Jackson
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82.1a Format.
DWB}

{12/5/96,
Initial: Fanuc 2000C Taka L138.82.1
Created: Fanuc 2000C Taka L138.82.2
Changed all references to resource #5001 to #4001,
Modified output of spindle speed in CheckOffset, it appears that output of both gear and speed table value
is required, only speed table value was being output,
MPK}

{1/2/97
Initial: Fanuc 2000C Taka L138.82.2
Created: Fanuc 2000C Taka L138.82.3
Develop: ComPost2 PPC v1.0b4, Virtual Gibbs 3.23
Comment: Minor corrections
Corrected NegSide / PosSide setting by moving to the beginning of the tool.
Unconditional X and Z on ToolPath ThreadFeat.
Rapid after ToolPath ThreadFeat.
Jim Radcliffe}

{1/30/97
Initial: Fanuc 2000C Taka L138.82.3
Created: Fanuc 2000C Taka L138.85
ForUser: CIM Solutions / Springfield Mold & Die
Control: Fanuc 2000C
Machine: Takasawa Astroturn Model CNX-540-SD
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.23
Comment: Modified per marked up readout from Dick Smith
Modified non-canned threading:
Changed code from G92 to G32
Changed ThrdLead label and format from F ##^###0 to E ^#####0
Added SpinOff between tools if changing spindle direction.
Updated to .85 format per Fanuc 10T MS [-] L001.85.01.02
Jim Radcliffe}

{1/30/97
Initial: Fanuc 2000C Taka L138.85
Created: Fanuc 2000C Taka L138.85m
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.23
Comment: Created metric version.
Jim Radcliffe}

{3/20/97
Initial: Fanuc 2000C Taka L138.85m
Created: Fanuc 2000C Taka L138.85.1m
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.31 PPC
Comment: At end of program, deleted 'M02' & changed LOfstOff to ToolNumber.
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###^##0'
#3 = '#######0'
#4 = '####^#0'
#5 = '00'
#6 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(FirstMoveEPX#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(ToolLess20#,5)
FORMAT(RapidF#,6)

{Prog Subroutines **********************************************************}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is a Metric post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

ToolNumber:
IF ToolOver?('20')
'T' ToolLess20#
ELSE
OpToolID
END
RETURN

AppMove:
StockOff ThisOpEntryZCP ToolNumber LatheOffset
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF NewGear?
SeqLabC SpinOff EOL
END
IF LAST ProgStop?
SeqLabC 'M00' EOL
END
DoOpComments
DoPostScript
IF NewGear?
SeqLabC GearRange TABLE(4001,Speed,1) SpinOn EOL
ELSE
IF LAST ProgStop?
SeqLabC GearRange TABLE(4001,Speed,1) SpinOn EOL
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC GearRange TABLE(4001,Speed,1) EOL
END
END
END
IF NewToolOffset?
SeqLabC ToolNumber '00' EOL
SeqLabC ToolNumber LatheOffset EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G04P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G04P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC
IF LAST ThreadFeat?
Rapid
ELSE
RapidC
END
MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveX MoveZ ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
IF LAST CannedCycle?
Rapid
ELSE
IF LAST Threading?
Rapid
ELSE
RapidC
END
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
SetMaxRPM('2000')
SetMinRPM('65')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE MILLIMETERS )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
IF ToolOver?('20')
NegSideLathe
ReverseXZArcs
ELSE
PosSideLathe
StandardXZArcs
END
SeqLab Preset Home GearRange TABLE(4001,Speed,1) SpinOn EOL
SeqLabC ToolNumber '00'
IF ToolOver?('20')
'M58'
ELSE
'M57'
END
EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
SeqLabC NewHome
IF LAST ToolOver?('20')
'T' LAST ToolLess20# '00'
ELSE
LOfstOff '00'
END
IF NewGear?
SpinOff
ELSE
IF CWSpindle? AND LAST NOT CWSpindle?
SpinOff
ELSE
IF NOT CWSpindle? AND LAST CWSpindle?
SpinOff
END
END
END
EOL
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
IF ToolOver?('20')
NegSideLathe
ReverseXZArcs
ELSE
PosSideLathe
StandardXZArcs
END
SeqLab Preset Home GearRange TABLE(4001,Speed,1) SpinOn EOL
SeqLabC ToolNumber '00'
IF ToolOver?('20')
'M58'
ELSE
'M57'
END
EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
'Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
IF RoughContour?
StockOn
SetPass1
ToolPath
ELSE
IF RoughPatternShift?
StockOn
SetPass1
ToolPath
END
END
IF AutoFinish?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
END
END
ELSE
IF Threading?
SeqLabC LCycle 'X' FirstMoveEPX# FinZ ThrdLead EOL
SimpleRough
IF AutoFinish?
SeqLabC XatFinZ EOL
END
ELSE
IF Drilling?
StockOn
SetPass1
ToolPath
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G32' XatFinZ FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G04P2000' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
IF CannedCycle?
Rapid
ELSE
IF Threading?
Rapid
ELSE
RapidC
END
END
IF ApproachOD?
SeqLabC XCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC ZCPC EOL
DoEndOpPS
SeqLabC FirstHome ToolNumber '00' SpinOff EOL
IF ProgStop?
SeqLabC 'M00' EOL
END
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END