{
MILL=F
LATHE=T
SIMPLE_ROT_POS=F
ROTARY_MILL=F
ADV_MILL=F
SUBS=F
MILLTURN_Y-AXIS=F
METRIC=F
}

{Change Comments ***********************************************************}

{7/18/90
Copied & modified: Fanuc 10T MS [+] L004.69.7
For: Viratec
Machine: Mori Seiki TL40
Control: Fanuc 15TF
Deleted 'Preset Home' at FirstOperation and NewTool.
Moved OpToolID LatheOffset from Approach sub to FirstOperation and NewTool.
Added GearRange.
Cancel Tool Offset on line by itself after move to index position.
JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{9/25/90, Updated to Version 3.2 per Fanuc 10T MS [-] L001.71.1 Format, DWB}
{10/2/90, Added StockOff globally at FirstOperation, DWB}
{10/8/90, Replace CalcRPM2 globally with CalcEPRPM# at end of prog, DWB}

{3/28/91
Modified: Fanuc 15T MS (+) L166.71.3
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format.
All normal Fanuc Canned Cycles are supported.
DWB}

{8/5/91
Updated: Fanuc 15T MS (+) L166.80
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.82 Format.
KM}

{11/1/94
Updated: Fanuc 15T MS (+) L166.82
For: Gibbs & Associates/Premier Mfg/SimFlo Pumps Inc.
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.03/Compost 4.21.22
Updated to Version 4.1 per Fanuc 10T MS [-] L001.82.1a Format.
DWB}

{11/1/94
Copied: Fanuc 15T MS (+) L166.82.1
Created: Fanuc 16T MS (+) L314.82.1
For: Premier Manufacturing/SimFlo Pumps Inc.
Machine:
Control:
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.03/Compost 4.21.23
Changes made per Glenn Johnson of Simflo, manual and sample printouts.
Modified Canned Cycles per manual.
DWB}

{1/9/95
Modified: Fanuc 16T MS (+) L314.82.1
Renamed: Fanuc 16T MS [+] L314.82.2
For: Premier Manufacturing/SimFlo Pumps Inc.
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.04/Compost 4.21.23
Versions: Catalyst v2.14.24C/Catalyst v2.14.24PPC/Compost 4.21.23
Changes made per Glenn Johnson of Simflo, cam and text files, and marked up printouts.
Added conditional move after returning from ToolPath, to SetPass1 XSPC for ApproachOD at
CannedCycle RoughContour.
Commented out File Length Comments at end of prog.
Customer reported problem with Communications software hanging up because control had read EOR at
end of output, and stopped reading, while sending software was still waiting to send the comments.
Deleted CheckGear sub and changed call to CheckGear to SpinOn at CheckOffset sub.
Deleted SpinOff and condition to output same when NewGear? = TRUE at CheckOffset sub and NewTool.
DWB}

{9/1/95, Updated Fanuc 16T MS [+] L314.82.2 to .85 format per Fanuc 10T MS [-] L001.85.01.01, JR}

{9/10/96
Initial: Fanuc 16T MS [+] L314.85
Created: Fanuc 18T Hardinge L000.85
ForUser: Braden Engineering / Stanley Mechanics Tools
Control: Fanuc 18T
Machine: Hardinge
Develop: ComPost2 68k v1.0b3, Catalyst68K v3.04.10.C
Comment: New processor per marked up readout.
Deleted GearRange.
Changed ':' Program# to ProgID1.
Changed SpinOn to SpinCoolOn to handle SpinOn and CoolOn.
Go directly to G96 in CSS operation and do not return to G97 at end of them.
Added sub call for safe index. Suppressed output of home commands.
Added Parts Catcher commands
Changed to R format arcs.
Jim Radcliffe}

{9/25/96
Initial: Fanuc 18T Hardinge L000.85
Created: Fanuc 18T Hardinge L000.85.1
Develop: ComPost2 68k v1.0b3, Catalyst68K v3.04.10.C
Comment: Modified per marked up readout from Monty Smith
Changed SetMaxRPM('3000') to SetMaxRPM('4500')
Unconditional M61 at beginning and end of program.
A custome sub program call.
Checks to see if there is a bar in the bar feeder.
If not it goes to a bar change routine.
Changed M98P8000 at beginning of program to M98P8001.
Jim Radcliffe}

{2Nov98
Original: Fanuc 18T Hard [SMT] L545.85.1
Created: Fanuc 18T Hard [CPC] Lxxx.85
For: CACO Pacific Corp
Changes made per: Michael Tuman
Added Post Header Comment at the top of Prog.
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
Deleted 'M61' in FirstOperation and End of Prog.
Changed M98P8001 to M98P1 in FirstOperation and NewTool
Changed M98P8000 to M98P1 at End of Prog
Added 'N' Tool# in FirstOperation and NewTool ( i.e. Line number = Tool Called )
Deleted PresetMaxRPM in NewTool. Call once only at the begining of the Output.
Re-wrote FirstOperation and NewTool and CommonPoint
Always output G97 then call Approach
Call ApproachSP at the Common Point.
Added 'M10' High-Pressure Coolant and SameTool Boolean at the Common Point.
Added IF ApproachID? Boolean to flip the XStkLeft polarity in ID rough cycle (G71).
The polarity of the U & W stock values must be reversed when roughing an ID.
Charles Winston}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.####;0.'
#6 = '###0'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(SPX#,2)
FORMAT(SPZ#,2)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(InFeedAngle#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Peck#,2)
FORMAT(Program#,3)
FORMAT(Operation#,3)
FORMAT(Tool#,3)
FORMAT(Dwell#,4)
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)

{Special Command Subroutines ***********************************************}

SpinCoolOn:
IF CoolOff?
SpinOn
ELSE
IF CWSpindle?
'M13'
ELSE
'M14'
END
END
RETURN

StopProg:
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ' - ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ' - ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST CutOff?
SeqLabC 'M25' EOL
END
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF CutOff?
SeqLabC 'M26' EOL
END
IF NewToolOffset?
SeqLabC OpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
SeqLabC
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' Speed
ELSE
SeqLabC
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
END
END
IF LAST ProgStop?
SpinCoolOn EOL
ELSE
EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC:
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('4500')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT - ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff
SetHome
DoOpComments
DoPostScript
Plane
'N' Tool# EOL
IF CutOff?
SeqLabC 'M26' EOL
END
IF NOT ToolChangeAtHome?
SeqLabC 'M98P8001' EOL
END
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinCoolOn OpToolID LatheOffset EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
IF LAST CutOff?
SeqLabC 'M25' EOL
END
IF ToolChangeAtHome?
SeqLabC NewHome LOfstOff '00' EOL
SeqLabC StopProg EOL
END

{Start new Operation}

DoOpComments
DoPostScript
IF CutOff?
SeqLabC 'M26' EOL
END
IF NOT ToolChangeAtHome?
SeqLabC 'M98P1' EOL
SeqLabC StopProg EOL
END
'N' Tool# EOL
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinCoolOn OpToolID LatheOffset EOL
Approach
ELSE
IF SameTool?

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
END
END
END
END {common point for all operations}
IF NOT SameTool?
IF ConstantSurfaceFeed?
SeqLabC CSSOn 'G96' Speed EOL
END
SeqLabC 'M10' EOL { High-Pressure Coolant On }
END
ApproachSP
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle XatFinZ
IF ApproachFace?
'Z' FirstMoveEPZ#
ELSE
FinZ
END
IF Taper?
XTapAtZ
END
FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle CutDepth 'R.05' EOL { R = Retract }
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag#
IF ApproachID?
NegSideLathe
XStkLeft
PosSideLathe
ELSE
XStkLeft
END
ZStkLeft FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove 'Z' SPZ# EOL
SeqLabC FeedC 'X' SPX# EOL
ELSE
SeqLab StepMove 'X' SPX# EOL
SeqLabC FeedC 'Z' SPZ# EOL
END
ELSE
IF RoughPatternShift?
SeqLabC LCycle XminusU ZminusW NumCuts EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag#
IF ApproachID?
NegSideLathe
XStkLeft
PosSideLathe
ELSE
XStkLeft
END
ZStkLeft FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove 'Z' SPZ# EOL
SeqLabC FeedC 'X' SPX# EOL
ELSE
SeqLab StepMove 'X' SPX# EOL
SeqLabC FeedC 'Z' SPZ# EOL
END
END
END
ToolPath
IF ApproachOD?
SetPass1
StockOff
LoadFeat Num#('0') CycleStartX#
IF XMove?
SeqLab RapidC MoveXC EOL
END
END
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
IF SingleEdgeCut? OR ConstantVolumeCut?
SeqLabC LCycle 'P'
IF AutoFinish?
'01'
ELSE
'00'
END
IF Chamfer?
'05'
ELSE
'00'
END
IF SingleEdgeCut?
'60' { ToolAngle }
ELSE
'00'
END
'Q080' { Minimum InFeed }
'R050' EOL { Finish Allowance }
SeqLabC LCycle XatFinZ FinZ
IF Taper?
XTapAtZ
END
ThrdHeight CutDepth ThrdLead EOL
ELSE
SeqLabC 'G92X' FirstMoveEPX# FinZ
IF Taper?
XTapAtZ
END
'F' FeedIPR# EOL
SimpleRough
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'F' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF PeckChipBreaker?
SeqLabC LCycle Retract EOL
SeqLabC LCycle ZDepth 'Q' Peck# FeedRate EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G32'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
IF CutOff?
SeqLabC 'M25' EOL
END
SeqLabC SpinOff EOL
IF FIRST ToolChangeAtHome?
SeqLabC FirstHome OpToolID '00' EOL
ELSE
SeqLabC 'M98P1' EOL
END
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH - ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH - ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH - ' FileMeters# ' METERS )' EOL
END
Close
END