{Change Comments ***********************************************************}

{9/12/95, M174.81.2, Updated for Catalyst v2.20 per Fanuc 6M M001.85 Format, DWB}
{1/17/96 - Updated .85 to .86 format, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{3/6/97
Initial: BP Boss 9 M174.89
Created: BP EZ-Track DX M000.89
ForUser: Braden Engineering / Quality Mold
Control: Bridgeport EZ-Track 2 Axis
Machine: Bridgeport EZ-Track DX
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.23
Comment: New processor per marked up readout and conversation with Paul Lovelace.
Changed format G codes to suppress leading zeros.
Changed ProgID1 to ':' Program# to remove decimal point from output.
Deleted sequnce number from macro call lines.
Changed Program Loops for Multiple Parts and Repeats to sub programs looping the sub call!
Changed ToolChng from M26 to M6.
Added Home to ToolChng line.
Commented out WFOStuff calls.
Replaced special Bridgeport Cutter Comp handling with standard stuff.
This gives control to the programmer!!
Corrected loop calls:
Changed RepLab to '/'
Changed Parts to Parts#
Changed RepCycs to Repeats#
Jim Radcliffe}

{5/8/97,
Intial: BP EZ-Trak DX MY78.89
Created: BP EZ-Trak DX MY78.89.1
Changed SaveMasterProg to SaveMasterTag, was causing incorrest output of program #s, MPK}

{9/8/97
Initial: BP EZ-Trak DX MY78.89.1
Created: BP EZ-Trak DX 3A Mxxx.89
ForUser: Accurate Machine, Inc.
Control: Bridgeport EZ Trak 3 Axis
Machine: Bridgeport EZ Trak DX
Develop: ComPost2 68K 1.0b11, Virtual Gibbs 3.35 PPC
Comment: CRCOn with restatment of current position.
Jim Radcliffe}

{10/29/97
Initial: BP EZ-Trak DX 3A MX93.89
Created: BP EZ-Trak DX 3A MX93.89
ForUser: Accurate Machine, Inc.
Control: Bridgeport EZ Trak 3 Axis
Machine: Bridgeport EZ Trak DX
Develop: ComPost2 PPC 1.0b11, Virtual Gibbs 4.21 PPC
Removed ZCP1 move from SameTool Op.
JM }

{10/31/97
Initial: BP EZ-Trak DX 3A MX93.891
Created: BP EZ-Trak DX 3A MX93.891
ForUser: Accurate Machine, Inc.
Control: Bridgeport EZ Trak 3 Axis
Machine: Bridgeport EZ Trak DX
Develop: ComPost2 PPC 1.0b11, Virtual Gibbs 4.21 PPC
Removed ZCP1 move from SameTool Op part 2. (My Bad)
JM }

{3/10/98,
Initial : BP EZ-Trak DX 3A MX93.89.2
Created: BP EZ-Trak DX 3A MX93.89.3
Customer: Accurate Machine, Inc.

All changes to support drilling with motion to ZCP1 (current output is same)

Changes to "Prog":

1. Added SetFlagF('3') to flag the first Process in multi Process drilling.
2. In ToolPath, added a check IF RetractToCP1 and four motion blocks if true.
3. In EachOp, added a check IF RetractToCP1 to go to ToolPath.
4. In EachOp, added a check IF NOT MasterOp AND NOT CallMasterOp to go to ToolPath.
5. In EachOp, moved MasterOp before CallMasterOp and call sub with Tag#.
JHE}

{12Jun98
Original: BP EZ-Trak DX 3A MX93.89.3
Created: BP DX32 [AM] MU15.89
For: Accurate Machine Inc
Changes made per: Tony Seharko
Deleted old version numbers and comments e.g. {.62}, {commands}, {literals}, etc
Added SpinOn to Speed Line in FirstOperation and NewTool
Changed all ASCII(39) to ASCII(59) in Comment fields ( Outputs SemiColons instead of Single_Quotes )
Charles Winston}

{13Jun98
Original: BP DX32 [AM] MU15.89
Created: BP DX32 [AM] MU15.89.1
For: Accurate Machine Inc
Changes made per: Tony Scharko
Changed M7 to M8 in MachSpec
Charles Winston}

{17Jun98
Original: BP DX32 [AM] MU15.89.1
Created: BP DX32 [AM] MU15.89.2
For: Accurate Machine Inc
Changes made per: Tony Scharko
Added WFOStuff and support for Multiple Parts WorkfixtureOffsets. G54 thru G59
Moved ZCP1 CoolOn to a seperate line in FirstOp3 and NewToolO5
Added CoolOff at End1
Charles Winston}

{29Jun98
Original: BP DX32 [AM] MU15.89.2
Created: BP DX32 [AM] MU15.89.3
For: Accurate Machine Inc
Changes made per: Tony Scharko
Added a Boolean for CallMasterNum# at IF Drilling.
Drill cycles were not calling the MasterOp if the Operations were split up in the Operations List
Charles Winston}

{2Jul98
Original: BP DX32 [AM] MU15.89.3
Created: BP DX32 [AM] MU15.89.4
For: Accurate Machine Inc
Changes made per: Tony Scharko
Added a Boolean to send the Tool Full up with 'M25' in NewToolOp1 and SameToolOp1, affects MP_1TAP_FU only.
Charles Winston}

{7/9/98
Updated & Modified: BP DX32 [AM] MU15.89.4
Created: BP DX32 [AM] MU15.89.5
For: Accurate Machine Inc
Versions: Catalyst v4.23.13(mac)/ComPost2 1.1b3
Changes made per Tony Scharko of Accurate Machine Inc, Fax and conversation with Charles Winston.
Updated for Catalyst v4.23.13C per Fanuc 6M M001.89b Format.
Updated ZonlyRepAutoCycle Procedure.
Customer requested modifications to RigidTap Cycle.
Added FeedTapIPR# to FORMAT#4 at Prog Numeric Format Definitions.
Added literal 'M29', Enable Rigid Tapping Mode, just prior to RigidTap Cycle Block at IF Drilling.
Added literal 'G95', FeedRate Per Revolution (pitch) Mode, just prior to RigidTap Cycle Block at IF Drilling.
Added condition to output FeedTapIPR#('1'), FeedRate Per Revolution (pitch), to RigidTap Cycle Block at IF Drilling.
Added literal 'M28', Cancel Rigid Tapping Mode, just prior to DrillOff Block at end of IF Drilling.
Added literal 'G94', FeedRate Per Minute Mode, just prior to DrillOff Block at end of IF Drilling.
DWB}

{7/14/98
Modified: BP DX32 [AM] MU15.89.5
Created: BP DX32 [AM] MU15.89.6
For: Accurate Machine Inc
Versions: Catalyst v4.23.13(mac)/ComPost2 1.1b3
Changes made per Tony Scharko of Accurate Machine Inc, Fax and conversation.
Customer reported that Rigid Tap Cycle that Retracts to CP1 still outputs FeedEnt.
Added condition to output FeedTapIPR#('1'), FeedRate Per Revolution (pitch), to RigidTap Cycle Block at ToolPath PointFeat.
DWB}

{7/16/98
Modified: BP DX32 [AM] MU15.89.6
Created: BP DX32 [AM] MU15.89.7
For: Accurate Machine Inc
Versions: Catalyst v4.23.13(mac)/ComPost2 1.1b3
Changes made per Tony Scharko of Accurate Machine Inc, Fax and conversation.
Modified handling of Drilling RetractToCP1 MasterOp/CallMasterOp.
Control requires RetractToCP1 to cancel and redefine Cycle between holes.
Updated usage of Taggin commands per Dynapath 20M M074.89.
Added TagUp, TagInc and TagDown at all applicable places and deleted all others.
Rewrote IF Drilling.
Previous problems included MasterOp not creating DrillSub and CallMasterOp calling non-related
or non-existing sub.
Changed usage of Flag(3).
Flag(3) outputs Coordinates in DrillSub.
FlagF(3) outputs cancel and redefine in Main.
MasterOp calls ToolPath with FlagF(3) to output cancel and redefine in Main and then
creates DrillSub and calls ToolPath with Flag(3) to output Coordinates for future CallMasterOp.
CallMasterOp calls ToolPath to output cancel and redefine in Main.
Does not call DrillSub.
DWB}

{7/28/98
Modified: BP DX32 [AM] MU15.89.7
Created: BP DX32 [AM] MU15.89.8
For: Accurate Machine Inc
Versions: Catalyst v4.23.13(mac)/ComPost2 1.1b3
Changes made per Tony Scharko of Accurate Machine Inc, Pocket Test file and conversation.
Customer reported that 6MP-WFO-OTAP-ECP output did not restore Roughing FeedRate when control
moved to second part.
Cause of problem was due to RIRO Operation containing same FeedRate value as previous value, which
suppressed FeedRate due to conditional FeedRateC command of ToolPath.
Added FORMAT#7, '#' at Prog Numeric Format Definitions.
Added RapidF# to FORMAT#7 at Prog Numeric Format Definitions.
Added RapidF# to RapidEntry at EntryMove.
DWB}

{01/12/99,
Initial: BP DX32 [AM] MU15.89.8
Created: BP DX32 [AM] MU15.89.9
For: Accurate Machine Inc.

Changes to Prog:
1) FormatArc - Changed ArcIJC to ArcIJ.
CDH}

{01/28/99,
Initial: BP DX32 [AM] MU15.89.9
Created: BP DX32 [AM] MU15.89.10
For: Accurate Machine

Changes to Prog:
1) FirstOp2 - Added literal 'G8'.
CDH}

{02/18/99,
Initial: BP DX32 [AM] MU15.89.10
Created: BP DX32 [AM] MU15.89.11
For: Accurate Machine

Changes to Prog:
1) ToolPath - Added literal 'G48' when LineFeat and CutterComp.
}

{Prog Numeric Format Definitions ****}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '###^#0'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4)
FORMAT(TrackZNO#,4)
FORMAT(SPX#,4)
FORMAT(SPY#,4)
FORMAT(Tag#,5)
FORMAT(Program#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Repeats#,5)
FORMAT(Dwell#,6)
FORMAT(FeedTapIPR#,4)
FORMAT(RapidF#,7)

{Prog Subroutines ****}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

WFONum:
'G' NewWFO#
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts? AND WorkFixtureOffsets?
EOL
ASCII('59') '*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' ASCII('59') EOL
ELSE
WFONum
END
ELSE
IF Flag?('2')
IF NOT SameTool?
IF MultipleParts?
IF WorkFixtureOffsets?
WFO1
ELSE
WFONum
END
ELSE
WFONum
END
END
END
END
SetFlagF('2')
RETURN

DoSubComment:
IF UseComments? AND SubComment?
ASCII('59') ' SUB NUMBER: ' Tag# ' ' ASCII('59') EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
ASCII('59') ' OPERATION ' Operation# ': ' OperationType$ ' ' ASCII('59') EOL
END
IF OperationComment?
ASCII('59') ' ' OperationComment$ ' ' ASCII('59') EOL
END
IF WorkGroupComment?
ASCII('59') ' ' WorkGroupComment$ ' ' ASCII('59') EOL
END
IF ToolTypeComment?
ASCII('59') ' TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' ' ASCII('59') EOL
END
IF ToolComment?
ASCII('59') ' ' ToolComment$ ' ' ASCII('59') EOL
END
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLabC 'A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLabC 'A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLabC 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLabC 'B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL
PSStuff
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLabC Feed ZIn FeedEnt EOL
ELSE
RapidF# { Forces FeedRate }
SeqLabC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
'#' Tag# EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
ASCII('59') ' ' ASCII('59') EOL
ASCII('59') ' ( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT ) ' ASCII('59') EOL
ASCII('59') ' ' ASCII('59') EOL
END
END
RETURN

StdSub:
'=Nł' Tag# '/' Repeats# EOL
'=#' Tag# EOL
'>' Tag# EOL
StartSub
RETURN

FinishSub1: {part 1}
SeqLabC CRCOffC EOL
SetFlagF('4')
SeqLabC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

FinishSubG92: {part 2}
'$' EOL
TagDown
CloseSub
SeqLab Preset ShiftRC EOL
SeqLabC Preset UnshftRC EOL
RETURN

OpenMP:
TagUp TagInc
IF WorkFixtureOffsets?
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('5') { Suppress Redundant WFO for MP-OTAP-ECP }
END
NewWFO
EachWFO {simple eachPart}
IF Flag?('5')
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
ELSE
SeqLabC SetWFO EOL
END
'=#' Tag# EOL
IncWFO
NextWFO {simple NextPart}
ELSE
'=Nł' Tag# '/' Parts# EOL
'=#' Tag# EOL
'>' Tag# EOL
IF OneToolAllParts? AND ExitClearancePlane?
SetFlag('2') { WFOStuff }
END
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
'$' EOL
TagDown
CloseSub
SeqLabC WFO1 EOL
ELSE
'$' EOL
CloseSub
TagDown
SeqLab Preset ShiftPC EOL
SeqLabC Preset UnshftPC EOL
END
RETURN

DoAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF ZMove? AND AbsValue?
IncValue
ELSE
IF NOT ZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

DoDrillAbsOrInc:
IF Flag?('1') AND AbsoluteMoves?
IF SPZMove? AND AbsValue?
IncValue
ELSE
IF NOT SPZMove? AND NOT AbsValue?
AbsValue
END
END
END
RETURN

RestoreAbsOrInc:
IF Flag?('1') AND AbsoluteMoves? AND NOT AbsValue?
SeqLabC AbsValue EOL
END
RETURN

FormatArc:
DoAbsOrInc
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJ
ELSE
ArcRC
END
RETURN

ToolPath:
ResetCRCNum
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqLabC MoveSXYC EOL
'=#' Tag# EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF RetractToCP1?
IF NOT FirstFeat?
IF Flag?('3') { MasterOp RetractToCP1/DrillSub Toggle }
SeqLabC DoDrillAbsOrInc MoveSXYZC EOL
ELSE
SeqLabC 'G80' Rapid ZCP1 EOL
SeqLabC MoveSXYC EOL
SeqLabC ZCP2 EOL
IF Dwell?
SeqLabC 'G04/' Dwell# EOL
END
SeqLabC Cycle MoveSX MoveSY ZDepthAbs Peck Retract
IF RigidTap?
'F' FeedTapIPR#('1')
ELSE
FeedEnt
END
EOL
END
END
ELSE
SeqLabC DoDrillAbsOrInc MoveSXYZC EOL
END
END
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
IF LastFeat?
SeqLabC DoAbsOrInc CRCOffC RapidC MoveXYZC EOL
SetFlagF('4')
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLabC DoAbsOrInc RapidC MoveXYZC EOL
ELSE
IF CutterRadiusCompensation? AND NOT Flag?('4')
SeqLabC DoAbsOrInc CRCOn RapidC 'X' SPX# 'Y' SPY# EOL
SetFlag('4')
END
SeqLabC DoAbsOrInc RapidC MoveXYZC EOL
END
END
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF LastFeat?
SeqLabC DoAbsOrInc CRCOffC FeedC MoveXYZC FeedRateC EOL
SetFlagF('4')
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLabC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
ELSE
IF Decelerate? AND NOT CutterRadiusCompensation?
IF RoomToDecel?
DecelMove1
SeqLabC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
DecelMove2
END
SeqLabC DoAbsOrInc FeedC MoveXYZC DecelFeed EOL
ELSE
IF CutterRadiusCompensation? AND NOT Flag?('4')
SeqLabC DoAbsOrInc CRCOn 'G48' FeedC 'X' SPX# 'Y' SPY# FeedRateC EOL
SetFlag('4')
END
SeqLabC DoAbsOrInc FeedC MoveXYZC FeedRateC EOL
END
END
END
END
ELSE
IF ArcFeat?
IF NOT XYPlane?
SeqLabC Plane EOL
END
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLabC FormatArc ArcFeedC EOL
DecelMove2
END
SeqLabC FormatArc DecelFeed EOL
ELSE
SeqLabC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RestoreAbsOrInc
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqLabC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqLabC AbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
'$' EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after TagInc for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagUp TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
TagDown
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SeqLabC Connect StrtPos EOL
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagUp TagInc
EachCycle
SetSRXYtoEP
IF FeedConnect?
Feed
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqLabC IncValue StrtPosC EOL
AbsOrInc
END
END
SeqLabC ZInPlusInc FeedEnt EOL
ELSE
IF NOT FirstCycle?
Rapid
IF SPXMove? OR SPYMove?
SeqLabC IncValue StrtPosC EOL
AbsOrInc
END
IF FeedEntry?
SeqLabC ZCP2PlusInc EOL
END
END
IF FeedEntry?
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
IF FirstCycle?
Rapid
END
SeqLabC RapidC ZInPlusInc EOL
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
'=#' Tag# EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
IF FeedConnect? {there is no Z up in the sub}
IF FIFO?
SeqLabC Feed ZCP2 FeedEnt EOL
ELSE
SeqLabC Rapid ZCP2 EOL
END
END
TagDown
'$' EOL
CloseSub
{Element shift, not pattern}
TagDown
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLabC Connect StrtPos EOL
END
IF FeedConnect?
SeqLabC FeedC ZInPlusInc FeedEnt EOL
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLabC RapidC ZCP2PlusIncC EOL
END
SeqLabC Feed ZInPlusInc FeedEnt EOL
ELSE
SeqLabC RapidC ZInPlusInc EOL
END
END
'=#' Tag# EOL
NextCycle
StartSub
TrackZNO# FIRST SPZ#
ToolPath
FinishSub1
'$' EOL
TagDown
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

OpGuts:
IF Milling?
SeqLabC ZCP2C EOL
IF Repeats?
TagUp TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
SetFlag('1') { Milling ZShiftOnly SepSubs }
ZonlyRep
SetFlagF('1')
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
SeqLabC CRCOffC EOL
SetFlagF('4')
IF AutoCycle?
SeqLabC ZCP3C EOL
ELSE
IF FIFO?
SeqLabC FeedC ZCP3C FeedEntC EOL
ELSE
SeqLabC RapidC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
TagUp TagInc
StdSub
SeqLabC AbsOrInc Rapid StrtPos EOL
END
SeqLabC ZCP2C EOL
GetCycle
IF Dwell?
SeqLabC 'G04/' Dwell# EOL
END
IF RigidTap?
SeqLabC 'M29G95' EOL { Enable Rigid Tapping Mode, FeedRate Per Revolution (pitch) Mode }
END
SeqLabC Cycle StrtPos ZDepthAbs Peck Retract
IF RigidTap?
'F' FeedTapIPR#('1')
ELSE
FeedEnt
END
EOL
IF CallMasterOp?
IF RetractToCP1?
TrackZNO# FIRST SPZ#
ToolPath
ELSE
'=#' CallMasterNum# EOL
SkipToLastFeat
END
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
IF RetractToCP1?
ToolPath
END
SetFlag('1') {std sep sub Zreps in effect}
TagUp
NewMasterTag
IF RetractToCP1?
SetFlag('3') { MasterOp RetractToCP1/DrillSub Toggle }
TrackXNO# FIRST SPX#
TrackYNO# FIRST SPY#
TrackZNO# FIRST SPZ#
ELSE
'=#' Tag# EOL
END
StartSub
ToolPath
'$' EOL
TagDown
CloseSub
SetFlagF('1') {not std sep sub Zreps in effect}
SetFlagF('3') { MasterOp RetractToCP1/DrillSub Toggle }
ELSE
ToolPath
END
END
SetDrillEndOpZ
IF RigidTap?
SeqLabC 'M28G94' EOL { Cancel Rigid Tapping Mode, FeedRate Per Minute Mode }
END
SeqLabC 'G80' Rapid ZCP3 EOL
IF Repeats?
FinishSubG92
END
END
END
RETURN

ProgStart:
InitProg
TagInit
ReverseYZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('500')
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
SetFlagF('1') { Milling ZShiftOnly SepSubs }
SetFlagF('2') { WFOStuff }
SetFlagF('3') { MasterOp RetractToCP1/DrillSub Toggle }
SetFlagF('4') { CRCOn }
SetFlagF('5') { Suppress Redundant WFO for MP-OTAP-ECP }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
RETURN

InitOp:
':' Program# EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
ASCII('59') ' PROGRAM: ' ProgramName$ ' ' ASCII('59') EOL
END
IF ProgramComment?
ASCII('59') ' ' ProgramComment$ ' ' ASCII('59') EOL
END
IF FormatNameComment?
ASCII('59') ' FORMAT: ' FormatName$ ' ' ASCII('59') EOL
END
IF TimeComment?
ASCII('59') ' ' Date$ ' AT ' Time$ ' ' ASCII('59') EOL
END
IF MovesComment?
ASCII('59') ' OUTPUT IN ' MoveType$ ' INCHES ' ASCII('59') EOL
END
IF PartsComment?
ASCII('59') ' PARTS PROGRAMMED: ' Parts# ' ' ASCII('59') EOL
END
IF StartToolComment?
ASCII('59') ' FIRST TOOL NOT IN SPINDLE ' ASCII('59') EOL
END
END
OpenSub
RestoreScale
RETURN

FirstOp1:
SeqLab Plane 'G80' AbsValue EOL
DoOpComments
DoPostScript
SeqLabC Rapid
IF ToolChangeAtHome?
Home
END
OpToolID ToolChng EOL
RETURN

FirstOp2:
SeqLabC 'G8' EOL
SeqLabC WFOStuff EOL
SeqLabC Speed SpinOn EOL
CheckPass
SeqLabC AbsOrInc RapidC StrtPos EOL
RETURN

FirstOp3:
SeqLabC ZCP1 CoolOn EOL
RETURN

NewToolOp1:
IF MultipleParts?
IF NOT AllToolsOnePart?
IF FullUp?
SeqLabC 'M25' EOL
END
END
END
RETURN

NewToolOp2:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END
RETURN

NewToolOp3: {Start new Operation}
DoOpComments
DoPostScript
SeqLab Rapid PlaneC
IF ToolChangeAtHome?
Home
END
OpToolID ToolChng EOL
RETURN

NewToolOp4:
SeqLabC WFOStuff EOL
SeqLabC Speed SpinOn EOL
CheckPass
SeqLabC AbsOrInc RapidC StrtPos EOL
RETURN

NewToolOp5:
SeqLabC ZCP1 CoolOn EOL
RETURN

SameToolOp1:
DoEndOpPS
IF LAST ProgStop?
IF MultipleParts?
IF NOT AllToolsOnePart?
IF FullUp?
SeqLabC 'M25' EOL
END
END
END
SeqLabC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
RETURN

SameToolOp2: {Start new Operation}
DoOpComments
DoPostScript
CheckPass
RETURN

SameToolOp3: {Start new Operation}
SeqLabC WFOStuff EOL
IF LAST ProgStop?
SeqLabC Speed SpinOn EOL
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
SeqLabC PlaneC AbsOrInc Rapid StrtPos CoolOn EOL
ELSE
SeqLabC SpeedC EOL
SeqLabC PlaneC AbsOrInc Rapid StrtPos EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
RETURN

End1:
SeqLabC CoolOff EOL
RETURN

End2:
DoEndOpPS
SeqLabC AbsOrInc Rapid EOL
IF ProgStop?
SeqLabC 'M00' EOL
END
RETURN

End3:
EOP EOL
CloseSub
Post2 {organize Subs into one program}
ASCII('19') EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
ASCII('59') ' FILE LENGTH: ' FileBytes# ' CHARACTERS ' ASCII('59') EOL
END
IF FileFeetComment?
ASCII('59') ' FILE LENGTH: ' FileFeet# ' FEET ' ASCII('59') EOL
END
IF FileMetersComment?
ASCII('59') ' FILE LENGTH: ' FileMeters# ' METERS ' ASCII('59') EOL
END
Close
END
RETURN

MPallTools1P: {Multiple Parts, All Tools 1 Part}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
OpenMP
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
CloseMP
End3
RETURN

MP1ToollAllPfu: {Multiple Parts, 1 Tool all Parts, full up}
EachOp {Start of post processing}
IF EquallySpacedOffsets?
SetFlag('2')
END
IF FirstOperation?
InitOp
FirstOp1
OpenMP
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
CloseMP
NewToolOp2 {to tool change, CS problem}
NewToolOp3
OpenMP
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
CloseMP
End2
End3
RETURN

MP1ToollAllPXcp: {Multiple Parts, 1 Tool all Parts, exit Clearance plane}
EachOp {Start of post processing}
SetFlag('2')
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
OpenMP
FirstOp2 {need StrtPos in Sub}
ELSE
IF NewTool?
CloseMP
NewToolOp1
NewToolOp2 {to tool change, CS problem}
NewToolOp3
NewToolOp4
NewToolOp5
OpenMP
NewToolOp4 {need StrtPos in Sub}
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
CloseMP {End of program}
End1
End2
End3
RETURN

NoMPs: {no multiple parts}
EachOp {Start of post processing}
SetFlag('2') { WFOStuff }
IF FirstOperation?
InitOp
FirstOp1
FirstOp2
FirstOp3
ELSE
IF NewTool?
NewToolOp1
NewToolOp2
NewToolOp3
NewToolOp4
NewToolOp5
ELSE {implied SameTool?}
SameToolOp1
SameToolOp2
SameToolOp3
END
END {common point for all operations}
OpGuts
NextOp {loops back to EachOP until last Operation}
End1 {End of program}
End2
End3
RETURN

{Start of executable Prog, Top Level ****}

ProgStart {setup and initializations}

IF MultipleParts?
IF AllToolsOnePart?
MPallTools1P
ELSE {implied OneToolAllParts?}
IF FullUp?
MP1ToollAllPfu
ELSE {implied ExitClearancePlane?}
MP1ToollAllPXcp
END
END
ELSE
NoMPs
END