{Change Comments ***********************************************************}

{9/2/89
Copied & modified: Yasnac LX1 MS L010.55
For: Aerodynamic Eng
Space between codes. Move tool preset call & CoolOn to 1st G50 line.
Delete UnTool from end of prog.
Jim Radcliffe}

{5/7/90, Updated: Yasnac LX3 MS L121.55 to .69.3 format, JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{8/2/91, Updated Yasnac LX3 MS L121.70 to .81 format, JR}

{8/7/91
Updated: Yasnac LX3 MS L121.81
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.82 Format.
Kim Michelman}

{4/15/93
Copied & modified: Yasnac LX3 MS L121.82
For Magness Machine Co., Inc.
Control: Yasnac LX3
Machine: Mori Seiki SL-25
Changed to PosSideLathe, deleted ReverseXZArcs
Added block delete before CoolOn
Moved OpToolID '00' to line by itself after 'G51'
Added to begin program
' G28 U0 W0'
' U-5. W-5.'
Added to end program
' G28 U0 W0'
Minor Update to .82.1 corrections.
Jim Radcliffe}

{9/10/95, Updated Yasnac LX3 MS SL-25 L277.82 to .85 foramt per Fanuc 10T MS [-] L001.85.01.01, JR}

{
Format: Yasnac LX3 MS SL-25 Lxxx.85.1
1/12/96
For: Warman Ind.
Removed all occurances of OpToolID '00'
Removed / and M8 from Preset line
Added OpToolID LatheOffset to SpinOn line in FirstOp and NewTool
Removed OpToolID LatheOffset from AppMove
Added CoolOn to Approach
Removed:
SeqLabC ' G28 U0 W0' EOL
SeqLabC Rapid ' U-5. W-5.' EOL
TH}

{4/11/96
Modified: Yasnac LX3 MS SL-25 L411.85.1
For: Warman Ind.
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.02.11/Compost 4.21.34.1/1.0a
Changes made per Ewen Ritchie.
Moved CoolOn from Approach to AppMove.
Modified for better SpeedC at CheckOffset.
Modified CkCRC sub.
Added StandardXZArcs at setup and initializations.
Just in case InitProg does not cancel ReverseXZArcs.
Simplified Canned Threading.
Added Address Spaces where needed.
Deleted G28 U0 W0 block at end of Prog.
DWB}

{4/25/96
Modified: Yasnac LX3 MS SL-25 L411.85.1
For: Warman Ind.
Versions: ncCad 4.33.02/ncCAM 4.33.01/ncPost 4.33.09/Catalyst v3.04C/Compost 4.21.34.1/1.0a
Changes made per Ewen Ritchie.
Added ADD# to FORMAT#3 at Prog Numeric Format Definitions.
Deleted logic and call to FeedNoCan at AppMove.
Deleted logic and call to FeedRateNoCan at AppMove.
Forces Rapid Move to XSP ZSP coordinates.
XSP ZSP block not output for Non-Canned RoughContour Cycle.
Added ToolPath2 sub.
Modifies StartPos MoveType for each pass of Non-Canned RoughContour Cycle.
Suppresses first block of two consecutive Rapid/Rapid, Rapid/Line OR Line/Line Features.
Does Not Apply to FirstFeat, LastFeat, Line/Rapid, Arc/Rapid, Arc/Line, Rapid/Arc OR
Line/Arc Features.
Forces StartPos MoveType to be RapidFeat.
Changed ' T5' Tool# to ' T' ADD# Tool# Num#('50') at FirstOperation and NewTool.
DWB}

{11/19/97,
Initial: Yasnac LX3 MS [WI] L411.85.3
Created: Yasnac LX3 MS [] Lxxx.85
For: Micron Tech
Moved OpToolID and LatheOffset down one line in FirstOp and NewTool.
Added 'G4 P1000' to OpToolID line in FirstOp and NewTool.
Added boolean so that XSP and ZSP will output on seperate lines
in IF Drilling/IF RoughContour depending on ApproachFace or
ApproachID/OD.
CDH}

{12/1/97,
Initial: Yasnac LX3 MS [] L667.85
Created: Yasnac LX3 MS [] L667.85.1
For: Micron Tech
Deleted DrillOff command in IF Drilling/If Peck.
CDH}

{4/21/1998,
Initial: Yasnac LX3 MS [] L667.85.1
Created: Yasnac LX3 MS []
For: Micron Tech/ Bryan Kramer
Added a M24 before canned cycle if chamfering was not wanted.
Yasnac controls have to have a 'M' code before a G76 threading
cycle.
TJL}


{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.####;0.'
#3 = '#######0'
#4 = '###^##0'
#5 = '#.######;0.'
#6 = '###0'
#7 = '#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(MUL#,2) { Non-Canned Threading AutoFinish }
FORMAT(InFeedAngle#,2)
FORMAT(FirstMoveEPX#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(ADD#,3)
FORMAT(Program#,3) {.72}
FORMAT(Operation#,3) {.72}
FORMAT(Tool#,3) {.72}
FORMAT(Dwell#,4) {.72}
FORMAT(FeedIPR#,5)
FORMAT(RapidF#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan:
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan:
IF NOT CannedCycle?
FeedRateC
END
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF Roughing? AND RoughContour? AND NOT CannedCycle?
ELSE
SeqLabC ZSPC EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF Roughing? AND RoughContour? AND NOT CannedCycle?
ELSE
SeqLabC XSPC EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC ' M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewToolOffset?
SeqLabC OpToolID LatheOffset EOL
END
CSSOff
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
IF LAST ProgStop? {OR NewGear?}
CSSOn ' G96' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
CSSOn ' G96' Speed
END
END
ELSE
SeqLabC Preset MaxRPM EOL
CSSOn ' G96' Speed
END
ELSE
IF LAST ConstantSurfaceFeed?
' G97' Speed
ELSE
IF LAST ProgStop?
' G97' Speed
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
' G97' Speed
END
END
END
END
IF LAST ProgStop?
SeqLabC {SpeedC} SpinOn EOL
SeqLabC ' /' CoolOn EOL
ELSE
SeqLabC {SpeedC} EOL
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC ' /' CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
IF LastFeat?
CRCOffC { Exit Length Feature }
ELSE
CRCOnC { Entry Length Feature }
END
END
RETURN

ToolPath2: { Non-Canned RoughContour Cycle }
IF NOT LastFeat? AND NEXT NOT ArcFeat? AND Equal? SPMoveAngle# NEXT EPMoveAngle#
IF LineFeat? AND NEXT RapidFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
{ Suppress first block of two consecutive Rapid/Rapid, Rapid/Line OR Line/Line Features }
END
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE { LineFeat }
SeqLabC CkCRC
IF FirstFeat?
{ Force StartPos MoveType to be RapidFeat }
MoveXC MoveZC
ELSE
IF LAST RapidFeat? AND Equal? EPMoveAngle# LAST SPMoveAngle#
{ Force StartPos MoveType to be RapidFeat }
MoveXC MoveZC
ELSE
FeedC MoveXC MoveZC FeedRateC
END
END
EOL
END
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC ' G4 P2000' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC ' G4 P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
IF Roughing? AND RoughContour? AND NOT CannedCycle?
ToolPath2
ELSE
SeqLabC RapidC MoveXC MoveZC EOL
END
ELSE
IF LineFeat?
IF Roughing? AND RoughContour? AND NOT CannedCycle?
ToolPath2
ELSE
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC ' G32' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
PosSideLathe
StandardXZArcs
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
RestoreScale
OpenSub
StockOff {.71.2}
SetHome
DoOpComments
DoPostScript
Plane
SeqLab ' G51' EOL
SeqLabC Preset
IF ConstantSurfaceFeed?
MaxRPM
END
' T' ADD# Tool# Num#('50') '00' EOL { OpToolID }
SeqLabC CSSOff ' G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn EOL
SeqLabC OpToolID LatheOffset ' G4 P1000' EOL
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff {.62}
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff ' G97' CalcRPM2 EOL
END
SeqLabC ' G51' EOL
IF LAST ProgStop?
SeqLabC ' M0' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation}

DoOpComments
DoPostScript
SeqLab ' G51' EOL
SeqLabC Preset
IF ConstantSurfaceFeed?
MaxRPM
END
' T' ADD# Tool# Num#('50') '00' EOL { OpToolID }
SeqLabC CSSOff ' G97'
IF ConstantSurfaceFeed?
CalcRPM1
ELSE
Speed
END
SpinOn OpToolID LatheOffset EOL
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

StockOff
DoOpComments
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
END
END
CheckOffset
ApproachSP
END
END
END
END {common point for all operations}
IF ConstantSurfaceFeed? AND NOT SameTool?
SeqLabC CSSOn ' G96' Speed EOL
END
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
SeqLabC LCycle
IF ApproachFace?
' Z' FirstMoveEPZ# XatFinZ
ELSE
XatFinZ FinZ
END
XTapAtZ FeedRate EOL
SimpleRough
ELSE
TagInc
SetPass2
IF RoughContour?
SeqLabC LCycle ' PÅ‚' Tag# ' Q²' Tag# XStkLeft ZStkLeft CutDepth FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove ZSP EOL
SeqLab FeedC XSP EOL
ELSE
SeqLab StepMove XSP EOL
SeqLab FeedC ZSP EOL
END
ELSE
IF RoughPatternShift?
SeqLabC LCycle ' PÅ‚' Tag# ' Q²' Tag# XStkLeft ZStkLeft XminusU ZminusW NumCuts FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
END
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC ' G70' ' PÅ‚' Tag# ' Q²' Tag# EOL
END
SetPass1
TrackXNO# CycleStartX#
TrackZNO# CycleStartZ#
END
ELSE
IF Threading?
IF Chamfer?
SeqLabC ' M23' EOL
ELSE ' M24' EOL
END
IF ConstantVolumeCut? OR SingleEdgeCut?
SeqLabC LCycle XatFinZ FinZ XTapAtZ ThrdHeight CutDepth ThrdLead
IF SingleEdgeCut?
' A' InFeedAngle#
ELSE
' A0.'
END
EOL
ELSE
SeqLabC ' G92 X' FirstMoveEPX# FinZ ThrdLead EOL
SimpleRough
END
IF AutoFinish?
SeqLabC Feed XatFinZ EOL
SeqLabC ' G32' FinZ ThrdLead EOL
SeqLabC RapidC XCSP EOL
SeqLabC ZCSP EOL
END
IF Chamfer?
SeqLabC ' M24' EOL
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth ' E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC ' G4 P2000' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF Peck?
SeqLabC LCycle ZDepth Dwell Peck Retract FeedRate EOL
SeqLabC EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC ' G4 P' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish? { .82.1c }
StockOff
IF Turning?
IF ApproachFace?
SeqLabC RapidC ZOpECPC EOL
ELSE
SeqLabC RapidC XOpECDC EOL
END
ApproachSP
SeqLabC StockOff StrtPosC EOL
ToolPath
ELSE
IF Roughing? AND NOT RoughSimple?
SetPass2
SeqLabC RapidC XSPC ZSPC EOL
SeqLabC StockOff StrtPosC EOL
ToolPath
SetPass1
ELSE
IF Threading?
SeqLabC ' X' MUL# Num#('2') ADD# FinishXRadius# Taper# EOL
SeqLabC ' G32'
IF Taper?
XatFinZ
END
FinZ ThrdLead EOL
SeqLabC Rapid XSP EOL
SeqLabC ZSP EOL
END
END
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC ' G4 P2000' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC EOL
DoEndOpPS
SeqLabC RapidC CoolOff EOL
SeqLabC ' G51' SpinOff EOL
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END