{Change Comments ***********************************************************}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{9/21/90, Updated: Fanuc 6T MS [+] L016.53 to .71 format, JR}
{10/2/90, Added StockOff globally at FirstOperation, DWB}
{10/8/90, Replace CalcRPM2 globally with CalcEPRPM# at end of prog, DWB}

{4/1/91
Modified: Fanuc 6T MS [+] L016.71.2
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format.
All normal Fanuc Canned Cycles are supported.
DWB}

{08/06/91
Updated: Fanuc 6T MS [+] L016.80
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.82 Format.
Kim Michelman}

{1/12/95
Copied & modified: Fanuc 6T MS [+] L016.82
For: Danotech / Hummel
Control: Seiki Multi
Machine: Hitachi Seiki
Use R format arcs
Go directly to G96 in CSS operations.
Rapid moves inhibit Speed changes in G96 mode!
No Preset Home at beginning of operations, MaxRPM only for CSS operations.
Tnn00 calls tool and geometry offset. They do not use wear offsets.
Customer does not want an Index Position output.
I tested the ToolChangeAtHome boolean with Catalyst 2.14.24C and it seems to be working!
Added GearRange, outputs M41 only.
Madified Drilling.
Added PeckFullOut.
Deleted DrillOff and RLevel.
Misc other format changes.
Updated to .82ż format.
Jim Radcliffe}

{2/20/95
Moved unconditional sequence label at beginning of operation to OpToolID line.
Modified FormatArc to force output ArcRC, deleted the IF ArcIJFormat? argument.
Jim Radcliffe}

{5/8/95
Initial: Seiki Multi L332.82.1
Created: Seiki Multi L332.82.2
ForUser: Danotech / Hummel
Comment: Modified per before and after edits outputs s2bit.txt and wewant.txt
Preset MaxRPM in 1st op only, commented out others.
Changed format of CutDepth in RoughContour to use decimal points
Changed StrtPos to StrtPosC in RoughContour
Jim Radcliffe}

{5/17/95, .83, Updated to .83 format, JR}
{9/10/95, Updated Seiki Multi L332.83.1 to .85 foramt per Fanuc 10T MS [-] L001.85.01.01, JR}

{6/5/96
Initial: Seiki Multi L332.85
Created: Seiki Multi-L HS [GR] L000.85
ForUser: Braden Engineering / Gates Rubber
Control: Seiki Multi L
Machine: Hitachi Seiki HT23S2
Develop: ComPost 4.21.37, Catalyst68K v3.04.10.C
Comment: New CUSTOM Processor per sample readout and conversations with David Kruse.
Jim Radcliffe}

{8/12/96
Initial: Seiki Multi-L HS [GR] L000.85
Created: Seiki Multi-L HS [GR] L000.85.1
ForUser: Braden Engineering / Gates Rubber
Develop: ComPost2 68k, Catalyst68K v3.04.10.C
Comment: Bug fix! Added missing GetLCycle after secong EachOp!
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.######;0'
#6 = '###0'
#7 = '#'
#8 = '00'
#9 = '2###.####;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(FirstMoveEPX#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Recall#,3)
FORMAT(MaxRPM#,3)
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)
FORMAT(Tag#,8)
FORMAT(InFeedAngle#,9)

{Special Subroutines *******************************************************}

TheToolComment:
IF UseComments?
'( ' OpToolID '00, ' ToolComment$ ' )' EOL
END
RETURN

TheOpComment:
IF UseComments?
'( ' ToolOffset# ' ' OperationComment$ ' )' EOL
END
RETURN

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF NOT SameTool?
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
END
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset: {with gear ranges}
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF NewGear?
SeqLabC SpinOff EOL
END
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
{ Start New Operation }
TheOpComment
DoOpComments
SeqLabC
IF NewToolOffset?
OpToolID LatheOffset
END
IF LAST ProgStop?
CoolOn
ELSE
IF NOT CoolOff? AND LAST CoolOff?
CoolOn
END
END
EOL
DoPostScript
IF NewGear?
SeqLabC GearRange EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
SeqLabC
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
ELSE
IF NotEqual? MaxRPM# Recall# Num#('1')
SeqLabC Preset MaxRPM EOL
END
SeqLabC CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' Speed
ELSE
SeqLabC
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
END
END
IF LAST ProgStop?
SpinOn EOL
ELSE
IF NewGear?
SpinOn EOL
ELSE
EOL
END
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC ArcRC
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
TagInit
SetAbs
PosSideLathe
SetMaxRPM('3600')
SetMaxFeed('500')
SetFlagF('1') { MaxRPM read }
SetFlagF('1') { CutOff read }
Save# Num#('1') Num#('3000') { default MaxRPM }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
ProgID1 ';' EOL
';' EOL
ProgID1 '( ' ProgramName$ ' )' EOL
' ' EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
' ' EOL
END
TheOpComment
{ save first MaxRPM setting for output as default at beginning of program }
IF ConstantSurfaceFeed?
IF NOT Flag?('1')
Save# Num#('1') MaxRPM#
SetFlag('1')
END
END
NextOp

EachOp
GetLCycle
IF FirstOperation?
' ' EOL
SeqLabC 'M62' EOL { Close Door }
SeqLabC 'M28' EOL { Tail Stock Retract }
SeqLabC 'G99G50S' Recall# Num#('1') EOL
SeqLabC 'G28U0' EOL
SeqLabC 'G28W0' EOL
SeqLabC ProgStop EOL
RestoreScale
OpenSub
Plane
StockOff {.71.2}
SetHome
' ' EOL
IF MinimizeSequencing?
'Åš' ToolOffset# EOL
END
SeqLab
TheToolComment
TheOpComment
DoOpComments
SeqLabC Rapid OpToolID LatheOffset CoolOn EOL
DoPostScript
SeqLabC 'G99' GearRange EOL
IF ConstantSurfaceFeed?
IF NotEqual? MaxRPM# Recall# Num#('1')
SeqLabC Preset MaxRPM EOL
END
SeqLabC CSSOn 'G96' Speed SpinOn EOL
ELSE
SeqLabC CSSOff 'G97' Speed SpinOn EOL
END
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
IF ToolChangeAtHome?
SeqLabC NewHome EOL
END
SeqLabC 'G30U0' EOL
SeqLabC 'G30W0' CoolOff EOL
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

' ' EOL
IF MinimizeSequencing?
'Åš' ToolOffset# EOL
END
SeqLab
TheToolComment
TheOpComment
DoOpComments
SeqLabC Rapid OpToolID LatheOffset CoolOn EOL
DoPostScript
SeqLabC 'G99' GearRange EOL
IF ConstantSurfaceFeed?
IF NotEqual? MaxRPM# Recall# Num#('1')
SeqLabC Preset MaxRPM EOL
END
SeqLabC CSSOn 'G96' Speed SpinOn EOL
ELSE
SeqLabC CSSOff 'G97' Speed SpinOn EOL
END
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CutOff?
SeqLabC 'M63' EOL { Parts Catcher Advance }
SetFlag('2')
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
'Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
{ Not working for more than 1 canned cycle with the same tool!
IF MinimizeSequencing?
'Åš' ToolOffset# Tag# EOL
END
}
SetPass2
IF RoughContour?
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft CutDepth FeedRate 'R1' EOL
'>' Tag# EOL
SeqLab StepMove StrtPosC EOL
ELSE
IF RoughPatternShift?
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft XminusU ZminusW NumCuts FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
END
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
IF NOT ConstantVolumeCut? AND NOT SingleEdgeCut?
SeqLabC 'G92X' FirstMoveEPX# FinZ XTapAtZ ThrdLead EOL
SimpleRough
SeqLabC XatFinZ EOL
IF AutoFinish?
SeqLabC XatFinZ EOL
END
ELSE
IF Chamfer?
SeqLabC 'M23' EOL
END
SeqLabC LCycle XatFinZ FinZ XTapAtZ ThrdHeight CutDepth ThrdLead
IF SingleEdgeCut?
'A' InFeedAngle#
ELSE
'A0'
END
EOL
IF Chamfer?
SeqLabC 'M24' EOL
END
IF AutoFinish?
SeqLabC 'G92' XatFinZ FinZ XTapAtZ ThrdLead EOL
END
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF Peck?
SeqLabC LCycle ZDepth Dwell Peck Retract FeedRate
IF PeckFullRetract?
'R1'
END
EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
ELSE
IF Grooving?
StockOn
SetPass1
SeqLabC StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G32'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P2000' EOL
SeqLabC Speed SpinOn EOL
END
IF Flag?('2')
SeqLabC 'M64' EOL { Parts Catcher Retract }
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
SeqLabC CoolOff EOL
IF FIRST ToolChangeAtHome?
SeqLabC FirstHome EOL
END
IF Flag?('2')
SeqLabC 'G30U0' SpinOff EOL
SeqLabC 'G30W0' CoolOff EOL
IF ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END
' ' EOL
IF MinimizeSequencing?
'N10'
ELSE
SeqLabC
END
'( T1000, Bar Feed Stock Stop )' EOL
'( 10 Bar Feed )' EOL
SeqLabC Rapid 'T1010' SpinOff EOL
SeqLabC 'G98' EOL
SeqLabC Rapid 'Z.025' EOL
SeqLabC 'X0' EOL
SeqLabC 'M69' EOL { Open Chuck }
SeqLabC 'M61' EOL { Open Door }
SeqLabC 'M0' EOL
' ' EOL
SeqLabC 'G99' EOL
SeqLabC Rapid 'W.2' EOL
SeqLabC 'G28U0' EOL
SeqLabC 'G28W0' EOL
SeqLabC 'M12' EOL { Part Counter }
SetLineStrtChr('/')
SeqLabC 'M99' EOL
SetLineStrtChr('')
ELSE
SeqLabC 'G28U0' SpinOff EOL
SeqLabC 'G28W0' CoolOff EOL
IF ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END
' ' EOL
SeqLabC 'M12' EOL { Part Counter }
SeqLabC 'M69' EOL { Open Chuck }
SeqLabC 'M61' EOL { Open Door }
END
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END