{Change Comments ***********************************************************}

{12/23/93
Copied & modified: Dynapath 20M M074.80.1
For: Rayco
Versions: ncCad 4.32/ncCam 4.32/ncPost 4.32.01/Compost4.21.19
Changes made per service call to Brian at Rayco.
Changed FORMAT for address T from '#0' to '00' in Mach Spec Default Format Dialog.
Added FORMAT#7 '00' for NewWFO# ToolOffset# in Prog.
Added ToolOffset# to Prog FORMATs.
Changed ToolOfst to OpToolID ToolOffset# at FirstOperation and NewTool.
Added OpToolID ToolOffset# at SameTool for LAST ProgStop and NewToolOffset condition.
Moved call to WFOStuff to OpToolID block at FirstOperation and NewTool.
Moved call to WFOStuff to OpToolID block at SameTool for LAST ProgStop and NewToolOffset condition.
Added condition to call WFOStuff only when needed at last SameTool branch.
Added Rapid at StrtPos at FirstOperation and NewTool.
Added literal 'E00' prior to EOP at end of prog.
DWB}

{1/3/94
Customer did not approve G-Code output of Dynapath 20M M617.80.2, requested Conversational.
Copied & modified: Dynapath 20M Convrs M312.80.1
For: Rayco
Versions: ncCad 4.32/ncCam 4.32/ncPost 4.32.01/Compost4.21.19
Changes made per service call to Brian at Rayco.
Made same changes per 12/23/93.
Changed FORMAT for addresses E and M from '#0' to '00' in Mach Spec Default Format Dialog.
Added Flag(2) to suppress double M30 for non subprogram output at end of Prog.
Will SetFlag(2) IF MultipleParts = TRUE or Repeats or AutoCycle = TRUE for any Operation.
Will output second M30 at end of output if Flag(2) = TRUE.
Changed Progam# to ProgramComment$ at FirstOperation.
Changed StartToolComment to FIRST TOOL IN Spindle at FirstOperation Program Comments.
Added UnTool FIRST ToolOffset# to ToolChng block at end of prog when needed.
Deleted PreTool ToolOfst from SpinOn block at FirstOperation and NewTool.
Moved CoolOn prior to StrtPos block at FirstOperation and NewTool.
Deleted excess CoolOn output per 8/91 comments at FirstOperation and NewTool.
Added condition to suppress Speed at SameTool.
Added SpinOff when M0 and ProgStop is not output at NewTool.
Added SpinOff at end of Prog.
Moved 'E00' to ToolChng block at end of prog.
DWB}

{1/5/94
Modified: Dynapath 20M Conv[RB] M617.80.3
For: Gibbs & Associates/Rayco B
Versions: ncCad 4.32/ncCam 4.32/ncPost 4.32.01/Compost4.21.19
Updated to Version 4.2 per Fanuc 6M M001.81.2c Format.
Added IF FIFO? for Milling.
Added TrackZNO# FIRST SPZ# at IF Drilling? section to allow for conditionality of MoveSXYZC command.
Moved UnSkipZ from FinishSub1 to ZOnlyRep where SkipZ is set.
Added RestoreScale Sub per 4-Axis Post Processor.
NOTE: Did not add CRCOffC per version 4.2.
Processor already cancels CRC after LastFeat at end of ToolPath.
Added WorkFixtureOffsets for MultipleParts at OpenMP and CloseMP subs.
Added condition to suppress ZCP2 when not needed at IF Milling.
DWB}

{3/8/95
Copied & modified: Dynapath 20M Conv[RB] M617.81.2
Versions Used: ComPost 4.21.26 / Virtual 2.14.30c
For: CNCCS / Micron
Control: Dynapath Delta 20
Machine: 425 Tree
Added percent sign, EOR, to beginning of program.
Changed 'END' to percent sign, EOR, at end of program.
Changed format of sequence numbers to 4 fixed integers.
Combined spindle WFO and tool on one line.
OpToolID sets the length and diameter offsets.
Deleted collant comands. Coolant is operated manually.
Suppressed output of StrtPos and ZCP1 for Drilling operations, its redundent.
Changed PropStop argument in NewTool to ToolChng, its a manual tool change machine!.
Deleted SpinOff and tool change lines from end of program.
Drilling with RetractToCP1 requires manually postioning to ZCP1 and recalling the cycle.
Jim Radcliffe}

{3/295
Copied & modified: Dynaoath Delta 20 M00G.81.2
For: CNCCS / SP Precision
Control: Dynapath Delta 20
Machine: Tree Master Jouryman 425
Added SpinOff at tool change and end of program.
Jim Radcliffe}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '###.#;0'
#7 = '00'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(SPX#,4)
FORMAT(SPY#,4)
FORMAT(Retract#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}
FORMAT(NewWFO#,7) {.72}
FORMAT(ToolOffset#,7)

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

Get$:
IF NOT EmptyLine?
'$'
END
RETURN

DoSubComment:
NewProg
IF UseComments? AND SubComment?
SeqLab '(T) SUB NUMBER ' Program# Get$ EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLab '(T) OPERATION ' Operation# ' ' OperationType$ Get$ EOL
END
IF OperationComment?
SeqLab '(T) ' OperationComment$ Get$ EOL
END
IF WorkGroupComment?
SeqLab '(T) ' WorkGroupComment$ Get$ EOL
END
IF ToolTypeComment?
SeqLab '(T) TOOL# ' Tool# ' ' ToolDiameter# ' ' ToolType$ Get$ EOL
END
IF ToolComment?
SeqLab '(T) ' ToolComment$ Get$ EOL
END
RestoreScale
END
RETURN

PSInit: {reset flags}
NewWFOF
RotateF
RETURN

PSStuff: {revised.72}
{No Rotate stuff for this post}
RETURN

DoPostScript:
PSInit
EachPS
SeqLab PostScript Get$ EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS Get$ EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLab '(1)' ZIn
IF AutoCycle?
'/'
END
FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZIn
IF AutoCycle?
'/'
END
Get$ EOL
END
RETURN

StartSub:
OpenSub
DoSubComment
'>' Tag# EOL
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
SeqLab '(T) ' Get$ EOL
SeqLab '(T) *** WARNING ***' Get$ EOL
SeqLab '(T) Z CLEARANCE WILL' Get$ EOL
SeqLab '(T) CHANGE WITH EACH' Get$ EOL
SeqLab '(T) CYCLE OF SUB!' Get$ EOL
SeqLab '(T) ' Get$ EOL
END
END
RETURN

StdSub:
'È' Tag# EOL
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
SeqLab '(6)FÇ' Tag# 'T' RepsLess1 Get$ EOL
StartSub
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
IF AutoCycle?
SeqLab '(0)' ZCP3 Get$ EOL
ELSE
IF FIFO? {.81}
SeqLab '(1)' ZCP3 FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZCP3 Rapid Get$ EOL
END
END
END
RETURN

FinishSubG92: {part 2}
SeqLab '(0)' ShiftRC Preset Get$ EOL
'<' Tag# EOL
TagDown
CloseSub
SeqLab '(0)' UnshftRC Preset Get$ EOL
RETURN

OpenMP:
IF WorkFixtureOffsets?
NewWFO
EachWFO
SeqLab '(9)' SetWFO Get$ EOL
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
IncWFO
NextWFO
ELSE
TagUp TagInc
'È' Tag# EOL
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
SeqLab '(6)FÇ' Tag# 'T' PartsLess1 Get$ EOL
END
StartSub
RETURN

CloseMP:
IF WorkFixtureOffsets?
CloseSub
SeqLab '(9)' WFO1 Get$ EOL
ELSE
SeqLab '(0)' ShiftPC Preset Get$ EOL
'<' Tag# EOL
TagDown
CloseSub
SeqLab '(0)' UnshftPC Preset Get$ EOL
END
RETURN

GetPlane:
IF XYPlane?
IF NOT AutoCycle?
IF FirstFeat?
IF XMove? OR YMove?
'P0' { This is the default Plane select }
END
END
END
ELSE
IF XZPlane?
'P2'
ELSE {YZPlane}
'P1'
END
END
RETURN

CheckMove:
IF AutoCycle?
IF XMove?
MoveX '/'
END
IF YMove?
MoveY '/'
END
IF ZMove?
MoveZ '/'
END
ELSE
MoveXYZC
END
RETURN

FormatArc:
GetPlane CheckMove
IF AutoCycle?
ArcI '/' ArcJ '/'
ELSE
ArcIJ
END
IF ArcCW?
CWArc
ELSE
CCWArc
END
RETURN

TurnOnCRC:
IF CutterRadiusCompensation? AND NOT Flag?('1')
SetFlag('1')
SeqLab '(1)'
IF AutoCycle?
'X' SPX# '/Y' SPY# '/'
ELSE
'X' SPX# 'Y' SPY#
END
CRCOff Get$ EOL
END
RETURN

TurnOffCRC:
IF CutterRadiusCompensation? AND Flag?('1')
SeqLab '(1)'
IF AutoCycle?
MoveX '/' MoveY '/'
ELSE
MoveXY
END
CRCOff Get$ EOL
END
RETURN

StdLine: {enables CRC on first call, .70}
TurnOnCRC
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab '(1)' GetPlane CheckMove CRCOnC FeedRateC Get$ EOL
DecelMove2
END
SeqLab '(1)' GetPlane CheckMove CRCOnC DecelFeed Get$ EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLab '(1)' GetPlane CheckMove CRCOnC FeedRateC Get$ EOL
END
END
RETURN

DrillCycle:
Dwell Peck
IF PeckChipBreaker?
'/Q' Retract#
END
FeedEnt Cycle
RETURN

ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
IF AutoCycle?
IF NOT FirstFeat?
SeqLab '(0)' MoveSXYC Get$ EOL
END
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF NOT FirstFeat?
IF RetractToCP1?
SeqLab '(0)' ZCP1 Rapid Get$ EOL
SeqLab '(0)' MoveSXYC RLevel MoveSZ DrillCycle Get$ EOL
ELSE
SeqLab '(0)' MoveSXYZC Get$ EOL {.80.01}
END
END
END
ELSE
IF RapidFeat?
IF CutterRadiusCompensation? AND Flag?('1')
IF XMove? OR YMove? OR ZMove?
SeqLab '(1)' GetPlane CheckMove RapidFC Get$ EOL
END
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLab '(0)' GetPlane CheckMove Get$ EOL
END
END
ELSE
IF LineFeat?
IF AutoCycle? {.70}
IF ZMove? {skip CRCOn until first non-Z move line, skipping ramps}
SeqLab '(1)' CheckMove FeedRateC Get$ EOL
ELSE
StdLine {enables CRC on first call}
END
ELSE
StdLine
END
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab '(2)' FormatArc ArcFeedC Get$ EOL
DecelMove2
END
SeqLab '(2)' FormatArc DecelFeed Get$ EOL
ELSE
SeqLab '(2)' FormatArc ArcFeedC Get$ EOL
END
NEXTQuadrant
END
END
END
IF LastFeat?
TurnOffCRC
END
END
NEXTFeat
RETURN

WFOStuff:
IF NewWFO?
IF MultipleParts?
Get$ EOL
SeqLab '(T) ' Get$ EOL
SeqLab '(T) *** WARNING ***' Get$ EOL
SeqLab '(T) DO NOT USE' Get$ EOL
SeqLab '(T) NEWWFO() WITH' Get$ EOL
SeqLab '(T) NCPOST MULTIPLE' Get$ EOL
SeqLab '(T) PARTS!' Get$ EOL
SeqLab '(T) ' Get$ EOL
ELSE
'E' NewWFO#
END
ELSE
IF NOT SameTool?
IF NeedWFO1?
'E' NewWFO#
END
END
END
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SetInc
SeqLab '(1)' 'P0X0./Y0./' Get$ EOL { AutoCycle dummy move to select correct Plane }
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SetAbs
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
SeqLab '(1)' ZCP2 FeedEnt Get$ EOL {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
SeqLab '(0)' ZCP2 Rapid Get$ EOL {.71.2 removed CRCOffC, gets turned off in ToolPath}
END
END
'<' Tag# EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagUp TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
TagDown
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
IF FeedConnect?
SeqLab '(1)' StrtPos Get$ EOL
ELSE
SeqLab '(0)' StrtPos Get$ EOL
END
Milling
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagUp TagInc
EachCycle
IF FeedConnect?
SeqLab '(1)' ZInPlusInc FeedEnt Get$ EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqLab '(0)' ZCP2PlusInc Get$ EOL {.69 added Rapid, reads better}
{can't call for cycle = 1, .69 changed to ZCP2PlusInc}
END
SeqLab '(1)' ZInPlusInc FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZInPlusInc Get$ EOL {.69 added Rapid, reads better}
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqLab '(1)' ZCP2 FeedEnt Get$ EOL {.69}
ELSE
SeqLab '(0)' ZCP2 Rapid Get$ EOL {.69}
END
END {.69}
TagDown
'<' Tag# EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
IF FeedConnect? {.71.2, added Connect}
SeqLab '(1)' StrtPos Get$ EOL
ELSE
SeqLab '(0)' StrtPos Get$ EOL
END
END
IF FeedConnect?
SeqLab '(1)' ZInPlusInc FeedEnt Get$ EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLab '(0)' ZCP2PlusInc Get$ EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLab '(1)' ZInPlusInc FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZInPlusInc Get$ EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
NextCycle
StartSub
SkipZ
ToolPath
UnSkipZ { Moved from FinishSub1 }
FinishSub1
'<' Tag# EOL
TagDown
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

CheckRapid:
IF NOT AutoCycle?
IF Repeats?
IF FeedConnect?
Rapid
END
ELSE
Rapid
END
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
InitWFONum
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls ('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetAbs
SetFlagF('2') { SubPrograms require 2nd M30 at end }
IF MultipleParts?
SetFlag('2')
END
IF PSComment? AND UseComments?
SeqLab '(T) PostScript:' Get$ EOL
SeqLab '(T) Literals: put between single or double quotes.' Get$ EOL
SeqLab '(T) Separate commands and literals with at least one space.' Get$ EOL
SeqLab '(T) A CR ( RETURN key ) will start a new line.' Get$ EOL
SeqLab '(T) Commands: may be capital and/or lower case letters. Separate commands with a space.' Get$ EOL
SeqLab '(T) EndOP -' Get$ EOL
SeqLab '(T) all literals and commands before an ENDOP command' Get$ EOL
SeqLab '(T) will appear at the beginning of the operation. All' Get$ EOL
SeqLab '(T) literals and commands after an ENDOP command will appear' Get$ EOL
SeqLab '(T) at the end of the operation.' Get$ EOL
SeqLab '(T) NewWFO(56), NWFO(56) -' Get$ EOL
SeqLab '(T) The Work Fixture Offset # you specify will be used for all following operations.' Get$ EOL
SeqLab '(T) Do not use with the ncPost multiple part option.' Get$ EOL
SeqLab '(T) 4thAxisCW(12.5), 4ACW(12.5) -' Get$ EOL
SeqLab '(T) generates a + A move of the value you specify' Get$ EOL
SeqLab '(T) 4thAxisCCW(22.5), 4ACCW(22.5) -' Get$ EOL
SeqLab '(T) generates a - A move of the value you specify' Get$ EOL
SeqLab '(T) 5thAxisCW(30), 5ACW(30) -' Get$ EOL
SeqLab '(T) generates a + B move of the value you specify' Get$ EOL
SeqLab '(T) 5thAxisCCW(22.5), 5ACCW(22.5) -' Get$ EOL
SeqLab '(T) generates a - B move of the value you specify' Get$ EOL
END
EachOp {Start of post processing *********************}
SetFlagF('1') { Flag to set-up CutterRadiusCompensation }
Plane { no output }
IF FirstOperation?
EOR EOL
'(' ProgramComment$ ')' Get$ EOL
IF ToolChangeAtHome?
SetHome
END
IF UseComments?
IF ProgramNameComment?
SeqLab '(T) PROGRAM ' ProgramName$ Get$ EOL
END
IF FormatNameComment?
SeqLab '(T) FORMAT ' FormatName$ Get$ EOL
END
IF TimeComment?
SeqLab '(T) ' Date$ ' AT ' Time$ Get$ EOL
END
IF MovesComment?
SeqLab '(T) OUTPUT IN ABSOLUTE INCHES' Get$ EOL
END
IF PartsComment?
SeqLab '(T) PARTS PROGRAMMED ' Parts# Get$ EOL
END
IF StartToolComment?
SeqLab '(T) FIRST TOOL IN SPINDLE' Get$ EOL
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
DoPostScript
SeqLab '(9)' SpinOn OpToolID WFOStuff Speed Get$ EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
IF Milling?
SeqLab '(0)' StrtPos Rapid Get$ EOL
SeqLab '(0)' ZCP1 Get$ EOL
END
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
IF Milling?
SeqLab '(0)' StrtPos Rapid Get$ EOL
END
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqLab '(9)' SpinOff Get$ EOL
SeqLab '(9)' ToolChng Get$ EOL

{Start new Operation}

DoOpComments
DoPostScript
SeqLab '(9)' SpinOn OpToolID WFOStuff Speed Get$ EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
IF Milling?
SeqLab '(0)' StrtPos Rapid Get$ EOL
SeqLab '(0)' ZCP1 Get$ EOL
END
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
IF Milling?
SeqLab '(0)' StrtPos Rapid Get$ EOL
END
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLab '(9)' SpinOff Get$ EOL
SeqLab '(9)' 'M0' Get$ EOL

{Start new Operation}

GetStartOfSameTool
SeqLab '(9)' SpinOn OpToolID WFOStuff Speed Get$ EOL
IF Milling?
SeqLab '(0)' StrtPos Rapid Get$ EOL
SeqLab '(0)' ZCP1 Get$ EOL
END
ELSE
IF NewToolOffset?

{Start new Operation}

GetStartOfSameTool
SeqLab '(9)' OpToolID WFOStuff
IF NotEqual? SpeedRPM# LAST SpeedRPM#
Speed
END
Get$ EOL
IF Milling?
SeqLab '(0)' StrtPos Rapid Get$ EOL
SeqLab '(0)' ZCP1 Get$ EOL
END
ELSE

{Start new Operation}

GetStartOfSameTool
SeqLab
IF NewWFO?
'(9)' WFOStuff
END
IF NotEqual? SpeedRPM# LAST SpeedRPM#
IF EmptyLine?
'(9)'
END
Speed
END
Get$ EOL
IF Milling?
SeqLab '(0)' StrtPos Rapid Get$ EOL
END
END
END
END
END
END {common point for all operations}
IF Repeats? OR AutoCycle?
SetFlag('2') { SubPrograms require 2nd M30 at end }
END
IF Milling?
LoadFeat Num#('0') Num#('0') ClearancePlane2#
IF ZMove?
SeqLab '(0)' ZCP2 Get$ EOL
END
IF Repeats?
TagUp TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLab '(0)' ZCP3 Get$ EOL
ELSE
IF FIFO? {.81}
SeqLab '(1)' ZCP3 FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZCP3 CheckRapid Get$ EOL
END
END
ELSE
IF Drilling?
IF Repeats?
TagUp TagInc
StdSub
SeqLab '(0)' StrtPos Get$ EOL
END
GetCycle
SeqLab '(0)' StrtPos RLevel ZDepth DrillCycle Get$ EOL
TrackZNO# FIRST SPZ# {.81.2}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
IF Repeats?
FinishSubG92
END
SeqLab '(0)' ZCP3 Rapid Get$ EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqLab '(9)' SpinOff Get$ EOL
IF MultipleParts? AND AllToolsOnePart?
SeqLab '(9)' ToolChng Get$ EOL
CloseMP
END
SeqLab '(9)' EOP Get$ EOL
CloseSub
Post2 {organize Subs into one program}
IF Flag?('2') { SubPrograms exist }
SetFlagF('2')
SeqLab '(9)' EOP Get$ EOL { This is required a second time, at end of all subs }
END
EOR EOL
Close
ReTag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'N9997(T) FILE LENGTH: ' FileBytes# ' CHARACTERS' Get$ EOL
END
IF FileFeetComment?
'N9998(T) FILE LENGTH: ' FileFeet# ' FEET' Get$ EOL
END
IF FileMetersComment?
'N9999(T) FILE LENGTH: ' FileMeters# ' METERS' Get$ EOL
END
Close
END