{Change Comments ***********************************************************}

{1/29/90, Updated: Fanuc 0T-Miyano L008.52 to .69 format, JR}
{7/24/90, Added InitProg globally to posts with this remark, DWB}
{9/25/90, Updated to Version 3.2 per Fanuc 10T MS [-] L001.71.1 Format, DWB}
{10/2/90, Added StockOff globally at FirstOperation, DWB}
{10/8/90, Replace CalcRPM2 globally with CalcEPRPM# at end of prog, DWB}

{3/27/91
Modified: Fanuc 0T/3T Miyano L008.71.3
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format.
All normal Fanuc Canned Cycles are supported.
Added Math to calculate start of Tapered Thread for AutoFinish.
DWB}

{4/17/91
Modified: Fanuc 0T/3T Miyano L008.80
Replaced AbsOrInc command with SetAbs, in FirstOperation, and changed MoveType$ to 'ABSOLUTE'.
DWB}

{8/5/91
Updated: Fanuc 0T/3T Miyano L008.81
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.82 Format.
KM}

{3/30/90
Updated: Fanuc 0T/3T Miyano L008.82
For: Gibbs & Associates
Corrected RoughContour Approach Bug.
3TCs and 0Ts do not support the Type II hill and valley contour.
Approach must be only X-axis for OD and ID Approaches, and Z-axis for Face Approaches.
Modified output of Speed & ConstantSurfaceFeed for SameTool in CheckOffset sub.
Added Logic to suppress Feed and FeedRate for Approaches.
Added bypass of AutoFinish for Non-Canned RoughSimple Operations.
DWB}

{4/16/91
Copied & modified: Fanuc 0T/3T Miyano L008.82.1
For: Valley Todeco
Machine: Okuma
Machine is like 2 lathes in one. It has 2 Spindles each with its own turret.
They can be run independently of each other or can be run simultainiusly.
Control has a Left/Right switch for maipulation of either side.
The processor should be written as if its just a regular lathe, nothing special.
Control: Fanuc 0T
Modifications to the beginning and ending of tools.
Using G50 Home preset.
Using G28 for index position.
This is a first draft per customer requests.
Jim Radcliffe}

{11/16/94
Modified: Fanuc 0T Okuma [VT] L255.82
For: Colquitt Machine Co.
Machine: Okuma
Control: Fanuc 0T

Moved Tool Change onto a line of it's own.
Added CoolOff to end of operation on move to Exit CP (ZCPC)
Moved Optional Stops and Program Stops to be on a line by themself.

Tom Hubina}

{8/26/95, Updated Fanuc 0T Okuma [CM] L318.82.1 to .85 format per Fanuc 10T MS [-] L001.85.01.01, JR}

{5/17/96,
Initial: Fanuc 0M Okuma [CM] L318.85
Created: Fanuc 0M Okuma [CM] L318.85.1
Modified canned threading cycle as per customer request, MPK}

{05/13/98,
Initial: Fanuc 0M Okuma [CM] L318.85.1
Created: Fanuc 0M Okuma [] Lxxx.85
For: Svedala

Changes to Form:
1) Arcs - Modified so that "R"-style arcs are used.

Changes to Prog:
1) FirstOp - Deleted Rapid 'G28U0.W0.' Replaced with G20. Added AbsOrInc on line after G20.
Changed Preset to 'G92'.
2) NewTool - Deleted Rapid 'G28U0.W0.' Replaced with G20. Added AbsOrInc on line after G20.
Changed Preset to 'G92'. Deleted ConstantSurface boolean before '{Start new Operation}'. Added
SpinOff to line after CoolOff.
3) End Of Prog - Added SpinOff to line after CoolOff. Deleted 'G28U0.W0.'
4) DoRangeCode - New sub-routine for gear changes. Takes into account Constant Surface Speed.
5) CheckOffset - Added SetFlag('1') so that DoRangeCode won't be output twice.
CDH}

{29Jun98
Original: Fanuc 0T Okuma [SP] L728.85
Created: Fanuc 0T Okuma [SP] L728.85.1
For: Svedala
Changes made per: Bill Pruitt
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
Added Literals 'G20' and 'G90' to FirstOperation and NewTool
Deleted Literal '00' and added LatheOffset to OpToolID in FirstOperation and NewTool
Added Rapid Home line in FirstOperation and NewTool and End of Prog
Added FirstHome at End of Prog
Deleted OpToolID '00' at End of Prog
Charles Winston}

{1Jul98
Original: Fanuc 0T Okuma [SP] L728.85.1
Created: Fanuc 0T Okuma [SP] L728.85.2
For: Svedala
Changes made per: Bill Pruitt
Added Boolean IF NewToolOffset? OR LAST ProgStop? at CheckOffset
Deleted OpToolID '00' at CheckOffset
Charles Winston}

{17Aug98
Original: Fanuc 0T Okuma [SP] L728.85.2
Created: Fanuc 0T Okuma [SP] L728.85.3
For: Svedala
Changes made per: Bill Pruitt
Moved Home before OpToolID LatheOffset in FirstOperation and NewTool
Charles Winston}

{19Aug98
Original: Fanuc 0T Okuma [SP] L728.85.2
Created: Fanuc 0T Okuma [SP] L728.85.3
For: Svedala
Changes made per: Bill Pruitt
Changed 'G32' to 'G33' in ToolPath at ThreadFeat and Common Point, Not canned.
Charles Winston}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.######;0.'
#6 = '###0'
#7 = '#'
#8 = '00'
#9 = '^0000'
#10 = '0.####'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(InFeedAngle#,2)
FORMAT(ADD#,2)
FORMAT(SPX#,2)
FORMAT(SPZ#,2)
FORMAT(FinishXDia#,2)
FORMAT(Taper#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Program#,3)
FORMAT(Operation#,3)
FORMAT(Tool#,3)
FORMAT(Dwell#,4)
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
FORMAT(SpringPasses#,8)
FORMAT(InFeedAngle#,8)
FORMAT(LastCutXRadius#,9)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP OpToolID LatheOffset
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

DoRangeCode:
IF ConstantSurfaceFeed?
IF GreaterThan? CalcRPM1# NUM#('1200')
'M44' {High Range}
ELSE
IF GreaterThan? CalcRPM1# NUM#('750')
'M43'
ELSE
IF GreaterThan? CalcRPM1# NUM#('301')
'M42'
ELSE
'M41'
END
END
END
ELSE
IF GreaterThan? SpeedRPM# NUM#('1200')
'M44' {High Range}
ELSE
IF GreaterThan? SpeedRPM# NUM#('750')
'M43'
ELSE
IF GreaterThan? SpeedRPM# NUM#('301')
'M42'
ELSE
'M41'
END
END
END
END
RETURN

CheckOffset:
SetFlag('1') {Makes Sure that DoRangeCode is not output twice - CDH}
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset? OR LAST ProgStop?
SeqLabC OpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC 'G92' DoRangeCode MaxRPM EOL
SetFlagF('1')
END
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC
IF Flag?('1')
DoRangeCode
END
Speed EOL
END
ELSE
SeqLabC 'G92' DoRangeCode MaxRPM EOL
SeqLabC CSSOn 'G96' Speed EOL
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' DoRangeCode Speed EOL
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC DoRangeCode Speed EOL
END
END
END
IF LAST ProgStop?
SeqLabC Speed SpinOn EOL
SeqLabC CoolOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC:
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G33' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
XsAreRadii
StandardXZArcs
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff
SetHome
DoOpComments
DoPostScript
Plane
SeqLab 'G20' EOL
SeqLabC 'G90' EOL
SeqLabC Rapid Home EOL
SeqLab OpToolID LatheOffset EOL
SeqLabC 'G92' DoRangeCode MaxRPM EOL
SeqLabC CoolOn EOL
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC CoolOff EOL
SeqLabC SpinOff EOL
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' ' ' EOL
ELSE
SeqLabC ProgStop ' ' EOL
END

{Start new Operation}

DoOpComments
DoPostScript
SeqLab 'G20' EOL
SeqLabC 'G90' EOL
SeqLabC Rapid Home EOL
SeqLab OpToolID LatheOffset EOL
SeqLabC 'G92' DoRangeCode MaxRPM EOL
SeqLabC CoolOn EOL
SeqLabC CSSOff 'G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL
Approach
ELSE
IF SameTool?

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn 'G96' Speed EOL
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
IF ApproachFace?
SeqLabC LCycle 'Z' FirstMoveEPZ# XatFinZ XTapAtZ FeedRate EOL
ELSE
SeqLabC LCycle XatFinZ FinZ XTapAtZ FeedRate EOL
END
SimpleRough
ELSE
TagInc
IF RoughContour?
SetPass2
SeqLabC LCycle CutDepth EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove 'Z' SPZ# EOL
SeqLabC 'X' SPX# EOL
ELSE
SeqLab StepMove 'X' SPX# EOL
SeqLabC 'Z' SPZ# EOL
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
ELSE
IF RoughPatternShift?
SetPass2
SeqLabC LCycle XminusU ZminusW NumCuts EOL
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
END
END
END
ELSE
IF Threading?
IF Chamfer?
SeqLabC 'M23' EOL
END
SeqLabC LCycle 'P'
SpringPasses#
IF Chamfer?
'10' {1 thread lead}
ELSE
'00'
END
InFeedAngle#
'Q' LastCutXRadius#
FORMAT (LastCutXRadius#,10)
'R' LastCutXRadius#
FORMAT(LastCutXRadius#,9)
EOL
SeqLabC LCycle XatFinZ FinZ XTapAtZ CutMethod ThrdHeight CutDepth ThrdLead EOL
IF Chamfer?
SeqLabC 'M24' EOL
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF PeckChipBreaker?
SeqLabC LCycle ZDepth RLevel Dwell Peck Retract FeedRate EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G33'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC CoolOff EOL
SeqLabC FirstHome EOL
SeqLabC SpinOff EOL
DoEndOpPS
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END