{Change Comments ***********************************************************}

{1/29/90 Updated: Fanuc 0T-Miyano L008.52 to .69 format, JR}

{5/29/90
Copied & modified: Fanuc OT Miyano L008.69
For: Thor
Control: Fanuc OT
Machine: Ikegai
Added Zero Index Position info
Modified layout of operation start-up blocks.
Changed literal X0.Z0. to Home stuff.
'T0' to cancel offset
Modified CSS, no call for CalcRPM1
Deleted ProgStop & UnTool from end of prog.
Added PostScript, OptCyc1, needed for BarFeed & CutOff.
Deleted M23 & M24 from Threading Canned cycle.
Jim Radcliffe}

{6/21/90
Changed 1st axis moves in Approach to unconditional moves.
Commented out Feed & Feedrate in Approach & FeedrateC in SameTool, rapid to start point.
Added FirstFeed sub and calls in ToolPath.
Changed Seq nubers at beginning of operation to op# times 100.
Deleted FromCP, RLevel & DrillOff in Drilling & Changed K to Q for peck.
Modified ToolPath for Tapping Cycle
Jim Radcliffe}

{6/25/90
Changed Approach to move to ZCP 1st regardless of approach type.
Changed return to Index Position to move X 1st then Z.
Jim Radcliffe}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{9/25/90, Updated to Version 3.2 per Fanuc 10T MS [-] L001.71.1 Format, DWB}
{10/2/90, Added StockOff globally at FirstOperation, DWB}
{11/14/90, Changed StrtPos to StrtPosC in RoughContour canned cycle, JR}

{06/21/91
Updated Fanuc 0T Ikegai L160.71.3 to Version 4.0 per L008.80 Format
Kim Michelman}

{07/26/91
Modified: Fanuc 0T Ikegai L160.81
For: Thor
Replaced (or took out) 'G4P2000' and 'Speed InverseSpinOn' with ''M4' LCycle ZCPC'
for Drilling operations with tapping.
Took out the 'FromCP' and 'RLevel' commands from the PeckChipBreaker.
Kim Michelman}

{08/02/91
Updated: Fanuc 0T (Anzon2) L078.80
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.82 Format.
Kim Michelman}

{4/10/92
Updated: Fanuc 0T Ikegai L160.82.1
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 0T/3T Miyano L008.82.1 Format.
KM}

{5/1/95
Initial: Fanuc 0T Ikegai L160.82.2
ForUser: CNCCS / Tool Sales & Service
Control: Fanuc 0T
Machine: Ikegai
Comment: New Processor from marked up and edited readouts
Deleted Preset turrent blocks from beginning of program.
Changed custome sequence numbers to standard.
Changed 'M17' to GearRange.
Preset for MaxRPM only before CSS. No Preset Home.
Index at G28 U0.W0.
Do not go directly to CSS, go to G97 1st as standard.
Replace approach routines with standard routines.
Added block deleted before CoolOn
Obvious minor corrections to Tapping.
Changed to output StrtPosC to begin RoughContour canned cycle.
Added a literal R.01 Rough Contour Canned Cycles.
Causes the cutter to use a 45Ä„ pullout.
Jim Radcliffe}

{5/30/97
Initial: Fanuc 0T Ikegai [TSS] L348.82.2
Created: Fanuc 0T Ikegai [TSS] L348.82.3
Develop: ComPost2 68K 1.0b11, ncCAD 4.33.02 PPC, ncCAM 4.33 PPC, ncPost 4.33.10 PPC
Comment: Modified per marked up file from Steve Seibert
Changed program label to a colon.
Moved CSS G96 output to approach subs to be output before any G1 output.
Moved SameTool DoOpComments to CheckOffset to output after M0.
Updated per Fanuc 10T MS [-] L001.82ż.
Added additional G76 line for threading canned cycle.
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.######;0.'
#6 = '###0'
#7 = '#'
#8 = '###^###0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(FirstMoveEPZ#,2)
FORMAT(ZStockMin#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
FORMAT(Peck#,8)
FORMAT(CutDepth#,8)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ckCSSOn:
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn 'G96' Speed EOL
END
RETURN

ODApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
ckCSSOn
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

IDApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
StockOnNoCan
ckCSSOn
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

FaceApproachSP:
SeqLabC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
ckCSSOn
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
RETURN

AppMove:
StockOff ZCP OpToolID LatheOffset '/' CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC StockOff XCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqLabC StockOff XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
FaceApproachSP
END
END
RETURN

CheckOffset: {with gear ranges}
DoEndOpPS
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
IF NewGear?
SeqLabC SpinOff EOL
END
IF LAST ProgStop?
SeqLabC 'M0' EOL
END
DoOpComments
DoPostScript
SeqLabC
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
Preset MaxRPM
END
ELSE
Preset MaxRPM
END
END
IF NewGear?
GearRange
END
EOL
SeqLabC
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
ELSE
CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
CSSOff 'G97' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
END
END
IF NewToolOffset?
OpToolID '00'
END
IF LAST ProgStop?
SpinOn
ELSE
IF NewGear?
SpinOn
END
END
EOL
SeqLabC
IF NewToolOffset?
OpToolID LatheOffset
END
IF LAST ProgStop?
'/' CoolOn
ELSE
IF NOT CoolOff? AND LAST CoolOff?
'/' CoolOn
END
END
EOL
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastOp? AND FirstFeat? AND OptCyc1?
SeqLabC 'M24' EOL {parts catcher advance}
END
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC
IF LAST ThreadFeat?
Rapid
ELSE
RapidC
END
MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC ThrdLead EOL
END
END
END
END
END
IF LastOp? AND LastFeat? AND OptCyc1?
SeqLabC 'M25' EOL {parts catcher retract}
END
NEXTFeat
RETURN

CheckRapid:
IF LAST CannedCycle?
Rapid
ELSE
IF LAST Threading?
Rapid
ELSE
RapidC
END
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('2000')
SetMaxFeed('500')
OptCyc1F
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
':' Program#
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
Plane
DoPostScript

IF OptCyc1?
IF UseComments?
'( BAR FEED )' EOL
END
SeqLab CoolOff EOL
SeqLabC SpinOff EOL
SeqLabC 'G97G98T1100' EOL {tool 11 is stop for barfeed}
SeqLabC Preset Home EOL {preset index position}
SeqLabC Rapid 'X0Z.5' EOL {move to clear position}
SeqLabC Feed 'Z' ZStockMin# 'F80.' EOL {move to stock}
SeqLabC 'M21' EOL {open chauck}
SeqLabC Feed 'Z.025F99.' EOL {stock feeds out}
SeqLabC 'M22' EOL {close chuck}
SeqLabC Rapid 'Z.5' EOL {move to clear position}
SeqLabC Home 'T0' EOL {index position}
SeqLabC 'G99' EOL
SeqLabC ProgStop EOL
END

DoOpComments
SeqLab GearRange EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOff 'G97' CalcRPM1
ELSE
SeqLabC CSSOff 'G97' Speed
END
SpinOn OpToolID '00' EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC XCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC ZCPC EOL
DoEndOpPS
SeqLabC
IF LAST ConstantSurfaceFeed?
CSSOff 'G97' CalcRPM2
END
CoolOff EOL
SeqLabC 'G28U0.W0.T0000'
IF NewGear?
SpinOff
END
EOL
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoPostScript
DoOpComments
SeqLab GearRange EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOff 'G97' CalcRPM1
ELSE
SeqLabC CSSOff 'G97' Speed
END
SpinOn OpToolID '00' EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
SeqLabC XCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
END
SeqLabC ZCPC EOL
SeqLabC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
IF ApproachFace?
SeqLabC LCycle 'Z' FirstMoveEPZ# XatFinZ XTapAtZ FeedRate EOL
ELSE
SeqLabC LCycle XatFinZ FinZ XTapAtZ FeedRate EOL
END
SimpleRough
ELSE
TagInc
IF RoughContour?
SetPass2
SeqLabC LCycle CutDepth 'R.01' EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
SeqLab StepMove StrtPosC EOL
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
ELSE
IF RoughPatternShift?
SetPass2
SeqLabC LCycle XminusU ZminusW NumCuts EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
END
END
END
ELSE
IF Threading?
SeqLabC LCycle 'P'
IF AutoFinish?
'02' {2 finish passes}
ELSE
'01'
END
IF Chamfer?
'10' {1 thread lead}
ELSE
'00'
END
IF SingleEdgeCut?
'60'
ELSE
'00'
END
'Q'
IF ConstantVolumeCut?
'5' {.0005 minimum cut depth}
ELSE
CutDepth# {if not ConstantVolumeCut? CutDepth is min depth, volume increases with depth}
END
'R.001' {******need XStckLeft#}
EOL
SeqLabC LCycle XatFinZ FinZ XTapAtZ ThrdHeight CutDepth ThrdLead EOL
IF AutoFinish?
IF Taper?
SeqLabC Rapid
'X' ADD# FinishXDia# MUL# Taper# NumSc#('2') { Outputs start of Taper }
EOL
SeqLabC 'G32' XatFinZ FinZ ThrdLead EOL
ELSE
SeqLabC Rapid XatFinZ EOL
SeqLabC 'G32' FinZ ThrdLead EOL
END
SeqLabC Rapid XCSP EOL
SeqLabC ZCSP EOL
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC LCycle ZSP InverseSpinOn EOL
ELSE
IF PeckChipBreaker?
SeqLabC LCycle ZDepth Dwell Peck Retract FeedRate EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple?
StockOff
IF Turning?
SetPass1
RapidC
IF ApproachFace?
SeqLabC ZOpECPC EOL
FaceApproachSP
ELSE
SeqLabC XOpECDC EOL
IF ApproachOD?
ODApproachSP
ELSE {ApproachID}
IDApproachSP
END
END
ELSE
SetPass2
SeqLabC RapidC StrtPos EOL
END
ToolPath
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
IF CannedCycle?
Rapid
ELSE
IF Threading?
Rapid
ELSE
RapidC
END
END
IF ApproachOD?
SeqLabC XCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC ZCPC EOL
DoEndOpPS
SeqLabC
IF ConstantSurfaceFeed?
CSSOff 'G97S' CalcEPRPM#
END
CoolOff EOL
SeqLabC 'G28U0.W0.T0000' SpinOff EOL
IF ProgStop?
SeqLabC 'M0' EOL
END
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END