{Change Comments ***********************************************************}

{9/12/89
Copied & modified: G & L 15VF 800 M178.60
For: Lawrence Berkley Lab
Machine: Giddings & Lewis 10VFS
Control: Numerpath 800
Modified per cusomer requests.
Deleted OpToolID & OfstOn & OfstOff.
Changed EOP to 'M02'.
Changed ProgStop to CRCOff 'H00M00' between tools.
Moved CRCOn to beginning of Operation.
Moved CoolOn to ZIn Move.
Added CoolOff to LastFeat in ToolPath.
Forcing EndPoints & Arc Centers for Arcs.
Added OR SameTool to IF NewTool.
Deleted SameTool section.
SameTool to be treated as NewTool.
JR}

{2/6/90
Modified: G & L 800 10VF M244.61
For: Lawrence Berkley Lab
Added Helical Interpolation at FormatArc.
JR}

{5/23/90
Modified: G & L 800 10VF M244.62
For: Gibbs & Associates
Updated per Fanuc 6M M001.72.1 Format.
JR}

{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}

{8/19/93
Modified: G & L 800 10VF M244.73
For: Gibbs & Associates
Changes made per request by Pete Jackson
Updated to Version 4.1 per Fanuc 6M M001.81.2 Format.
DWB}

{2/9/96, Updated .81 version to .84, MPK}

{3/22/96, Tested ZOnlyRepAutCycle, Incremented number to .87, MPK}
{4/10/96
Initial: G&L 800 10VF M244.87
Created: G&L 800 10VF MXXX.87
Added OpToolID and ToolOfst to line containing Speed and SpinOn in FirstTool, NewTool, and
SameTool, moved FeedEnt to same line, changed Feed label to 'E', changed the numerical format to match, MPK }

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0'
#3 = '*###.###;0'
#4 = '####.####;0'
#5 = '#######0'
#6 = '00'
#7 = '##.######;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ClearancePlane1#,4)
FORMAT(ClearancePlane2#,4)
FORMAT(ArcZRads#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Repeats#,5)
FORMAT(Tag#,6)
FORMAT(FeedTapIPR#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUBROUTINE: ' Tag# ' FOR PROGRAM: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn CoolOn EOL
ELSE
SeqC RapidC ZIn CoolOn EOL
END
RETURN

StartSub:
OpenSub
SeqC 'M' Tag# EOL
DoSubComment
RETURN

SubWarning:
IF UseComments?
IF NOT FeedConnect?
IF AnyZshift?
' ' EOL
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
' ' EOL
END
END
END
RETURN

StdSub:
SeqC 'L' Repeats# EOL {number of loops}
SeqC 'G' Tag# EOL {call sub}
SeqC 'M77' EOL {end of loop range}
StartSub
RETURN

FinishSub1: {part 1}
SeqC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
SeqC Preset ShiftRC EOL
SeqC 'M' Tag# EOL
CloseSub
SeqC Preset UnshftRC EOL
RETURN

OpenMP:
IF WorkFixtureOffsets?
' ' EOL
' ( Note - Post does not support MultipleParts with WorkFixtureOffsets. )' EOL
' ( Please change to EquallySpacedOffsets. )' EOL
' ' EOL
ELSE
TagUp TagInc
SeqC 'L' Parts# EOL {number of loops}
SeqC 'G' Tag# EOL {call sub}
SeqC 'M77' EOL {end of loop range}
StartSub
END
RETURN

CloseMP:
IF NOT WorkFixtureOffsets?
SeqC Preset ShiftPC EOL
SeqC 'M' Tag# EOL
CloseSub
SeqC Preset UnshftPC EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
IF XYPlane? AND ZMove? AND NOT Flag?('1') {helical move}
MoveXYZ ArcIJ 'K' ArcZRads#
ELSE
IF XYPlane?
MoveXY
ELSE
IF XZPlane?
MoveX MoveYC MoveZ
ELSE { YZplane }
MoveXC MoveY MoveZ
END
END
IF ArcIJFormat?
ArcIJ
ELSE
ArcR
END
END
RETURN

CkCoolOff:
IF LastFeat? AND NOT CoolOff?
CoolOff
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FeedC MoveXYZC FeedRateC CkCoolOff EOL
DecelMove2
END
SeqC FeedC MoveXYZC DecelFeed CkCoolOff EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC FeedC MoveXYZC FeedRateC CkCoolOff EOL
END
END
RETURN

ToolPath:
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC 'G' Tag# EOL {call sub}
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF PeckChipBreaker?
IF NOT FirstFeat?
SeqC MoveSXYC EOL {.80.01}
PeckManual
END
SeqC CkCoolOff EOL
ELSE
SeqC MoveSXYZC CkCoolOff EOL {.80.01}
END
END
ELSE
IF RapidFeat?
IF LastFeat? AND AutoCycle? {.70}
SeqC CRCOffC RapidC MoveXYZC CkCoolOff EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC RapidC MoveXYZC CkCoolOff EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF LastFeat?
SeqC CRCOffC FeedC MoveXYZC FeedRateC CkCoolOff EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
StdLine {enables CRC on first call}
END
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC CkCoolOff EOL
DecelMove2
END
SeqC FormatArc DecelFeed CkCoolOff EOL
ELSE
SeqC FormatArc ArcFeedC CkCoolOff EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
{ NOTE: This Post Processor does not support WorkFixtureOffsets. }
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
Seq IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC 'M' Tag# EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagUp TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
TagDown
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
TagUp TagInc
SubWarning
StdSub
SeqC AbsOrInc Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
TagDown
RETURN

ZonlyRepAutoCycle:
TagUp TagInc
AutoCycPat {write pattern moves and main calls}
StartSub
TagUp TagInc
EachCycle
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed IncValue StrtPosC EOL
SeqC AbsOrInc
ELSE
SeqC Feed
END
ELSE
SeqC Feed
END
ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid IncValue StrtPosC EOL
IF FeedEntry?
SeqC AbsOrInc ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC AbsOrInc ZInPlusInc EOL
END
ELSE
IF FeedEntry?
SeqC Rapid ZCP2PlusInc EOL
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
ELSE
IF FeedEntry?
SeqC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqC Rapid ZInPlusInc EOL
END
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqC 'G' Tag# EOL {call sub}
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
TagDown
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqC Feed ZCP2 FeedEnt EOL {.69}
ELSE
SeqC Rapid ZCP2 EOL {.69}
END
END {.69}
SeqC 'M' Tag# EOL
CloseSub
TagDown
{Element shift, not pattern}
RETURN

ZonlyRep:
TagUp TagInc
EachCycle
IF NOT FirstCycle?
SeqC Connect StrtPos EOL {.71.2, added Connect}
END
IF FeedConnect?
SeqC FeedC ZInPlusInc FeedEntC CoolOn EOL {.71.2, changed to FeedC} {4/10/96, Changed to FeedEntC, MPK}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqC RapidC ZCP2PlusIncC EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqC Feed ZInPlusInc FeedEntC CoolOn EOL {4/10/96, Changed to FeedEntC, MPK}
ELSE
SeqC RapidC ZInPlusInc CoolOn EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqC 'G' Tag# EOL {call sub}
NextCycle
StartSub
SkipZ
SetFlag('1') { suppress helical K ArcZRads }
ToolPath
SetFlagF('1')
UnSkipZ { Moved from FinishSub1 }
FinishSub1
SeqC 'M' Tag# EOL
TagDown
CloseSub
RETURN

SpeedCall:
IF Tap?
TABLE(2,Speed,1)
ELSE
TABLE(1,Speed,1)
END
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
' OPTCYC1 or OPTIONALCYCLE1 -' EOL
' using this command before an ENDOP will cause that one' EOL
' operation to use Hydrosense cycles instead of the normal cycles.' EOL
' FI-RO without dwell will use G81 instead of G85.' EOL
' FI-RO with dwell will use G82 instead of G89, dwell amount will be ignored.' EOL
' FI-FO is not available on this control, G81 will be used.' EOL
' Tapping will use G84 instead of G83' EOL
' Pecking is not available with sensing cycles, non sensing G88 will be used.' EOL
' Sensing cycles measure Z and K from the touch point. The Z depth in ncCAM' EOL
' will be used as the depth (Z) from touch point. Clearance Plane 1, in ncCAM,' EOL
' or Clearance Plane 2 will be used as the clearance value (K) from the touch point,' EOL
' depending on which you selected as the retract level.' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
{start with first tag# = 61}
TagUp
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc TagInc
EOR EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
'( PROGRAM: ' ProgramName$ ' )' EOL
END
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
DoPostScript
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
Seq Rapid Plane AbsOrInc StrtPos SpeedCall SpinOn FeedEnt OpToolID ToolOfst EOL
IF CutterRadiusCompensation?
SeqC CRCOn CRCOfst EOL
END
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC RapidC StrtPos EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts?
CloseMP
END
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid Home EOL
END
SeqC CRCOff 'H00M00' EOL

{Start new Operation}

DoOpComments
DoPostScript
CheckPass
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
Seq Rapid PlaneC AbsOrInc StrtPos SpeedCall SpinOn FeedEnt OpToolID ToolOfst EOL
IF CutterRadiusCompensation?
SeqC CRCOn CRCOfst EOL
END
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqC RapidC StrtPos EOL
END
ELSE
IF SameTool?
DoEndOpPS
SeqC CRCOff 'H00M00' EOL

{Start new Operation}

GetStartOfSameTool
Seq Rapid PlaneC AbsOrInc StrtPos SpeedCall SpinOn FeedEnt EOL
IF CutterRadiusCompensation?
SeqC CRCOn CRCOfst EOL
END
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqC ZCP3C EOL
ELSE
IF FIFO? {.81}
SeqC FeedC ZCP3C FeedEntC EOL
ELSE
SeqC RapidC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
TagUp TagInc
StdSub
SeqC Rapid StrtPos EOL
END
GetCycle
IF PeckChipBreaker?
SeqC ZCP2C CoolOn EOL
PeckManual
ELSE
IF Peck? OR NOT OptCyc1?
SeqC Cycle ZDepth RLevel
IF RetractToCP1?
'K' ClearancePlane1#
ELSE
'K' ClearancePlane2#
END
Peck
IF Tap?
'E' FeedTapIPR# ('1')
END
CoolOn EOL
ELSE {OptCyc1 hydrosense, no pecking}
IF Tap?
SeqC 'G84Z' ZDepth# 'K'
IF RetractToCP1?
ClearancePlane1#
ELSE
ClearancePlane2#
END
CoolOn EOL
ELSE
IF Dwell?
SeqC 'G82Z'
ELSE
SeqC 'G81Z'
END
ZDepth# 'K'
IF RetractToCP1?
ClearancePlane1#
ELSE
ClearancePlane2#
END
CoolOn EOL
END
END
END
TrackZNO# FIRST SPZ# {.81.2}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
IF Repeats?
FinishSubG92
TagDown
END
SeqC Rapid ZCP3 EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts?
CloseMP
END
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC FirstHome EOL
END
SeqC CRCOff 'H00'
IF MultipleParts? AND AllToolsOnePart?
'M00' EOL
CloseMP
END
EOL
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END