{Change Comments ***********************************************************}

{5/12/92
Copied & modified: Fanuc 6M M001.81
For: Armco.
Machine: Giddings & Lewis Horizontal Machining Center
Control: G & L NumeriPath 8000B
Changes made per conversation with Bill Barber @ Armco, and manual.
Changed all occurances of Z address to W address in Form and Prog.
FORM Changes:
Use Absolute Arc Centers = T
Allow R-Format Arcs = F
Keep Subs in Front of Program = T
Z EndPoint Label = W
Rapid Z EndPoint Label = W
Sub Call Label =
Sub Repeat Label =
Program ID Label =
Optional Program ID Label =
Tool Length Offset Label = D
Call sub =
Return from Sub =
Tool Length Offset Enable =
Tool Length Offset Cancel =
First Work Fixture Offset = E1
Last Work Fixture Offset = E99
Drill from CP1 =
Drill from CP2 =
PROG Changes:
Changed FORMAT 6 for Dwell# from ####^##0 to ###.#;0.
Added FORMAT 7 ##.#####;0. for FeedTapIPR# used in Canned Tapping Cycle.
Added Address 'K' for this.
Added ClearancePlane1# and ClearancePlane2# to FORMAT 4 used in Canned Drilling Cycles
and based on RetractToCP1 Boolean, and replaces FromCP Command.
Added ArcZRads# to FORMAT 4 used for 3-Axis ArcFeat.
Added Repeats# to FORMAT 5.
Added TYPE II Conversational Codes:
PGM, Program Name
MSG, Operator Message
CLS, Call Subroutine
Changed all SeqC EndSub to EOR.
Modified FormatArc Sub to handle all Planes.
Unconditional h, v, I and J; d and K for Helical ArcFeat.
Added Flag('1') to bypass Helical ArcFeat for ZonlyRep Sub which uses SkipZ Command.
Changed Address G to Address E at WFOStuff Sub.
Added literal 'D0' to IncValue OfstOff.
Changed Address P to Address F for Canned Drilling Cycle Dwells.
Dwell for Canned Cycle is output as 'G4' Dwell.
Deleted FeedEnt from Canned Drilling Cycles.
I didn't see an example of FeedEnts being used in the manual, I assume it is defaulted.
DWB}

{7/1/92
Modified: G & L Numeripath 8000 M499.81
For: Armco.
Changes made per conversation with Bill Barber @ Armco.
Bill requested that the Tool Length Offset be output prior to any table motion. The D Address
controls both the Length AND Diameter Offset values.
Deleted CRCOffsetC 3 places at StdLine sub.
Deleted ResetCRCNum at ToolPath sub.
Added ToolOfst to block prior to StrtPos at FirstOperation, NewTool and 2 places at SameTool.
Changed OfstOn to ZCP1 at FirstOperation, NewTool and 2 places at SameTool.
DWB}

{10/7/94
Copied & modified: G & L Numeripath 8000 M499.81.1
For: CNCCS / Marshall Engineering
Changed to a no subs format per Fanuc 6M NoSubs M001.81.2
Added sequence numbers to all comments.
Changed Z address from W to Z
Added codes to saftey start blocks.
WFO's output by PostScript request only.
SpinOff on ZCP3.
Commented out OfstOff.
Added FeedEnt to DrillCycle.
Added move to machine home at end of program.
Jim Radcliffe}

{10/11/96,
Initial: G&L Numeripath 8000B M758.81.2
Created: G&L Num 8000B [RE] MXXX.81
For: Remmele Eng. Plant #40
Deleted SpinOff commands,
Changed label for Z moves in form to W. Customer wants to use W (table depth axis) for
milling ops and clearance planes, but use z axis for drill depths.
Changed G94 in saftey start block to G95, customer wants to program feed rates in IPR,
Put OpToolID and ToolChng on same line,
Put ToolOffset on line with OpToolID and ToolChng,
instead of calling ZCP3C at tool changes before tool changes and at the last op, post outputs
'Z0.W' TCZ#, TCZ it set in initalizations to 20,
deleted output of program number,
deleted literal 'G98X0.Y0.' at program end,
added literal 'Z0.' before ZCP1 calls (zeros the Z axis so W axis moves are correct,
moved Speed command in FirstOp and NewTool to same line with OpToolID,
Added literal 'G98Z0.' to line with SpinOn in FirstOp and NewTool,
deleted format #7, changed FeedTapIPR to format #4,
MPK}

{1/16/97
Initial: G & L Num 8000B [RE] MZ64.89
Created: G & L Num 8000B [RE] MZ64.89.1
ForUser: Remmele Plant 40
Develop: ComPost2 MSL 68K, Virtual Gibbs 3.23
Comment: Modified per fax and conversation with Dave Lemire
Changed format of F to 4 decimal places.
Jim Radcliffe}

{*** NOTE ***}
{ Customer is typing in IPR feeds into the Virtual Feed dialog boxes! That is the way he wants it! }

{09/28/98,
Initial: G & L Num 8000B [RE] MZ64.89.1
Created: G & L Num 8000B [RE] MZ64.89.2
For: Remmele Plant 40

Changes to Prog:
1) FirstOp/NewTool - Moved DoOpComments and DoPostScript to before Tool call.
2) IF Drilling? - Deleted IF Dwell? boolean.
CDH}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '###.#;0.'
#7 = '#;'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ClearancePlane1#,4)
FORMAT(ClearancePlane2#,4)
FORMAT(ClearancePlane3#,4)
FORMAT(ArcZRads#,4)
FORMAT(ToolDiameter#,4)
FORMAT(EPZ#,4)
FORMAT(ZDepth#,4)
FORMAT(SPZ#,4)
FORMAT(TCZ#,4)
FORMAT(FeedTapIPR#,4)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Repeats#,5)
FORMAT(Dwell#,6)
FORMAT(RapidF#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
SeqC '(MSG, SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF MultipleParts? AND SubComment?
SeqC '(MSG, PART ' Tag# ' )' EOL
END
IF OperationIDComment?
SeqC '(MSG, OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
SeqC '(MSG, ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
SeqC '(MSG, ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
SeqC '(MSG, TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
SeqC '(MSG, ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

ExitType:
IF FIFO?
FeedC
ELSE
RapidC
END
RETURN

ExitFeed:
IF FIFO?
FeedEntC
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF XYPlane?
IF ZMove?
MoveXYZ ArcIJ 'K' ArcZRads#
ELSE
MoveXY ArcIJ
END
ELSE
IF XZPlane?
IF YMove?
MoveXYZ ArcIJ 'K' ArcZRads#
ELSE
MoveX MoveZ ArcIJ
END
ELSE { YZPlane }
IF XMove?
MoveXYZ ArcIJ 'K' ArcZRads#
ELSE
MoveY MoveZ ArcIJ
END
END
END
RETURN

StdRapid:
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC EOL
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CRCOnC FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqC CRCOnC FeedC MoveXYZC DecelFeed EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC CRCOnC FeedC MoveXYZC FeedRateC EOL
END
END
RETURN

StdArc:
EACHQuadrant
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
RETURN

ToolPath2: {for AutoCycle element moves}
EACHFeat
IF RapidFeat?
IF LastFeat?
SeqC CRCOffC RapidC MoveXYZC EOL
ELSE
StdRapid
END
ELSE
IF LineFeat?
IF LastFeat?
SeqC CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
IF ArcFeat?
StdArc
END
END
END
NEXTFeat
RETURN

EntryMove:
IF FeedEntry?
SeqC FeedC ZInC FeedEntC EOL
ELSE
SeqC RapidC ZInC EOL
END
RETURN

CutAutoCycle:
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
SeqC IncValue EOL
IF Repeats? AND ZshiftOnly?
EachRep
EntryMove
ToolPath2
IF NOT FeedConnect?
IF FIFO?
SeqC FeedC PRIME ZCP2 FeedEntC EOL
ELSE
SeqC RapidC PRIME ZCP2 EOL
END
END
NextRep
ELSE
EntryMove
ToolPath2
END
IF FIFO?
SeqC AbsOrInc FeedC ZCP2 FeedEntC EOL
ELSE
SeqC AbsOrInc RapidC ZCP2 EOL
END
SetSRSubXY {restore tool position}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
IF NOT FirstFeat?
SeqC
IF FIFO?
Rapid
END
MoveSXYC EOL
END
CutAutoCycle
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC MoveSXYC
IF SPZMove?
'Z' SPZ#
END
EOL
END
ELSE
IF RapidFeat?
StdRapid
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
StdArc
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
ELSE
SeqC 'E' NewWFO# EOL
END
END
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
WFOStuff
CheckPass
RETURN

DoOp:
IF FirstOperation?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
EOL
IF FullUp?
SeqC CoolOff EOL
{SeqC IncValue OfstOff 'D0' EOL}
END
DoOpComments
ELSE
Seq Rapid Plane CRCOff DrillOff AbsOrInc 'G95' EOL
DoOpComments
DoPostScript
SeqC OpToolID ToolOfst Speed ToolChng EOL
SeqC 'G98Z0.' SpinOn EOL
WFOStuff
END
CheckPass
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane? AND NOT FirstPart?
SeqC Rapid StrtPos EOL
ELSE
SeqC AbsOrInc Rapid StrtPos EOL
SeqC 'Z0.' ZCP1 EOL
SeqC CoolOn EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
{only need to set up for tool change on 1st part}
ELSE
EOL
SeqC CoolOff EOL
{SeqC IncValue OfstOff 'D0' EOL}
DoEndOpPS
IF ToolChangeAtHome?
SeqC AbsOrInc Rapid Home EOL
END
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
END

{Start new Operation}

IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
IF FullUp?
SeqC CoolOff EOL
{SeqC IncValue OfstOff 'D0' EOL}
END
DoOpComments
ELSE
Seq Rapid Plane CRCOff DrillOff AbsOrInc 'G95' EOL
DoOpComments
DoPostScript
SeqC OpToolID ToolOfst Speed ToolChng EOL
SeqC 'G98Z0.' SpinOn EOL
WFOStuff
END
SeqC EOL
CheckPass
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane? AND NOT FirstPart?
SeqC Rapid StrtPos EOL
ELSE
SeqC AbsOrInc Rapid StrtPos EOL
SeqC 'Z0.' ZCP1 EOL
SeqC CoolOn EOL
END
ELSE
IF SameTool?
IF LAST ProgStop?
SeqC CoolOff EOL
{SeqC IncValue OfstOff 'D0' EOL}
DoEndOpPS
SeqC 'M0' EOL

{Start new Operation}

GetStartOfSameTool
SeqC ToolOfst EOL
SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC SpinOn EOL
SeqC 'Z0.' ZCP1 EOL
SeqC CoolOn EOL
ELSE
EOL
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
{SeqC IncValue OfstOff 'D0' EOL}
DoEndOpPS

{Start new Operation}

GetStartOfSameTool
SeqC ToolOfst EOL
SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC EOL
SeqC 'Z0.' ZCP1 EOL
ELSE
DoEndOpPS

{Start new Operation}

GetStartOfSameTool
SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END

{ Common Point for All Operations }

ResetCRCNum {call here to reset for each new operation only, call in tool path to reset for each repeat in an operation}
RapidF# {forces the output of a conditional feedrate for each operation}

IF Milling?
SeqC ZCP2C EOL
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
EACHRep
DoSubComment
IF NOT FirstCycle?
SeqC Connect StrtPos EOL
IF NOT FeedConnect?
SeqC ZCP2C EOL
END
END
END
END
IF NOT AutoCycle?
EntryMove
END
ToolPath
IF Repeats?
IF ZshiftOnly? AND AutoCycle?
{done in CutAutoCycle called from ToolPath}
ELSE
SeqC CRCOffC
IF NOT FeedConnect?
ExitType PRIME ZCP3C
END
ExitFeed
EOL
NEXTRep
END
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
SeqC CRCOffC ExitType
IF NEXT NewTool? OR LastOp?
'W' TCZ# 'Z0.'
ELSE
ZCP3C
END
ExitFeed EOL
END
ELSE
IF Drilling?
IF Repeats?
EACHRep
IF NOT FirstCycle?
EOL
END
DoSubComment
END
SeqC DrillCP EOL
GetCycle
SeqC Cycle StrtPos RLevel 'Z' ZDepth#
IF RetractToCP1? {.81}
'P' ClearancePlane1# { FromCP }
ELSE
'P' ClearancePlane2# { FromCP }
END
Peck
IF Tap?
'K' FeedTapIPR#('1')
ELSE
FeedEnt
END
EOL
TrackZNO# ZDepth# {.81}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
SeqC DrillOff EOL
SeqC
IF NEXT NewTool? OR LastOp?
'W' TCZ# 'Z0.'
ELSE
ZCP3C
END
IF Repeats?
NEXTRep
END
END
END
RETURN

FinishLastOp:
SeqC CoolOff EOL
{SeqC IncValue OfstOff 'D0' EOL}
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqC AbsOrInc Rapid FirstHome EOL
END
IF MultipleParts? AND AllToolsOnePart? AND NOT LastPart? {no tool change after doing last part}
IF ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END
ELSE
SeqC EOP EOL
END
RETURN

DoToolsOps:
EachOp
IF GTEqual? Operation# Recall# Num#('1') AND LTEqual? Operation# Recall# Num#('2')
{Tools1stOp ² op ² ToolsLastOp}
DoOp
END
NextOp
RETURN

NextTools1stOp:
SetNextToolOp Operation#
RETURN

GetToolsOps:
EachOp
IF Equal? Operation# Recall# Num#('1') {if op = Tools1stOp}
IF GreaterThan? NextTools1stOp Recall# Num#('1') {if NextTools1stOp is greater Tools1stOp}
Save# Num#('2') SUB# NextTools1stOp Num#('1') {ToolsLastOp becomes NextTools1stOp less 1}
ELSE {else}
Save# Num#('2') Recall# Num#('3') {ToolsLastOp becomes ncCAMsLastOp}
END
END
NextOp
RETURN

DoTool:
IF NOT Flag?('1')
GetToolsOps
EachPart
TagInc
DoToolsOps
NextPart
IF LessThan? Recall# Num#('2') Recall# Num#('3') {if ToolsLastOp < ncCAMsLastOp}
Save# Num#('1') ADD# Recall# Num#('2') Num#('1') {Tools1stOp becomes NextTools1stOp}
ELSE {else}
SetFlag('1') {set DoneFlag}
END
TagInit
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetFlagF('1') {done flag}
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetTCZ('20')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
SeqC '(MSG, PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
SeqC '(MSG, ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
SeqC '(MSG, FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
SeqC '(MSG, ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
SeqC '(MSG, OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
SeqC '(MSG, PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
SeqC '(MSG, FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
END
NextOp
IF MultipleParts?
IF AllToolsOnePart?
EachPart
TagInc
EachOp
DoOp
NextOp
FinishLastOp
NextPart
ELSE
IF OneToolAllParts?
EachOp
IF FirstOperation?
Save# Num#('1') Operation# {ncCAMs1stOp becomes Tools1stOp}
END
IF LastOp?
Save# Num#('3') Operation# {save ncCAMsLastOp}
END
NextOp
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool DoTool
FinishLastOp
END
END
ELSE
EachOp
DoOp
NextOp
FinishLastOp
END
IF UseComments?
SetScale('1') {restore scale for comments}
IF FileBytesComment?
SeqC '(MSG, FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
SeqC '(MSG, FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
SeqC '(MSG, FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
END
EOR EOL
CloseSub
Post2
Close