{Change Comments ***********************************************************}

{10/30/89, updated to .66 version from 001.66, WFG}
{10/30/89, set up with no loops, incremental repeats and multiple parts, WFG}
{11/25/89, more cust mods, WFG}
{2/28/90, Modified safe start block per Cliff, J. Cusimano}
{7/24/90, Added InitProg globally to posts with this remark, DWB}

{1/25/91
Modified: Yasnac MX3 Mat 1000 M265.70
For: Hughes Radar
Updated to Version 3.2 per Fanuc 6M M001.76.1 Format.
Cleaned up prog.
Added capability to output all incremental subs for AutoCycles.
DWB}

{2/22/91
Modified: Yasnac MX3 Mat 1000 M265.76.1
For: Hughes Radar
Updated to Version 3.4 per Fanuc 6M M001.76.3 Format.
Added Safe End Block stuff from NewTool to Safe Startup Block of FirstOperation.
Replaced all occurances of IncValue OfstOff with Safe End Block stuff from NewTool.
DWB}

{12/17/91
Modified: Yasnac MX3 Mat 1000 M265.76.3
For: Gibbs & Associates
Updated to Version 4.0 per Fanuc 6M M001.81 Format.
Kim Michelman}

{12/18/91
Modified: Yasnac MX3 Mat 1000 M265.81
For: Hughes Radar
Changed logic for WFOStuff:.
Removed WFOStuff from the GetStartOfSameTool.
Added OpenSpindleCheck and CloseSpindleCheck.
Changed the SetMaxRPM to ('6000') instead of ('10000') to allow the program to
begin in the normal spindle speed enable.
Changed FirstOp to add IF ToolOver? logic.
Added WFOStuff to IF SameTool? logic.
Changed the literal 'G52' in the safe start-up to a WFOStuff command in IF SameTool? logic.
Kim Michelman}

{10/18/93
Modified: Yasnac MX3 Mat 1000 M265.81.1
For: Hughes Radar
Updated to .81.2 format per Fanuc 6M IncSubs M001.81.2
Jim Radcliffe}

{10/17/94
Modified: Yasnac MX3 Mat 1000 M265.81.2
For: Hughes Radar
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.03/Compost 4.21.22
Changes made per Steve Sato of Hughes Radar
Deleted blank lines at SubWarning sub.
Added CkCRC sub for CRCOffC per version 4.2.
CutterRadiusCompensation ExitLength will output G40 on LastFeat AND LineFeat at StdLine sub.
Added support of CRC during multiple pocket dog-bone operation.
Outputs G41/G42 on Z Plunge block at CkCRC sub.
Modified condition to output CRCOffC for LastFeat AND AutoCycle at ToolPath RapidFeat.
Assures that G40 is not output prior to LastFeat.
Added condition to output CRCOffC for ZMoveOnly Feature at ToolPath RapidFeat
Outputs G40 at all Z Retract blocks.
Customer requested WFOStuff output at all Operations.
Moved IF ToolOver?('30') to WFOStuff sub from OpenSpindleCheck sub and FirstOperation.
Will output literal 'G54' permanent register IF TRUE.
Register contains difference between low speed and high speed spindles.
Will handle normal support IF FALSE.
Changed First Work Fixture Offset from G54 to G56 in Compost Commands 5 dialog.
G56 is default value for Tools Less Than or Equal to 30.
Deleted IF NOT SameTool? AND IF NeedWFO1? condition at WFOStuff sub.
Modified OpenSpindleCheck sub.
Following blocks were output at end of all 3 conditions of sub.
Moved the blocks to NewTool, following call of sub.
DoPostScript
DoOpComments
SeqC Plane 'G80' CRCOffC EOL
SeqC WFOStuff EOL
Combined OpToolID and ToolChng on one block at OpenSpindleCheck sub.
Moved this block to end of SpindleChange sub and deleted occurances within.
Changed SafeStart block from Rapid CRCOff 'G49G52G61G80' 'Z0' to
Rapid Plane CRCOff 'G49G52G61G80' AbsOrInc 'Z0' SpinOff at NewTool.
Changed SafeStart block from Rapid CRCOff 'G49G52G61G80' 'Z0' to
Rapid CRCOff 'G49G52G61G80' AbsOrInc 'Z0' SpinOff at end of Prog.
Moved these blocks after IF MultipleParts? AND OneToolAllParts? AND FullUp?
Added literal 'G49' inside IF MultipleParts? AND OneToolAllParts? AND FullUp? at NewTool and
end of Prog.
Added literal 'G28X0Y0' block following SafeStart block at NewTool and end of Prog.
Deleted SpinOff from IF ToolChangeAtHome? condition at NewTool.
Deleted SpinOff from IF FirstToolChangeAtHome? condition at end of Prog.
Added Seq at OpenSpindleCheck call at NewTool.
Changed SpinOff to 'G28X0Y0' for LAST ProgStop? at SameTool.
Deleted calls to WFOStuff at SameTool and added at GetStartOfSameTool sub.
Added Speed SpinOn block to all conditions at SameTool.
Added OfstOn block to all conditions at SameTool.
DWB}

{
Format: Yasnac MX3 Mat 1000 M265.81.4
5/9/95
Removed 'G28X0Y0' from NewTool.
TH}

{9/26/95, Updated Yasnac MX3 Mat 1000 M265.81.4 to .85 format per Fanuc 6M IncSubs M001.85, JR}

{2/6/96, Updated .85 version to .86, MPK}

{3/22/96, Tested ZOnlyRepAutoCycle, Changed version # to .89, MPK}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '##.####;'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(ClearancePlane1#,4)
FORMAT(SUB#,4)
FORMAT(Program#,5) {.72}
FORMAT(Program2#,5)
FORMAT(CallMasterNum#,5)
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(NewWFO#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

DoSubComment:
IF UseComments? AND SubComment?
'( SUB NUMBER: ' Program# ' )' EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
'( OPERATION ' Operation# ': ' OperationType$ ' )' EOL
END
IF OperationComment?
'( ' OperationComment$ ' )' EOL
END
IF WorkGroupComment?
'( ' WorkGroupComment$ ' )' EOL
END
IF ToolTypeComment?
'( TOOL ' Tool# ': ' ToolDiameter# ' ' ToolType$ ' )' EOL
END
IF ToolComment?
'( ' ToolComment$ ' )' EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
OptCyc1F
MasterOpF
CallMasterOpF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqC 'A' FourthDegree# EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqC 'A' FourthDegree# EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqC 'B' FifthDegree# EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqC 'B' FifthDegree# EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqC PostScript EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqC EndOpPS EOL {literals}
PSStuff {commands}
NextPS
RETURN

CheckAbsOrInc:
IF Flag?('1') {we are in a MultipleParts sub}
IncValue
ELSE
IF Flag?('2') {we are in a Repeats sub}
IncValue
ELSE {we are not in a sub}
AbsOrInc
END
END
RETURN

EntryMove:
IF FeedEntry?
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC RapidC ZIn EOL
END
RETURN

StartSub:
OpenSub
SubID EOL
DoSubComment
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
'( WARNING Z CLEARANCE WILL CHANGE WITH EACH CYCLE OF SUB REPEAT )' EOL
END
END
RETURN

FinishSub1: {part 1}
SeqC CRCOffC
IF NOT FeedConnect?
IF AutoCycle?
ZCP3C
ELSE
IF FIFO? {.81}
FeedC ZCP3C FeedEntC
ELSE
RapidC ZCP3C
END
END
END
EOL
RETURN

HomeOrStrtPos:
IF AllToolsOnePart?
Home
ELSE {OneToolAllParts}
StrtPos
END
RETURN

DrillClearancePlane:
IF RetractToCP1?
IF SameTool?
IF NotEqual? LAST ClearancePlane3# ClearancePlane1#
SeqC 'Z' ClearancePlane1# EOL {ZCP1 does not output in incremental}
END
END
ELSE
SeqC ZCP2C EOL
END
RETURN

ECPZmove:
IF OneToolAllParts? AND ExitClearancePlane?
IF Milling?
SeqC ZCP2 EOL
ELSE {Drilling}
IF RetractToCP1?
SeqC ZCP1 EOL
ELSE
SeqC ZCP2 EOL
END
END
END
RETURN

OpenMP:
NewProg
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqC SetWFO AbsOrInc Rapid HomeOrStrtPos EOL
ECPZmove
SeqC SubCall CallLab EOL
IncWFO
NextWFO
ELSE
EachPart
SeqC AbsOrInc Rapid HomeOrStrtPos EOL
ECPZmove
SeqC SubCall CallLab EOL
IF FirstPart?
SetStatusOff
END
NextPart
SetStatusOn
END
StartSub
SeqC IncValue EOL
SetFlag('1') {set true, we are in a MP sub}
RETURN

CloseMP:
SeqC EndSub EOL
CloseSub
SetFlagF('1')
IF WorkFixtureOffsets?
SeqC WFO1 AbsOrInc EOL
ELSE
SeqC AbsOrInc EOL
END
RETURN

FormatArc:
IF ArcCW?
CWArcC
ELSE
CCWArcC
END
MoveXYZC
IF ArcIJFormat?
ArcIJC
ELSE
ArcRC
END
RETURN

ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
IF AutoCycle?
SeqC MoveSXYC EOL
SeqC SubCall CallLab EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
SeqC MoveSXYZC EOL {.80.01}
END
ELSE
IF RapidFeat?
IF LastFeat?
SeqC CRCOffC RapidC MoveXYZC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC RapidC MoveXYZC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC CRCOnC RapidC MoveXYZC CRCOffsetC EOL
END
END
END
ELSE
IF LineFeat?
IF LastFeat?
SeqC CRCOffC FeedC MoveXYZC FeedRateC EOL
ELSE
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqC FeedC MoveXYZC FeedRateC EOL
ELSE
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqC CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
DecelMove2
END
SeqC CRCOnC FeedC MoveXYZC DecelFeed CRCOffsetC EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqC CRCOnC FeedC MoveXYZC FeedRateC CRCOffsetC EOL
END
END
END
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqC FormatArc ArcFeedC EOL
DecelMove2
END
SeqC FormatArc DecelFeed EOL
ELSE
SeqC FormatArc ArcFeedC EOL
END
NEXTQuadrant
END
END
END
END
NEXTFeat
RETURN

WFOStuff:
IF ToolOver?('30')
SeqC 'G54' EOL
ELSE
IF NewWFO?
IF MultipleParts?
'*** WARNING *** DO NOT USE NEWWFO() WITH NCPOST MULTIPLE PARTS' EOL
ELSE
SeqC 'G' NewWFO# EOL
END
ELSE
SeqC 'G' NewWFO# EOL { Output at all Operations }
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SeqC IncValue EOL
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SeqC CheckAbsOrInc
IF Repeats? AND FeedConnect? AND ZshiftOnly?
ELSE
IF FIFO? {.81}
FeedC ZCP2 FeedEntC
ELSE
RapidC ZCP2
END
END
EOL
SeqC EndSub EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

NoReps:
IF AutoCycle?
NewProg
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
ELSE
EntryMove
ToolPath
END
RETURN

RepAutoCycle:
EachRep
IF FirstCycle?
SeqC SubCall CallLab EOL
SaveProgNum2
StartSub
SetFlag('2') {set true, we are in a Repeats sub}
SeqC IncValue EOL
NewProg
AutoCycPat
AutoCycCutSub1
EntryMove
AutoCycCutSub2
SeqC EndSub EOL
CloseSub
SetFlagF('2')
ELSE
ResetPass2
SeqC CheckAbsOrInc StrtPos EOL
SeqC SubCall 'P' Program2# EOL
SetSRSubXYRC
END
NextRep
RETURN

RepZOnlyAutoCycle:
AutoCycPat
StartSub
SetFlag('2') {set true, we are in a Repeats sub}
SeqC IncValue EOL
NewProg
EachRep
SetSRXYtoEP
IF FeedConnect?
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Feed StrtPosC EOL
ELSE
SeqC
END
ELSE
SeqC Feed
END
ZIn FeedEnt EOL
ELSE
IF NOT FirstCycle?
IF SPXMove? OR SPYMove?
SeqC Rapid StrtPosC EOL
END
END
IF FeedEntry?
SeqC ZCP2C EOL
SeqC Feed ZIn FeedEnt EOL
ELSE
SeqC ZIn EOL
END
END
SeqC SubCall CallLab EOL
IF FirstCycle?
AutoCycCutSub1 {save substatus at Z depth}
AutoCycCutSub2 {goes to ZCP2}
ELSE
IF NOT FeedConnect?
TrackZNo# ClearancePlane2#
END
END
NextRep
SeqC
IF NOT MultipleParts?
AbsOrInc
END
RapidC ZCP2C EOL
SeqC EndSub EOL
CloseSub
SetFlagF('2')
IF NOT FeedConnect?
SetStatusRapid
END
RETURN

SetDrillEndOpZ:
IF RetractToCP1?
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
RETURN

SkipToLastFeat:
EachFeat
IF LastFeat?
TrackXNO# SPX#
TrackYNO# SPY#
END
NextFeat
RETURN

DrillStuff:
GetCycle
SeqC Cycle FromCP
{ZDepth outputs incorrectly when in incremental and retract from 1st clearance plane}
{ZDepth# will only output absolute values}
IF MultipleParts? OR Repeats?
SetAbs
'Z' SUB# ZDepth# ClearancePlane2# {calculate incremental depth}
SetInc
ELSE
ZDepth
END
RLevel Dwell Peck Retract FeedEnt EOL
IF CallMasterOp?
SeqC SubCall CallLabB CallMasterNum# EOL
SkipToLastFeat
ELSE
TrackZNO# FIRST SPZ#
IF MasterOp?
NewMasterProg
SeqC SubCall CallLab EOL
StartSub
SeqC IncValue EOL
ToolPath
IF NOT Repeats? AND NOT MultipleParts?
SeqC AbsOrInc EOL
END
SeqC EndSub EOL
CloseSub
ELSE
ToolPath
END
END
SetDrillEndOpZ
RETURN

StdRep:
EachRep
IF FirstCycle?
SubWarning
EntryMove
SeqC SubCall CallLab EOL
StartSub
SetFlag('2') {set true, we are in a Repeats sub}
SeqC IncValue EOL
ToolPath
FinishSub1
SaveSubStatus
SeqC EndSub EOL
CloseSub
SetFlagF('2')
ELSE
SeqC CheckAbsOrInc Connect StrtPos EOL
IF FeedConnect?
SeqC ZinC EOL {takes care of different tool path start and end Z values}
ELSE
IF NOT Equal? ClearancePlane2# ClearancePlane3#
SeqC ZCP2 EOL
END
EntryMove
END
SeqC SubCall CallLab EOL
SetSRSubXYRC
SetSRSubZRC
END
NextRep
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

OpenSpindleCheck:
IF ToolOver?('30') {This Op in High Speed}
IF LAST NOT ToolOver?('30') {If Last Op was Normal Speed, need to setup High Speed Mode}
SetMaxRPM('60000')
Seq 'T30' ToolChng EOL
SeqC 'M41' EOL
END
SeqC 'M0' EOL
ELSE {This Op in Normal Speed}
SetMaxRPM('6000')
SeqC OpToolID ToolChng EOL
END
RETURN

CloseSpindleCheck:
IF NOT ToolOver?('30') AND LAST ToolOver?('30') {Changing from High Speed to Normal Speed Mode}
SeqC 'M40' EOL
END
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('6000')
SetMaxFeed('500')
IF PSComment? AND UseComments?
'PostScript:' EOL
' Literals: put between single or double quotes.' EOL
' Separate commands and literals with at least one space.' EOL
' A CR ( RETURN key ) will start a new line.' EOL
' Commands: may be capital and/or lower case letters. Separate commands with a space.' EOL
' EndOP -' EOL
' all literals and commands before an ENDOP command' EOL
' will appear at the beginning of the operation. All ' EOL
' literals and commands after an ENDOP command will appear' EOL
' at the end of the operation. ' EOL
' NewWFO(56), NWFO(56) -' EOL
' The Work Fixture Offset # you specify will be used for all following operations.' EOL
' Do not use with the ncPost multiple part option.' EOL
' 4thAxisCW(12.5), 4ACW(12.5) -' EOL
' generates a + A move of the value you specify' EOL
' 4thAxisCCW(22.5), 4ACCW(22.5) -' EOL
' generates a - A move of the value you specify' EOL
' 5thAxisCW(30), 5ACW(30) -' EOL
' generates a + B move of the value you specify' EOL
' 5thAxisCCW(22.5), 5ACCW(22.5) -' EOL
' generates a - B move of the value you specify' EOL
END
EachOp {Start of post processing *********************}
IF FirstOperation?
EOR EOL
ProgID1
IF UseComments? AND ProgramNameComment?
'( ' ProgramName$ ' )'
END
EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramComment?
'( ' ProgramComment$ ' )' EOL
END
IF FormatNameComment?
'( FORMAT: ' FormatName$ ' )' EOL
END
IF TimeComment?
'( ' Date$ ' AT ' Time$ ' )' EOL
END
IF MovesComment?
'( OUTPUT IN ' MoveType$ ' INCHES )' EOL
END
IF PartsComment?
'( PARTS PROGRAMMED: ' Parts# ' )' EOL
END
IF StartToolComment?
'( FIRST TOOL NOT IN SPINDLE )' EOL
END
END
OpenSub
RestoreScale
CheckPass
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
Seq Rapid Plane CRCOff 'G49G52G61G80' AbsOrInc 'Z0' SpinOff EOL
IF ToolOver?('30')
SetMaxRPM('60000')
SeqC OpToolID ToolChng EOL
SeqC 'M41' EOL
SeqC 'M00' EOL
ELSE
SetMaxRPM('6000')
SeqC OpToolID EOL
SeqC ToolChng EOL
END
DoPostScript
DoOpComments
SeqC Plane 'G80' CRCOffC EOL
WFOStuff
SeqC Speed SpinOn EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
ELSE
SeqC CheckAbsOrInc Rapid StrtPos EOL
END
SeqC OfstOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
CloseSpindleCheck
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC 'G49' EOL { OfstOff }
CloseMP
END
SeqC Rapid Plane CRCOff 'G49G52G61G80' AbsOrInc 'Z0' SpinOff EOL
SeqC 'G28X0Y0' EOL { Allows Tool to clear part and fixturing }
DoEndOpPS
IF ToolChangeAtHome?
SeqC CheckAbsOrInc Rapid Home EOL
END
IF LAST ProgStop?
SeqC 'M0' EOL
ELSE
SeqC ProgStop EOL
END

{Start new Operation}

Seq OpenSpindleCheck
DoPostScript
DoOpComments
SeqC Plane 'G80' CRCOffC EOL
WFOStuff
SeqC Speed SpinOn EOL
CheckPass
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
ELSE
SeqC CheckAbsOrInc Rapid StrtPos EOL
END
SeqC OfstOn EOL
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
END
ELSE
IF SameTool?

{Finish off last Operation}

IF LAST ProgStop? OR NewToolOffset?
IF MultipleParts?
SeqC OfstOff EOL {we are in incremental, output G28Z0}
SeqC 'G49' EOL {we did not cancel the offset}
ELSE
SeqC 'G49Z0' EOL {we are in absolute, output G49Z0, also cancels offset}
END
END
DoEndOpPS
IF LAST ProgStop?
SeqC 'G28X0Y0' EOL { Allows Tool to clear part and fixturing }
SeqC 'M0' EOL
END

{Start new Operation}

DoOpComments
DoPostScript
WFOStuff
CheckPass
SeqC Speed SpinOn EOL
SeqC PlaneC CheckAbsOrInc Rapid StrtPos EOL
SeqC OfstOn EOL
END
END
END {common point for all operations}
IF Milling?
SeqC ZCP2C EOL
IF Repeats?
NewProg
IF AutoCycle?
IF ZshiftOnly?
RepZOnlyAutoCycle
ELSE
RepAutoCycle
END
ELSE {not AutoCycle}
StdRep
END {end Auto Cycle IF}
ELSE {no repeat OPs}
NoReps
END
SeqC CheckAbsOrInc
IF AutoCycle?
ZCP3C EOL
ELSE
IF FIFO? {.81}
FeedC CRCOffC ZCP3C FeedEntC EOL
ELSE
RapidC CRCOffC ZCP3C EOL
END
END
ELSE
IF Drilling?
IF Repeats?
NewProg
EachRep
IF FirstCycle?
DrillClearancePlane
SeqC SubCall CallLab EOL
StartSub
SetFlag('2') {set true, we are in a Repeats sub}
SeqC IncValue EOL
DrillStuff
SeqC
IF NOT MultipleParts?
AbsOrInc
END
DrillOff ZCP3 EOL
SaveSubStatus
SeqC EndSub EOL
CloseSub
SetFlagF('2')
ELSE
SeqC Rapid StrtPos EOL
IF RetractToCP1?
IF NOT Equal? ClearancePlane3# ClearancePlane1#
SeqC 'Z' ClearancePlane1# EOL {ZCP1 does not output in incremental}
END
ELSE
SeqC ZCP2C EOL
END
SeqC SubCall CallLab EOL
SetSRSubXYRC
SetSRSubZRC
END
NextRep
ELSE
DrillClearancePlane
DrillStuff
SeqC DrillOff ZCP3 EOL
END
SeqC RapidC ZCP3C EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
SeqC 'G49' EOL { OfstOff }
CloseMP
END
SeqC Rapid CRCOff 'G49G52G61G80' AbsOrInc 'Z0' SpinOff EOL
SeqC 'G28X0Y0' EOL { Allows Tool to clear part and fixturing }
CloseSpindleCheck
DoEndOpPS
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqC CheckAbsOrInc Rapid FirstHome EOL
END
IF ProgStop?
SeqC 'M0' EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqC EOP EOL
CloseSub
Post2 {organize Subs into one program}
EOR EOL
Close
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'( FILE LENGTH: ' FileBytes# ' CHARACTERS )' EOL
END
IF FileFeetComment?
'( FILE LENGTH: ' FileFeet# ' FEET )' EOL
END
IF FileMetersComment?
'( FILE LENGTH: ' FileMeters# ' METERS )' EOL
END
Close
END