{Change Comments ***********************************************************}

{4/17/91
Modified: Fanuc 10T MS [-] L001.80
For: Gibbs & Associates
Replaced AbsOrInc command with SetAbs, in FirstOperation, and changed MoveType$ to 'ABSOLUTE'.
This is because Fanuc controls that operate in Standard 'G' code group 'A', interpret 'G90'
as Cutting Cycle 'A', and all incremental moves are output using 'U' and 'W' addresses. All
Post Processors that fall into this category MUST BE MODIFIED!!!
All Fanuc controls that operate in Special 'G' code groups 'B' and 'C', do interpret 'G90'
to set the control into incremental mode, and therefore, any post processors that fall into
this category do not need this modification.
DWB}

{8/2/91
Modified: Fanuc 10T MS [-] L001.81
For: Gibbs & Associates
Deleted StockOff form Approach sub, it's called from all operations.
Broke up Approach sub for all operations for improved readability and less nested decisions.
Combined and modified CheckRapid subs.
Moved XOpECDC for IDExit from end of operation to NewTool, SameTool and end of Prog.
This was to ensure that all operations end at the LAST Features EndPoint.
Added LAST to XOpECDC and ZOpECPC commands at SameTool.
DWB}

{11/14/91
Modified: Fanuc 10T MS [-] L001.82
For: Gibbs & Associates
Added RestoreScale Sub per 4-Axis Post Processor.
Added Logic to suppress Feed and FeedRate for Approaches.
Modified output of Speed & ConstantSurfaceFeed for SameTool in CheckOffset sub.
Changed SetAbs to SetAbsOrInc at setup and initializations.
Added bypass of AutoFinish for Non-Canned RoughSimple Operations.
Modified AutoFinish Approach.
DWB}

{5/2/95
Initial: Fanuc 10T MS [-] L001.82ż
ForUser: Tenk Machine
Control: Westinghouse Producer
Machine: Gray VFR (Vertical Turret Lathe)
Comment: New Virtual Mac Post Processor created from Manual
Jim Radcliffe}

{6/27/95
Initial: Westinghouse Producer L335.82
Created: Westinghouse Producer L335.82.1
ForUser: Tenk Machine
Comment: Modified per e-mail from Roger
Changed format of spindle speed S word to output with a decimal point.
Changed to output unconditional I&K for arcs.
Jim Radcliffe}

{1/20/98,
Initial : Westinghouse Producer L335.82.1
Created: Fanuc 6TB Gray [TMT] L335.85
Customer: Tenk Machine (Retrufit with new control)

Changes to "Form":

1. Under General Info, changed Program ID Label to O
2. Under Default Formats, changed A, B, & C to ###.###;0.
changed F to #.####;0.
changed S to ###0
changed D, G, H, & M to #0
changed I, J, K, R, X, Y, & Z to ###.####;0.
3. Under Origins and Values, changed Preset Number to 50
removed First Work Fixture Offset Label
changed First Work Fixture Offset Number to 0
4. Under Subs, Changed Sub Call Label to P
5. Under Threading, changed Lead of Thread Format (K) to #.#####;0.

Changes to "Prog":

1. Added CRC support per Rev .85
2. Added AutoClearance support per Rev .85
3. Changed Format #1, #2, & 5.
4. Removed MSG, from all comments.
5. Added Program# to FirstOperation.
6. Removed CSSEnable (M58) and CSSDisable (M59).
7. Removed CycleStartXRadius#.
8. Changed InchInput code to G20 and IPRFeed to G99
9. Removed TrailingZeros (G72) output.
10. Removed SetInc, SetAbsOrInc, all AbsOrInc, and added SetAbs.
11. Changed G33 to G32 (Thread) and changed taper output.
*** Per Roger Smith, No need for Canned Cycles. ***
JHE}


{Prog Numeric Format Definitions *******************************************}

#1 = '#.#0'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###^#0'
#5 = '#.#####;0.'
#6 = '###0'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(FirstMoveEPZ#,2)
FORMAT(CycleStartXRadius#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(MUL#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle? AND NOT Threading?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle? AND NOT Threading?
FeedRateC
END
RETURN

ODApproachSP:
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

IDApproachSP:
SeqC StockOnNoCan ZSPC EOL
SeqC StockOff XOpCDC EOL { for SameTool ApproachID }
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

FaceApproachSP:
SeqC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqC FeedNoCan ZSPC FeedRateNoCan EOL
END
RETURN

AppMove:
StockOff ThisOpEntryZCP CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqC StockOff ThisOpEntryXCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqC StockOff XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqC StockOnNoCan XSP AppMove EOL
FaceApproachSP
END
END
RETURN

CheckOffset: {with gear ranges}
DoEndOpPS
IF LAST ProgStop?
SeqC ' M00' EOL
ELSE
IF NewGear?
SeqC SpinOff EOL
END
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
END
IF NewToolOffset?
SeqC LOfstOff '00' EOL
SeqC OpToolID LatheOffset EOL
END
IF NewGear?
SeqC GearRange EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqC Preset MaxRPM EOL
END
SeqC SpeedC
ELSE
SeqC Preset MaxRPM EOL
SeqC CSSOn ' G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqC CSSOff ' G97' Speed
ELSE
SeqC SpeedC
END
END
IF LAST ProgStop?
SpinOn EOL
SeqC CoolOn EOL
ELSE
IF NewGear?
SpinOn EOL
ELSE
EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJ
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqC SpinOff EOL
SeqC ' G04 F200' EOL
SeqC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqC ' G04 F' Dwell# EOL
END
END
ELSE
IF CannedCycle?
Seq
END
END
END
IF PointFeat?
SeqC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
{SetInc} {Removed this line - JHE}
SetStatusOff
Save# Num#('1') ABS# EPZ#
SetStatusOn
{SetAbsOrInc} {Removed this line - JHE}
SeqC ' G32' {Changed from G33 - JHE}
IF Taper?
{' I' MUL# DIV# Num#('1') Thread# DIV# Taper# Recall# Num#('1')}
MoveXC {Replace with previous line - JHE}
END
MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid1:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

CheckRapid2:
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

InchInput:
' G20' {Changed from G70 - JHE}
RETURN

TrailingZeros:
' G72'
RETURN

LeadingZeros:
' G73'
RETURN

IPMFeed:
' G94'
RETURN

IPRFeed:
' G99' {Changed from G95 - JHE}
RETURN

CSSEnable:
' M58'
RETURN

CSSDisable:
' M59'
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
PosSideLathe
XsAreRadii
SetMaxRPM('486')
SetMaxFeed('9.999')
SetAbs {Added this line - JHE}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
':' Program# EOL {Added this line - JHE}
IF UseComments?
IF ProgramNameComment?
'( ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
Plane
Seq Rapid OpToolID LatheOffset ToolChng EOL
DoOpComments
DoPostScript
SeqC InchInput IPRFeed GearRange EOL {Removed TrailingZeros AbsOrInc - JHE}
SeqC CSSOff ' G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
IF LAST ApproachOD?
SeqC CheckRapid1 LAST OpExitXCPC EOL {Removed CSSDisable - JHE}
SeqC LAST OpExitZCPC EOL
ELSE
IF LAST ApproachID?
SeqC CheckRapid1 LAST XOpECDC EOL {Removed CSSDisable - JHE}
SeqC LAST OpExitZCPC EOL
ELSE
SeqC CheckRapid1 LAST OpExitZCPC EOL {Removed CSSDisable - JHE}
END
END
DoEndOpPS
SeqC NewHome CoolOff EOL
IF LAST ProgStop?
SeqC ' M00' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

Seq Rapid OpToolID LatheOffset ToolChng EOL
DoOpComments
DoPostScript
SeqC InchInput IPRFeed GearRange EOL {Removed TrailingZeros AbsOrInc - JHE}
SeqC CSSOff ' G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid1
SeqC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid1
IF ApproachOD?
IF LAST ApproachOD?
SeqC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC LAST OpExitXCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
END
SeqC LAST OpExitZCPC EOL
SeqC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqC LAST XOpECDC EOL
END
SeqC LAST OpExitZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqC Preset MaxRPM EOL {Removed ' R' CycleStartXRadius# - JHE}
SeqC CSSOn ' G96' Speed EOL {Removed CSSEnable - JHE}
END
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple?
StockOff
IF Turning?
SetPass1
RapidC
IF ApproachFace?
SeqC ZOpECPC EOL
FaceApproachSP
ELSE
SeqC XOpECDC EOL
IF ApproachOD?
ODApproachSP
ELSE {ApproachID}
IDApproachSP
END
END
ELSE
SetPass2
SeqC RapidC StrtPos EOL
END
ToolPath
END
END
IF Drilling? AND Tap?
SeqC SpinOff EOL
SeqC ' G04 F200' EOL
SeqC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
IF ApproachOD?
SeqC CheckRapid2 OpExitXCPC EOL {Removed CSSDisable - JHE}
SeqC OpExitZCPC EOL
ELSE
IF ApproachID?
SeqC CheckRapid2 XOpECDC EOL {Removed CSSDisable - JHE}
SeqC OpExitZCPC EOL
ELSE
SeqC CheckRapid2 OpExitZCPC EOL {Removed CSSDisable - JHE}
END
END
DoEndOpPS
SeqC FirstHome CoolOff EOL
IF ProgStop?
SeqC ' M00' EOL
END
SeqC EOP EOL
Post
IF UseComments?
SetScale('1') {restore scale for comments}
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
EOR EOL
Close