{Change Comments ***********************************************************}

{5/26/88
Modified: Dynapath Sys 10M M078.53.
NOTE: This Post Processor doesn't support incremental output.
Deleted all blank spaces.
Modified Drill Cycles.
JR}

{6/22/88
Modified: Dynapath Sys 10M M078.54.
Modified Feed moves to 1 decimal place.
Control requires that first line of program have Prog# in parentheses.
JR}

{10/24/89
Modified: Dynapath Sys 10M M078.55
For: Schobers
Added GearRange.
Added 'END' at end of prog to terminate Communications.
Moved CoolOn to line before SpinOn.
JR}

{11/29/89
Modified: Dynapath Sys 10M M078.56
Modified FormatArc subroutine to use standard format.
Add '/Q' and changed Retract to Retract# in ToolPath IF PeckChipBreaker = TRUE.
Modified Feed to FeedC in ToolPath.
NOTE: ReverseXZArcs has no effect on literals.
JR}

{7/24/90, Added InitProg globally to posts with this remark, DWB}
{8/31/90, Updated: Dynapath 10M (SM) M262.63 to .76.1 format,JR}

{11/2/90
Modified: Dynapath 10M M078.76.1
For: Gibbs & Associates
Made much needed corrections.
DWB}

{4/16/91
Copied & modified: Dynapath 10M M
For: Gibbs & Associates
Machine:
Control: Dynapath 10M
Updated to Version 4.0 per Fanuc 6M M001.80 Format.
Made major modifications per conversation with Dale Bachman at Dynapath Systems, Inc.
This processor is totally conversational.
NOTE: This Post Processor does not support WorkFixtureOffsets.
Added Flag('1') to check if CRCOn (C1) has been output.
CutterRadiusCompensation rules:
CRCOn (C1) must only be activated when Feed (1) or CWArc/CCWArc (2) are active.
Control requires CRCOff (C0) DummyMove on line preceeding CRCOn (C1).
Added logic to output SPX# SPY# CRCOff (C0) in TurnOnCRC Sub.
Rapid (0) must NOT be output while CRCOn (C1) is active.
When RapidFeat, CutterRadiusCompensation and Flag('1') are TRUE:
Added logic to output FeedC (1) MoveXYZC RapidFC (F199.1) in ToolPath.
RapidFC set to output F199.1 in Mach Spec.
Control requires CRCOff (C0) DummyMove when cancelling CRCOn (C1).
Added logic to output MoveXY CRCOff (C0) in TurnOffCRC Sub.
DWB}

{1/26/95
Updated: Dynapath 10M M078.80
For: Gibbs & Associates/Dickman Enterprises Inc.
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.04/Compost 4.21.25
Updated to Version 4.2 per Fanuc 6M M001.81.2f Format.
Corrected FORMAT5 from '########;0' to '#######0'.
Added RestoreScale Sub per 4-Axis Post Processor.
Moved UnSkipZ from FinishSub1 to ZOnlyRep where SkipZ is set.
Added FIFO? at FinishSub1, AutoCycCutSub2, ZonlyRepAutoCycle subs and end of IF Milling.
Added Variable Drill Depths.
Added TrackZNO# FIRST SPZ# at IF Drilling? section to allow for conditionality of MoveSXYZC command.
NOTE: Did not update CRC per version 4.2 due to complexity of current handling.
DWB}

{1/31/95
Copied: Dynapath 10M M078.81.2
Created: Dynapath 10AM [DE] M742.81.2
For: Dickman Enterprises Inc.
Machine:
Control: DynaPath System 10 MDI
Versions: ncCad 4.33/ncCAM 4.33/ncPost 4.33.04/Compost 4.21.25
Versions: Catalyst v2.14.24C/Catalyst v2.14.24PPC/Compost 4.21.25
Changes made per Jim Dickman of Dickman Enterprises Inc.
Deleted Program# at FirstOperation.
Added logic to output WorkGroupComment, ToolTypeComment and ToolComment for FirstOperation and
NewTool only, not SameTool.
Commented out ProgramComment, FormatNameComment, MovesComment, PartsComment and StartToolComment
at FirstOperation.
Added logic to output all Repeat subprograms in Incremental.
Added StartPosX# and StartPosY# to Format#4 at Prog Numeric Format Definitions.
Added condition to test for Repeats at EntryMove and CheckMove subs.
Added SetInc just prior to 'X' StartPosX# '/Y' StartPosY# '/' block at G92Sub.
Added SetAbs just after RETURNing from Milling Sub at G92Sub.
Added SetInc just prior to calling ToolPath Sub at ZonlyRep.
Added SetAbs just after RETURNing from ToolPath Sub at ZonlyRep.
Deleted GetPlane sub.
Added P0, P1 and P2 to XYPlane, YZPlane and XZPlane fields in Mach Spec.
Added Plane command to StrtPos block at FirstOperation.
Added PlaneC command to StrtPos block at NewTool and SameTool.
Changed Absolute Arc Centers to Incremental Arc Centers.
Set Use Absolute Arc Centers to FALSE in Mach Spec Booleans Dialog.
Added literal '/' code to ArcI ArcJ at FormatArc.
Modified handling of Coolant control.
Deleted CheckCoolantOn sub.
Moved CoolOn and CoolOff to standard places.
Deleted all GearRange output.
Added literal 'T0', for OfstOff, at NewTool, SameTool and end of Prog.
Modified CutterRadiusCompensation.
Currently, CutterRadiusCompensation is activated by first outputting a dummy, non-move block to
cancel any active CRC. CRCOn is then output on next LineFeat block. After output of LastFeat,
another dummy, non-move block is output to cancel CRC.
Added CkCRC sub to do this.
New method just outputs CRCOn prior to FirstFeat on block by itself, and output CRCOffC just after
output of LastFeat on block by itself.
DWB}

{2/14/95
Modified: Dynapath 10AM [DE] M742.81.2
For: Dickman Enterprises Inc.
Versions: Catalyst v2.14.30C/Catalyst v2.14.30PPC/Compost 4.21.27
Changes made per Jim Dickman of Dickman Enterprises Inc.
Added GetPlane sub back in, see notes of 1/31/95.
Customer reported that Plane output on StrtPos block is not allowed because this is an event(0),
positioning, block, and Plane must only appear on either event(1), linear, or event(2), arc, block.
DWB}

{Prog Numeric Format Definitions *******************************************}

#1 = '#.00'
#2 = '###.###;0.'
#3 = '*###.###;0.'
#4 = '####.####;0.'
#5 = '#######0'
#6 = '###.#;0'

FORMAT(FileFeet#,1)
FORMAT(FileMeters#,1)
FORMAT(StartPosX#,4)
FORMAT(StartPosY#,4)
FORMAT(SPX#,4)
FORMAT(SPY#,4)
FORMAT(Retract#,4)
FORMAT(ToolDiameter#,4) {.72}
FORMAT(Program#,5) {.72}
FORMAT(Operation#,5) {.72}
FORMAT(Tool#,5) {.72}
FORMAT(Parts#,5) {.72}
FORMAT(Dwell#,6) {.72}

{Prog Subroutines **********************************************************}

RestoreScale:
IF Metric? {CAM file is in Metric, tools and tool path}
SetScale('.03937007874') { change to English, this is an English post}
END
RETURN

Get$:
IF NOT EmptyLine?
'$'
END
RETURN

DoSubComment:
NewProg
IF UseComments? AND SubComment?
SeqLab '(T) SUB NUMBER ' Program# Get$ EOL
END
RETURN

DoOpComments:
IF UseComments?
SetScale('1')
IF OperationIDComment?
SeqLab '(T) OPERATION ' Operation# ' ' OperationType$ Get$ EOL
END
IF OperationComment?
SeqLab '(T) ' OperationComment$ Get$ EOL
END
IF FirstOperation? OR NewTool?
IF WorkGroupComment?
SeqLab '(T) ' WorkGroupComment$ Get$ EOL
END
IF ToolTypeComment?
SeqLab '(T) TOOL# ' Tool# ' ' ToolDiameter# ' ' ToolType$ Get$ EOL
END
IF ToolComment?
SeqLab '(T) ' ToolComment$ Get$ EOL
END
END
RestoreScale
END
RETURN

PSInit: {reset flags}
RotateF
RETURN

PSStuff: {revised.72}
IF FourthCW?
FORMAT(FourthDegree#,2)
SeqLab '(0)' 'A' FourthDegree# Get$ EOL
FourthCWF {reset flag}
END
IF FourthCCW?
FORMAT(FourthDegree#,3)
SeqLab '(0)' 'A' FourthDegree# Get$ EOL
FourthCCWF {reset flag}
END
IF FifthCW?
FORMAT(FifthDegree#,2)
SeqLab '(0)' 'B' FifthDegree# Get$ EOL
FifthCWF {reset flag}
END
IF FifthCCW?
FORMAT(FifthDegree#,3)
SeqLab '(0)' 'B' FifthDegree# Get$ EOL
FifthCCWF {reset flag}
END
RETURN

DoPostScript:
PSInit
EachPS
SeqLab PostScript Get$ EOL {literals}
PSStuff {commands}
NextPS
RETURN

DoEndOpPS:
PSInit
EachEOPS
SeqLab EndOpPS Get$ EOL {literals}
PSStuff {commands}
NextPS
RETURN

EntryMove:
IF FeedEntry?
SeqLab '(1)' ZIn
IF AutoCycle? OR Repeats?
'/'
END
FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZIn
IF AutoCycle? OR Repeats?
'/'
END
Get$ EOL
END
RETURN

StartSub:
OpenSub
DoSubComment
'>' Tag# EOL
RETURN

SubWarning:
IF NOT FeedConnect?
IF AnyZshift?
SeqLab '(T) ' Get$ EOL
SeqLab '(T) *** WARNING ***' Get$ EOL
SeqLab '(T) Z CLEARANCE WILL' Get$ EOL
SeqLab '(T) CHANGE WITH EACH' Get$ EOL
SeqLab '(T) CYCLE OF SUB!' Get$ EOL
SeqLab '(T) ' Get$ EOL
END
END
RETURN

StdSub:
'È' Tag# EOL
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
SeqLab '(6)FÇ' Tag# 'T' RepsLess1 Get$ EOL
StartSub
RETURN

FinishSub1: {part 1}
IF NOT FeedConnect?
IF AutoCycle?
SeqLab '(0)' ZCP3 Get$ EOL
ELSE
IF FIFO? {.81}
SeqLab '(1)' ZCP3 FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZCP3 Rapid Get$ EOL
END
END
END
RETURN

FinishSubG92: {part 2}
SeqLab '(0)' ShiftRC Preset Get$ EOL
'<' Tag# EOL
TagDown
CloseSub
SeqLab '(0)' UnshftRC Preset Get$ EOL
RETURN

OpenMP:
TagUp TagInc
'È' Tag# EOL
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
SeqLab '(6)FÇ' Tag# 'T' PartsLess1 Get$ EOL
StartSub
RETURN

CloseMP:
SeqLab '(0)' ShiftPC Preset Get$ EOL
'<' Tag# EOL
TagDown
CloseSub
SeqLab '(0)' UnshftPC Preset Get$ EOL
RETURN

GetPlane:
IF XYPlane?
IF NOT AutoCycle?
IF FirstFeat?
IF XMove? OR YMove?
'P0' { This is the default Plane select }
END
END
END
ELSE
IF XZPlane?
'P2'
ELSE {YZPlane}
'P1'
END
END
RETURN

CheckMove:
IF AutoCycle? OR Repeats?
IF XMove?
MoveX '/'
END
IF YMove?
MoveY '/'
END
IF ZMove?
MoveZ '/'
END
ELSE
MoveXYZC
END
RETURN

FormatArc:
GetPlane CheckMove ArcI '/' ArcJ '/'
IF ArcCW?
CWArc
ELSE
CCWArc
END
RETURN

CkCRC: { 4.2 }
IF CutterRadiusCompensation? AND NOT Flag?('1')
IF XMove? OR YMove?
SetFlag('1')
SeqLab '(1)' CRCOn Get$ EOL
END
END
RETURN

StdLine: {enables CRC on first call, .70}
IF Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab '(1)' GetPlane CheckMove FeedRateC Get$ EOL
DecelMove2
END
SeqLab '(1)' GetPlane CheckMove DecelFeed Get$ EOL
ELSE
IF XMove? OR YMove? OR ZMove?
SeqLab '(1)' GetPlane CheckMove FeedRateC Get$ EOL
END
END
RETURN

ToolPath:
ResetCRCNum {.72}
EACHFeat
IF PointFeat?
IF AutoCycle?
IF NOT FirstFeat?
SeqLab '(0)' MoveSXYC Get$ EOL
END
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
CalcACSRXY {calc tool position after sub call, CalcAutoCycleStatusRecordXY}
ELSE
IF NOT FirstFeat?
SeqLab '(0)' MoveSXYZC Get$ EOL
END
END
ELSE
CkCRC
IF RapidFeat?
IF XMove? OR YMove? OR ZMove?
SeqLab '(0)' CheckMove Get$ EOL
END
ELSE
IF LineFeat?
StdLine
ELSE
IF ArcFeat?
EACHQuadrant { Do not use NOT, FIRST, LAST or NEXT modifiers in this loop }
IF LastQuadrant? AND Decelerate?
IF RoomToDecel?
DecelMove1
SeqLab '(2)' FormatArc ArcFeedC Get$ EOL
DecelMove2
END
SeqLab '(2)' FormatArc DecelFeed Get$ EOL
ELSE
SeqLab '(2)' FormatArc ArcFeedC Get$ EOL
END
NEXTQuadrant
END
END
END
IF LastFeat? AND CutterRadiusCompensation? AND Flag?('1')
SetFlagF('1')
SeqLab '(1)' CRCOff Get$ EOL
END
END
NEXTFeat
RETURN

WFOStuff:
{ NOTE: This Post Processor doesn't support incremental output. }
RETURN

AutoCycCutSub1: {part 1}
SaveSubStatus {save tool position}
SetPass1 {element cut moves}
StartSub
SetSRXYtoSP
SetInc
RETURN

AutoCycCutSub2: {part 2}
ToolPath
SetAbs
IF Repeats? AND FeedConnect? AND ZshiftOnly?
{.69 removed RapidC} {.71.2 removed CRCOffC, gets turned off in ToolPath}
ELSE
IF FIFO? {.81}
SeqLab '(1)' ZCP2 FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZCP2 Rapid Get$ EOL
END
END
'<' Tag# EOL
CloseSub
SetSRSubXY {restore SR to 1st position value}
SetSRSubMove
RETURN

AutoCycPat:
SetPass2 {position pattern}
ToolPath {call after NewProg for correct sub calls}
SetPass1 {reset}
RETURN

Milling:
IF AutoCycle?
TagUp TagInc
AutoCycCutSub1
EntryMove
AutoCycCutSub2
AutoCycPat
TagDown
ELSE
EntryMove
ToolPath
END
RETURN

G92Sub:
SubWarning
StdSub
SetInc
SeqLab
IF FeedConnect?
'(1)'
ELSE
'(0)'
END
'X' StartPosX# '/Y' StartPosY# '/' Get$ EOL
Milling
SetAbs
FinishSub1
FinishSubG92
RETURN

ZonlyRepAutoCycle:
AutoCycPat {write pattern moves and main calls}
StartSub
TagUp TagInc
EachCycle
IF FeedConnect?
SeqLab '(1)' ZInPlusInc FeedEnt Get$ EOL
ELSE
IF FeedEntry?
IF NOT FirstCycle?
SeqLab '(0)' ZCP2PlusInc Get$ EOL {.69 added Rapid, reads better}
{can't call for cycle = 1, .69 changed to ZCP2PlusInc}
END
SeqLab '(1)' ZInPlusInc FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZInPlusInc Get$ EOL {.69 added Rapid, reads better}
END
END
IF FirstCycle?
SetStatusOff {protect Z position for incremental sub}
END
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
NextCycle
SetStatusOn
AutoCycCutSub1 {build element sub}
AutoCycCutSub2
{.69, removed FinishSub1}
IF FeedConnect? {there is no Z up in the sub, .69}
IF FIFO? {.81}
SeqLab '(1)' ZCP2 FeedEnt Get$ EOL {.69}
ELSE
SeqLab '(0)' ZCP2 Rapid Get$ EOL {.69}
END
END {.69}
TagDown
'<' Tag# EOL
CloseSub
{Element shift, not pattern}
RETURN

ZonlyRep:
EachCycle
IF NOT FirstCycle?
SeqLab
IF FeedConnect? {.71.2, added Connect}
'(1)'
ELSE
'(0)'
END
StrtPos Get$ EOL
END
IF FeedConnect?
SeqLab '(1)' ZInPlusInc FeedEnt Get$ EOL {.71.2, changed to FeedC}
ELSE {Entry/Exit Connect}
IF FeedEntry?
IF NOT FirstCycle?
SeqLab '(0)' ZCP2PlusInc Get$ EOL {can't call for cycle =1} {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
SeqLab '(1)' ZInPlusInc FeedEnt Get$ EOL
ELSE
SeqLab '(0)' ZInPlusInc Get$ EOL {.69 added Rapid, reads better} {.71.2, changed to RapidC, reads better}
END
END
SeqLab '(7)FÅ‚' Tag# 'L²' Tag# Get$ EOL
NextCycle
StartSub
SetInc
SkipZ
ToolPath
UnSkipZ { Moved from FinishSub1 }
SetAbs
FinishSub1
'<' Tag# EOL
TagDown
CloseSub
RETURN

CheckPass:
IF AutoCycle? {use the correct StrtPos}
SetPass2
ELSE
SetPass1
END
RETURN

GetStartOfSameTool:
DoOpComments
DoPostScript
CheckPass
RETURN

{Start of executable Prog **************************************************}

{setup and initializations}
InitProg
ReverseXZArcs
SetFlood
UseSeparateSubCalls
SetMaxSeparateSubCalls('50')
SetMaxRPM('10000')
SetMaxFeed('500')
SetAbs
IF PSComment? AND UseComments?
SeqLab '(T) PostScript:' Get$ EOL
SeqLab '(T) Literals: put between single or double quotes.' Get$ EOL
SeqLab '(T) Separate commands and literals with at least one space.' Get$ EOL
SeqLab '(T) A CR ( RETURN key ) will start a new line.' Get$ EOL
SeqLab '(T) Commands: may be capital and/or lower case letters. Separate commands with a space.' Get$ EOL
SeqLab '(T) EndOP -' Get$ EOL
SeqLab '(T) all literals and commands before an ENDOP command' Get$ EOL
SeqLab '(T) will appear at the beginning of the operation. All' Get$ EOL
SeqLab '(T) literals and commands after an ENDOP command will appear' Get$ EOL
SeqLab '(T) at the end of the operation.' Get$ EOL
SeqLab '(T) NewWFO(56), NWFO(56) -' Get$ EOL
SeqLab '(T) The Work Fixture Offset # you specify will be used for all following operations.' Get$ EOL
SeqLab '(T) Do not use with the ncPost multiple part option.' Get$ EOL
SeqLab '(T) 4thAxisCW(12.5), 4ACW(12.5) -' Get$ EOL
SeqLab '(T) generates a + A move of the value you specify' Get$ EOL
SeqLab '(T) 4thAxisCCW(22.5), 4ACCW(22.5) -' Get$ EOL
SeqLab '(T) generates a - A move of the value you specify' Get$ EOL
SeqLab '(T) 5thAxisCW(30), 5ACW(30) -' Get$ EOL
SeqLab '(T) generates a + B move of the value you specify' Get$ EOL
SeqLab '(T) 5thAxisCCW(22.5), 5ACCW(22.5) -' Get$ EOL
SeqLab '(T) generates a - B move of the value you specify' Get$ EOL
END
EachOp {Start of post processing *********************}
SetFlagF('1') { Flag to set-up CutterRadiusCompensation }
Plane { no output }
IF FirstOperation?
IF ToolChangeAtHome?
SetHome
END
IF XYPlane?
SetHome
ELSE
END
IF UseComments?
IF ProgramNameComment?
SeqLab '(T) PROGRAM ' ProgramName$ Get$ EOL
END
IF ProgramComment?
{SeqLab '(T) ' ProgramComment$ Get$ EOL}
END
IF FormatNameComment?
{SeqLab '(T) FORMAT ' FormatName$ Get$ EOL}
END
IF TimeComment?
SeqLab '(T) ' Date$ ' AT ' Time$ Get$ EOL
END
IF MovesComment?
{SeqLab '(T) OUTPUT IN ABSOLUTE INCHES' Get$ EOL}
END
IF PartsComment?
{SeqLab '(T) PARTS PROGRAMMED ' Parts# Get$ EOL}
END
IF StartToolComment?
{SeqLab '(T) FIRST TOOL IN SPINDLE' Get$ EOL}
END
END
OpenSub
RestoreScale
IF MultipleParts? AND AllToolsOnePart?
OpenMP
END
DoOpComments
DoPostScript
SeqLab '(9)' SpinOn ToolOfst Speed Get$ EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab '(0)' StrtPos ZCP1 Rapid Get$ EOL
IF NOT CoolOff?
SeqLab '(9)' CoolOn Get$ EOL
END
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab '(0)' StrtPos Rapid Get$ EOL
END
ELSE
IF NewTool?

{Finish off last Operation}

IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLab '(9)' CoolOff Get$ EOL
SeqLab '(9)' 'T0' Get$ EOL { OfstOff }
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
IF LAST ProgStop?
SeqLab '(9)' 'M0' Get$ EOL
ELSE
IF OptionalStops?
SeqLab '(9)' ProgStop Get$ EOL
END
END

{Start new Operation}

SeqLab '(9)' ToolChng Get$ EOL
DoOpComments
DoPostScript
SeqLab '(9)' SpinOn ToolOfst Speed Get$ EOL
IF MultipleParts? AND OneToolAllParts? AND FullUp?
OpenMP
END
CheckPass
SeqLab '(0)' StrtPos ZCP1 Rapid Get$ EOL
IF NOT CoolOff?
SeqLab '(9)' CoolOn Get$ EOL
END
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
OpenMP
SeqLab '(0)' StrtPos Rapid Get$ EOL
END
ELSE
IF SameTool?
DoEndOpPS
IF LAST ProgStop?
SeqLab '(9)' CoolOff Get$ EOL
SeqLab '(9)' 'T0' Get$ EOL { OfstOff }
SeqLab '(9)' 'M0' Get$ EOL

{Start new Operation}

GetStartOfSameTool
SeqLab '(9)' SpinOn ToolOfst Speed Get$ EOL
SeqLab '(0)' StrtPos ZCP1 Rapid Get$ EOL
IF NOT CoolOff?
SeqLab '(9)' CoolOn Get$ EOL
END
ELSE
IF CoolOff? AND LAST NOT CoolOff?
SeqLab '(9)' CoolOff Get$ EOL
END
IF NewToolOffset?
SeqLab '(9)' 'T0' Get$ EOL { OfstOff }

{Start new Operation}

GetStartOfSameTool
SeqLab '(9)' ToolOfst Speed Get$ EOL
SeqLab '(0)' StrtPos ZCP1 Rapid Get$ EOL
ELSE

{Start new Operation}

GetStartOfSameTool
SeqLab '(9)' Speed Get$ EOL
SeqLab '(0)' StrtPos Rapid Get$ EOL
END
IF NOT CoolOff? AND LAST CoolOff?
SeqLab '(9)' CoolOn Get$ EOL
END
END
END
END
END {common point for all operations}
IF Milling?
SeqLab '(0)' ZCP2 Get$ EOL
IF Repeats?
TagUp TagInc
IF ZshiftOnly?
IF AutoCycle? {incremental Autocycle sub can have Z moves}
ZonlyRepAutoCycle
ELSE {Z shift only, NOT Auto Cycle}
IF UseSeparateSubCalls? AND CyclesLessThanMaxSubCalls?
FindAnyZMoves {for normal abs subroutine}
IF NoZMoves?
ZonlyRep
ELSE
G92Sub {pattern shift, not element}
END
ELSE {no sep subs desired}
G92Sub
END
END {end Auto Cycle IF}
ELSE {not Z only}
G92Sub
END {end Z only IF}
ELSE {no repeat OPs}
Milling
END
IF AutoCycle?
SeqLab '(0)' ZCP3 Get$ EOL
ELSE
IF FIFO? {.81}
SeqLab '(1)' ZCP3 FeedEntC Get$ EOL
ELSE
SeqLab '(0)' ZCP3 RapidC Get$ EOL
END
END
ELSE
IF Drilling?
IF Repeats?
TagUp TagInc
StdSub
SeqLab '(0)' StrtPos Get$ EOL
END
IF NOT RetractToCP1?
SeqLab '(0)' ZCP2 Get$ EOL
END
GetCycle
SeqLab '(0)' StrtPos RLevel ZDepth Dwell Peck
IF PeckChipBreaker?
'/Q' Retract#
END
FeedEnt Cycle Get$ EOL
TrackZNO# FIRST SPZ# {.81.2}
ToolPath
IF RetractToCP1? {.81}
TrackZNO# ClearancePlane1#
ELSE
TrackZNO# ClearancePlane2#
END
IF Repeats?
FinishSubG92
END
SeqLab '(0)' ZCP3 Rapid Get$ EOL
END
END
NextOp {loops back to EachOP until last Operation}

{End of program ************************************************************}

{finish last operation}
IF MultipleParts? AND OneToolAllParts? AND ExitClearancePlane?
CloseMP
END
SeqLab '(9)' CoolOff Get$ EOL
SeqLab '(9)' 'T0' Get$ EOL { OfstOff }
IF MultipleParts? AND OneToolAllParts? AND FullUp?
CloseMP
END
DoEndOpPS
SeqLab '(9)' ToolChng Get$ EOL
IF FIRST ToolChangeAtHome? {.71.2 added FIRST modifier}
SeqLab '(0)' FirstHome Get$ EOL
END
IF ProgStop?
SeqLab '(9)' 'M0' Get$ EOL
END
IF MultipleParts? AND AllToolsOnePart?
CloseMP
END
SeqLab '(9)' EOP Get$ EOL
CloseSub
Post2 {organize Subs into one program}
SeqLab '(9)' EOP Get$ EOL { This is required a second time, at end of all subs }
'END' EOL
Close
ReTag
IF UseComments?
SetScale('1') {restore scale for comments}
Reopen
IF FileBytesComment?
'N9997(T) FILE LENGTH: ' FileBytes# ' CHARACTERS' Get$ EOL
END
IF FileFeetComment?
'N9998(T) FILE LENGTH: ' FileFeet# ' FEET' Get$ EOL
END
IF FileMetersComment?
'N9999(T) FILE LENGTH: ' FileMeters# ' METERS' Get$ EOL
END
Close
END