{Change Comments ***********************************************************}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{9/21/90, Updated: Fanuc 6T MS [+] L016.53 to .71 format, JR}
{10/2/90, Added StockOff globally at FirstOperation, DWB}
{10/8/90, Replace CalcRPM2 globally with CalcEPRPM# at end of prog, DWB}
{12/21/90, Modified from L016.71
Changed Format #4 from '###^##0' to '###.##0'
Changed Format #6 from '###0' to '0000'
Changed form per customer request. JC}

{6/4/91
Modified: Yasnac 2000G TM (PM) L213.71
For: Precision Machine
Deleted ProgID1
Updated to .81
Jim Radcliffe}

{08/07/91
Updated: Yasnac 2000G TM (PM) L213.81
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.82 Format.
Kim Michelman}

{2/26/96
Initial : Yasnac 2000G TM (PM) L213.82
Created: Yasnac 2000G TM (PM) L213.82.1
Changed to negative X values, put depth moves for g71 and G72 cycles on separate line, MPK}
{2/26/96
Initial : Yasnac 2000G TM (PM) L213.82.1
Created: Yasnac 2000G TM (PM) L213.82.2
Changed format in form for depth of cut in G71/G72 cycles to ^0000, eliminated all occurences of DrillOff,
added GearRange, put SpinOn command on Preset line, modified Peck cycle by added X0. after G74,
added D for retract label in form, MPK}

{1/9/97, update to .85 format, MPK}

{6/2/97
Initial : Yasnac 2000G TM (PM) L213.85
Created: Yasnac 2000G TM (PM) L213.85.1
Changed to Pos side lathe, MPK}

{9/1/98,
Initial : Yasnac 2000G TM (PM) L213.85.1
Created: Yasnac 2000G MS [BMR] L769.85
Customer: B & M Racing Products, Jon Parker - 818/882-6422 ext.227

Changes to "Form":

1. Under Default Format, changed E & F to #0.####;0. and R, X, Y, & Z to ###0.####;0.
Also G, H, & M to #0 and N, O, P, & Q to ###0
2. Under Arcs, changed CW Arc Number to 22 and CCW Arc Number to 23
Also changed I-J Max Arc Radius to 0.000
3. Under Turn Rough - OD/ID, changed X Stock Left (U) and Z Stock Left (W)
Format to ###0.####;0. Start Seq Number (P) and End Seq Number (Q) Format to ###0
and Depth of Cut (D) Format to ##^0000
4. Under Turn Rough - Face, changed X Stock Left (U) and Z Stock Left (W)
Format to ###0.####;0. Start Seq Number (P) and End Seq Number (Q) Format to ###0
and Depth of Cut (D) Format to ##^0000
5. Under Pattern Shift, changed X Stock Left (U) and Z Stock Left (W) Format to
###0.####;0. Start Seq Number (P) and End Seq Number (Q) Format to ###0
and Number of Cut (D) Format to #0
6. Under Threading, changed Depth of First Cut (D) Format to ##^0000 and changed
Lead of Thread Label to F. Also changed Lead of Thread (F) Format to #0.####;0.
Finish X (X), Finish Z (Z), Height of Thread (K), and X Taper (I) to ###0.####;0.
and Cutting Method (P) Format to #0
7. Under Lathe Drill Cycles, changed the two Formats to ###0.####;0.
8. Under Edit Tables, changed M41 to 1500 and M42 to 5000

Changes to "Prog":

1. Added FORMAT for SPX#, SPZ#, Tag#, and ADD#.
2. Removed G97 output when CSS is On.
3. Changed Tool Change sequence per customer spec.
4. Changed Threading output per customer spec.
5. Added Format #7 and FORMAT for RapidF#. Also added RapidF# in Approach sub.
6. Added NegSideLathe.
7. Changed #2, #4, and #5 FORMATs.
8. Added calcToolNum sub (output tool# + 50).
9. Added FeedNoCan and FeedRateNoCan subs. Replaced ODApproachSP, IDApproachSP, and
FaceApproachSP subs with ApproachSP sub.
JHE}

{Prog Numeric Format Definitions *******************************************}

#1 = '0.00'
#2 = '###0.####;0.' {Changed from '###.0###' - JHE}
#3 = '########;0'
#4 = '##0.###' {Changed from '###.##0' - JHE}
#5 = '#0.####;0.' {Changed from '#.######;0.' - JHE}
#6 = '0000'
#7 = '#' {Added - JHE}

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(FirstMoveEPX#,2)
FORMAT(FirstMoveEPZ#,2)
FORMAT(SPX#,2) {Added - JHE}
FORMAT(SPZ#,2) {Added - JHE}
FORMAT(Program#,3)
FORMAT(Operation#,3)
FORMAT(Tool#,3)
FORMAT(Tag#,3) {Added - JHE}
FORMAT(ADD#,3) {Added - JHE}
FORMAT(Dwell#,4)
FORMAT(FeedIPR#,5)
FORMAT(CalcEPRPM#,6)
FORMAT(RapidF#,7) {Added - JHE}

{Prog Subroutines **********************************************************}

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolSize$ ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
END
RETURN

PSInit: {reset flags from last Op, .70}
RETURN

PSStuff:
RETURN

DoPostScript:
PSInit
EachPS
SeqLabC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLabC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

StockOnNoCan:
IF NOT CannedCycle?
StockOn {need stock for SP positioning, if not a canned cycle}
END
RETURN

FeedNoCan: {Added - JHE}
IF NOT CannedCycle?
FeedC
END
RETURN

FeedRateNoCan: {Added - JHE}
IF NOT CannedCycle?
FeedRateC
END
RETURN

ODApproachSP: {Removed calls to this sub - JHE}
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
SeqLabC Feed StockOnNoCan XSPC FeedRate EOL
RETURN

IDApproachSP: {Removed calls to this sub - JHE}
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL { for SameTool ApproachID }
SeqLabC Feed StockOnNoCan XSPC FeedRate EOL
RETURN

FaceApproachSP: {Removed calls to this sub - JHE}
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
SeqLabC Feed StockOnNoCan ZSPC FeedRate EOL
RETURN

ApproachSP:
IF ApproachFace?
SeqLabC StockOnNoCan XSPC EOL
SeqLabC StockOff ZOpCPC EOL
StockOnNoCan
IF NotEqual? CycleStartZ# ZOpCP#
SeqLabC FeedNoCan ZSPC FeedRateNoCan EOL
END
ELSE { ODApproach/IDApproach }
SeqLabC StockOnNoCan ZSPC EOL
SeqLabC StockOff XOpCDC EOL
StockOnNoCan
IF NotEqual? CycleStartX# XOpCD#
SeqLabC FeedNoCan XSPC FeedRateNoCan EOL
END
END
RETURN

AppMove:
StockOff ThisOpEntryZCP CoolOn
RETURN

Approach: { NOT FOR TAILSTOCK, .82 }
Rapid RapidF# { RapidF# Forces FeedRate }
IF ApproachOD?
SeqLabC ThisOpEntryXCP AppMove EOL
{ODApproachSP}
ELSE
IF ApproachID?
SeqLabC XOpCD AppMove EOL
{IDApproachSP}
ELSE {ApproachFace}
SeqLabC StockOnNoCan XSP AppMove EOL
{FaceApproachSP}
END
END
ApproachSP
RETURN

CheckOffset:
DoEndOpPS
IF LAST ProgStop?
SeqLabC 'M0' EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLabC CoolOff EOL
END
END
IF NewGear?
SeqLabC GearRange EOL
END
IF NewToolOffset?
SeqLabC LOfstOff '00' EOL
SeqLabC OpToolID LatheOffset EOL
END
IF ConstantSurfaceFeed?
IF LAST ConstantSurfaceFeed?
IF NotEqual? MaxRPM# LAST MaxRPM#
SeqLabC Preset MaxRPM EOL
END
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC 'G96' Speed EOL
END
ELSE
SeqLabC Preset MaxRPM EOL
SeqLabC CSSOn 'G96' Speed EOL
END
ELSE
IF LAST ConstantSurfaceFeed?
SeqLabC CSSOff 'G97' Speed EOL
ELSE
IF NotEqual? SpeedRPM# LAST SpeedRPM#
SeqLabC Speed EOL
END
END
END
IF LAST ProgStop?
SeqLabC SpeedC SpinOn EOL
SeqLabC CoolOn EOL
ELSE
IF NOT CoolOff? AND LAST CoolOff?
SeqLabC CoolOn EOL
END
END
DoPostScript
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXC MoveZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

CkCRC: { 4.2 }
IF XMove? OR ZMove? { Approach Length Feature and Multiple Pockets }
CRCOnC
END
IF LastFeat? AND EmptyLine? { Exit Length Feature }
CRCOffC
END
RETURN

ToolPath:
EACHFeat
GetToolTip
IF LastFeat?
IF Drilling?
IF Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P0.5' EOL
SeqLabC Speed InverseSpinOn EOL
ELSE
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
END
ELSE
IF CannedCycle?
SeqLab
END
END
END
IF PointFeat?
SeqLabC MoveSXYC EOL
ELSE
IF RapidFeat?
SeqLabC RapidC MoveXC MoveZC EOL
ELSE
IF LineFeat?
SeqLabC CkCRC FeedC MoveXC MoveZC FeedRateC EOL
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, LAST, FIRST or NEXT modifiers in this loop }
SeqLabC FormatArc FeedRateC EOL
NEXTQuadrant
ELSE
IF ThreadFeat?
SeqLabC 'G32' MoveXC MoveZC ThrdLead EOL
Rapid
END
END
END
END
END
NEXTFeat
RETURN

CheckRapid:
CRCOffC
IF LAST CannedCycle?
Rapid
ELSE
RapidC
END
RETURN

calcToolNum:
ADD# Num#('50') Tool# '00'
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
SetAbs
NegSideLathe {Added - JHE}
ReverseXZArcs
SetMaxRPM('10000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: must be all capital letters when typed in.' EOL
' ENDOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
END
EachOp {Start of post processing *********************}
GetLCycle
IF FirstOperation?
EOR EOL
'N' Program#
IF UseComments? AND ProgramNameComment?
' ( ' ProgramName$ ' )'
END
EOL
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ABSOLUTE INCHES )' EOL
END
END
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
OpenSub
StockOff
SetHome
DoOpComments
DoPostScript
Plane
SeqLab ' '
IF ConstantSurfaceFeed?
Rapid Preset MaxRPM 'T' calcToolNum EOL
SeqLabC 'G51' EOL {move to tool change position - JHE}
SeqLabC GearRange EOL
SeqLabC CSSOn 'G96' Speed SpinOn OpToolID LatheOffset EOL
ELSE
Rapid 'T' calcToolNum EOL
SeqLabC 'G51' EOL {move to tool change position - JHE}
SeqLabC GearRange EOL
SeqLabC CSSOff 'G97' Speed SpinOn OpToolID LatheOffset EOL
END
Approach
ELSE
IF NewTool?

{Finish off last Operation}

StockOff
CheckRapid
IF LAST ApproachOD?
SeqLabC LAST OpExitXCPC EOL
ELSE
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
END
SeqLabC LAST OpExitZCPC EOL
DoEndOpPS
IF ToolChangeAtHome?
SeqLabC Rapid NewHome CoolOff EOL
ELSE
SeqLabC Rapid CoolOff EOL
END
SeqLabC 'G51' EOL
IF LAST ProgStop?
SeqLabC 'M00' EOL
ELSE
SeqLabC ProgStop EOL
END

{Start new Operation, NewTool}

DoOpComments
DoPostScript
Plane
SeqLab ' '
IF ConstantSurfaceFeed?
Rapid Preset MaxRPM 'T' calcToolNum EOL
SeqLabC 'G51' EOL {move to tool change position - JHE}
SeqLabC GearRange EOL
SeqLabC CSSOn 'G96' Speed SpinOn OpToolID LatheOffset EOL
ELSE
Rapid 'T' calcToolNum EOL
SeqLabC 'G51' EOL {move to tool change position - JHE}
SeqLabC GearRange EOL
SeqLabC CSSOff 'G97' Speed SpinOn OpToolID LatheOffset EOL
END
Approach
ELSE
IF SameTool? {.62}

{Start new Operation}

DoOpComments
StockOff
IF LAST StraightConnect?
CheckOffset
CheckRapid
SeqLabC StockOnNoCan XSPC ZSPC EOL
ELSE
CheckRapid
IF ApproachOD?
IF LAST ApproachOD?
SeqLabC LAST XOpECDC EOL
ELSE {around}
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC LAST OpExitXCPC EOL
END
CheckOffset
ApproachSP
ELSE
IF ApproachID?
IF LAST ApproachID?
SeqLabC LAST XOpECDC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
END
SeqLabC LAST OpExitZCPC EOL
SeqLabC XOpCDC EOL
END
CheckOffset
ApproachSP
ELSE {ApproachFace}
IF LAST ApproachFace?
SeqLabC LAST ZOpECPC EOL
ELSE
IF LAST ApproachOD? {around}
SeqLabC LAST OpExitXCPC EOL
ELSE {LAST ApproachID}
SeqLabC LAST XOpECDC EOL
END
SeqLabC LAST OpExitZCPC EOL
END
CheckOffset
ApproachSP
END
END
END
END
END
END {common point for all operations}
IF CannedCycle?
StockOff
IF Roughing?
IF RoughSimple?
StockOn
SetPass1
IF ApproachFace?
SeqLabC LCycle 'Z' FirstMoveEPZ# XatFinZ XTapAtZ FeedRate EOL
ELSE
SeqLabC LCycle XatFinZ FinZ XTapAtZ FeedRate EOL
END
SimpleRough
ELSE
TagInc
IF RoughContour?
SetPass2
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft CutDepth FeedRate EOL
'>' Tag# EOL
IF ApproachFace?
SeqLab StepMove MoveSZ EOL
SeqLabC FeedC MoveSX EOL
ELSE
SeqLab StepMove MoveSX EOL
SeqLabC FeedC MoveSZ EOL
END
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
ELSE
IF RoughPatternShift?
SetPass2
SeqLabC LCycle 'PÅ‚' Tag# 'Q²' Tag# XStkLeft ZStkLeft XminusU ZminusW NumCuts FeedRate EOL
'>' Tag# EOL
SeqLab Rapid StrtPos EOL
ToolPath
'<' Tag# EOL
IF AutoFinish?
SeqLabC 'G70' 'PÅ‚' Tag# 'Q²' Tag# EOL
END
END
END
END
ELSE
IF Threading?
IF Chamfer?
SeqLabC 'M23' EOL
END
SeqLabC LCycle XatFinZ FinZ
IF Taper?
XTapAtZ
END
ThrdHeight CutDepth ThrdLead ToolAngle CutMethod EOL
IF AutoFinish?
SeqLabC Feed XatFinZ EOL
SeqLabC 'G32' FinZ ThrdLead EOL
SeqLabC RapidC XCSP EOL
SeqLabC ZCSP EOL
END
IF Chamfer?
SeqLabC 'M24' EOL
END
ELSE
IF Drilling?
IF Tap?
SeqLabC LCycle ZDepth 'E' FeedIPR# EOL
SeqLabC SpinOff EOL
SeqLabC 'G4P0.5' EOL
SeqLabC Speed InverseSpinOn EOL
SeqLabC ZSP EOL
ELSE
IF PeckChipBreaker?
SeqLabC LCycle 'X0.' ZDepth RLevel Dwell Peck Retract FeedRate EOL
IF AutoFinish?
SeqLabC Feed ZDepth EOL
IF Dwell?
SeqLabC 'G4P' Dwell# EOL
END
SeqLabC Rapid ZSP EOL
END
END
END
ELSE
IF Grooving?
SeqLab StrtPos EOL
ToolPath
END
END
END
END
ELSE
StockOn
SetPass1
ToolPath
IF AutoFinish?
IF NOT Drilling? AND NOT Grooving?
StockOff
IF Turning?
SetPass1
ELSE
SetPass2
END
SeqLab RapidC StrtPos EOL
ToolPath
END
END
END
IF Drilling? AND Tap?
SeqLabC SpinOff EOL
SeqLabC 'G4P0.5' EOL
SeqLabC Speed SpinOn EOL
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
StockOff
CRCOffC
IF CannedCycle?
Rapid
ELSE
RapidC
END
IF ApproachOD?
SeqLabC OpExitXCPC EOL
ELSE
IF ApproachID?
SeqLabC XOpECDC EOL
END
END
SeqLabC OpExitZCPC CoolOff EOL
DoEndOpPS
IF FIRST ToolChangeAtHome?
SeqLabC Rapid FirstHome SpinOff EOL
ELSE
SeqLabC Rapid SpinOff EOL
END
SeqLabC 'G51' EOL
SeqLabC 'M30' EOL
'N999G28U0.W0.' EOL
SeqLabC 'G0W-8.' EOL
SeqLabC EOP EOL
Post
EOR EOL
Close
Retag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END