{Change Comments ***********************************************************}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{9/21/90, Updated: Fanuc 6T MS [+] L016.53 to .71 format, JR}
{10/2/90, Added StockOff globally at FirstOperation, DWB}
{10/8/90, Replace CalcRPM2 globally with CalcEPRPM# at end of prog, DWB}

{4/1/91
Modified: Fanuc 6T MS [+] L016.71.2
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format.
All normal Fanuc Canned Cycles are supported.
DWB}

{08/06/91
Updated: Fanuc 6T MS [+] L016.80
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.82 Format.
Kim Michelman}

{1/12/95
Copied & modified: Fanuc 6T MS [+] L016.82
For: Danotech / Hummel
Control: Seiki Multi
Machine: Hitachi Seiki
Use R format arcs
Go directly to G96 in CSS operations.
Rapid moves inhibit Speed changes in G96 mode!
No Preset Home at beginning of operations, MaxRPM only for CSS operations.
Tnn00 calls tool and geometry offset. They do not use wear offsets.
Customer does not want an Index Position output.
I tested the ToolChangeAtHome boolean with Catalyst 2.14.24C and it seems to be working!
Added GearRange, outputs M41 only.
Madified Drilling.
Added PeckFullOut.
Deleted DrillOff and RLevel.
Misc other format changes.
Updated to .82ż format.
Jim Radcliffe}

{2/20/95
Moved unconditional sequence label at beginning of operation to OpToolID line.
Modified FormatArc to force output ArcRC, deleted the IF ArcIJFormat? argument.
Jim Radcliffe}

{5/8/95
Initial: Seiki Multi L332.82.1
Created: Seiki Multi L332.82.2
ForUser: Danotech / Hummel
Comment: Modified per before and after edits outputs s2bit.txt and wewant.txt
Preset MaxRPM in 1st op only, commented out others.
Changed format of CutDepth in RoughContour to use decimal points
Changed StrtPos to StrtPosC in RoughContour
Jim Radcliffe}

{5/17/95, .83, Updated to .83 format, JR}
{9/10/95, Updated Seiki Multi L332.83.1 to .85 format per Fanuc 10T MS [-] L001.85.01.01, JR}

{2/4/96
Modified: Seiki Multi L332.85
Created: Seiki Multi [IM] Lxxx.85.1
For: Isimac; per Jim Adams
Corrected G70 > G73 finish/rough cycles; added CkLastLineMove and CkLastArcMove subs (called from
LineFeat, ArcFeat, and RapidFeat in toolpath) to output move to X & Z CSP in canned rough cycle.
Changed format of G74 (peck drilling) cycle to their specification.
Fixed G76 (threading) cycle; changed 'D' (1st depth of cut) to decimal format in Form,
changed format of InFeedAngle# to multiply value by 2 (to get included angle).
Added parts catcher support (M63 in, M64 out).
Added blank line between tools.
Changed tool start-up code at FirstOp and NewTool to their specifications.
Changed DoOpComments; they only want Operation and Tool comments.
Also moved comments to output after the first line of a tool, not before.
Added SetGearRange, SetNewGearFlag, and GetGearRange subs to handle high/low spindle logic
(low speed/M40 for roughing ops, high speed/M41 for finish or contouring ops;
low speed is <= 1500 and high speed is >1500. This logic is required in order to work
correctly in SameTool (CheckOffset sub).
Added DoToolData sub to create Tool Data Header.
Added SetCutOffFlag sub to determine if any ops had CutOff selected; if any ops had CutOff
selected then I set Flag 3 true. I then use this flag to output their stock stop subprogram
before first op if CutOff? was true in any op.
Added logic at end of program to output '/M30' and then 'M99' if CutOff? is true on last op;
this allows them to loop the program by turning on 'Block Delete' on their control.
Added IF ApproachID? then flip the XStkLeft polarity in ID rough cycle (G71). The polarity of
the U & W stock values must be reversed when roughing an ID.
Deleted G40/G41/G42 by stripping them in the Format.
Added logic in Canned Rough cycles to break up first move inside the cycle to two moves, a
move with simultaneous X and Z movement is illegal as the first move of a canned rough cycle.
Joe Cusimano}

{5/14/96
Modified: Seiki Multi [IM] Lxxx.85.1
Created: Seiki Multi [TL] L419.85.2
For: Tinsley Labs; per James Verrico
Modified First Op startup code per their specifications.
Changed Tool# from Format 3 to Format 8.
Deleted 'SeqLabC Preset MaxRPM EOL' from IF ConstantSurface Feed? in First Op.
Moved CoolOn to same line as Speed; moved SpinOn to first rapid line.
Changed Approach sub to rapid in Z first and then X (Tailstock type Approach).
Changed NewHome to NewHomeX# for Tailstock type exit; added FORMAT(NewHomeX#,2);
Changed FirstHome at Last Operation to FirstHomeX# for Tailstock exit.
Modified a bunch of other stuff in Last Op to their specs.
Joe Cusimano}

{2/27/97
Modified: Seiki Multi [TL] L419.85.2
Created: Seiki Multi [INS] L568.85
For: Inspirnetics
Added support for all L001 comments.
WS}

{3/1/99
Updated: Seiki Multi [INS] L568.85
Created: Seiki Multi [INS] L568.85.01
For: Gibbs & Associates/Continental Disk
Versions: Virtual 5.04.07/ComPost2 1.7b15
Updated for Catalyst v4.23.13C per Fanuc 10T MS [-] L001.85.02e Format.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.######;0.'
#6 = '###0'
#7 = '#'
#8 = '00'
#9 = '+###.####;0.'
#10 = '2+###.####;0.'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(NewHomeX#,2)
FORMAT(NewHomeZ#,2)
FORMAT(FirstHomeX#,2)
FORMAT(FirstMoveEPX#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
FORMAT(Tool#,8) {.72}
FORMAT(TLNum#,8)
FORMAT(ZStockMax#,9)
FORMAT(ZStockMin#,9)
FORMAT(XStockMax#,9)
FORMAT(InFeedAngle#,10)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

CkPartsCatcher:
IF CutOff?
'M63'
END
RETURN

PartsCatcherOut:
IF CutOff?
'M64'
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC CkPartsCatcher EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC CkPartsCatcher EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP
RETURN

Approach: { FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
SeqLabC AppMove SpinOn EOL
IF ApproachOD?
SeqLabC ThisOpEntryXCP EOL
ELSE
IF ApproachID?
SeqLabC XOpCD EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP EOL
END
END
ApproachSP
RETURN

SetGearRangeFlag: { Flag 1 is used for gear range; true is low and false is high }
IF ConstantSurfaceFeed?
IF Roughing?
SetFlag('1') {low speed}
ELSE
SetFlagF('1') {high speed}
END
ELSE
IF LTEqual? SpeedRPM# Num#('1500')
SetFlag('1') {low speed}
ELSE
SetFlagF('1') {high speed}
END
END
RETURN

GetGearRange:
IF Flag?('1')
'M40' {low speed}
ELSE
'M41' {high speed}
END
RETURN

SetNewGearFlag: { Flag 2 is used to flag a gear range change }
IF ConstantSurfaceFeed?
IF Roughing?
IF Flag?('1')
SetFlagF('2') { no gear range change }
ELSE
SetFlag('2') { gear range change true }
END
ELSE
IF Flag?('1')
SetFlag('2') { gear range change true }
ELSE
SetFlagF('2') { no gear range change }
END
END
ELSE
IF LTEqual? SpeedRPM# Num#('1500')
IF Flag?('1')
SetFlagF('2') { no gear range change }
ELSE
SetFlag('2') { gear range change true }
END
ELSE
IF Flag?('1')
SetFlag('2') { gear range change true }
ELSE
SetFlagF('2') { no gear range change }
END
END
END
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset CRCOfstNum EOL
END
IF ConstantSurfaceFeed?
CSSOn
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
IF LAST ProgStop?
'G96' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
'G96' Speed
END
END
ELSE
SeqLabC Preset MaxRPM EOL
'G96' Speed
END
ELSE
CSSOff
IF LAST ConstantSurfaceFeed?
'G97' Speed
ELSE
IF LAST ProgStop?
'G97' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
'G97' Speed
END
END
END
END
IF LAST ProgStop?
SeqLabC {SpeedC} GetGearRange SpinOn EOL
SeqLabC CoolOn EOL
ELSE
IF Flag?('2') { New gear range required }
SeqLabC {SpeedC} GetGearRange EOL
ELSE
SeqLabC {SpeedC} EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

CkLastLineMove:
IF LastFeat? AND CannedCycle? AND Roughing?
SetPass1
Rapid XCSP ZCSP { output rapid move to X & Z contour start point at end of canned rough }
ResetPass2
ELSE
IF LineFeat?
FeedC MoveXC MoveZC { normal feed move }
ELSE
IF RapidFeat?
RapidC MoveXC MoveZC { normal rapid move }
END
END
END
RETURN

CkLastArcMove: { this will only happen if an arc is the last feature of a canned rough cycle }
{ although I don't think this can happen, I figured I better cover it just in case }
IF LastFeat? AND CannedCycle? AND Roughing?
SetPass1
Rapid XCSP ZCSP { add rapid move to XZ contour start point at end of canned rough after completing the arc move }
ResetPass2
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC ArcRC
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF LastFeat?
CRCOffC { Exit Length Feature }
ELSE
CRCOnC { Entry Length Feature }
END
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
IF NOT FirstFeat? AND LAST ThreadFeat?
Rapid
END
SeqLabC CkLastLineMove EOL
ELSE
IF LineFeat?
SeqLabC CkCRC CkLastLineMove FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
CkLastArcMove
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC ThrdLead EOL
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle? OR LAST Threading?
Rapid
ELSE
RapidC
END
RETURN

DoToolData:
'('
EachTool
'TL' TLNum# '/00'
IF NOT LastTool?
' '
END
NextTool
')' EOL
'(W' ZStockMin# ' D' XStockMax# ' H' ZStockMax# ' L0)' EOL
RETURN

SetCutOffFlag:
SetFlagF('3')
EachOp
IF CutOff?
SetFlag('3')
END
NextOp
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
SetMaxRPM('10000')
IF Metric?
SetMaxFeed('12700')
ELSE
SetMaxFeed('500')
END
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
SetCutOffFlag
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
DoToolData
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
IF Flag?('3') { IF Flag3 true then call up stock stop cycle }
{'N1000M98P9950 (Stock Stop)' EOL} { subprogram call for stock stop cycle }
END
'N01' Preset
IF ConstantSurfaceFeed?
MaxRPM
ELSE
'S1500'
END
EOL
'N02G28U0' EOL
'N03G28W0' EOL
'N04M01' EOL

' ' EOL
DoPostScript
Plane
SetGearRangeFlag
IF ConstantSurfaceFeed?
SeqLab 'T' Tool# '00' GetGearRange EOL
DoOpComments
SeqLabC 'G99' CSSOn 'G96' Speed CoolOn EOL
ELSE
SeqLab 'T' Tool# '00' GetGearRange EOL
DoOpComments
SeqLabC 'G99' CSSOff 'G97' Speed CoolOn EOL
END
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
IF ToolChangeAtHome?
SeqLabC 'X' NewHomeX# EOL
END
SeqLabC 'G97G30U0W0' EOL
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

' ' EOL
DoPostScript
SetNewGearFlag
SetGearRangeFlag
IF ConstantSurfaceFeed?
SeqLab 'T' Tool# '00' GetGearRange EOL
DoOpComments
SeqLabC 'G99' CSSOn 'G96' Speed CoolOn EOL
ELSE
SeqLab 'T' Tool# '00' GetGearRange EOL
DoOpComments
SeqLabC 'G99' CSSOff 'G97' Speed CoolOn EOL
END
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
SetNewGearFlag
SetGearRangeFlag
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
'Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag#
IF ApproachID?
NegSideLathe
XStkLeft
PosSideLathe
ELSE
XStkLeft
END
ZStkLeft CutDepth FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove ZSP EOL
SeqLabC CRCOnC FeedC XSP EOL
ELSE { ODApproach/IDApproach }
SeqLab StepMove XSP EOL
SeqLabC CRCOnC FeedC ZSP EOL
END
ELSE
IF RoughPatternShift?
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag#
IF ApproachID?
NegSideLathe
XStkLeft
PosSideLathe
ELSE
XStkLeft
END
ZStkLeft XminusU ZminusW NumCuts FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab Rapid ZSP EOL
SeqLabC CRCOnC FeedC XSP EOL
ELSE { ODApproach/IDApproach }
SeqLab Rapid XSP EOL
SeqLabC CRCOnC FeedC ZSP EOL
END
END
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
IF NOT ConstantVolumeCut? AND NOT SingleEdgeCut?
SeqLabC 'G92X' FirstMoveEPX# FinZ XTapAtZ ThrdLead EOL
SimpleRough
SeqLabC XatFinZ EOL
IF AutoFinish?
SeqLabC XatFinZ EOL
END
ELSE
IF Chamfer?
SeqLabC 'M23' EOL
END
SeqLabC LCycle XatFinZ FinZ XTapAtZ ThrdHeight CutDepth ThrdLead
IF SingleEdgeCut?
'A' InFeedAngle#
ELSE
'A0'
END
EOL
IF Chamfer?
SeqLabC 'M24' EOL
END
IF AutoFinish?
SeqLabC 'G92' XatFinZ FinZ XTapAtZ ThrdLead EOL
END
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF Peck?
SeqLabC LCycle ZDepth Dwell Peck Retract
IF PeckFullRetract?
'R1'
END
FeedRate EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
ELSE
IF Grooving?
StockOn
SetPass1
SeqLabC StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G32'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle? OR Threading?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC PartsCatcherOut EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC PartsCatcherOut EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqLabC 'X' FirstHomeX# EOL
END
SeqLabC 'G97G30U0W0' EOL
IF ProgStop?
SeqLabC ProgStop EOL
END
' ' EOL
SeqLabC CoolOff EOL
SeqLabC SpinOff EOL
SeqLabC 'G54W0' EOL
SeqLabC 'G28U0W0' EOL
IF CutOff?
SeqLabC '/' EOP EOL
SeqLabC 'M99' EOL
ELSE
SeqLabC EOP EOL
END
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END