{Change Comments ***********************************************************}

{9/12/95, M233.79, Updated for Catalyst v2.20 per Fanuc 6M M001.85 Format, DWB}
{1/17/96 - Updated .85 to .86 format, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{9/26/96, created advanced mill version, per BP Boss 9 D174.11
*******WARNING*******, this post dies not support multiple parts, OTAP, full up. The customer did not require
this feature.}

{4/15/97,
Initial: BP Boss 8 D233.13
Created: BP Boss 8 Dxxx.13
For: Stonewill Plastics
Made output of G2/G3, XY pos, IJK, and R values all uncondition for arcs, MPK}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '###^#0'
#7 = '#####.##;0.'
#8 = '*#####.##;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(CSOffsetX#,4)
FORMAT(CSOffsetY#,4)
FORMAT(CSOffsetZ#,4)
FORMAT(TrackZNO#,4)
FORMAT(Tag#,5)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(ADD#,5)
FORMAT(CS#,5)
FORMAT(Parts#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Dwell#,6)
FORMAT(CSOffsetA#,8)
FORMAT(CSOffsetB#,8)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
ASCII('39') 'SUB NUMBER: ' Program# ASCII('39') EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
ASCII('39') 'OPERATION ' Operation# ': ' OperationType$ ASCII('39') EOL
END
IF OperationComment?
ASCII('39') OperationComment$ EOL
END
IF WorkGroupComment?
ASCII('39') WorkGroupComment$ ASCII('39') EOL
END
IF ToolTypeComment?
ASCII('39') 'TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ EOL
END
IF ToolComment?
ASCII('39') ToolComment$ EOL
END
RestoreScale
END
RETURN

CSWFO:
'G' ADD# CS# SUB# NewWFO# Num#('1')
RETURN

CalcCSWFO: {(iPart-1)*NumOfCS#)}
'G' ADD# MUL# NumOfCS# SUB# PartNum# Num#('1') ADD# CS# SUB# NewWFO# Num#('1')
RETURN

CSAngleA:
IF AAxisAvail?
'A' CSOffsetA#
END
RETURN

CSAngleAC:
IF AChange?
CSAngleA
END
RETURN

CSAngleB:
IF BAxisAvail?
'B' CSOffsetB#
END
RETURN

CSAngleBC:
IF BChange?
CSAngleB
END
RETURN

DoCSWFOComment:
'( CS#' CS# ' - ' CSComment$ ' )' EOL
'( ' CalcCSWFO '= X' CSOffsetX# ' Y' CSOffsetY# ' Z' CSOffsetZ# ' )' EOL
RETURN

DoCSG97Comment:
'( CS#' CS# ' - ' CSComment$ ' )' EOL
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
SeqLabC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
'#' Program# EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
RETURN

StdSub:
TagUp TagInc
SeqLabC '=N²' Tag# RepLab RepCycs EOL
{StartSub}
RETURN

GetStartPos:
IF CutterRadiusCompensation? AND NOT AutoCycle?
BPCRCStartPos
ELSE
StrtPos
END
RETURN

GetEndPos:
IF CutterRadiusCompensation?
CRCOffC BPCRCEndPos
END
RETURN

FinishSub1: {part 1}
SeqLabC
IF FeedConnect?
IF CutterRadiusCompensation? AND NOT AutoCycle?
RapidC GetEndPos
END
ELSE
IF AutoCycle?
ZCP3C
ELSE
IF CutterRadiusCompensation?
RapidC GetEndPos ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqLab Preset ShiftRC EOL
'<' Tag# EOL
TagDown
{CloseSub}
SeqLabC Preset UnshftRC EOL
RETURN

ToggleIncDecWFO:
IF Flag?('3')
SetFlagF('3')
ELSE
SetFlag('3')
END
RETURN

OpenMP:
IF WFOCS? OR Flag?('2')
NewProg
StartSub
SaveCSProg
SaveCSOpStart
ClearCSOffset
ELSE
IF EquallySpacedOffsets?
TagUp TagInc
SeqLabC '=N²' Tag# RepLab Parts EOL
{StartSub}
ELSE
' ' EOL
' ( Note - Post does not support MultipleParts with WorkFixtureOffsets. )' EOL
' ( Please change to EquallySpacedOffsets. )' EOL
' ' EOL
END
END
RETURN

CloseMP:
IF WFOCS? OR Flag?('2')
SeqLabC EndSub EOL
CloseSub
IF Flag?('3')
NewWFO
EachWFO {simple eachPart}
IF Flag?('2')
SeqLabC SetWFO EOL
EachCSOp
DoCSG97Comment
ClearCSOffset
SeqLabC 'G97X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ# EOL
SeqLabC SubCall CallLabB CSSubID# RepLab OnePart EOL
NextCSOp
ELSE
EachCSOp
DoCSWFOComment
ClearCSOffset
SeqLabC CalcCSWFO EOL
SeqLabC SubCall CallLabB CSSubID# RepLab OnePart EOL
NextCSOp
END
ClearCSOffset
IncWFO
NextWFO {simple NextPart}
ELSE
LastWFO
EachWFO {simple eachPart}
IF Flag?('2')
SeqLabC SetWFO EOL
EachCSOp
DoCSG97Comment
ClearCSOffset
SeqLabC 'G97X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ# EOL
SeqLabC SubCall CallLabB CSSubID# RepLab OnePart EOL
NextCSOp
ELSE
EachCSOp
DoCSWFOComment
ClearCSOffset
SeqLabC CalcCSWFO EOL
SeqLabC SubCall CallLabB CSSubID# RepLab OnePart EOL
NextCSOp
END
ClearCSOffset
DecWFO
NextPrevWFO {simple NextPart}
END
IF Flag?('4')
ToggleIncDecWFO
END
ELSE
IF EquallySpacedOffsets?
SeqLab Preset ShiftPC EOL
'<' Tag# EOL
TagDown
{CloseSub}
SeqLabC Preset UnshftPC EOL
END
END
RETURN

SubCSMP:
IF WFOCS?
IF ChangeCS?
SeqLabC EndSub EOL
CloseSub
NewProg
StartSub
SaveCSProg
END
ClearCSOffset
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLabC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArc
ELSE
CCWArc
END
MoveXY MoveZC
IF ArcIJFormat?
ArcIJ
ELSE
ArcR
END
RETURN

CkCRC:
{ This is a Bridgeport, CRC handled outside of ToolPath. }
RETURN

FormatLine:
DoAbsOrInc CkCRC FeedC MoveXYZC
RETURN

ckCRCNum:
{ Not supported }
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC EOL
SeqLabC '=#' Program# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLabC DoDrillAbsOrInc MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqLabC DoAbsOrInc ckCRC RapidC MoveXYZC EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate? AND NOT CutterRadiusCompensation?
IF RoomToDecel?
DecelMove1
SeqLabC FormatLine FeedRateC EOL
DecelMove2
END
SeqLabC FormatLine DecelFeed EOL
ELSE
SeqLabC FormatLine FeedRateC EOL
END
END
ELSE
IF ArcFeat?
IF NOT XYPlane?
SeqLabC Plane EOL
END
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLabC IncValue EOL
IF CutterRadiusCompensation?
SeqLabC RapidC BPCRCStartPos EOL
SeqLabC FeedC CRCOn StrtPos FeedRateC EOL
END
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqLabC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
IF CutterRadiusCompensation?
RapidC GetEndPos
END
ELSE
IF CutterRadiusCompensation?
RapidC GetEndPos ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
END
EOL
'$' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
IF CutterRadiusCompensation?
SeqLabC FeedC CRCOn StrtPos FeedRate EOL
END
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLabC Connect GetStartPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
NewProg
AutoCycPat {write pattern moves and main calls}
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC Feed IncValue StrtPosC EOL
SeqLabC AbsOrInc
ELSE
SeqLabC Feed
END
ELSE
SeqLabC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqLabC AbsOrInc ZCP2PlusInc EOL
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqLabC Rapid ZCP2PlusInc EOL
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLabC '=#' Program# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqLabC Feed ZCP2 FeedEnt EOL
ELSE
SeqLabC Rapid ZCP2 EOL
END
END
TagDown
'$' EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
NewProg
EachCycle
IF NOT FirstCycle?
SeqLabC Connect GetStartPos EOL
END
IF CutterRadiusCompensation?
SeqLabC FeedC CRCOn StrtPos FeedRate EOL
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC ZInPlusInc EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqLabC '=#' Program# EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
TagDown
'$' EOL
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

ProgStart:
InitProg
TagInit
ReverseYZArcs
InitWFONum
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END

IF MultipleParts?
IF WorkFixtureOffsets?
IF LTEqual? MUL# Parts# NumOfCS# Num#('0')
SetWFOCS { use WFO for CS changes }
ELSE
SetFlag('2')
END
END
ELSE
IF LTEqual? NumOfCS# Num#('0') {****}
SetWFOCS { use WFO for CS changes }
ELSE
SetFlag('2')
END
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF Milling?
SeqLabC ZCP2C EOL
IF Repeats?
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
SeqLabC CRCOffC
IF NOT EmptyLine?
RapidC GetEndPos ZCP3C
ELSE
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
END
ELSE
IF Drilling?
IF Repeats?
TagUp TagInc
StdSub
SeqLabC AbsOrInc Rapid StrtPos EOL
END
SeqLabC ZCP2C EOL
GetCycle
IF Dwell?
SeqLabC 'G04/' Dwell# EOL
END
SeqLabC Cycle StrtPos ZDepthAbs Peck Retract FeedEnt EOL
IF CallMasterOp?
SeqLabC '=#' CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqLabC '=#' Program# EOL
StartSub
ToolPath
'$' EOL
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqLabC 'G80' EOL
SeqLabC Rapid ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
RETURN

DefaultWFO:
IF NOT SameTool?
IF NeedWFO1?
SeqC WFO1 EOL
END
END
RETURN

DoCSG97:
DoCSG97Comment
SeqC 'G97X' CSOffsetX# 'Y' CSOffsetY# 'Z' CSOffsetZ# EOL
RETURN

DefaultCSG97:
IF NOT SameTool?
DoCSG97
END
RETURN

DefaultCSWFO:
IF NOT SameTool?
SeqC CSWFO EOL
END
RETURN

WFOStuff:
IF MultipleParts?
{IF NOT WorkFixtureOffsets?
DefaultWFO
END}
ELSE
IF WFOCS?
IF ChangeCS?
DoCSWFOComment
SeqC CSWFO EOL
ELSE
DefaultCSWFO
END
ELSE
IF ChangeCS?
DoCSG97
ELSE
DefaultCSG97
END
END
ClearCSOffset
END
RETURN

InitOp:
ProgID1 EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
ASCII('39') 'PROGRAM: ' ProgramName$ ASCII('39') EOL
END
IF ProgramComment?
ASCII('39') ProgramComment$ ASCII('39') EOL
END
IF FormatNameComment?
ASCII('39') 'FORMAT: ' FormatName$ ASCII('39') EOL
END
IF TimeComment?
ASCII('39') Date$ ' AT ' Time$ ASCII('39') EOL
END
IF MovesComment?
ASCII('39') 'OUTPUT IN ' MoveType$ ' INCHES' ASCII('39') EOL
END
IF PartsComment?
ASCII('39') 'PARTS PROGRAMMED: ' Parts# ASCII('39') EOL
END
IF StartToolComment?
ASCII('39') 'FIRST TOOL NOT IN SPINDLE' ASCII('39') EOL
END
END
OpenSub
RestoreScale
SeqLab Plane 'G80' AbsValue EOL
RETURN

FirstOp1:
DoOpComments
SeqLabC Rapid WFO1 Home OpToolID ToolChng EOL
SeqLabC Speed EOL
RETURN

FirstOp2:
RETURN

FirstOp3:
DoPostScript
CheckPass
SeqLabC RapidC GetStartPos ZCP1 CSAngleA CSAngleB EOL
RETURN

FirstOp4:
SeqC CoolOn EOL
RETURN

NewToolOp1:
DoEndOpPS
RETURN

NewToolOp2:
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
DoOpComments
SeqLab Rapid PlaneC WFO1 Home OpToolID ToolChng EOL
SeqLabC Speed EOL
RETURN

NewToolOp4:
RETURN

NewToolOp5:
DoPostScript
CheckPass
SeqLabC RapidC GetStartPos ZCP1 CSAngleA CSAngleB EOL
RETURN

NewToolOp6:
SeqC CoolOn EOL
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
SeqLabC ProgStop EOL
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
IF LAST ProgStop?
SeqLabC Rapid PlaneC GetStartPos ZCP1 CSAngleA CSAngleB EOL
SeqC CoolOn EOL
ELSE
SeqLabC Rapid PlaneC GetStartPos ZCP1 CSAngleA CSAngleB EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
RETURN

End1:
DoEndOpPS
RETURN

End2:
SeqLabC AbsOrInc Rapid WFO1
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
FirstHome
END
EOL
IF NOT Equal? CSOffsetA# Num#('0') OR NOT Equal? CSOffsetB# Num#('0')
IF AAxisAvail?
SeqLabC CSAngleA
END
IF BAxisAvail?
SeqLabC CSAngleB
END
EOL

SeqLabC 'G92'
IF AAxisAvail?
'A0'
END
IF BAxisAvail?
'B0'
END
EOL
END
IF ProgStop?
'M00' EOL
SeqLabC
END
RETURN

End3:
EOP EOL
CloseSub
Post2 {organize Subs into one program}
ASCII('19') EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
ASCII('39') 'FILE LENGTH: ' FileBytes# ' CHARACTERS' ASCII('39') EOL
END
IF FileFeetComment?
ASCII('39') 'FILE LENGTH: ' FileFeet# ' FEET' ASCII('39') EOL
END
IF FileMetersComment?
ASCII('39') 'FILE LENGTH: ' FileMeters# ' METERS' ASCII('39') EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
OpenMP
FirstOp1
WFOStuff
FirstOp2
FirstOp3
FirstOp4
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
SubCSMP
NewToolOp3
WFOStuff
NewToolOp4
NewToolOp5
NewToolOp6
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
WFOStuff
FirstOp2
OpenMP
FirstOp3
FirstOp4
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
WFOStuff
NewToolOp4
OpenMP
NewToolOp5
NewToolOp6
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
WFOStuff
FirstOp2
FirstOp4
OpenMP
FirstOp3 {can't XY position before WFO}
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
WFOStuff
NewToolOp4
NewToolOp6
OpenMP
NewToolOp5 {can't XY position before WFO}
ELSE {implied SameTool?}
SameToolOp1
SubCSMP
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
IF FirstOperation?
InitOp
FirstOp1
WFOStuff
FirstOp2
FirstOp3
FirstOp4
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
WFOStuff
NewToolOp4
NewToolOp5
NewToolOp6
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
WFOStuff
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END