{Change Comments ***********************************************************}

{7/24/90, Updated: Yasnac MX2 Matsuura M017.55 to .72.1 format, JR}
{7/30/90, Replaced SetSRXYZero with SetSRXYtoSP, JR}

{4/3/91
Modified: Yasnac MX2 Matsuura M017.73
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
DWB}

{2/3/94
Updated: Yasnac MX2 Matsuura M017.79
For: Gibbs & Associates
Versions: ncCad 4.32/ncCAM 4.32/ncPost 4.32.02/Compost 4.21.20
Changes made per Pete Jackson
Updated to Version 4.2 per Fanuc 6M M001.81.2c Format.
DWB}

{2/3/94
Copied & modified: Yasnac MX2 Matsuura M017.81.2
For: Gibbs & Associates
Versions: ncCad 4.32/ncCAM 4.32/ncPost 4.32.02/Compost 4.21.20
Changes made per Pete Jackson
Created METRIC version.
DWB}

{5/25/95
Initial: Yasnac MX2 Matsuura M017.81.2m
ForUser: Fructus
Comment: New Processor per e-mailed instructions
Modified saftey start block at beginning of program.
Added G10 lines to beginning of program.
OpToolID ToolChng on same line with ToolComment.
Combined WFOStuff Speed SpinOn & StrtPos onto same line.
Added PreTool.
Combined OfstOn and CoolOn onto same line.
Replaced tool change position and OfstOff calls with 'M98P101'
Added G53 psoitioning to end of program.
First Tool In Spindle!
Jim Radcliffe}

{11/21/95
Updated: Yasnac MX2 Transema M797.81.2m
For: Fructus/Transema
Versions: ncCad 4.33.01/ncCAM 4.33.01/ncPost 4.33.08/Catalyst v2.28.04/Compost 4.21.33/1.0a
Changes made per Mikael Bagge, Virtual "Transema Posttest" file, editted text file.
Updated to Version 4.2 per LongHand M001.81.3j Format.
Added literal 'G93' block prior to Drill Cycle block at DrillStuff sub.
Limited to Tapping Operations only, synchronizes RPM/Feed.
Deleted StrtPos from Drill Cycle block at DrillStuff sub.
Moved PlaneC from SafeStart block to StrtPos block at NewTool.
Deleted SafeStart block at NewTool.
DWB}

{8/7/97
Updated & Modified: Yasnac MX2 Transema M797.81.3m
Created: Yasnac I80 Mat 510VF M797.89m
NOTE: Customer requested name change.
For: Fructus/Transema
Machine: Matsurra 510VF
Control: Yasnac I80
Versions: Catalyst v3.35C/ComPost2 MSL 68K
Changes made per Mikael Bagge, Virtual "M_POST" file, editted text file.
Updated for Catalyst v3.35C per LongHand M001.89e Format.
Customer requested deletion of ToolChng blocks.
Deleted DoToolComment sub.
Deleted SeqC OpToolID ToolChng DoToolComment EOL at MasterSub FirstOperation.
Changed literal 'P101' to 'P19006' at MasterSub NewTool and two places at SameTool.
Changed literal 'P101' to 'P19006' at EndPartSub and MPLoop subs.
Used to call User Defined CoolOff & OfstOff SafeCode Macro.
Macro now includes M6, ToolChng command.
Deleted Seq ToolChng DoToolComment EOL at MasterSub NewTool.
Deleted ToolChng FIRST ToolComment$ block at end of Prog.
Customer requested support of HighSpeed Machining.
Applies to Contouring Operations only.
Turned On following Tool Plunge into Material.
Turned Off prior to Tool Retraction from Material.
Added HighSpeedOn sub.
Outputs literal 'GON' for Contouring Operations only.
Called 3 places at ckHighSpeedOn sub.
Called at AutoCycCutSub1 and XYZRep subs.
Added ckHighSpeedOn sub.
Called from Milling sub.
Added HighSpeedOff sub.
Outputs literal 'GOFF' for Contouring Operations only.
Called 3 places at ckHighSpeedOn sub.
Called at XYZRep and ZonlyRepAutoCycle subs.
Added ckHighSpeedOff sub.
Called from Milling sub.
Added Var(3) to count Cycles for purposes of calling HighSpeedOn and HighSpeedOff subs.
Increased SetMaxRPM from 10000 to 15000 at setup and initializations.
Increased SetMaxFeed from 500 to 10000 at setup and initializations.
Added SetMaxFeed(393.70078740157) condition for English Files at setup and initializations.
DWB}

{12/12/97,
Initial : Yasnac I80 Mat 510VF M797.89m
Created: Yasnac I80 Mat 510VF M797.89.1m
Customer: Fructus/Transema

Changes to "Prog":

1. Changed GOFF to GOF.
2. Added ResetCRCNum in ToolPath sub-routine.
3. Added OpToolID (T_) and ToolChng (M6) to FirstOperation.
4. Changed FIRST TOOL IN SPINDLE Comment to FIRST TOOL NOT IN SPINDLE.
JHE}


{Prog Numeric Format Definitions *************************************}

#1 = '#.00'
#2 = '#####.###;0.'
#3 = '*#####.###;0.'
#4 = '#####.###;0.'
#5 = '#######0'
#6 = '####^##0'
#7 = '#'
#8 = 'ą#bbbb.bbbb#'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ADD#,4)
FORMAT(ToolDiameter#,4)
FORMAT(TrackXNO#,4)
FORMAT(TrackYNO#,4)
FORMAT(TrackZNO#,4)
FORMAT(Recall#,5)
FORMAT(PartNum#,5)
FORMAT(Program#,5)
FORMAT(Operation#,5)
FORMAT(Tool#,5)
FORMAT(NewWFO#,5)
FORMAT(Parts#,5)
FORMAT(Dwell#,6)
FORMAT(RapidF#,7)
FORMAT(PartShiftX#,8)
FORMAT(PartShiftY#,8)
FORMAT(PartShiftZ#,8)

{Prog Subroutines ******************************************}

RestoreScale:
IF NOT Metric? {CAM file is in English, tools and tool path}
SetScale('25.4') { change to Metric, this is an Metric post}
END
RETURN

WFONum:
'G' NewWFO#
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts? AND WorkFixtureOffsets?
EOL
'*** WARNING *** DO NOT USE NEWWFO() WITH MULTIPLE PARTS AND WORK FIXTURE OFFSETS' EOL
ELSE
WFONum
END
ELSE
IF Flag?('2')
IF NOT SameTool?
IF MultipleParts?
IF WorkFixtureOffsets?
SetWFO
ELSE
WFONum
END
ELSE
WFONum
END
END
END
END
SetFlagF('2')
RETURN

ResetWFO:
IF WorkFixtureOffsets?
SeqC WFO1 EOL
END
RETURN

DoPartCycleComment:
IF MultipleParts? AND UseComments? AND SubComment?
'( PART NO. ' PartNum# ' )' EOL
END
RETURN

DoCycleComment:
IF UseComments? AND SubComment?
'( CYCLE START )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit:
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff:
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL
PSStuff
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL
PSStuff
NextPS
RETURN

HighSpeedOn:
SeqC 'GON' EOL
RETURN

ckHighSpeedOn:
IF AutoCycle?
IF Repeats?
IF FirstCycle?
ReSetPass2 {restore for positioning moves}
IF FirstFeat?
HighSpeedOn
END
ReSetPass1 {restore for element cut moves}
END
ELSE
IF Equal? Recall# Num#('3') Num#('1') { FirstCycle }
HighSpeedOn
END
END
ELSE
HighSpeedOn
END
RETURN

HighSpeedOff:
SeqC 'GOF' EOL {Changed from GOFF - JHE}
RETURN

ckHighSpeedOff:
IF AutoCycle?
IF Repeats?
ReSetPass2 {restore for positioning moves}
IF LastFeat?
IF Equal? Recall# Num#('3') Repeats# { LastCycle }
HighSpeedOff
END
END
ReSetPass1 {restore for element cut moves}
ELSE
ReSetPass2 {restore for positioning moves}
IF LastFeat?
HighSpeedOff
END
ReSetPass1 {restore for element cut moves}
END
ELSE
HighSpeedOff
END
RETURN

EntryMove:
IF FeedEntry?
SeqC FeedC ZInC FeedEntC EOL
ELSE
SeqC RapidC ZInC EOL
END
RETURN

ExitMove:
IF FeedConnect?
IF NOT AutoCycle?
IF NOT NoZMoves?
FeedC ZInC FeedEntC
END
END
ELSE
CRCOffC
IF FIFO?
FeedC PRIME ZCP2C FeedEntC
ELSE
RapidC PRIME ZCP2C
END
END
RETURN

ExitMove2:
LoadFeat Num#('0') Num#('0') ClearancePlane3#
IF ZMove?
IF FIFO?
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
RETURN

CycleWarning:
{ NOTE: This Post Processor takes care of Z Clearance. }
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ckCRC:
IF LastFeat?
CRCOffC
ELSE
IF NOT ZMove?
CRCOnC
END
END
RETURN

ckCRCNum:
IF NOT LastFeat? AND Equal? SPZ# EPZ#
CRCOffsetC
END
RETURN

ToolPath:
ResetCRCNum {Added this line - JHE}
EACHFeat
IF PointFeat? { Drilling Only }
SeqC MoveSXYZC EOL
ELSE
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqC ckCRC RapidC MoveXYZC ckCRCNum EOL
END
ELSE
IF LineFeat?
IF XMove? OR YMove? OR ZMove?
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
DecelMove2
END
SeqC ckCRC FeedC MoveXYZC DecelFeed ckCRCNum EOL
ELSE
SeqC ckCRC FeedC MoveXYZC FeedRateC ckCRCNum EOL
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

AutoCycCutSub1: {part 1}
CalcACSRXY {calc tool position, CalcAutoCycleStatusRecordXY}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
SetSRXYtoSP
IF Repeats? AND ZShiftOnly?
EntryMove
IF Equal? Recall# Num#('3') Num#('1') { FirstCycle }
HighSpeedOn
END
END
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
SeqC AbsOrInc
IF FIFO?
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
EOL
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
ReSetPass2 {restore for positioning moves}
RETURN

Milling:
EntryMove
ckHighSpeedOn
ToolPath
ckHighSpeedOff
RETURN

XYZRep:
Save# Num#('3') Num#('0') { Cycle# counter }
CycleWarning
FindAnyZMoves
EachRep
Save# Num#('3') ADD# Recall# Num#('3') Num#('1') { Cycle# counter }
DoCycleComment
IF FirstCycle?
EntryMove
HighSpeedOn
ELSE
CRCOffC
IF FeedConnect?
IF SPXMove? OR SPYMove?
SeqC FeedC MoveSXYC FeedEntC EOL
END
IF ZShiftOnly?
EntryMove
END
ELSE
IF SPXMove? OR SPYMove?
SeqC RapidC MoveSXYC EOL
END
IF FeedEntry?
SeqC ZCP2C EOL
END
EntryMove
END
END
ToolPath
IF Equal? Recall# Num#('3') Repeats# { LastCycle }
HighSpeedOff
END
SeqC ExitMove EOL
NextRep
RETURN

NoRepAutoCycle:
Save# Num#('3') Num#('0') { Cycle# counter }
EACHFeat
Save# Num#('3') ADD# Recall# Num#('3') Num#('1') { Cycle# counter }
DoCycleComment
IF SPXMove? OR SPYMove?
IF FIFO?
Rapid
END
SeqC RapidC MoveSXYC EOL
END
AutoCycCutSub1
Milling
AutoCycCutSub2
NEXTFeat
RETURN

XYZRepAutoCycle:
CycleWarning
Save# Num#('3') Num#('0') { Cycle# counter }
EachRep
Save# Num#('3') ADD# Recall# Num#('3') Num#('1') { Cycle# counter }
DoCycleComment
IF NOT FirstCycle?
IF FIFO?
Rapid
END
SeqC RapidC StrtPos EOL
IF NOT FeedConnect?
SeqC ZCP2C EOL
END
END
EACHFeat
IF NOT FirstFeat?
DoCycleComment
END
IF SPXMove? OR SPYMove?
IF FIFO?
Rapid
END
SeqC RapidC MoveSXYC EOL
END
AutoCycCutSub1
Milling
AutoCycCutSub2
NEXTFeat
SeqC CRCOffC
LoadFeat Num#('0') Num#('0') PRIME ClearancePlane2#
IF ZMove?
ExitMove
END
EOL
NextRep
RETURN

ZonlyRepAutoCycle:
Save# Num#('3') Num#('0') { Cycle# counter }
EACHFeat
Save# Num#('3') ADD# Recall# Num#('3') Num#('1') { Cycle# counter }
DoCycleComment
IF SPXMove? OR SPYMove?
IF FIFO?
Rapid
END
SeqC RapidC MoveSXYC EOL
END
AutoCycCutSub1
EachRep
IF NOT FirstCycle?
IF FeedConnect?
DoCycleComment
IF SPXMove? OR SPYMove?
SeqC FeedC MoveSXYC FeedEntC EOL
END
AbsOrInc
ELSE
SeqC AbsOrInc ExitMove EOL
DoCycleComment
IF SPXMove? OR SPYMove?
SeqC IncValue RapidC MoveSXYC EOL
AbsOrInc
END
IF FeedEntry? AND NOT FIFO?
SeqC RapidC ZCP2 EOL
END
END
EntryMove
SeqC IncValue EOL
END
ToolPath
NextRep
ReSetPass2 {restore for positioning moves}
IF LastFeat?
HighSpeedOff
END
ReSetPass1 {restore for element cut moves}
AutoCycCutSub2
NEXTFeat
RETURN

DrillStuff:
SeqC DrillCP EOL
GetCycle
IF Tap?
SeqC 'G93' EOL { Synchronize RPM/Feed }
END
SeqC Cycle FromCP ZDepth RLevel Dwell Peck Retract FeedEnt EOL
TrackZNO# FIRST SPZ# {.81.2}
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

GetStartOfSameTool:
DoPartCycleComment
DoOpComments
DoPostScript
CheckPass
RETURN

MasterSub:
IF MultipleParts?
IF AllToolsOnePart?
IF FirstOperation? OR EquallySpacedOffsets?
SetFlag('2') { WFOStuff }
END
ELSE {implied OneToolAllParts?}
SetFlag('2') { WFOStuff }
END
ELSE
SetFlag('2') { WFOStuff }
END
IF FirstOperation?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
ELSE
Seq Plane CRCOff 'G49' DrillOff AbsOrInc EOL
SeqC 'G10Q2P1X0.Y0.Z0.' EOL
SeqC 'G10Q2P2X0.Y0.Z0.' EOL
SeqC OpToolID ToolChng EOL {Added this line - JHE}
DoPartCycleComment
DoOpComments
DoPostScript
CheckPass
SeqC Rapid WFOStuff StrtPos Speed SpinOn
IF NOT LastTool?
PreTool
END
EOL
SeqC OfstOn CoolOn EOL
END
ELSE
IF NewTool?
IF MultipleParts? AND OneToolAllParts? AND NOT FirstPart?
ELSE

{Finish off last Operation}

SeqC SubCall 'P19006' EOL { User CoolOff & OfstOff SafeCode Macro }
IF MultipleParts? AND OneToolAllParts?
ResetWFO
END
DoEndOpPS
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

DoPartCycleComment
DoOpComments
DoPostScript
CheckPass
Seq Rapid PlaneC WFOStuff StrtPos Speed SpinOn PreTool EOL
SeqC OfstOn CoolOn EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqC SubCall 'P19006' EOL { User CoolOff & OfstOff SafeCode Macro }
SeqC 'M0' EOL

{Start new Operation}

GetStartOfSameTool
SeqC Rapid PlaneC WFOStuff StrtPos SpeedC SpinOn EOL
SeqC OfstOn CoolOn EOL
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqC CoolOff EOL
END
IF NewToolOffset?
SeqC SubCall 'P19006' EOL { User CoolOff & OfstOff SafeCode Macro }

{Start new Operation}

GetStartOfSameTool
SeqC Rapid PlaneC WFOStuff StrtPos SpeedC EOL
SeqC OfstOn EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqC Rapid PlaneC WFOStuff StrtPos SpeedC EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqC CoolOn EOL
END
END
END
END
END {common point for all operations}
ResetCRCNum
RapidF# { No Output }
IF Milling?
SeqC ZCP2C EOL
IF AutoCycle?
IF Repeats?
IF ZShiftOnly?
ZonlyRepAutoCycle
ELSE
XYZRepAutoCycle
END
IF NOT FeedConnect?
SeqC ExitMove2 EOL
END
ELSE
NoRepAutoCycle
SeqC ExitMove2 EOL
END
SetPass1
ELSE { NOT AutoCycle }
IF Repeats?
XYZRep
ELSE
Milling
END
SeqC CRCOffC ExitMove2 EOL
END
ELSE
IF Drilling?
IF Repeats?
EachRep
DoCycleComment
IF FirstCycle?
DrillStuff
END
ToolPath
NextRep
ELSE
DrillStuff
ToolPath
END
SetDrillEndOpZ
SeqC Rapid 'G80' ZCP3 EOL
END
END
RETURN

EndPartSub:
{End of program ************************************************************}

{finish last operation}
SeqC SubCall 'P19006' EOL { User CoolOff & OfstOff SafeCode Macro }
IF MultipleParts? AND OneToolAllParts?
ResetWFO
END
DoEndOpPS
IF ProgStop?
SeqC 'M0' EOL
ELSE
IF MultipleParts? AND AllToolsOnePart? AND NOT LastPart?
SeqC ProgStop EOL
END
END
RETURN

DoNewPart:

{Finish off last Part}

IF FullUp?
SeqC SubCall 'P19006' EOL { User CoolOff & OfstOff SafeCode Macro }
END
{DoEndOpPS}

{Start new Part}

SetFlag('2') { WFOStuff }
GetStartOfSameTool
SeqC Rapid PlaneC WFOStuff StrtPos SpeedC EOL
IF FullUp?
SeqC OfstOn CoolOn EOL
END
RETURN

MPLoop:
Save# Num#('2') Recall# Num#('1')
IF WorkFixtureOffsets?
NewWFO
EachWFO
ELSE
EachPart
END
IF AllToolsOnePart?
EachOp
MasterSub
NextOp
EndPartSub
ELSE { OneToolAllParts }
EachOp
IF Equal? Operation# Recall# Num#('2') { Tool First Op }
IF FirstOperation? OR NewTool?
IF NOT FirstPart?
DoNewPart
END
END
MasterSub
IF LastOp?
IF LastPart?
Save# Num#('1') Num#('0')
END
Save# Num#('2') Recall# Num#('1')
ELSE
IF NEXT SameTool?
Save# Num#('2') NEXT Operation#
ELSE
IF LastPart?
Save# Num#('1') NEXT Operation#
Save# Num#('2') Num#('0')
ELSE
Save# Num#('2') Recall# Num#('1')
END
END
END
END
NextOp
END
IF WorkFixtureOffsets?
IncWFO
NextWFO
ELSE
NextPart
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
SetMaxRPM('15000')
IF Metric?
SetMaxFeed('10000')
ELSE
SetMaxFeed('393.70078740157')
END
Save# Num#('1') Num#('0') { MultipleParts Current Tool FirstOp# }
Save# Num#('2') Num#('0') { MultipleParts ToolOp# Counter }
Save# Num#('3') Num#('0') { Cycle# counter }
SetFlagF('2') { WFOStuff }
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
EachOp
IF FirstOperation?
IF ToolChangeAtHome?
SetHome
END
END
NextOp
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' MILLIMETERS )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL {Added NOT - JHE}
END
END
RestoreScale
IF MultipleParts?
IF WorkFixtureOffsets?
{'NOTE: This Post Processor does not support Work Fixture Offsets for Multiple Parts.' EOL
'It is recommended that you change your selection to Equally Spaced Offsets.' EOL}
END
IF AllToolsOnePart?
MPLoop
ResetWFO
ELSE
EachOp
IF FirstOperation?
Save# Num#('1') Operation#
END
NextOp
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
MPLoop MPLoop MPLoop MPLoop MPLoop
EndPartSub
END
ELSE
EachOp
MasterSub
NextOp
EndPartSub
END
SeqC WFOOff 'X-250.Y0.' EOL
SeqC EOP EOL
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END