{
MILL=T
LATHE=F
SIMPLE_ROT_POS=F
ROTARY_MILL=F
ADV_MILL=F
SUBS=T
MILLTURN_Y-AXIS=F
METRIC=F
}

{from M001.57, 4/16/89 by WFG}
{requested changes, 6/4/89, WFG}
{added PostScript commands}
{added PostScript command comments, use ncPost 3.10Ś9 or better}
{removed run time comments}
{added "must be all capital letters when typed in" to Postscript Command comment}
{added metric, 6/25/89, WFG}
{added Drill Surf and depth commands}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{7/24/90, Deleted SetZSurf command at start of prog, DWB}

{8/30/90, Updated: Maho CNC 432 M194.57 to .76.1 format, JR}

{8/30/90
Copied & modifed: Maho CNC 432 M194.76.1
For: NIST
Machine is a horizontal Maho with a vertical head.
Changed: ' Z' ClearancePlane1# to ZCP1
Deleted: 'F1=1'
Deleted: 'B0'
Deleted: PreTool
Changed: '%MM' to ASCII('04')
Changed:
G17 to G18
G18 to G17
Z to Y
K to J
Y to Z and change sign
J to K and change sign
Jim Radcliffe}

{4/2/91
Modified: Maho (NIST) M338.76.1
For: NIST
Changed signs for X,Z,I & K values.
Drilling problems fixed by switching labels Z & Y, changing sign on CalcCP2FmSurf#.
Changed to "Format 1" looping for MPs & Repeats program calls.
Deleted "' Y0. T0 M67'" lines, it does not send the tool full up. No known way to do a full up without an M6 command.
Updated to .80 format.
Jim Radcliffe}

{9/28/95, Updated Maho (NIST) M338.80 to .85 format per Maho CNC 432 M194.85, JR}

{1/17/96, Updated .85 to .86 version, MPK}

{3/25/96, Updated .86 to .89 version, TH}

{7/9/96,
Initial: Maho (NIST) M338.85
Created: Maho [LANL] M061.89
For: Los Alamos Nat'l Labs
Made output of I , J, and R unconditional, MPK}

{12/14/98,
Initial : Maho [LANL] M061.89
Created: Maho [LANL] M061.89.1
Customer: Los Alamos Nat'l Labs, George Harper 505/667-4852
ComPost2: v1.7b13

Changes to "Form":

1. Under Drill Cycles, changed Peck-Partial Retract cycle Ret Label from K to J

Changes to "Prog":

1. Added Post Header Comment.
2. Added FORMAT for TrackZNO#.
3. Added SetMaxFeed for Inch and Metric.
4. Removed 'K0' from PeckFullRetract cycle.
JHE}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '#######0'
#3 = '###.####;0.'
#4 = '###.#;0.'
#5 = '###.###;0.'
#6 = '*###.###;0.'
#7 = '*###.####;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(Program#,2)
FORMAT(CallMasterNum#,2)
FORMAT(Operation#,2)
FORMAT(Tool#,2)
FORMAT(NewWFO#,2)
FORMAT(Parts#,2)
FORMAT(PartShiftY#,3) {changed sign 4/2/91}
FORMAT(PartShiftZ#,3)
FORMAT(RepeatY#,3) {changed sign 4/2/91}
FORMAT(RepeatZ#,3)
FORMAT(CalcZSurf#,3)
FORMAT(CP1LessCP2#,3)
FORMAT(CalcZFmSurf#,3)
FORMAT(CalcCP2FmSurf#,3) {changed sign 4/2/91}
FORMAT(ToolDiameter#,3)
FORMAT(TrackZNO#,3) {Added - JHE}
FORMAT(Dwell#,4)
FORMAT(PartShiftX#,7) {changed sign 4/2/91}
FORMAT(RepeatX#,7) {changed sign 4/2/91}

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
SeqLab '( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLab '( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
SeqLab '( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
SeqLab '( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
SeqLab '( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
SeqLab '( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,5)
SeqLab ' A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,6)
SeqLab ' A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,5)
SeqLab ' B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,6)
SeqLab ' B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLab PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLab Feed ZIn FeedEnt EOL
ELSE
SeqLab RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
'N9' Program# EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
SeqLab ' ' EOL
SeqLab '( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
SeqLab ' ' EOL
END
END
RETURN

StdSub:
TagInc
'>' Tag# EOL
SeqLab ' G22 N=9' Program# EOL
SeqLab ' G14' ' J' RepsLess1 ' N1=ł' Tag# ' N2=ł' Tag# EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqLab CRCOffC EOL
SeqLab
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqLab ' G92 X' RepeatX# ' Z' RepeatY# ' Y' RepeatZ# EOL
CloseSub
SeqLab ' G93 X0 Y0 Z0' EOL
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqLab SetWFO EOL
SeqLab ' G22 N=9' Program# EOL
IncWFO
NextWFO
ELSE
TagInc
'>' Tag# EOL
SeqLab ' G22 N=9' Program# EOL
SeqLab ' G14' ' J' PartsLess1 ' N1=ł' Tag# ' N2=ł' Tag# EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
CloseSub
SeqLab WFO1 EOL
ELSE
SeqLab ' G92 X' PartShiftX# ' Z' PartShiftY# ' Y' PartShiftZ# EOL
CloseSub
SeqLab ' G93 X0 Y0 Z0' EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLab AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJ
ELSE
ArcR
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
DecelMove2
END
SeqLab DoAbsOrInc CRCOnC FeedC MoveXYZC DecelFeed CRCOffsetC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLab DoAbsOrInc CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
END
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLab MoveSXYC EOL
SeqLab ' G22 N=9' Program# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqLab DoDrillAbsOrInc ' G79' MoveSXYC
IF FirstFeat?
' Y' CalcZSurf#
END
EOL
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqLab DoAbsOrInc CRCOffC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLab DoAbsOrInc RapidC MoveXYZC EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqLab DoAbsOrInc CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLab FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab FormatArc ArcFeedC EOL
DecelMove2
END
SeqLab FormatArc DecelFeed EOL
ELSE
SeqLab FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS'
ELSE
' G' NewWFO#
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
WFO1
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLab IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqLab AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLab Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat
StartSub
NewProg
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLab Feed IncValue StrtPosC EOL
SeqLab AbsOrInc
ELSE
SeqLab Feed
END
ELSE
SeqLab Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLab Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqLab AbsOrInc ZCP2PlusInc EOL
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqLab Rapid ZCP2PlusInc EOL
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLab ' G22 N=9' Program# EOL
NextCycle
SetStatusOn
AutoCycCutSub1
AutoCycCutSub2
IF FeedConnect?
IF FIFO? {.81}
SeqLab Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqLab Rapid ZCP2 EOL {.69}
END
END
CloseSub
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLab Connect StrtPos EOL
END
IF FeedConnect?
SeqLab FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLab RapidC ZCP2PlusIncC EOL
END
SeqLab Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLab RapidC ZInPlusInc EOL
END
END
SeqLab ' G22 N=9' Program# EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
SeqLab WFOStuff EOL
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
UseSeparateSubCalls
IF Metric? {Added - JHE}
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
SetMaxSeparateSubCalls ('50')
SetFlagF('1') { Milling ZShiftOnly SepSubs }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals : put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
' SetZSurf(-.05)' EOL
' This is a non-modal command affecting the current operation only.' EOL
' The value in ( ) establishes the Z surface position incrementally' EOL
' from clearance plane #2. For example, if clearance plane #2 equals' EOL
' Z.1 and SetZSurf(-.05) is given for that operation, the Z top surface' EOL
' will be Z.05. This command only effects drilling operations. If SetZSurf()' EOL
' is not given, the default value is Z-.1 or .100 below the value given for' EOL
' Clearance Plane #2. Use this command before ENDOP for any given operation.' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
'START' EOL
'%PM' EOL
'N9' Program# EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
SeqLab '( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
SeqLab '( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
SeqLab '( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
SeqLab '( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
SeqLab '( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
SeqLab '( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
SeqLab '( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub

RestoreScale

IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
SeqLab AbsOrInc EOL
DoOpComments
SeqLab Plane Speed OpToolID ToolChng EOL
DoPostScript
CheckPass
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqLab WFOStuff SpinOn EOL
OpenMP
SeqLab Rapid StrtPos EOL
ELSE
SeqLab WFOStuff StrtPos ZCP1 SpinOn EOL
END
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
DoOpComments
IF ToolChangeAtHome?
SeqLab Rapid Home Speed OpToolID ToolChng EOL
ELSE
SeqLab Speed OpToolID ToolChng EOL
END
SeqLab PlaneC
IF LAST ProgStop?
' M0' EOL
ELSE
ProgStop EOL
END

{Start new Operation}

DoPostScript
SeqLab WFOStuff EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab RapidC StrtPos ZCP1 EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLab SpinOff EOL
SeqLab ' M0' EOL

{Start new Operation}

GetStartOfSameTool
SeqLab PlaneC EOL
SeqLab Rapid StrtPos SpeedC SpinOn EOL
SeqLab ZCP1 EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqLab PlaneC EOL
SeqLab Rapid StrtPos SpeedC EOL
END
END
END
END {common point for all operations}
IF Milling?
SeqLab ZCP2C EOL
IF Repeats?
NewProg
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
SeqLab CRCOffC EOL
IF AutoCycle?
SeqLab ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqLab FeedC ZCP3C FeedEntC EOL
ELSE
SeqLab RapidC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
StdSub
SeqLab Rapid StrtPos EOL
END
SeqLab DrillCP EOL
GetCycle
SeqLab Cycle
IF Dwell?
' X' Dwell#
END
' Y' CalcCP2FmSurf#
IF RetractToCP1?
' B' CP1LessCP2#
END
' Z' CalcZFmSurf#
IF PeckChipBreaker?
Peck Retract
ELSE
IF PeckFullRetract?
Peck {' K0'} {Removed K0 - JHE}
END
END

FeedEnt EOL
IF CallMasterOp?
SeqLab ' G22 N=9' CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
SetFlag('1') {std sep sub Zreps in effect}
NewMasterProg
SeqLab ' G22 N=9' Program# EOL
StartSub
ToolPath
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
ELSE
ToolPath
END
END
SetDrillEndOpZ
SeqLab RapidC ZCP3C EOL
IF Repeats?
FinishSubG92
END
SeqLab RapidC ZCP3C EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqLab RapidC FirstHome SpinOff EOL
ELSE
SeqLab SpinOff EOL
END
IF ProgStop?
SeqLab ' M0' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLab EOP EOL
ASCII('04') EOL
Post
{'%TM' EOL}
{'%ZO' EOL}
Close
Retag
IF UseComments?
SetScale('1')
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END