{Change Comments ***********************************************************}

{9/27/89, added PostScript to: Okuma OSP5000M-G M101.51, JR}
{3/29/90, Updated: Okuma OSP5000M-G M101.61 to .70.3 format, JR}
{7/5/90, Updated: Okuma OSP5000M-G M101.70.3 to .72.1 format, JR}
{7/24/90, Replaced all occurances of SetSRXYZero with SetSRXYtoSP, DWB}

{12/19/90
Copied & modified: Okuma 5000M-G M101.73
For: Gibbs & Associates
Machine: Okuma
Control: 5000M-G
Updated to Version 3.2 per Fanuc 6M M001.76.1 Format.
DWB}

{4/03/91
Modified: Okuma 5000M-G M101.76.1
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{09/30/91
Modified: Okuma 5000M-G M101.79
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.81 Format.
Kim Michelman}

{2/11/94, Updated Okuma 5000M-G M101.81 to .81.2 format, JR}

{10/6/95, Updated Okuma 5000M-G M101.81.2 to .85 format per Fanuc 6M M001.85.01.03, JR}

{1/17/96, Updated .85 to .86 version, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{6/19/96
Initial: Okuma 5000M-G M101.89
Created: Okuma OSP7000M Mxxx.89
ForUser: DEN-TAL-EZ, Inc.
Control: Okuma OSP7000M
Machine: Okuma MC500H
Develop: ComPost 4.21.37, Catalyst68K v3.04.10.C
Comment: New Processor per manual.
Manual says it is totaly comapataple with the OSP5000M-G
and after some review it appears so!
Changed to First Tool Not In Spindle format.
Deleted PreTool
Moved OfstOn to nest line, off of the StrtPos line.
Added support for additional Drill Cycles.
Jim Radcliffe}

{10/4/97
Initial: Okuma OSP7000M M143.89
Created: Okuma OSP700M [GTR] MW14.89
Version: ComPost2 1.0b11
Control: Okuma OSP700M
Machine: Okuma
Customer: GTR Enterprises.
Comments: Change tool change commands to full pre-select method.
Added the literal line 'G11T2Q2' at start of program. This is a Okuma macro call to avoid
a machine alarm if the spindle tool is selected.
Change G53 to Z30. for Z axis zero return. (The Z30. value must exceed the
distance to Machine zero).
Cancel canned cycles with G0 in place of G80.
Added Y30. on the line before M30 to move spindle clear for easy access to table.
KC}

{10/9/97
Removed literal G28's from Z axis machine zero commands. Machine does not accept them.
Updated from Okuma OSP700M [GTR] MW14.89 to Okuma OSP700M [GTR] MW14.89.1
KC}

{29Dec97
Original: Okuma OSP700M [GTR] MW14.89.1
Created: Okuma LH OSP700M [HIR] Mxxx.12
For: Hirschler Maunfacturing
Changes made per: Jim or Matt
Provisional LONGHAND post processor for customer testing.
Changes too numerous to list at this time: To be made into an Advanced mill post.
Charles Winston}

{04/14/98,
Initial: Okuma LH OSP700M [HIR] MW84.12
Created: Okuma LH OSP700M [AT] Mxxx.12
For: Andrew Tool

Changes to Form:
1) Movement/Arcs/Spindle & Coolant - Made all G codes and M codes output in a
two digit format (G1, M8, etc.)
2) Default Formats - Changed N from ###0.b to ###0

Changes to Prog:
1) Deleted Tool List.
2) Made all moves conditional.
3) Deleted various literals througout post.
4) End2 - Added 'Z50' and 'Y50'.
5) IncrementToolUseage - Commented out.
6) DoToolLineNumber - Commented out.
7) FirstOp1 - Added literal ' IF [VTLCN EQ 1] N3'.
CDH}

{04/15/98,
Initial: Okuma LH OSP700M [AT] MV57.12
Created: Okuma LH OSP700M [AT] MV57.12.1
For: Andrew Tool

Changes to Prog:
1) Made all G-code moves (G1, G2, G3) conditional.
2) FirstOp1 - Deleted Safety block.
3) FirstOp1/NewToolOp3 - Deleted Tool Comments.
4) DoOpComments - Added Tool Comments.
5) InitOp - Deleted EOR and ProgID.
CDH}

{05/11/98,
Initial: Okuma LH OSP700M [AT] MV57.12.1
Created: Okuma LH OSP700M [AT] MV57.12.2
For: Andrew Tool

Changes to Prog:
1) FirstOp2/NewToolOp5 - Moved everything after Startpos onto a
seperate line.
CDH}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '###0'
#8 = '###0.000#;0.'
#9 = '#'
#10 = 'Ä…#bbbb.bbbb#'
#11 = '######00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(TLLength#,4)
FORMAT(TLNum#,5)
FORMAT(Tag#,5)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(ToolDiameter#,8)
FORMAT(TLDia#,8)
FORMAT(RapidF#,9)
FORMAT(PartShiftX#,10)
FORMAT(PartShiftY#,10)
FORMAT(PartShiftZ#,10)
FORMAT(Recall#,11)

{Testing Subroutines *}

#20 = 'Ä…0000.0000'
FORMAT(OriginShiftPX#,20)
FORMAT(OriginShiftPY#,20)
FORMAT(OriginShiftPZ#,20)
FORMAT(OriginUnshiftPX#,20)
FORMAT(OriginUnshiftPY#,20)
FORMAT(OriginUnshiftPZ#,20)
FORMAT(OriginUSPXCTP#,20)
FORMAT(OriginUSPYCTP#,20)
FORMAT(OriginUSPZCTP#,20)

Report:
IF MultipleParts? AND WorkFixtureOffsets?
SetStatusOff
' ' EOL
' PartShiftX# = ' PartShiftX# ' '
' PartShiftY# = ' PartShiftY# ' '
' PartShiftZ# = ' PartShiftZ# EOL
'OriginUnshiftPX#(0) = ' OriginUnshiftPX#('0') ' '
'OriginUnshiftPY#(0) = ' OriginUnshiftPY#('0') ' '
'OriginUnshiftPZ#(0) = ' OriginUnshiftPZ#('0') EOL
'OriginUnshiftPX#(1) = ' OriginUnshiftPX#('1') ' '
'OriginUnshiftPY#(1) = ' OriginUnshiftPY#('1') ' '
'OriginUnshiftPZ#(1) = ' OriginUnshiftPZ#('1') EOL
'OriginUnshiftPX#(2) = ' OriginUnshiftPX#('2') ' '
'OriginUnshiftPY#(2) = ' OriginUnshiftPY#('2') ' '
'OriginUnshiftPZ#(2) = ' OriginUnshiftPZ#('2') EOL
' OriginShiftPX# = ' OriginShiftPX# ' '
' OriginShiftPY# = ' OriginShiftPY# ' '
' OriginShiftPZ# = ' OriginShiftPZ# EOL
' OriginUSPXCTP#(0) = ' OriginUSPXCTP#('0') ' '
' OriginUSPYCTP#(0) = ' OriginUSPYCTP#('0') ' '
' OriginUSPZCTP#(0) = ' OriginUSPZCTP#('0') EOL
' OriginUSPXCTP#(1) = ' OriginUSPXCTP#('1') ' '
' OriginUSPYCTP#(1) = ' OriginUSPYCTP#('1') ' '
' OriginUSPZCTP#(1) = ' OriginUSPZCTP#('1') EOL
' OriginUSPXCTP#(2) = ' OriginUSPXCTP#('2') ' '
' OriginUSPYCTP#(2) = ' OriginUSPYCTP#('2') ' '
' OriginUSPZCTP#(2) = ' OriginUSPZCTP#('2') EOL
' ' EOL
SetStatusOn
END
RETURN

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoPartCycleComment:
IF MultipleParts? AND UseComments? AND SubComment?
'( PART NO. ' Tag# ' )' EOL
END
RETURN

DoCycleComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

BadMPWFOReport:
SetStatusOff
' ' EOL
'Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„' EOL
'Ä„ NOTE: Even though you have elected to Ä„' EOL
'Ä„ process this file using Multiple Ä„' EOL
'Ä„ Parts with Work Fixtures, there exist Ä„' EOL
'Ä„ non-zero values in the invisible, Ä„' EOL
'Ä„ Equally SpacedÉ fields, as follows: Ä„' EOL
'Ä„ Ä„' EOL
'*****************************************' EOL
IF NotEqual? PartShiftX# Num#('0')
' X axis shift = ' PartShiftX# EOL
END
IF NotEqual? PartShiftY# Num#('0')
' Y axis shift = ' PartShiftY# EOL
END
IF NotEqual? PartShiftZ# Num#('0')
' Z axis shift = ' PartShiftZ# EOL
END
'*****************************************' EOL
'Ä„ Ä„' EOL
'Ä„ Please reset these values to zero as Ä„' EOL
'Ä„ they affect the coordinate values Ä„' EOL
'Ä„ output, starting with Part# 2. Ä„' EOL
'Ä„ Thank You. Ä„' EOL
'Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„Ä„' EOL
' ' EOL
SetStatusOn
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC ' A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC ' A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC ' B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC ' B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqC FeedC ZIn FeedEntC EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

ExitMove:
SeqC
IF FeedConnect?
IF NOT AutoCycle?
IF NOT NoZMoves?
FeedC ZInC FeedEntC
END
END
ELSE
CRCOffC
IF FIFO? { .81 }
FeedC
ELSE
RapidC
END
PRIME ZCP2C
IF FIFO? { .81 }
FeedEntC
END
END
EOL
RETURN

ExitMove2:
IF FIFO?
FeedC ZCP3 FeedEntC
ELSE
RapidC ZCP3
END
RETURN

CycleWarning:
{ NOTE: This Post Processor takes care of Z Clearance. }
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
SetFlag('1') { CRCOffsetC }
CRCOnC
END
END
RETURN

ckCRCNum:
IF Flag?('1')
SetFlagF('1')
CRCOffsetC
END
RETURN

FormatLine:
ckCRC FeedC MoveXYC MoveZC ckCRCNum
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat? { Drilling Only }
SeqC MoveSXC MoveSYC MoveSZC EOL
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC ckCRC ckCRCNum Rapid MoveXYC MoveZC EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatLine FeedRateC EOL
DecelMove2
END
SeqC FormatLine DecelFeed EOL
ELSE
SeqC FormatLine FeedRateC EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
IF AutoCycle?
SetAbs
Save# Num#('46') SUB# EPX# CurOriginPosX#
Save# Num#('47') SUB# EPY# CurOriginPosY#
SetInc
END
END
NEXTFeat
RETURN

AutoCycCutSub1: {part 1}
CalcACSRXY {calc tool position, CalcAutoCycleStatusRecordXY}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
IF Repeats? AND ZShiftOnly?
EntryMove
END
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
SeqC AbsOrInc
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
EOL
SetSRSubXY {restore SR to 1st position value}
ReSetPass2 {restore for positioning moves}
RETURN

Milling:
EntryMove
ToolPath
RETURN

XYZRep:
CycleWarning
FindAnyZMoves
EachRep
DoCycleComment
IF FirstCycle?
EntryMove
ELSE
CRCOffC
IF FeedConnect?
IF SPXMove? OR SPYMove?
SeqC FeedC MoveSXC MoveSYC FeedEntC EOL
END
IF ZShiftOnly?
EntryMove
END
ELSE
IF SPXMove? OR SPYMove?
SeqC Rapid MoveSXC MoveSYC EOL
END
IF FeedEntry?
SeqC ZCP2C EOL
END
EntryMove
END
END
ToolPath
ExitMove
NextRep
RETURN

NoRepAutoCycle:
EACHFeat
DoCycleComment
IF SPXMove? OR SPYMove?
SeqC Rapid MoveSXC MoveSYC EOL
END
AutoCycCutSub1
Milling
AutoCycCutSub2
NEXTFeat
RETURN

XYZRepAutoCycle:
CycleWarning
EachRep
EACHFeat
DoCycleComment
IF SPXMove? OR SPYMove?
SeqC Rapid MoveSXC MoveSYC EOL
END
SetAbs
Save# Num#('44') SPX#
Save# Num#('45') SPY#
SetInc
AutoCycCutSub1
Milling
AutoCycCutSub2
SetAbs
TrackXNO# ADD# Recall# Num#('44') Recall# Num#('46')
TrackYNO# ADD# Recall# Num#('45') Recall# Num#('47')
SetAbsOrInc
NEXTFeat
NextRep
RETURN

ZonlyRepAutoCycle:
EACHFeat
DoCycleComment
IF SPXMove? OR SPYMove?
SeqC Rapid MoveSX MoveSY EOL
END
AutoCycCutSub1
EachRep
IF NOT FirstCycle?
IF FeedConnect?
SeqC AbsOrInc EOL
DoCycleComment
IF SPXMove? OR SPYMove?
SeqC IncValue MoveSXC MoveSYC EOL
AbsOrInc
END
ELSE
AbsOrInc
ExitMove
DoCycleComment
IF SPXMove? OR SPYMove?
SeqC IncValue MoveSXC MoveSYC EOL
AbsOrInc
END
IF FeedEntry? AND NOT FIFO?
SeqC ZCP2 EOL
END
END
EntryMove
SeqC IncValue EOL
END
EntryMove
ToolPath
NextRep
AutoCycCutSub2
NEXTFeat
RETURN

DrillStuff:
IF RetractToCP1?
SeqC ' G71' ZCP1 EOL
END
GetCycle
SeqC
IF Tap? AND NOT CWSpindle?
' G74'
ELSE
Cycle
END
StrtPos ZDepth RLevel Dwell Peck Retract FeedEnt FromCP EOL
TrackZNO# FIRST SPZ# {.81.2}
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SetZero:
Save# NUM#('50') ADD# Recall# NUM#('50') NUM#('1') { Increment counter by 1 }
Save# Recall# NUM#('50') NUM#('0')
RETURN

Call_SetZero:
Save# Num#('50') NUM#('0') { Setup the Op Number to be examined, (Initialized to zero) }
SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero
SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero
SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero
SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero SetZero {Call 40 times}
Save# Num#('50') NUM#('0')
EOL
RETURN

{IncrementToolUseage: { Adds an index e.g. 01, 02, 03 etc each time the tool is used }
Save# Tool# ADD# Recall# Tool# NUM#('1')
RETURN} {No longer used - CDH}

{DoToolLineNumber: { uses Tool# as the line number and adds an index e.g. 01, 02, 03 etc each time the tool is re-used }
'N' Tool#
IF NotEqual? Recall# Tool# NUM#('0')
Recall# Tool#
END
IncrementToolUseage
RETURN} {No longer in use - CDH}

ProgStart:
InitProg
TagInit
ReverseXZArcs
InitWFONum
SetFlood
SetMaxRPM('10000')
SetMaxFeed('500')
Call_SetZero { Initialises variables from 0 to 40 to Zero }
Save# Num#('41') Num#('0') { This Tool FirstOp# }
Save# Num#('42') Num#('0') { This Tool LastOp# }
Save# Num#('43') Num#('0') { LastOp# }
Save# Num#('44') Num#('0') { XPos Status Register Updated Position for Repeated AutoCycles }
Save# Num#('45') Num#('0') { YPos Status Register Updated Position for Repeated AutoCycles }
Save# Num#('46') Num#('0') { LastFeat EPX# AbsPosValue for Repeated AutoCycles }
Save# Num#('47') Num#('0') { LastFeat EPY# AbsPosValue for Repeated AutoCycles }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
RapidF# { No Output }
IF Milling?
SeqC ZCP2C EOL
IF AutoCycle?
IF Repeats?
IF ZShiftOnly?
ZonlyRepAutoCycle
ELSE
XYZRepAutoCycle
END
IF NOT FeedConnect?
SeqC ExitMove2 EOL
END
ELSE
NoRepAutoCycle
SeqC ExitMove2 EOL
END
ELSE { NOT AutoCycle }
IF Repeats?
XYZRep
ELSE
Milling
END
SeqC CRCOffC EOL
SeqC ExitMove2 EOL
END
ELSE
IF Drilling?
IF Repeats?
EachRep
DoCycleComment
IF FirstCycle?
DrillStuff
END
ToolPath
NextRep
ELSE
DrillStuff
ToolPath
END
SetDrillEndOpZ
SeqC RapidC ' G80' CRCOffC EOL
END
END
RETURN

WFOStuff:
IF MultipleParts? AND WorkFixtureOffsets? AND NewWFO?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
IF NewWFO?
SeqC ' G15 H' NewWFO#
ELSE
IF MultipleParts? AND WorkFixtureOffsets? AND NOT SameTool?
FORMAT(ADD#,5)
SeqC ' G15 H' ADD# NewWFO# SUB# Tag# Num#('1')
FORMAT(ADD#,4)
ELSE
IF NeedWFO1? AND NOT SameTool?
SeqC ' G15 H' NewWFO#
END
END
END
END
RETURN

ResetWFO:
IF WorkFixtureOffsets?
SeqC WFO1 EOL
END
RETURN

InitOp:
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
Plane
Seq ' G15 H1' EOL
' IF [VTLCN EQ 1] N3' EOL
Seq OpToolID ToolChng EOL
DoOpComments
DoPostScript
RETURN

FirstOp2:
CheckPass
SeqC Rapid StrtPos EOL
SeqC OfstOn SpinOn Speed EOL
SeqC PreTool CoolOn EOL
RETURN

FirstOp3:
RETURN

NewToolOp1:
IF NOT LAST Drilling?
SeqC RapidC CoolOff ' G80' CRCOff EOL
END
RETURN

NewToolOp2:
DoEndOpPS
IF ToolChangeAtHome?
SeqC Rapid Home EOL
END
IF LAST ProgStop?
SeqC ' M00' EOL
ELSE
SeqC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
SeqC ToolChng EOL
IF OptCyc1?
SeqC ' G15 H1' EOL
SeqC Rapid ' Z0' EOL
SeqC Rapid ' X0 Y0' EOL
SeqC ' M00 (Change Clamps)' EOL
END
SeqC WFOStuff EOL
DoOpComments
DoPostScript
RETURN

NewToolOp4:
SeqC PreTool CoolOn EOL
RETURN

NewToolOp5:
CheckPass
Seq AbsOrInc Rapid StrtPos EOL
SeqC SpinOn Speed OfstOn EOL
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
SeqC CoolOff EOL
SeqC ' G53' EOL
SeqC ' M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC ' G53' EOL
END
END
RETURN

SameToolOp2: {Start new Operation}
DoPartCycleComment
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
IF LAST ProgStop?
SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC SpinOn EOL
SeqC OfstOn EOL
SeqC CoolOn EOL
ELSE
SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC EOL
IF NewToolOffset?
SeqC OfstOn EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
RETURN

End1:
RETURN

End2:
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqC Rapid FirstHome EOL
END
SeqC CoolOff EOL
SeqC ToolChng EOL
SeqC ' Z50' EOL
SeqC ' Y50' EOL
RETURN

End3:
SeqC EOP EOL
EOR EOL
Post
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
' ( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
' ( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
' ( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
IF FirstOperation?
IF FirstPart?
InitOp
END
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
IF FirstOperation?
IF FirstPart?
InitOp
FirstOp1
FirstOp2
OpenMP
FirstOp3
END
ELSE
IF NewTool?
IF FirstPart?
NewToolOp1
CloseMP
ResetWFO
NewToolOp2
NewToolOp3
NewToolOp4
OpenMP
NewToolOp5
END
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
IF FirstOperation?
IF FirstPart?
InitOp
FirstOp1
FirstOp2
FirstOp3
OpenMP
END
ELSE
IF NewTool?
IF FirstPart?
CloseMP
NewToolOp1
ResetWFO
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
OpenMP
END
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN

NoMPs: {no multiple parts}
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END
OpGuts
RETURN

MasterSub:
IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END
RETURN

EndPartSub:
{End of program ************************************************************}

{finish last operation}
IF MultipleParts?
IF AllToolsOnePart?
End1
End2
CloseMP
ELSE {implied OneToolAllParts?}
IF FullUp?
End1
CloseMP
ResetWFO
End2
ELSE {implied ExitClearancePlane?}
CloseMP
End1
ResetWFO
End2
END
END
ELSE {NoMPs}
End1
End2
END
RETURN

DoNewPart:
IF NOT FirstPart?

{Finish off last Part}

IF FullUp?
SeqC CoolOff EOL
IF AbsoluteMoves?
IncValue
END
SeqC OfstOff EOL
END
{DoEndOpPS}

{Start new Part}

DoPartCycleComment
DoOpComments
DoPostScript
WFOStuff
CheckPass
SeqC PlaneC AbsOrInc Rapid StrtPos SpeedC EOL
IF FullUp?
SeqC OfstOn EOL
SeqC CoolOn EOL
END
END
RETURN

DoParts:
TagInit
EachPart
TagInc
EachOp
IF AllToolsOnePart?
MasterSub
ELSE { OneToolAllParts }
IF GTEqual? Operation# Recall# Num#('41') { Tool First Op }
IF LTEqual? Operation# Recall# Num#('42') { Tool Last Op }
IF Equal? Operation# Recall# Num#('41') { Tool First Op }
DoNewPart
END
MasterSub
END
END
END
NextOp
IF AllToolsOnePart?
EndPartSub
END
NextPart
RETURN

GetToolFirstOp:
Save# Num#('42') Recall# Num#('41')
RETURN

GetToolLastOP:
EachOp
IF Equal? Operation# Recall# Num#('42')
Save# Num#('42') ADD# Operation# Num#('1')
IF NewTool?
IF Equal? Recall# Num#('41') Recall# Num#('43')
Save# Num#('42') Operation#
ELSE
IF NotEqual? Recall# Num#('41') SUB# Recall# Num#('42') Num#('1')
Save# Num#('42') SUB# Operation# Num#('1')
END
END
END
END
NextOp
RETURN

MPLoop:
IF AllToolsOnePart?
DoParts
ELSE { OneToolAllParts }
GetToolFirstOp
IF LTEqual? Recall# Num#('41') Recall# Num#('43')
GetToolLastOP
DoParts
Save# Num#('41') ADD# Recall# Num#('42') Num#('1') { Next Tool First Op }
END
END
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF WorkFixtureOffsets?
{'NOTE: This Post Processor does not support Work Fixture Offsets for Multiple Parts.' EOL
'Therefore, the output will be controlled by the following values that are' EOL
'already entered in Equally Spaced Offsets Edit Fields:' EOL
'X' PartShiftX# ' Y' PartShiftY# ' Z' PartShiftZ# EOL
'It is recommended that you change your selection to Equally Spaced Offsets.' EOL}
IF NotEqual? PartShiftX# Num#('0')
BadMPWFOReport
ELSE
IF NotEqual? PartShiftY# Num#('0')
BadMPWFOReport
ELSE
IF NotEqual? PartShiftZ# Num#('0')
BadMPWFOReport
END
END
END
END
EachOp
IF FirstOperation?
Save# Num#('41') Operation#
ELSE
IF LastOp?
Save# Num#('43') Operation#
END
END
NextOp
MPLoop
IF OneToolAllParts?
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
EndPartSub
ELSE
ResetWFO
END
ELSE
EachOp
MasterSub
NextOp
EndPartSub
END
End3