{Change Comments ***********************************************************}

{6/5/89, changed tool path to force feed on first TP move after a tool change,added Metric, WFG}
{.62,1/24/90, added OP clearances for v3.2, WFG}

{1/29/90
Modified: Fanuc 10T MS [-] L001.69
Deleted ClearancePlane1# & FirstMoveEPX# prog format, they are not being used.
Deleted extra 4 lines not needed from fall thru if not canned cycle.
Added SetHome command, enables incremental ouput.
Deleted ZeroPosReg command, has no effect.
Jim Radcliffe}

{2/16/90
Modified: Fanuc 10T MS [-] L001.69.1
Added Feedrate to Approach sub.
Deleted FirstFeed sub & changed FirstFeed command to Feedrate in ToolPath.
Jim Radcliffe}

{2/20/90
Modified: Fanuc 10T MS [-] L001.69.2
Deleted extra StockOnNoCan command from Approach sub.
Added missing CheckOffset commands to Sametool.
Added FeedrateC commands to SameTool Feed lines.
Jim Radcliffe}

{5/10/90
Modified: Fanuc 10T MS [-] L001.69.3
Added missing CSS stuff for same tool where the last operation was not CSS.
Jim Radcliffe}

{5/30/90
Modified: Fanuc 10T MS [-] L001.69.4
Changed 1st axis moves in Approach to unconditional moves.
Jim Radcliffe}

{6/4/90
Modified: Fanuc 10T MS [-] L001.69.5
Commented out Feedrate in Approach & FeedrateC in SameTool, rapid to start point.
Jim Radcliffe}

{6/21/90
Modified: Fanuc 10T MS [-] L001.69.6
Commented out Feed in Approach & in SameTool, see last note.
Put back the FirstFeed sub and calls in ToolPath that was deleted earlier.
Jim Radcliffe}

{7/3/90
Modified: Fanuc 10T MS [-] L001.69.7
Modified Approach sub and Approach handling for SameTool.
Moved all ConstantSurfaceFeed output to common point of all operations.
Modified the FirstFeed sub to output Feedrate on FirstFeat of each operation.
Added comment restricting use of modifiers during EACHQuadrant/NEXTQuadrant loop.
DWB}

{.71, Added PSComments, minor fixes, 8/1/90, JR}
{9/25/90, Update to Version 3.2 per Fanuc 10T MS [-] L001.71.1 Format, DWB}
{10/2/90, Added StockOff globally at FirstOperation, DWB}
{10/8/90, Replace CalcRPM2 globally with CalcEPRPM# at end of prog, DWB}

{2/15/91,
Modified: Fanuc 10T MS [-] L001.71.3
Deleted PostScript handling of ProgStop and CoolOff related commands.
Added General Info 1 handling of ProgStop and CoolOff related commands.
Added Feed and FeedRate back in to Contour StartPoint Approach move, and Deleted FirstFeed sub.
Modified handeling of ConstantSurfaceSpeed for SameTool operations in CheckOffset sub.
Added code for handling Tap cycles correctly in ToolPath and at end of each Operation.
Deleted XTapAtZ from Thread feature line in ToolPath.
Added CheckRapid sub to output Rapid where needed.
Added AbsOrInc to FirstOperation to allow for incremental output.
Deleted Plane command from IF NewTool? because it is already set in FirstOperation.
Deleted XStkLast and ZStkLast from RoughContour canned cycle line, they are obsolete.
Modified Canned Drilling output to handle Tapping and AutoFinish better.
DWB}

{3/29/91, Update to Version 4.0 Format, DWB}

{4/17/91
Modified: Fanuc 10T MS [-] L001.80
For: Gibbs & Associates
Replaced AbsOrInc command with SetAbs, in FirstOperation, and changed MoveType$ to 'ABSOLUTE'.
This is because Fanuc controls that operate in Standard 'G' code group 'A', interpret 'G90'
as Cutting Cycle 'A', and all incremental moves are output using 'U' and 'W' addresses. All
Post Processors that fall into this category MUST BE MODIFIED!!!
All Fanuc controls that operate in Special 'G' code groups 'B' and 'C', do interpret 'G90'
to set the control into incremental mode, and therefore, any post processors that fall into
this category do not need this modification.
DWB}

{8/2/91
Modified: Fanuc 10T MS [-] L001.81
For: Gibbs & Associates
Deleted StockOff form Approach sub, it's called from all operations.
Broke up Approach sub for all operations for improved readability and less nested decisions.
Combined and modified CheckRapid subs.
Moved XOpECDC for IDExit from end of operation to NewTool, SameTool and end of Prog.
This was to ensure that all operations end at the LAST Features EndPoint.
Added LAST to XOpECDC and ZOpECPC commands at SameTool.
DWB}

{11/14/91
Modified: Fanuc 10T MS [-] L001.82
For: Gibbs & Associates
Added RestoreScale Sub per 4-Axis Post Processor.
Added Logic to suppress Feed and FeedRate for Approaches.
Modified output of Speed & ConstantSurfaceFeed for SameTool in CheckOffset sub.
Changed SetAbs to SetAbsOrInc at setup and initializations.
Added bypass of AutoFinish for Non-Canned RoughSimple Operations.
Modified AutoFinish Approach.
DWB}

{1/5/95
Copied & modified: Fanuc 10T MS [-] L001.82ż
For: Braden Eng / Cardinal Scales
Machine: Mori Seiki AL-2
Control: Fanuc 10TA
Positive side lathe
Bar Feed routine.
G99 for feed per revolution
R radius format arcs.
Suppress tool comments for SameTool operations.
Jim Radcliffe}

{1/30/95
Modified: Fanuc 10TA MS [CS] L321.82
For: Braden Eng / Cardinal Scales
Modified literal bar feed stop operation at beginning of program.
Not using Home Positions. Deleted all Home calls.
Preset for MaxRPM only if CSS operation.
Index position at G30U0W0
Changed Dwell label from X to U
Call tool and offset at same time in main.
Using OptionalCycle1 for BarFeed-CutOff program.
Jim Radcliffe}

{2/23/95
Modified: Fanuc 10TA MS [CS] L321.82.1
Changed GearRange to 'M42'.
Deleted G30U0W0 lines, added Home commands.
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.######;0.'
#6 = '###0'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
FORMAT(ZStockMin#,2)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF NOT SameTool?
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
END
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ODApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

IDApproachSP:
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
RETURN

FaceApproachSP:
SeqLabC StockOnNoCan XSPC EOL { for SameTool ApproachFace }
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
RETURN

AppMove:
StockOff ZCP CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC StockOff XCP AppMove EOL
ODApproachSP
ELSE
IF ApproachID?
SeqLabC StockOff XOpCD AppMove EOL
IDApproachSP
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
FaceApproachSP
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' Speed
END
END
IF LAST ProgStop?
SeqLabC SpeedC SpinOn EOL
SeqLabC CoolOn EOL
ELSE
SeqLabC SpeedC EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4U2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4U' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

WFOStuff:
'G54'
RETURN

OpenChuck:
'M11'
RETURN

CloseChuck:
'M10'
RETURN

InchesPerMin:
'G98'
RETURN

InchesPerRev:
'G99'
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
OptCyc1F
SetAbsOrInc
PosSideLathe
SetMaxRPM('4000')
SetMaxFeed('500') {?}
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' OptionalCycle1, OptCyc1 -' EOL
' When it is called in the first operation before an ENDOP,' EOL
' it sets the first operation to a Bar Feed operation' EOL
' and sets the last operation to use the parts catcher.' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
' ' EOL

DoPostScript

IF OptCyc1?
SeqLab
IF UseComments?
'( TOOL 1: Stock Stop )' EOL
END
SeqLabC Rapid WFOStuff InchesPerMin 'M41' EOL
SeqLabC 'G97S100T0101M3' EOL
SeqLabC Rapid 'X0.Z.1' EOL
SeqLabC Feed 'Z' ZStockMin# 'F250.' EOL
SeqLabC OpenChuck EOL
SeqLabC 'G4U500' EOL
SeqLabC Feed 'Z.02' EOL
SeqLabC CloseChuck EOL
SeqLabC 'G4U500' EOL
SeqLabC Rapid XCP ZCP EOL
SeqLabC Home 'T0100' EOL
SeqLabC ProgStop EOL
' ' EOL
END

SeqLab DoOpComments
SeqLabC Rapid WFOStuff InchesPerRev 'M42' EOL
Plane
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOff 'G97' CalcRPM1
ELSE
SeqLabC CSSOff 'G97' Speed
END
OpToolID LatheOffset SpinOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC XCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC ZCPC EOL
DoEndOpPS
SeqLabC
IF LAST ConstantSurfaceFeed?
CSSOff 'G97' CalcRPM2
END
NewHome LOfstOff '00' CoolOff EOL
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

' ' EOL
DoPostScript
SeqLab DoOpComments
SeqLabC Rapid WFOStuff InchesPerRev 'M42' EOL
Plane
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOff 'G97' CalcRPM1
ELSE
SeqLabC CSSOff 'G97' Speed
END
OpToolID LatheOffset SpinOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
SeqLabC XCPC EOL
END
CheckOffset
ODApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
END
SeqLabC ZCPC EOL
SeqLabC XOpCDC EOL
END
CheckOffset
IDApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC XCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC ZCPC EOL
END
CheckOffset
FaceApproachSP
END
END
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn 'G96' Speed EOL
END
IF LastOp?
IF OptCyc1?
SeqLabC 'M73' EOL { parts catcher extend }
END
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
IF ApproachFace?
SeqLabC LCycle 'Z' FirstMoveEPZ# XatFinZ XTapAtZ FeedRate EOL
ELSE
SeqLabC LCycle XatFinZ FinZ XTapAtZ FeedRate EOL
END
SimpleRough
ELSE
TagInc
IF RoughContour?
SetPass2
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft CutDepth FeedRate EOL
'>' Tag# EOL
SeqLab StepMove StrtPos EOL
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
ELSE
IF RoughPatternShift?
SetPass2
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft XminusU ZminusW NumCuts FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
END
END
END
ELSE
IF Threading?
IF Chamfer?
SeqLabC 'M23' EOL
END
SeqLabC LCycle XatFinZ FinZ XTapAtZ CutMethod ThrdHeight CutDepth ThrdLead ToolAngle EOL
IF AutoFinish?
SeqLabC 'G92' XatFinZ FinZ XTapAtZ ThrdLead EOL
END
IF Chamfer?
SeqLabC 'M24' EOL
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G4U2000' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF PeckChipBreaker?
SeqLabC LCycle ZDepth RLevel Dwell Peck Retract FeedRate EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G4U' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
ELSE
IF Grooving?
StockOn
SetPass1
SeqLabC StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving? AND NOT RoughSimple?
StockOff
IF Turning?
SetPass1
RapidC
IF ApproachFace?
SeqLabC ZOpECPC EOL
FaceApproachSP
ELSE
SeqLabC XOpECDC EOL
IF ApproachOD?
ODApproachSP
ELSE {ApproachID}
IDApproachSP
END
END
ELSE
SetPass2
SeqLabC RapidC StrtPos EOL
END
ToolPath
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4U2000' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC XCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC ZCPC EOL
DoEndOpPS
IF OptCyc1?
SeqLabC 'M74' EOL { parts catcher retract }
END
SeqLabC
IF ConstantSurfaceFeed?
CSSOff 'G97S' CalcEPRPM#
END
FirstHome OpToolID '00' CoolOff EOL
IF ProgStop?
SeqLabC 'M0' EOL
END
SeqLabC 'M98P9000' EOL { call sub for parts counter }
SetLineStrtChr('/')
SeqLabC 'M99' EOL
SetLineStrtChr('')
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END