{Change Comments ***********************************************************}

{7/31/91,
Copied & modified: Fanuc 10T MS [-] L001.81
For: SAC. Tool & Die Shop, Inc
Machine: Miyano JNC-60
Control: Fanuc 10T E-Control.
Added PulseCoolant On/Off logic for High Pressure Coolant.
'M28/M29' controls Coolant flow through the Turret.
Added TurnOn Call in Approach from Home and CheckOffset sub.
Added TurnOff Call at CheckOffset sub, NewTool and at end of Prog.
Changed all occurances of LatheOffset to ToolOffset#.
Added logic for CW 8-position Turret Indexing.
Added subroutine for Bar Puller.
Output logic differs from the norm.
Changed ReverseXZArcs to StandardXZArcs.
Changed NegSideLathe to PosSideLathe.
Deleted Preset Home in FirstOperation and NewTool.
Modified to output G96 CSSOn at ToolChng position in FirstOperation and NewTool.
Added literal 'M25' at end of Prog to inform control when to stop at end of bar stock.
DWB}

{8/6/91
Updated: Fanuc 10T Miyano JNC-60 L228.81
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.82 Format.
KM}

{4/9/92
Updated: Fanuc 10T Miyano JNC-60 L228.82
For: SAC. Tool & Die Shop, Inc
Changes made per conversations with Jeff Cogshaw at SAC and sample printout.
Added RestoreScale Sub.
Added FORMAT for RapidF#.
Eliminated Karate Approach and Exit Moves.
ApproachOD:
IF XOpCD > XCP THEN XOpCD ZSP ELSE XCP ZSP { NOT ZCP }
XOpCDC
IF XOpCD ­ XSP THEN XSP ELSE RapidF# { To Force FeedRate in ToolPath }
ApproachID:
XOpCD ZCP
ZSPC
IF XOpCD ­ XSP THEN XSP ELSE RapidF# { To Force FeedRate in ToolPath }
ApproachFace:
IF ZOpCP > ZCP THEN XSP ZOpCP ELSE XSP ZCP
ZOpCPC
IF ZOpCP ­ ZSP THEN ZSP ELSE RapidF# { To Force FeedRate in ToolPath }
Exit to Home is normal for ApproachID and ApproachFace but ApproachOD does not go to ZCPC.
Simplified CheckIndex Sub.
Variable Num#('1') calculates and stores the difference between LAST Tool# and Current Tool#.
DoIndex sub checks calculation and outputs 'M16' when needed.
Deleted CheckLastOpIndex Sub.
Didn't want to do UnTool at end.
Modified DoBarPuller Sub.
Moved DoEndOpPS Call at NewTool and end of Prog.
Jeff used literals to move Tailstock and PartsCatcher In/Out and needed them after move to Home.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.####;0'
#6 = '00'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(TrackX#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(ClearancePlane3#,2)
FORMAT(SUB#,3)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(ADD#,5)
FORMAT(FeedIPR#,5)
FORMAT(ToolOffset#,6)
FORMAT(RapidF#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

CheckCoolOn:
IF Pulse?
'M28' { High Pressure Coolant On }
SetFlag('1')
ELSE
CoolOn
END
RETURN

CheckCoolOff:
IF Flood? and Flag?('1')
SeqLabC 'M29' EOL { High Pressure Coolant Off }
SetFlagF('1')
END
IF Pulse? and NOT Flag?('1')
CoolOff
END
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

GetFeedRate:
IF FirstOperation? OR NewTool?
FeedRate
ELSE
FeedRateC
END
RETURN

SetFeedRate:
IF FirstOperation? OR NewTool?
RapidF#
END
RETURN

ODApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC Feed XSPC GetFeedRate EOL
ELSE
SetFeedRate
END
RETURN

IDApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC Feed XSPC GetFeedRate EOL
ELSE
SetFeedRate
END
RETURN

FaceApproachSP:
SeqLabC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC Feed ZSPC GetFeedRate EOL
ELSE
SetFeedRate
END
RETURN

AppMove:
OpToolID ToolOffset# CheckCoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
IF ApproachOD?
SeqLabC Rapid XCP ZSP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqLabC Rapid XOpCD ZCP AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqLabC Rapid StockOnNoCan XSP StockOff
IF GreaterThan? CycleStartZ# ZStockMax#
ZSP
ELSE
IF GreaterThan? ZOpCP# ZStockMax#
ZOpCP
ELSE
ZCP
END
END
AppMove EOL
FaceApproachSP
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CheckCoolOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' Speed
END
END
IF LAST ProgStop?
SeqLabC SpeedC SpinOn EOL
SeqLabC CheckCoolOn EOL
ELSE
SeqLabC SpeedC EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CheckCoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

DoIndex:
IF LTEqual? Recall# Num#('1') Num#('-5')
IF GTEqual? Recall# Num#('1') Num#('-7')
'M16' { ClockWise Turret Index }
END
ELSE
IF LTEqual? Recall# Num#('1') Num#('3')
IF GTEqual? Recall# Num#('1') Num#('1')
'M16' { ClockWise Turret Index }
END
END
END
RETURN

CheckIndex: { 8 Turret Station }
IF NOT FirstOperation? { Cannot compare against FINAL Tool# }
IF ToolOver?('20') AND NOT ToolOver?('28') { Special BarPuller Routine }
Save# Num#('1') SUB# LAST Tool# SUB# Tool# Num#('20')
DoIndex
ELSE
IF LAST ToolOver?('20') AND LAST NOT ToolOver?('28') { Special BarPuller Routine }
Save# Num#('1') SUB# SUB# LAST Tool# Num#('20') Tool#
DoIndex
ELSE
Save# Num#('1') SUB# LAST Tool# Tool#
DoIndex
END
END
END
RETURN

DoBarPuller:
SeqLab 'T' SUB# Tool# Num#('20') '00' CheckIndex EOL
SeqLabC Rapid XCP StockOnNoCan ZSP EOL
SeqLabC 'X' TrackX# Num#('0') EOL
SeqLabC 'M17' EOL { ChuckOpen }
SeqLabC 'G4P400' EOL { Dwell .4 seconds }
SetInc
SeqLabC 'W' ClearancePlane3# 'T' SUB# Tool# Num#('20') ToolOffset# EOL
SetAbs
SeqLabC 'M18' EOL { ChuckClose }
SeqLabC 'G4P300' EOL { Dwell .3 seconds }
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' PULSECOOLANT, PCOOL -' EOL
' Will output M28 for turning on High Pressure Coolant.' EOL
' Every ToolChange operation afterwords, will output M28, until the FLOODCOOLANT' EOL
' PostScript command has been issued.' EOL
' FLOODCOOLANT, FCOOL -' EOL
' Will output M29 for turning off High Pressure Coolant.' EOL
' Every ToolChange operation afterwords, will output M8, until the PULSECOOLANT' EOL
' PostScript command has been issued.' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
IF ToolOver?('20') AND NOT ToolOver?('28') { Special BarPuller Routine }
DoBarPuller
ELSE
SeqLab OpToolID '00' CheckIndex EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
CSSOn 'G96'
ELSE
CSSOff 'G97'
END
SeqLabC Speed SpinOn EOL
Approach
END
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
SetTTOff
IF LAST ToolOver?('20') AND LAST NOT ToolOver?('28') { Special BarPuller Routine }
LoadFeat ZStockMax# XStockMax#
IF XMove?
SeqLabC SETLASTOP MoveX EOL
END
{ No MoveZ here! }
ELSE
IF LAST ApproachOD?
LoadFeat ZStockMax# XStockMax#
IF XMove?
SeqLabC SETLASTOP MoveX EOL
END
{ No MoveZ here! }
ELSE
IF LAST ApproachID?
LoadFeat ZStockMax# LAST ClearancePlane3#
IF XMove?
SeqLabC SetTTOk SETLASTOP MoveX EOL
END
IF ZMove?
SeqLabC SetTTOff SETLASTOP MoveZ EOL
END
ELSE { LAST AppproachFace }
LoadFeat ZStockMax# XStockMax#
IF ZMove?
SeqLabC SETLASTOP MoveZ EOL
END
END
END
END
SetTTOk
IF ToolOver?('20') AND NOT ToolOver?('28') { Special BarPuller Routine }
SeqLabC NewHome SpinOff EOL
DoEndOpPS
SeqLabC CoolOff EOL
ELSE
SeqLabC NewHome DoEndOpPS EOL
END
SeqLabC CheckCoolOff EOL
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
IF ToolOver?('20') AND NOT ToolOver?('28') { Special BarPuller Routine }
DoBarPuller
ELSE
SeqLab OpToolID '00' CheckIndex EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
CSSOn 'G96'
ELSE
CSSOff 'G97'
END
SeqLabC Speed SpinOn EOL
Approach
END
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
SeqLabC XCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
END
SeqLabC ZCPC EOL
SeqLabC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF ToolOver?('20') AND NOT ToolOver?('28') { Special BarPuller Routine }
ELSE
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
IF ApproachFace?
SeqLabC LCycle 'Z' FirstMoveEPZ# XatFinZ XTapAtZ FeedRate EOL
ELSE
SeqLabC LCycle XatFinZ FinZ XTapAtZ FeedRate EOL
END
SimpleRough
ELSE
TagInc
IF RoughContour?
SetPass2
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft CutDepth FeedRate EOL
'>' Tag# EOL
SeqLab StepMove StrtPos EOL
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
ELSE
IF RoughPatternShift?
SetPass2
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft XminusU ZminusW NumCuts FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
END
END
END
ELSE
IF Threading?
IF Chamfer?
SeqLabC 'M23' EOL
END
SeqLabC LCycle XatFinZ FinZ
IF Taper?
XTapAtZ
END
ThrdHeight CutDepth ThrdLead ToolAngle CutMethod EOL
IF AutoFinish?
SeqLabC 'G92' XatFinZ FinZ
IF Taper?
XTapAtZ
END
ThrdLead EOL
END
IF Chamfer?
SeqLabC 'M24' EOL
END
TrackXNO# SPX#
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'F' FeedIPR# EOL
SeqLabC Feed ZSP 'F' ADD# FeedIPR# Num#('.001') InverseSpinOn EOL
TrackZNO# SPZ#
ELSE
IF PeckChipBreaker?
SeqLabC LCycle ZDepth Dwell Peck Retract FeedRate EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
TrackZNO# SPZ#
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple?
StockOff
IF Turning?
SetPass1
ELSE
SetPass2
END
SeqLabC RapidC StrtPos EOL
ToolPath
END
END
END
IF Drilling? AND Tap? AND NOT CannedCycle?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed SpinOn EOL
END
END { Special BarPuller Routine }
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
IF CannedCycle?
Rapid
ELSE
RapidC
END
SetTTOff
IF ToolOver?('20') AND NOT ToolOver?('28') { Special BarPuller Routine }
LoadFeat ZStockMax# XStockMax#
IF XMove?
SeqLabC MoveX EOL
END
{ No MoveZ here! }
ELSE
IF ApproachOD?
LoadFeat ZStockMax# XStockMax#
IF XMove?
SeqLabC MoveX EOL
END
{ No MoveZ here! }
ELSE
IF ApproachID?
LoadFeat ZStockMax# ClearancePlane3#
IF XMove?
SeqLabC SetTTOk MoveX EOL
END
IF ZMove?
SeqLabC SetTTOff MoveZ EOL
END
ELSE { AppproachFace }
LoadFeat ZStockMax# XStockMax#
IF ZMove?
SeqLabC MoveZ EOL
END
END
END
END
SetTTOk
SeqLabC FirstHome DoEndOpPS EOL
SeqLabC CheckCoolOff EOL
IF ProgStop?
SeqLabC 'M0' EOL
END
SeqLabC 'M25' EOL { Signal For Counter, tells control when to shut off at end of barstock }
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END