{Change Comments ***********************************************************}

{2/21/90, Updated: Fanuc 6T MS [-] L005.55 to .69.3 format, JR}
{7/24/90, Added InitProg globally to posts with this remark, DWB}
{9/25/90, Updated to Version 3.2 per Fanuc 10T MS [-] L001.71.1 Format, DWB}
{10/2/90, Added StockOff globally at FirstOperation, DWB}
{10/8/90, Replace CalcRPM2 globally with CalcEPRPM# at end of prog, DWB}
{3/19/91, Updated to Version 4.0 per Fanuc 10T MS [-] L001.80 Format, DWB}

{08/06/91
Updated: Fanuc 6T MS (-) L005.80
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.82 Format.
Kim Michelman}

{2/3/94
Copied & modified: Fanuc 6T MS (-) L005.82
For: CNCCS / Winegar, Inc.
Added GearRange.
Updated Approach subs to .82ż format, other misc update stuff.
Changed StrtPos to StrtPosC in Roughing canned cycle to suppress output of axis already in position.
Moved CoolOff to ZCPC line at end of program.
Combined CSSOff line and ZCPC line at end of tools.
Changed thread lead label from an E to an F.
Changed ToolAngle to 'A29' in CannedCycle Threading.
Jim Radcliffe}

{8/9/95, Updated Fanuc 6T MS [-WB] L299.82 to .85 format per Fanuc 6T MS (-) L005.85, JR}

{7/8/96,
Initial: Fanuc 6T L299.85
Created: Fanuc 6T Lxxx.85
For: Hydrasun
Changed CRC handling to output G41 for OD approach and G42 for other approaches, added start block at beginning of program,
added start block at program beginning, inverted the sign of 'U' value for G71/G72, changed threading cycle to output an 'M23'
for tapered theads and 'M24' otherwise for a straight pull out, changed thread lead label form 'F' to 'E', added 'G04P0200' dwell
to after every peck in peck drilling cycles, rearranged the order of the commands in FirstOperation and NewTool (changed to
match customer sample, supficial changes only), post formerly output the Tool# followed by '00' and then loaded the tool offset
on the next line, moved the tool offset command up one line in the place of the Tool# and '00'. Changed Default formats so that
G codes, M codes, and sequence numbers always output at least two digits. Added custom sequence # at tool
changes, outputs the Tool# plus 1000 the fist time the tool is called, then if the tool is called again it outputs the tool# plus
2000, and so on. Due to use of variables, the post is limited to tools 1-25. Moved tool comments out of DoOpComments and
put them after the custom sequence # at tool changes. Because of this, no tool comments will be made in SameTool situations.
Removed Untool at program end. MPK}
{7/24/96
Initial: Fanuc 6T MS SL4 [HS] L472.85
Created: Fanuc 6T MS SL4 [HS] L472.85.1
Changed the format of 'U' for G71/G72 back to previous sign,
added blank line before custom sequence # and beofore DoOpComment in NewTool
moved DoOpComment in FirstOperation to after saftey start block
changed hard coded dwell after every peck to 'G4P' Dwell#, eliminated previous dwell at the end of the manual peck cycle,
eliminated saftey G97 call at the end of CSS operations (beginning of NewTool),
deleted GearRange stuff, M41 is now output for rpughing ops and M42 for all others,
M05 is now only output at program end and when spindle changes directions,
Moved G96 call from beginning of common point to inside ApproachSP,
MPK}
{7/26/96
Initial: Fanuc 6T MS SL4 [HS] L472.85.1
Created: Fanuc 6T MS SL2 [HS] L482.85
For: Hydrasun
Added a custom hard-coded cutoff operation. This was nesessary to achieve two separate feed rates for the same countour.
Cutoff operations must have only one feature. The post feeds at a user specified feed rate to x.5 (regardless of what X dimension is
programmed), and then to X0 at .001 SFPM, then backs off in Z by .01.
Added Hard-coded barfeeder. Assumes that barfeeder always has the same preset dimensions. It does not use its own
operation, it is automatically added to the code when OptCyc1? us true. It feeds to the Z value of the cutoff operation
plus .05 and pulls to Z.015.
Added OptCyc1F at prog end to reset condition.
Changed ProgStop in FirstOperation safe start block to 'M00'.
Added M00 to FirstOperation that only outputs when OptCyc1? is true (when doing a barfeed)
Added a M99 loop to end of program. Automatically loops to the sequence number of the first operation.
Changed M41/M42 output to output M41 for tapping operations, M42 for all others
MPK}

{8/26/96
Initial: Fanuc 6T MS SL2 [HS] L482.85
Created: Fanuc 6T MS SL2 [HS] L482.85.1
Customized Tapping non-canned tapping cycle per customer request,
Reformatted Dwell# to output seconds instead of milliseconds
Changed all G04 statements to use U label (seconds) instead of P (milliseconds)
MPK}

{10/2/96
Initial: Fanuc 6T MS SL2 [HS] L482.85.1
Created: Fanuc 6T MS SL2 [HS] L482.85.2
changed format for X taper at Z to *####.####;0,
MPK}

{11/18/96
Initial: Fanuc 6T MS SL2 [HS] L482.85.2
Created: Fanuc 6T MS SL2 [HS] L482.85.3
added literal 'F' before FeedTapIPR(1)# in ToolPath LineFeat,
Moved G20 line before G53 line in FirstOp,
made literal 'M00' in FirstOp conditional upon OptCyc1? being true,
control can not have X&Z moves on the line after G71 call, broke them up accordingly,
MPK}

{6/16/98,
Initial : Fan 6T MS SL2 [HS-SF] L482.85.3
Created: Fan 6T MS SL2 [HS-SF] L482.85.4
Customer: Hydrasun Limited, UK - Ian Pullen

Changes to "Form":

1. Under Turn Rough - Face, removed * from the X Stock Left (U) Format.
2. Under Threading, removed * from the X Taper at Start Z (I) Format.

Changes to "Prog":

1. Replaced XStkLeft with 'U' & calcXStkLeft sub for RoughContour and PatternShift.
2. Added #8 FORMAT to reverse the U sign.
JHE}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.######;0.'
#6 = '###0'
#7 = '#'
#8 = '*###.####;0.' {Added - JHE}

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(FirstMoveEPX#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(SPX#,2)
FORMAT(SPZ#,2)
FORMAT(ADD#,2)
FORMAT(SUB#,2)
FORMAT(FeedTapIPR#,2)
FORMAT(Dwell#,2)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Recall#,3)
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

calcXStkLeft: {Added this sub - JHE}
IF ApproachID?
FORMAT(MUL#,8) {reverse sign - JHE}
MUL# Num#('2') StockXRadius#
FORMAT(MUL#,2)
ELSE
MUL# Num#('2') StockXRadius#
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn 'G96' Speed EOL
END
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn 'G96' Speed EOL
END
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD# AND NOT CutOff?
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
RapidC RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF NOT CWSpindle? AND LAST CWSpindle?
SpinOff
ELSE
IF CWSpindle? AND LAST NOT CWSpindle?
SpinOff
END
END
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC Speed
END
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC Speed
END
END
END
IF LAST ProgStop?
SpinOn EOL
SeqLabC CoolOn EOL
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat? AND CutterRadiusCompensation?
IF NOT Flag?('5')
IF ApproachOD?
'G41' CRCOnC
ELSE
'G42' CRCOnC
END
SetFlag('5')
END
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
SetFlagF('5')
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
ELSE
IF Dwell? AND NOT Peck?
SeqLabC 'G04U' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
IF Tap?
SeqLabC Feed MoveZC
IF LastFeat?
'F' FeedTapIPR#('1') InverseSpinOn EOL
ELSE
FeedRate EOL
END
ELSE
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
END
IF Peck? And Dwell?
SeqLabC 'G04U' Dwell# EOL
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
NegSideLathe
ReverseXZArcs
OptCyc1F {Clear BarFeeder Flag}
SetMaxRPM('10000')
SetMaxFeed('500')
SetFlagF('5') {For CRC handling}
Save# Num#('1') Num#('1')
Save# Num#('2') Num#('2')
Save# Num#('3') Num#('3')
Save# Num#('4') Num#('4')
Save# Num#('5') Num#('5')
Save# Num#('6') Num#('6')
Save# Num#('7') Num#('7')
Save# Num#('8') Num#('8')
Save# Num#('9') Num#('9')
Save# Num#('10') Num#('10')
Save# Num#('11') Num#('11')
Save# Num#('12') Num#('12')
Save# Num#('13') Num#('13')
Save# Num#('14') Num#('14')
Save# Num#('15') Num#('15')
Save# Num#('16') Num#('16')
Save# Num#('17') Num#('17')
Save# Num#('18') Num#('18')
Save# Num#('19') Num#('19')
Save# Num#('20') Num#('20')
Save# Num#('21') Num#('21')
Save# Num#('22') Num#('22')
Save# Num#('23') Num#('23')
Save# Num#('24') Num#('24')
Save# Num#('25') Num#('25')

IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
' ' EOL
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
Plane
SeqLabC 'G20' EOL
SeqLabC 'G28U0W0' EOL
SeqLabC Rapid 'U W-' EOL
'M00' EOL
' ' EOL
DoOpComments
DoPostScript
' ' EOL
Save# Tool# Add# Recall# Tool# Num#('1000')
'N' Recall# Tool# EOL
Save# Num#('50') Recall# Tool#
' ' EOL
IF NOT OptCyc1?
'M00' EOL
' ' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
' ' EOL
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
' ' EOL
SeqLabC Preset Home MaxRPM EOL
SeqLabC CSSOff 'G97' CRCOff
IF Tap?
'M41'
ELSE
'M42'
END
EOL
SeqLabC Rapid
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
OpToolID LatheOffset SpinOn EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
SeqLabC NewHome EOL
SeqLabC LOfstOff '00'
IF NOT CWSpindle? AND LAST CWSpindle?
SpinOff
ELSE
IF CWSpindle? AND LAST NOT CWSpindle?
SpinOff
END
END
EOL
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

' ' EOL
DoOpComments
' ' EOL
Save# Tool# Add# Recall# Tool# Num#('1000')
'N' Recall# Tool# EOL
' ' EOL
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
' ' EOL
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
' ' EOL
DoPostScript
SeqLabC Preset Home MaxRPM EOL
SeqLabC CSSOff 'G97' CRCOff
IF Tap?
'M41'
ELSE
'M42'
END
EOL
SeqLabC Rapid
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
OpToolID LatheOffset SpinOn EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
'Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# 'U' calcXStkLeft ZStkLeft CutDepth FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove 'Z' SPZ# EOL
SeqLabC FeedC 'X' SPX# EOL
ELSE
SeqLab StepMove 'X' SPX# EOL
SeqLabC FeedC 'Z' SPZ# EOL
END
ELSE
IF RoughPatternShift?
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# 'U' calcXStkLeft ZStkLeft XminusU ZminusW NumCuts FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPosC EOL
END
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
IF Taper?
SeqLabC 'M23' EOL
ELSE
SeqLabC 'M24' EOL
END
IF ConstantVolumeCut? AND SingleEdgeCut?
SeqLabC LCycle XatFinZ FinZ XTapAtZ ThrdHeight CutDepth ThrdLead 'A29' EOL
ELSE
IF ConstantVolumeCut? AND NOT SingleEdgeCut?
SeqLabC LCycle XatFinZ FinZ XTapAtZ ThrdHeight CutDepth ThrdLead 'A0' EOL
ELSE
IF NOT ConstantVolumeCut? AND SingleEdgeCut?
SeqLabC LCycle XatFinZ FinZ XTapAtZ ThrdHeight CutDepth ThrdLead 'A29' EOL
ELSE
IF NOT ConstantVolumeCut? AND NOT SingleEdgeCut?
SeqLabC 'G92X' FirstMoveEPX# FinZ ThrdLead EOL
SimpleRough
END
END
END
END
IF AutoFinish?
SeqLabC 'G92' XatFinZ FinZ XTapAtZ ThrdLead EOL
END
IF Chamfer?
SeqLabC 'M24' EOL
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G04U' Dwell# EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
SeqLabC LCycle FromCP ZDepth RLevel Dwell Peck Retract FeedRate EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G04U' Dwell# EOL
END
IF NOT FIFO?
Rapid
END
SeqLabC ZSP EOL
END
END
ELSE
IF Grooving?
StockOn
SetPass1
SeqLabC StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
IF NOT CutOff?
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G32'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
IF Drilling? AND Tap?
IF Dwell?
SeqLabC 'G04U' Dwell# EOL
END
SeqLabC SpinOff EOL
END
ELSE {hard-coded cutoff routine}
SeqLabC Feed 'X-.5' FeedRate EOL
SeqLabC 'X0.F0.001' EOL
SeqLabC 'Z' Add# EPZ# Num#('0.01') EOL
SeqLabC Rapid
SeqLabC OpExitXCP EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
IF NOT Cutoff?
SeqLabC OpExitZCPC EOL
END
DoEndOpPS
IF NOT OptCyc1?{Still must do BarFeeder}
SeqLabC FirstHome CoolOff EOL
ELSE
SeqLabC Home CoolOff EOL
END
SeqLabC OpToolID '00'
IF CutOff?
'M73'
END
EOL
SeqLabC ProgStop EOL
IF OptCyc1?
' ' EOL
'N1001' EOL
' ' EOL
'( PULL TO STOP )' EOL
' ' EOL
SeqLabC 'G50X' ADD# TurretX# Num#('3.2') 'Z' SUB# TurretZ# Num#('.3') EOL
SeqLabC CSSOff 'G97' CRCOff 'M42' EOL
SeqLabC Rapid 'T0101' SpinOff EOL
SeqLabC 'X0.Z' Add# EPZ# Num#('.05') EOL
SeqLabC 'M11' EOL
SeqLabC 'G04U1.' EOL
SeqLabC Feed 'G98Z.015F60.' EOL
SeqLabC 'M01' EOL
SeqLabC 'M10' EOL
SeqLabC 'G04U2.' EOL
SeqLabC Rapid 'G99X' ADD# TurretX# Num#('3.2') 'Z' SUB# TurretZ# Num#('.3') EOL
SeqLabC 'T0100' EOL
ProgStop EOL
SeqLabC '/M82' EOL
END
SeqLabC '/' EOP EOL
SeqLabC 'M99P' Recall# Num#('50') EOL
Post
EOR EOL
OptCyc1F {Reset Bar Feeder Flag}
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END