{Change Comments ***********************************************************}

{8/26/95, Updated Yasnac LX3 HS 20/25 L234.82.1 to .85 format per Fanuc 10T MS [-] L001.85.01.01, JR}

{11/26/96
Initial: Yasnac LX3 HS 20/25 L234.85
Created: Yasnac i80 MS Lxxx.85
ForUser: New West Machine Tool
Control: Yasnac i80
Machine: Mori Seiki
Develop: ComPost2 68k v1.0b4, Catalyst68K v3.09.05C
Comment: New Processor per marked up readout from Tim Loomis
Deleted 'T0100' from beginning of program.
Changed OpToolID '00' to Rapid OpToolID LatheOffset at beginning of tools.
Deleted 'M99P100' from end of program.
Changed 'M0' to EOP (M30) at end of program.
Deleted UnTool '00' from end of program.
Jim Radcliffe}

{11Jun97
Original: Yasnac I80 MS [CBM] L544.85
Created: Yasnac I80 MS [NI] L603.85
For: Next Intent
Changes made per: Frank Vettel
Added FORMATs #7 & #8 and formatted Recall# and SpringPasses#
Moved CoolOn to AppMove sub from FirstOperation and NewTool and deleted literal '/'.
Deleted literal '/'. from CheckOffset
Added SpringPass and DoThreadSpringPass Subs
Modified StartUp Output lines in FirstOp
Added literal 'G30U0.W0.' at IF LAST ProgStop? in NewTool?
Changed IF Threading to output simple a G92 Canned Cycle with SpringPasses
Added literal 'G28U0.W0.M30' at EndOps
Charles Winston}

{8/21/98,
Initial : Yasnac I80 MS [NI] L603.85
Created: Yasnac I80 HS [HA] L765.85 (Hitachi Seki)
Customer: Heli-Arc Specialty, Tim Tepper - 541/878-3600

Changes to "Form":

1. Under Turn Rough - OD/ID, changed X Stock - Last Pass (I) to Rad
2. Under Turn Rough - Face, changed X Stock - Last Pass (I) to Rad
3. Under Threading, changed Lead of Thread Label to F and Format to #.####;0.

Changes to "Prog":

1. Added FORMAT to Tag#.
2. Removed GetSequence sub.
3. Changed FirstOperation output per customer spec.
4. Changed NewTool output per customer spec.
5. Changed End output per customer spec.
6. Added FeedC to the second block in G71 & G72 cycles.
7. Added doRangeCode sub to output M40 or M41.
JHE}

{09/10/98,
Initial: Yasnac I80 HS [HA] L765.85
Created: Yasnac I80 HS [HA] L765.85.1
For Heli-Arc Specialty

Changes to Prog:
1) End Of Prog - Changed CalcRPM2 to CalcEpRPM# because CalcRPM2 was causing
Virtual to Crash when only 1 operation had been entered.
CDH}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.######;0.'
#6 = '#'
#7 = '###.0###'
#8 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(InFeedAngle#,2)
FORMAT(FirstMoveEPX#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(Program#,3)
FORMAT(Operation#,3)
FORMAT(Tool#,3)
FORMAT(Tag#,3) {Added - JHE}
FORMAT(Dwell#,4)
FORMAT(FeedIPR#,5)
FORMAT(RapidF#,6)
FORMAT(Recall#,7) {Canned Threading Spring Passes}
FORMAT(SpringPasses#,8)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

doRangeCode: {Added this sub - JHE}
IF ConstantSurfaceFeed?
IF GreaterThan? MaxRPM# Num#('2000')
'M41'
ELSE
'M40'
END
ELSE
IF GreaterThan? SpeedRPM# Num#('2000')
'M41'
ELSE
'M40'
END
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
{ not using tool offsets }
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC doRangeCode EOL {Added this block - JHE}
SeqLabC Preset MaxRPM EOL
END
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC Speed
END
ELSE
SeqLabC doRangeCode EOL {Added this block - JHE}
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' Speed
END
END
IF LAST ProgStop?
SeqLabC SpeedC SpinOn CoolOn EOL
ELSE
SeqLabC SpeedC
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn
END
EOL
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC:
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF NOT LastFeat?
CRCOnC
END
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P200' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

SpringPass:
IF GreaterThan? Recall# NUM#('9') NUM#('0')
SeqLabC 'X' Recall# NUM#('10') EOL
END
Save# NUM#('9') SUB# Recall# NUM#('9') NUM#('1') {counter}
RETURN

DoThreadSpringPass:
Save# NUM#('9') SpringPasses#
SpringPass SpringPass SpringPass SpringPass SpringPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
' ( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff
SetHome
DoOpComments
' ' EOL
DoPostScript
Plane
'N' Tool# '00'
IF UseComments? AND ToolComment?
' ( ' ToolComment$ ' )'
END
EOL
SeqLabC 'G54Z0.' EOL
SeqLabC OpToolID '00' doRangeCode EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G99G96' Speed SpinOn EOL
ELSE
SeqLabC CSSOff 'G99G97' Speed SpinOn EOL
END
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed? {Added - JHE}
SeqLabC CSSOff 'G97' CalcRPM2 CoolOff EOL
ELSE
SeqLabC CoolOff EOL
END
{SeqLabC NewHome EOL} {Removed - JHE}
SeqLabC 'G30U0.W0.' EOL
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END
' ' EOL

{Start new Operation, NewTool}

DoOpComments
DoPostScript
'N' Tool# '00'
IF UseComments? AND ToolComment?
' ( ' ToolComment$ ' )'
END
EOL
SeqLabC 'G54Z0.' EOL
SeqLabC OpToolID '00' doRangeCode EOL
IF ConstantSurfaceFeed?
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G99G96' Speed SpinOn EOL
ELSE
SeqLabC CSSOff 'G99G97' Speed SpinOn EOL
END
Approach
ELSE
IF SameTool?

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
IF ApproachFace?
SeqLabC LCycle 'Z' FirstMoveEPZ# XatFinZ XTapAtZ FeedRate EOL
ELSE
SeqLabC LCycle XatFinZ FinZ XTapAtZ FeedRate EOL
END
SimpleRough
ELSE
TagInc
IF RoughContour?
SetPass2
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft CutDepth FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove ZCSP EOL
SeqLabC FeedC XCSP EOL
ELSE
SeqLab StepMove XCSP EOL
SeqLabC FeedC ZCSP EOL
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
ELSE
IF RoughPatternShift?
SetPass2
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft XminusU ZminusW NumCuts FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
END
END
END
ELSE
IF Threading?
SetFlag('10')
SeqLabC 'G92'
EachFeat
IF ThreadFeat?
SeqLabC MoveXC MoveZC
IF Flag?('10')
SetFlagF('10')
IF Taper?
XTapAtZ
END
ThrdLead
END
EOL
Save# Num#('10') EPX#
END
NextFeat
IF GreaterThan? SpringPasses# Num#('0')
DoThreadSpringPass
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G4P200' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF Peck?
SeqLabC LCycle ZDepth Peck FeedRate
IF PeckFullRetract?
RLevel
END
EOL
SeqLabC DrillOff EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
ELSE
IF Grooving?
StockOn
SetPass1
SeqLabC StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC 'X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC 'G32'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P200' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
IF ConstantSurfaceFeed? {Added - JHE}
SeqLabC CSSOff 'G97S' CalcEpRPM# CoolOff EOL
ELSE
SeqLabC CoolOff EOL
END
SeqLabC 'G30U0.W0.' SpinOff EOL
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END
' ' EOL
SeqLabC 'G28U0.W0.' EOL
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END